configure.in

   1 dnl
   2 dnl Configure.in file for the Midnight Commander
   3 dnl
   4
   5 AC_INIT([GNU Midnight Commander], [], [mc-devel@gnome.org])
   6 AC_PREREQ(2.52)
   7 AC_CONFIG_SRCDIR(src/main.c)
   8 AC_CONFIG_AUX_DIR(config)
   9 AM_INIT_AUTOMAKE(mc, 4.6.0-pre1b)
  10
  11 AM_CONFIG_HEADER(config.h)
  12 AM_MAINTAINER_MODE
  13
  14 AC_CANONICAL_HOST
  15
  16 AC_AIX
  17 AC_MINIX
  18 AC_ISC_POSIX
  19
  20 AC_PROG_CC_STDC
  21
  22 dnl
  23 dnl Check if the user requested to compile with glib 2.x.  If not, use
  24 dnl glib 1.2.x.  This check should be kept close to the beginning, as it
  25 dnl fails for the users without any glib.
  26 dnl
  27 AC_ARG_WITH(glib2, [  --with-glib2             Use glib 2.x [[no]]])
  28
  29 if test "x$with_glib2" = "xyes" ; then
  30         PKG_CHECK_MODULES(GLIB, "glib-2.0")
  31 else
  32         dnl This temporary variable is a workaround for a bug in Autoconf-2.53
  33         glib_path=$PATH:/usr/local/bin
  34
  35         dnl Klugde for FreeBSD, where glib-config is renamed to glib12-config.
  36         AC_PATH_PROGS([GLIB_CONFIG], [glib-config glib12-config],,[$glib_path])
  37
  38         AC_ARG_VAR([GLIB_CONFIG], [Path to glib-config (version 1.2.x only)])
  39         AM_PATH_GLIB(1.2.6,,[AC_MSG_ERROR([Test for glib failed.
  40 GNU Midnight Commander requires glib 1.2.6 or above.])])
  41 fi
  42
  43
  44 AC_HEADER_MAJOR
  45 AC_C_CONST
  46 AC_SYS_LARGEFILE
  47
  48 AC_PROG_LN_S
  49 AC_CHECK_TOOL(AR, ar, ar)
  50
  51 dnl Only list browsers here that can be run in background (i.e. with `&')
  52 AC_CHECK_PROGS(X11_WWW, [gnome-moz-remote mozilla konqueror opera netscape])
  53
  54 dnl
  55 dnl Ovverriding mmap support.  This has to be before AC_FUNC_MMAP is used.
  56 dnl We use only part of the functionality of mmap, so on AIX,
  57 dnl it's possible to use mmap, even if it doesn't pass the autoconf test.
  58 dnl
  59 AC_ARG_WITH(mmap,
  60         [  --with-mmap              Force using the mmap call (only useful on AIX)],
  61         [case $withval in
  62 yes)
  63         ac_cv_func_mmap_fixed_mapped=yes
  64         AC_MSG_NOTICE([forcing MMAP support])
  65         ;;
  66 no)
  67         ac_cv_func_mmap_fixed_mapped=no
  68         AC_MSG_NOTICE([disabling MMAP support])
  69         ;;
  70 esac])
  71 AC_FUNC_MMAP
  72
  73 ALL_LINGUAS="az be bg ca cs da de el es es_ES eu fi fr hu it ja ko lv \
  74 nl no pl pt pt_BR ro ru sk sl sv uk ta tr wa zh_CN zh_TW"
  75
  76 dnl
  77 dnl Internationalization
  78 dnl
  79 AM_GNU_GETTEXT
  80 AM_GNU_GETTEXT_VERSION(0.11.5)
  81
  82 if test "x$USE_INCLUDED_LIBINTL" = xyes; then
  83     CPPFLAGS="$CPPFLAGS -I\$(top_builddir)/intl -I\$(top_srcdir)/intl"
  84 fi
  85
  86 dnl
  87 dnl Hack to make extraconf.h visible even if compiling outside srcdir.
  88 dnl
  89 CPPFLAGS="$CPPFLAGS -I\$(top_srcdir)"
  90
  91 dnl
  92 dnl Enforce coding standards
  93 dnl
  94 if test "x$GCC" = xyes; then
  95     CFLAGS="$CFLAGS -Wall"
  96 fi
  97
  98 dnl
  99 dnl OS specific flags.
 100 dnl
 101
 102 posix_libs=""
 103 case $host_os in
 104 aux*)
 105     # A/UX
 106     posix_libs="-lposix"
 107     AC_DEFINE(_POSIX_SOURCE)
 108     ;;
 109 sco*)
 110     AC_DEFINE(SCO_FLAVOR, 1, [Define if you want to turn on SCO-specific code])
 111     AC_DEFINE(_SVID3, 1, [Needs to be defined on SCO])
 112     ;;
 113 esac
 114
 115 AC_PROG_INSTALL
 116 AC_CHECK_HEADERS([unistd.h string.h memory.h crypt.h grp.h limits.h \
 117         malloc.h stdlib.h termios.h utime.h fcntl.h pwd.h sys/statfs.h \
 118         sys/time.h sys/timeb.h sys/select.h sys/ioctl.h stropts.h \
 119         arpa/inet.h])
 120
 121 AC_HEADER_TIME
 122 AC_HEADER_SYS_WAIT
 123 AC_HEADER_DIRENT
 124 AC_HEADER_STDC
 125
 126 dnl Missing structure components
 127 AC_STRUCT_ST_BLKSIZE
 128 AC_STRUCT_ST_BLOCKS
 129 AC_STRUCT_ST_RDEV
 130
 131 dnl
 132 dnl Check availability of some functions
 133 dnl
 134
 135 AC_CHECK_FUNCS([strerror statfs strftime \
 136                 memmove pwdauth truncate initgroups putenv \
 137                 memset memcpy tcsetattr tcgetattr cfgetospeed \
 138                 sigaction sigemptyset sigprocmask sigaddset \
 139                 sysconf setuid setreuid telldir seekdir])
 140
 141 dnl
 142 dnl getpt is a GNU Extension (glibc 2.1.x)
 143 dnl
 144 AC_CHECK_FUNCS(getpt)
 145
 146
 147 dnl
 148 dnl On SCO and some SVR4, crypt is on libcrypt.a
 149 dnl         grantpt in  libpt.a
 150 dnl
 151 LCRYPT=""
 152 AC_CHECK_FUNCS(crypt, , [
 153     AC_CHECK_LIB(crypt, crypt, [LCRYPT="-lcrypt"], [
 154         AC_CHECK_LIB(crypt_i, crypt, [LCRYPT="-lcrypt_i"])])])
 155 AC_SUBST(LCRYPT)
 156
 157 AC_CHECK_FUNCS(grantpt, , [AC_CHECK_LIB(pt, grantpt)])
 158
 159 dnl replacing lstat with statlstat on sco makes it more portable between
 160 dnl sco clones
 161 AC_CHECK_FUNCS(statlstat)
 162
 163 dnl
 164 dnl If running under AIX, AC_AIX does not tell us that
 165 dnl
 166 AC_MSG_CHECKING([for AIX defines])
 167 AC_EGREP_CPP(yes,
 168 [#if defined(AIX) || defined(_AIX) || defined(__aix__) || defined(aix)
 169 yes
 170 #endif
 171 ], [
 172 AC_DEFINE(IS_AIX, 1, [Define if compiling for AIX])
 173 AC_MSG_RESULT(yes)
 174 ], [AC_MSG_RESULT(no)])
 175
 176 dnl
 177 dnl This is from GNU fileutils, check aclocal.m4 for more information
 178 dnl
 179 AC_GET_FS_INFO
 180
 181 dnl
 182 dnl Missing typedefs and replacements
 183 dnl
 184
 185 AC_TYPE_MODE_T
 186 AC_CHECK_TYPE(umode_t, int)
 187 AC_CHECK_TYPE(off_t, long)
 188 AC_TYPE_PID_T
 189 AC_TYPE_UID_T
 190 AC_CHECK_TYPE(nlink_t, unsigned int)
 191
 192 AC_FUNC_ALLOCA
 193 AC_FUNC_STRCOLL
 194
 195 dnl
 196 dnl X11 support.
 197 dnl
 198
 199 textmode_x11_support="no"
 200 AC_ARG_WITH(tm-x-support,
 201         [  --with-tm-x-support      Get keyboard events from X Window System [[no]]],
 202         [if test x$withval = xyes; then
 203                 AC_PATH_XTRA
 204                 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 205                 MCLIBS="$X_LIBS $X_PRE_LIBS -lX11 $X_EXTRA_LIBS"
 206                 AC_DEFINE(HAVE_TEXTMODE_X11_SUPPORT, 1,
 207                           [Define to enable getting events from X Window System])
 208                 textmode_x11_support="yes"
 209         fi
 210 ])
 211
 212 dnl
 213 dnl Network related functions
 214 dnl
 215
 216 AC_CHECK_LIB(nsl, t_accept)
 217 AC_CHECK_LIB(socket, socket)
 218
 219 have_socket=no
 220 AC_CHECK_FUNCS(socket, have_socket=yes)
 221 if test $have_socket = no; then
 222   # socket is not in the default libraries.  See if it's in some other.
 223   for lib in bsd socket inet; do
 224     AC_CHECK_LIB($lib, socket, [
 225         LIBS="$LIBS -l$lib"
 226         have_socket=yes
 227         AC_DEFINE(HAVE_SOCKET)
 228         break])
 229   done
 230 fi
 231
 232 have_gethostbyname=no
 233 AC_CHECK_FUNC(gethostbyname, [have_gethostbyname=yes])
 234 if test $have_gethostbyname = no; then
 235   # gethostbyname is not in the default libraries.  See if it's in some other.
 236   for lib in bsd socket inet; do
 237     AC_CHECK_LIB([$lib], [gethostbyname],
 238                  [LIBS="$LIBS -l$lib"; have_gethostbyname=yes; break])
 239   done
 240 fi
 241
 242 AC_CHECK_FUNCS(socketpair)
 243
 244 dnl
 245 dnl Sequent wants getprocessstats
 246 dnl
 247 AC_CHECK_LIB(seq, get_process_stats, [
 248         LIBS="$LIBS -lseq"
 249         AC_DEFINE(HAVE_GET_PROCESS_STATS, 1,
 250                   [Define if you have function `get_process_stats' and
 251 have to use that instead of gettimeofday])])
 252
 253 MC_VFS_CHECKS
 254
 255 vfs_type="normal"
 256 if test x$use_vfs = xyes; then
 257         AC_MSG_NOTICE([enabling VFS code])
 258         vfs_type="Midnight Commander Virtual File System"
 259 fi
 260
 261 dnl This should be unadorned "slang" or "ncurses"
 262 screen_type=""
 263
 264 dnl Screen manager name (for the output only)
 265 screen_manager=unknown
 266
 267 mouse_lib="xterm only"
 268 case $host_os in
 269 linux*)
 270     AC_ARG_WITH(gpm-mouse,
 271         [  --with-gpm-mouse[[=base-dir]]  Compile with gpm mouse support (Linux only)
 272                                [[yes if found]]],
 273         [if test x$withval != xno
 274         then
 275                 if test x$withval != xyes
 276                 then
 277                         LDFLAGS="$LDFLAGS -L$withval/lib"
 278                         CPPFLAGS="$CPPFLAGS -I$withval/include"
 279                 fi
 280                 AC_DEFINE(HAVE_LIBGPM, 1,
 281                           [Define to enable gpm mouse support on Linux])
 282                 mouse_lib="GPM and xterm"
 283                 MCLIBS="-lgpm $MCLIBS"
 284         fi],
 285         [AC_CHECK_LIB(gpm, Gpm_Repeat,
 286                 [AC_DEFINE(HAVE_LIBGPM)
 287                 mouse_lib="GPM and xterm"
 288                 MCLIBS="-lgpm $MCLIBS"],
 289                 [AC_MSG_WARN([libgpm is missing or older than 0.18])],
 290                 [$LIBS])
 291         ])
 292     ;;
 293 esac
 294
 295 AC_ARG_WITH(ncurses,
 296         [  --with-ncurses[[=base-dir]]    Compile with ncurses [[no]]],
 297 [if test x$withval != xno; then
 298         if test x$withval != xyes; then
 299                 LDFLAGS="$LDFLAGS -L$withval/lib"
 300                 CPPFLAGS="$CPPFLAGS -I$withval/include"
 301         fi
 302
 303         AC_CHECK_HEADERS([ncurses/curses.h ncurses.h curses.h],
 304                          [ncurses_h_found=yes; break])
 305         if test -z "$ncurses_h_found"; then
 306             AC_MSG_ERROR([Could not find ncurses header])
 307         fi
 308
 309         dnl curses_version is specific to ncurses, it's not in old curses
 310         AC_CHECK_LIB(ncurses, has_colors, [MCLIBS="$MCLIBS -lncurses"],
 311                      [AC_MSG_ERROR([Could not find ncurses library])])
 312
 313         screen_type="ncurses"
 314         screen_manager="ncurses"
 315         AC_DEFINE(USE_NCURSES, 1,
 316                   [Define to use ncurses for screen management])
 317 fi
 318 ])
 319
 320 dnl
 321 dnl Check for the -mandoc package
 322 dnl
 323 AC_CHECK_PROG(HAVE_nroff, nroff, true, false)
 324 if $HAVE_nroff; then
 325     AC_MSG_CHECKING([for manual formatting macros])
 326     AC_CACHE_VAL(ac_cv_mandoc, [
 327     nroff -mandoc < /dev/null > /dev/null 2>&1
 328     if test $? = 0
 329     then
 330         ac_cv_mandoc=-mandoc
 331     else
 332         ac_cv_mandoc=-man
 333     fi
 334     ])
 335     MANDOC=$ac_cv_mandoc
 336     AC_MSG_RESULT([$MANDOC])
 337 else
 338     MANDOC=-man
 339 fi
 340 AC_SUBST(MANDOC)
 341
 342 dnl
 343 dnl Check if nroff accepts -Tlatin1 or -Tascii
 344 dnl
 345 if $HAVE_nroff; then
 346     AC_MSG_CHECKING([if nroff accepts -Tlatin1 or -Tascii])
 347     AC_CACHE_VAL(ac_cv_nroff_tascii, [
 348     nroff -Tlatin1 < /dev/null > /dev/null 2>&1 /dev/null
 349     if test $? = 0
 350     then
 351         ac_cv_nroff_tascii=" -Tlatin1"
 352     else
 353         nroff -Tascii < /dev/null > /dev/null 2>&1 /dev/null
 354         if test $? = 0
 355         then
 356             ac_cv_nroff_tascii=" -Tascii"
 357         else
 358             ac_cv_nroff_tascii=""
 359         fi
 360     fi
 361     ])
 362     if test "x$ac_cv_nroff_tascii" = x; then
 363         AC_MSG_RESULT([no])
 364     else
 365         AC_MSG_RESULT([yes,$ac_cv_nroff_tascii])
 366     fi
 367 fi
 368 TROFFASCII="$ac_cv_nroff_tascii"
 369 AC_SUBST(TROFFASCII)
 370
 371 dnl
 372 dnl Check for - option to file
 373 dnl
 374 AC_CHECK_PROG(HAVE_FILECMD, file, true, false)
 375 if $HAVE_FILECMD; then
 376     AC_MSG_CHECKING([for - option to file command])
 377     AC_CACHE_VAL(ac_cv_filestdin, [[
 378     cat > conftest.c <<\EOF
 379 /* A comment */
 380 #if 0
 381 #endif
 382 void main(void)
 383 { return; }
 384 EOF
 385     cat > conftest.sed <<\EOF
 386 s/^[^:]*:[      ]*//
 387 s/[     ]*$//
 388 EOF
 389     filehyphen_1=`file conftest.c 2>/dev/null | sed -f conftest.sed`
 390     filehyphen_2=`cat conftest.c | file - 2>/dev/null | sed -f conftest.sed`
 391     if test "x$filehyphen_1" = "x$filehyphen_2"; then
 392         ac_cv_filestdin=yes
 393     else
 394         ac_cv_filestdin=no
 395     fi
 396     rm conftest.c conftest.sed
 397     ]])
 398
 399     if test x$ac_cv_filestdin = xyes; then
 400         AC_DEFINE(FILE_STDIN, 1,
 401                   [Define if the file command accepts - for stdin])
 402     fi
 403     filestdin=$ac_cv_filestdin
 404     AC_MSG_RESULT([$filestdin])
 405
 406     dnl
 407     dnl Check for -L option to file
 408     dnl
 409
 410 AC_MSG_CHECKING([for -L option to file command])
 411 AC_CACHE_VAL(ac_cv_filel, [
 412 file -L . > /dev/null 2>&1
 413 if test $? = 0
 414 then
 415     ac_cv_filel=yes
 416 else
 417     ac_cv_filel=no
 418 fi
 419 ])
 420 if test x$ac_cv_filel = xyes; then
 421     AC_DEFINE(FILE_L, 1, [Define if the file command accepts the -L option])
 422 fi
 423 filel=$ac_cv_filel
 424 AC_MSG_RESULT([$filel])
 425 fi
 426
 427
 428 AC_MSG_CHECKING([for subshell support])
 429 AC_ARG_WITH(subshell,
 430         [  --with-subshell          Compile in concurrent subshell [[yes]]
 431   --with-subshell=optional Don't run concurrent shell by default [[no]]],
 432         [result=no
 433         if test x$withval = xoptional
 434         then
 435                 AC_DEFINE(SUBSHELL_OPTIONAL, 1,
 436                           [Define to make subshell support optional])
 437                 result="optional"
 438         fi
 439         if test x$withval = xyes
 440         then
 441                 result="yes"
 442         fi],
 443         [dnl Default: enable the subshell support
 444         result="yes"
 445 ])
 446 if test "x$result" != xno; then
 447         AC_DEFINE(HAVE_SUBSHELL_SUPPORT, 1,
 448                   [Define to enable subshell support])
 449 fi
 450 AC_MSG_RESULT([$result])
 451 subshell="$result"
 452
 453 if test "x$screen_type" != xncurses; then
 454         slang_check_lib=true
 455         slang_term=""
 456         slang_use_system_installed_lib=false
 457         AC_CHECK_LIB(slang,SLang_init_tty,
 458                 [AC_CHECK_HEADERS([slang.h slang/slang.h],
 459                                   [slang_h_found=yes; break])
 460                 if test "x$slang_h_found" = xyes; then
 461                      slang_use_system_installed_lib=true
 462                      slang_check_lib=false
 463                 fi
 464         ])
 465 fi
 466
 467 AC_ARG_WITH(slang,
 468         [  --with-slang             Compile with S-Lang screen manager [[yes]]],
 469         [if test x$withval = xyes; then
 470                 AC_WITH_SLANG
 471         fi]
 472 )
 473
 474 AC_ARG_WITH(included-slang,
 475         [  --with-included-slang    Use S-Lang library included with mc sources
 476                            [[use installed library if found]]],
 477         [if test x$withval = xyes; then
 478             slang_use_system_installed_lib=false
 479             slang_check_lib=true
 480         fi]
 481 )
 482
 483 AC_ARG_WITH(termcap,
 484         [  --with-termcap           Same as above, and try using termcap database [[no]]],
 485         [if test x$withval = xyes; then
 486                 AC_USE_TERMCAP
 487                 slang_check_lib=false
 488                 slang_use_system_installed_lib=false
 489         fi]
 490 )
 491
 492
 493 dnl
 494 dnl Internal editor support.
 495 dnl
 496 AC_ARG_WITH(edit,
 497         [  --with-edit              Enable internal editor [[yes]]])
 498
 499 if test x$with_edit != xno; then
 500         AC_DEFINE(USE_INTERNAL_EDIT, 1, [Define to enable internal editor])
 501         use_edit=yes
 502         EDIT_msg="yes"
 503         AC_MSG_NOTICE([using internal editor])
 504 else
 505         EDIT_msg="no"
 506 fi
 507
 508
 509 if test $use_vfs = yes; then
 510     AC_ARG_WITH(ext2undel,
 511         [  --with-ext2undel         Compile with ext2 undelete code [[yes if found]]],
 512         [if test x$withval != xno; then
 513                 if test x$withval != xyes; then
 514                         LDFLAGS="$LDFLAGS -L$withval/lib"
 515                         CPPFLAGS="$CPPFLAGS -I$withval/include"
 516                 fi
 517                 AC_EXT2_UNDEL
 518         fi],[
 519         dnl Default: detect
 520         AC_CHECK_LIB(ext2fs, ext2fs_close, [AC_EXT2_UNDEL], , [-lcom_err])
 521     ])
 522 fi
 523
 524
 525 dnl Ncurses specific checks
 526 dnl
 527 dnl If ncurses exports the ESCDELAY variable it should be set to 0
 528 dnl or you'll have to press Esc three times to dismiss a dialog box.
 529 dnl
 530 if test "x$screen_type" = xncurses; then
 531   save_LIBS="$LIBS"
 532   LIBS="$MCLIBS $LIBS"
 533   AC_CACHE_CHECK([for ESCDELAY variable],
 534                  [mc_cv_ncurses_escdelay],
 535                  [AC_TRY_COMPILE([], [
 536                         extern int ESCDELAY;
 537                         int main ()
 538                         {
 539                           ESCDELAY = 0;
 540                         }
 541                         ],
 542                         [mc_cv_ncurses_escdelay=yes],
 543                         [mc_cv_ncurses_escdelay=no]
 544                   )
 545   ])
 546   if test "$mc_cv_ncurses_escdelay" = yes; then
 547     AC_DEFINE(HAVE_ESCDELAY, 1,
 548               [Define if ncurses has ESCDELAY variable])
 549   fi
 550
 551   AC_CHECK_FUNCS(resizeterm)
 552   LIBS="$save_LIBS"
 553 fi
 554
 555 if test "x$screen_type" = "x"; then
 556     AC_WITH_SLANG
 557 fi
 558
 559 dnl
 560 dnl The variables used for expanding the auto saver.
 561 dnl
 562 cons_saver=""
 563 install_saver="no"
 564 PAMLIBS=""
 565 case $host_os in
 566 linux*)
 567     cons_saver="cons.saver"
 568     install_saver="yes"
 569
 570     dnl
 571     dnl On Linux, check for PAM authentication available
 572     dnl
 573     AC_CHECK_LIB(pam, pam_start, [
 574         AC_DEFINE(HAVE_PAM, 1,
 575                   [Define if PAM (Pluggable Authentication Modules) is available])
 576         PAMLIBS="-lpam -ldl"
 577     ],[],[-ldl])
 578     ;;
 579 esac
 580 AC_SUBST(cons_saver)
 581 AC_SUBST(PAMLIBS)
 582
 583 dnl
 584 dnl User visible support for charset conversion.
 585 dnl
 586 AC_ARG_ENABLE([charset],
 587               [  --enable-charset         Support for charset selection and conversion [[no]]])
 588 have_charset=
 589 if test "x$enable_charset" = xyes; then
 590   if test "x$am_cv_func_iconv" != xyes; then
 591     AC_MSG_WARN([Cannot enable charset support because iconv function is missing])
 592   else
 593     AC_DEFINE(HAVE_CHARSET, 1,
 594               [Define to enable charset selection and conversion])
 595     have_charset=yes
 596   fi
 597 fi
 598
 599 if test "$GLIBC21" != yes; then
 600     AC_DEFINE(USE_INCLUDED_REGEX, 1, [Use the regex included here])
 601 fi
 602
 603 dnl
 604 dnl This code should be moved to the ac_WITH_SLANG
 605 dnl
 606 dnl We check for the existance of setupterm on curses library
 607 dnl this is required to load certain definitions on some termcaps
 608 dnl editions (AIX and OSF/1 I seem to remember).
 609 dnl Note that we avoid using setupterm
 610 if test "x$screen_type" = xslang; then
 611         case $host_os in
 612         linux*)
 613                 ;;
 614         *)
 615                 AC_CHECK_LIB(curses,setupterm,
 616                         [AC_TRY_COMPILE([
 617 #include <curses.h>
 618 #include <term.h>],[
 619    if (key_end == parm_insert_line)
 620         return 1;
 621    return 0;
 622 ],
 623                         [MCLIBS="$MCLIBS -lcurses"
 624                         AC_DEFINE(USE_SETUPTERM, 1,
 625                                   [Define to use function `setupterm'
 626 from `curses' library in S-Lang])])
 627                 ])
 628         esac
 629 fi
 630
 631 LIBS="$LIBS $posix_libs"
 632
 633 AC_SUBST(CFLAGS)
 634 AC_SUBST(CPPFLAGS)
 635 AC_SUBST(LDFLAGS)
 636 AC_SUBST(LIBS)
 637
 638 dnl Libraries used only when building the mc binary
 639 AC_SUBST(MCLIBS)
 640
 641 dnl Version for the RedHat package, without dashes
 642 RH_VERSION=`echo $VERSION | sed 's/-//'`
 643 AC_SUBST(RH_VERSION)
 644
 645 if test -n "$use_smbfs"; then
 646   AC_CONFIG_SUBDIRS([vfs/samba])
 647 fi
 648
 649 AM_CONDITIONAL(USE_EDIT, [test -n "$use_edit"])
 650 AM_CONDITIONAL(USE_VFS, [test "x$use_vfs" = xyes])
 651 AM_CONDITIONAL(USE_VFS_NET, [test x"$use_net_code" = xtrue])
 652 AM_CONDITIONAL(USE_UNDEL_FS, [test -n "$use_undelfs"])
 653 AM_CONDITIONAL(USE_SAMBA_FS, [test -n "$use_smbfs"])
 654 AM_CONDITIONAL(USE_MCFS, [test -n "$use_mcfs"])
 655 AM_CONDITIONAL(INCLUDED_SLANG,
 656                [test "x$slang_use_system_installed_lib" = xfalse])
 657 AM_CONDITIONAL(CHARSET, [test -n "$have_charset"])
 658 AM_CONDITIONAL(CONS_SAVER, [test -n "$cons_saver"])
 659
 660 AH_BOTTOM([#include <extraconf.h>])
 661
 662 AC_CONFIG_FILES([
 663 Makefile
 664 mc.spec
 665 doc/Makefile
 666 vfs/Makefile
 667 vfs/extfs/Makefile
 668 lib/Makefile
 669 src/Makefile
 670 slang/Makefile
 671 edit/Makefile
 672 syntax/Makefile
 673 pc/Makefile
 674 m4/Makefile
 675
 676 lib/mc.ext
 677 lib/mc.sh
 678 lib/mc.csh
 679
 680 vfs/extfs/deb
 681 vfs/extfs/ftplist
 682 vfs/extfs/lslR
 683 vfs/extfs/uar
 684 vfs/extfs/ucpio
 685 vfs/extfs/ulha
 686 vfs/extfs/uha
 687 vfs/extfs/urar
 688 vfs/extfs/uzoo
 689
 690 doc/mc.1 doc/mcedit.1 doc/mcserv.8
 691 doc/es/mc.1 doc/es/Makefile
 692 doc/hu/Makefile doc/hu/mc.hlp.hu
 693 doc/it/mc.1 doc/it/Makefile
 694 doc/pl/mc.1 doc/pl/Makefile
 695 doc/ru/mc.1 doc/ru/Makefile
 696
 697 intl/Makefile
 698 po/Makefile.in
 699 ])
 700
 701 AC_OUTPUT
 702
 703 if test "x$screen_type" = xslang; then
 704     screen_manager="${screen_manager}${slang_term}"
 705 fi
 706
 707 echo "
 708 Configuration:
 709
 710   Source code location:       ${srcdir}
 711   Compiler:                   ${CC}
 712   Compiler flags:             ${CFLAGS}
 713   File system:                ${vfs_type}
 714                               ${vfs_flags}
 715   Screen manager:             ${screen_manager}
 716   Install console saver:      ${install_saver}
 717   Mouse support:              ${mouse_lib}
 718   X11 events support:         ${textmode_x11_support}
 719   With subshell support:      ${subshell}
 720   Internal editor:            ${EDIT_msg}
 721   Install path:               ${prefix}/bin, ${prefix}/lib/mc
 722 "