CMakeLists.txt

   1 #  Copyright (c) 2008 Peter Kuemmel
   2 #  Copyright (c) 2008 Mauro Iazzi
   3 #
   4 #  Permission is hereby granted, free of charge, to any person
   5 #  obtaining a copy of this software and associated documentation
   6 #  files (the "Software"), to deal in the Software without
   7 #  restriction, including without limitation the rights to use,
   8 #  copy, modify, merge, publish, distribute, sublicense, and/or sell
   9 #  copies of the Software, and to permit persons to whom the
  10 #  Software is furnished to do so, subject to the following
  11 #  conditions:
  12 #
  13 #  The above copyright notice and this permission notice shall be
  14 #  included in all copies or substantial portions of the Software.
  15 #
  16 #  THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
  17 #  EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES
  18 #  OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND
  19 #  NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT
  20 #  HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY,
  21 #  WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  22 #  FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR
  23 #  OTHER DEALINGS IN THE SOFTWARE.
  24
  25 cmake_minimum_required(VERSION 2.6)
  26
  27 project(lqt)
  28
  29
  30 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY  ${CMAKE_BINARY_DIR}/bin)
  31 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY  ${CMAKE_BINARY_DIR}/lib)
  32 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY  ${CMAKE_BINARY_DIR}/lib)
  33
  34 find_package(Qt4 REQUIRED)
  35 set(QT_USE_QTCORE 1)
  36 set(QT_USE_QTGUI 1)
  37 set(QT_USE_QTNETWORK 1)
  38 set(QT_USE_QTWEBKIT 1)
  39 set(QT_USE_QTOPENGL 1)
  40 set(QT_USE_QTSCRIPT 1)
  41 set(QT_USE_QTSVG 1)
  42 set(QT_USE_QTUITOOLS 1)
  43 set(QT_USE_QTXML 1)
  44 set(QT_USE_QTSQL 1)
  45 set(QT_USE_QTXMLPATTERNS 1)
  46 include(${QT_USE_FILE})
  47
  48 if(noqt)
  49         set(QT_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/test)
  50         #set(nomerge TRUE)
  51 endif()
  52
  53 find_package(Lua51 REQUIRED)
  54 find_program(LUA_CMD NAMES lua lua5.1 lua51)
  55
  56 if(MSVC)
  57         set(CMAKE_SUPPRESS_REGENERATION TRUE)
  58         add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_SECURE_NO_WARNINGS -D_SCL_SECURE_NO_WARNINGS -DLUA_BUILD_AS_DLL /bigobj)
  59         set(CMAKE_DEBUG_POSTFIX)
  60 endif()
  61
  62 if(MINGW)
  63         set(CMAKE_SHARED_LINKER_FLAGS "-Wl,-add-stdcall-alias")
  64         SET(CMAKE_VERBOSE_MAKEFILE ON)
  65 endif()
  66
  67
  68 macro(lqt_files name folder)
  69         file(GLOB ${name}_sources ${folder}/*.cpp)
  70         file(GLOB ${name}_headers ${folder}/*.hpp)
  71         qt4_wrap_cpp(${name}_moc ${${name}_headers})
  72         qt4_automoc(${${name}_sources})
  73         set(${name}_src ${${name}_sources} ${${name}_moc})
  74         set(${name}_h ${${name}_headers})
  75         source_group(generated FILES ${${name}_moc})
  76         project_source_group("${GROUP_CODE}" ${name}_sources ${name}_headers)
  77 endmacro()
  78
  79
  80 # folders in the msvc projects
  81 # mode==flat  : headers and sources not in folders
  82 # mode==split : standard behavior of cmake, split headers and sources
  83 # mode==<other values> : code is in this folder
  84 macro(project_source_group mode sources headers)
  85         if(${mode} MATCHES "flat")
  86                 source_group("Source Files" Files)
  87                 source_group("Header Files" Files)
  88                 source_group("cmake" FILES CMakeLists.txt)
  89         else()
  90                 if(NOT ${mode} MATCHES "split")
  91                         source_group("${mode}" FILES ${${sources}} ${${headers}})
  92                 endif()
  93         endif()
  94 endmacro()
  95 set(GROUP_CODE "Source Files")
  96
  97
  98 add_subdirectory(cpptoxml)
  99
 100
 101 function(build_qt_lib_binding BINDING_HEADER)
 102
 103         string(TOLOWER ${BINDING_HEADER} BINDING_NAME)
 104
 105         # hardcoded in generator.lua
 106         set (LQT_GEN_DIR ${CMAKE_BINARY_DIR}/${BINDING_NAME}_src)
 107         file(MAKE_DIRECTORY ${LQT_GEN_DIR})
 108
 109         set (BINDING_SRC ${LQT_GEN_DIR}/${BINDING_NAME}_merged_build.cpp)
 110         set_source_files_properties(${BINDING_SRC} PROPERTIES  GENERATED TRUE)
 111
 112         if (UNIX)
 113                 set (PP_CONFIG ${CMAKE_SOURCE_DIR}/cpptoxml/parser/rpp/pp-qt-configuration)
 114         else()
 115                 set (PP_CONFIG ${CMAKE_SOURCE_DIR}/cpptoxml/parser/rpp/pp-qt-configuration-win)
 116         endif()
 117
 118         if(NOT REUSE_FILES)
 119                 set (GEN_XML ${LQT_GEN_DIR}/${BINDING_NAME}.xml)
 120                 add_custom_target(generate_${BINDING_NAME}_xml  COMMAND cpptoxml
 121                                                                 ${BINDING_HEADER}
 122                                                                 -C ${PP_CONFIG}
 123                                                                 -Q ${QT_INCLUDE_DIR}
 124                                                                 -o ${GEN_XML}
 125                                                         COMMENT "Generating XML: running cpptoxml on ${BINDING_NAME} "
 126                                                         VERBATIM)
 127
 128
 129                 math(EXPR MAX ${ARGC}-1)
 130                 if(MAX)
 131                         foreach(I RANGE 1 ${MAX})
 132                                 string(TOLOWER ${ARGV${I}} DEPNAME)
 133                                 set(${BINDING_NAME}_TYPES ${${BINDING_NAME}_TYPES} -t ${DEPNAME}_src/${DEPNAME}_types.lua)
 134                                 set(${BINDING_NAME}_DEPENDS ${${BINDING_NAME}_DEPENDS} generate_${DEPNAME}_cpp)
 135                         endforeach()
 136                 endif()
 137
 138                 add_custom_target(generate_${BINDING_NAME}_cpp
 139                                                         COMMAND ${LUA_CMD}
 140                                                                 "${CMAKE_SOURCE_DIR}/generator/generator.lua"
 141                                                                 ${GEN_XML}
 142                                                                 -i ${BINDING_HEADER} -i lqt_qt.hpp
 143                                                                 -n ${BINDING_NAME}
 144                                                                 -t ${CMAKE_SOURCE_DIR}/generator/qtypes.lua
 145                                                                 ${${BINDING_NAME}_TYPES}
 146                                                                 -f ${CMAKE_SOURCE_DIR}/generator/qt_internal.lua
 147                                                         COMMENT "Generating binding code with Lua"
 148                                                         VERBATIM)
 149         else()
 150                 add_custom_target(generate_${BINDING_NAME}_xml  COMMAND
 151                                                         COMMENT "Reusing old XML on ${BINDING_NAME} "
 152                                                         VERBATIM)
 153                 add_custom_target(generate_${BINDING_NAME}_cpp
 154                                                         COMMENT "Reusing old binding code with Lua"
 155                                                         VERBATIM)
 156         endif()
 157
 158         set(COMMON COMMON_${BINDING_NAME})
 159         file(GLOB ${COMMON}_SRC ${CMAKE_SOURCE_DIR}/common/*.cpp)
 160         file(GLOB ${COMMON}_HPP ${CMAKE_SOURCE_DIR}/common/*.hpp)
 161
 162
 163         set(${BINDING_NAME}_GENERATED ${LQT_GEN_DIR}/${BINDING_NAME}_enum.cpp
 164                                                                         ${LQT_GEN_DIR}/${BINDING_NAME}_meta.cpp
 165                                                                         ${LQT_GEN_DIR}/${BINDING_NAME}_slot.cpp)
 166         set_source_files_properties(${${BINDING_NAME}_GENERATED} PROPERTIES GENERATED TRUE)
 167
 168         if(nomerge)
 169                 #TODO fix this build process:
 170                 #       1. cmake ../lqt -Dnomerge=1
 171                 #       2. make -> will generate cpp files but they are not part of the Makefile (GLOB was at 1.)
 172                 #       3. cmake ../lqt -Dnomerge=1 -> GLOB now finds the generated cpp files
 173                 #       4. make
 174                 file(GLOB BINDING_SRC ${LQT_GEN_DIR}/*.cpp)
 175                 set(${COMMON}_SRC)
 176                 list(REMOVE_ITEM BINDING_SRC ${LQT_GEN_DIR}/${BINDING_NAME}_merged_build.cpp)
 177         else()
 178                 set(${COMMON}_SRC ${${COMMON}_SRC}      ${${BINDING_NAME}_GENERATED})
 179         endif()
 180
 181         qt4_wrap_cpp(${COMMON}_MOC ${LQT_GEN_DIR}/${BINDING_NAME}_slot.hpp)
 182
 183         include_directories(${CMAKE_SOURCE_DIR}/common ${LUA_INCLUDE_DIR} ${QT_INCLUDES})
 184
 185         add_library(${BINDING_NAME} SHARED  ${BINDING_SRC}
 186                                                                                         ${${COMMON}_SRC}
 187                                                                                         ${${COMMON}_HPP}
 188                                                                                         ${${COMMON}_MOC})
 189
 190         target_link_libraries(${BINDING_NAME} ${QT_LIBRARIES} ${LUA_LIBRARIES})
 191         set_target_properties(${BINDING_NAME} PROPERTIES PREFIX "" COMPILE_DEFINITIONS "MODULE_${BINDING_NAME}")
 192
 193         if(LQT_BUILDIN_CPPTOXML)
 194                 add_dependencies(generate_${BINDING_NAME}_xml  cpptoxml)
 195         endif()
 196
 197         add_dependencies(generate_${BINDING_NAME}_cpp  generate_${BINDING_NAME}_xml ${${BINDING_NAME}_DEPENDS})
 198         add_dependencies(${BINDING_NAME} generate_${BINDING_NAME}_cpp)
 199 endfunction()
 200
 201 if(noqt)
 202         include_directories(${CMAKE_CURRENT_SOURCE_DIR}/test/noqt)
 203         build_qt_lib_binding(noqt)
 204 else()
 205         build_qt_lib_binding(QtCore)
 206         build_qt_lib_binding(QtNetwork QtCore)
 207         build_qt_lib_binding(QtGui QtNetwork QtCore)
 208         build_qt_lib_binding(QtScript QtGui QtNetwork QtCore)
 209         build_qt_lib_binding(QtOpenGL QtGui QtNetwork QtCore)
 210         build_qt_lib_binding(QtSvg QtScript QtGui QtNetwork QtCore)
 211         build_qt_lib_binding(QtXml QtSvg QtScript QtGui QtNetwork QtCore)
 212         build_qt_lib_binding(QtXmlPatterns QtCore QtXml)
 213         build_qt_lib_binding(QtUiTools QtCore QtGui QtXml)
 214         build_qt_lib_binding(QtWebKit QtXmlPatterns QtSvg QtScript QtOpenGL QtGui QtNetwork QtCore QtXml)
 215         build_qt_lib_binding(QtSql QtCore)
 216         # TODO
 217         #build_qt_lib_binding(QtScriptTools) # 4.5 only
 218         #build_qt_lib_binding(Phonon)
 219 endif()
 220
 221
 222
 223
 224
 225
 226