utils.ml

   1 exception Quit;;
   2
   3 module E = struct
   4   let s = "";;
   5   let b = Bytes.empty;;
   6   let a = [||];;
   7 end;;
   8
   9 type platform = | Punknown | Plinux | Pmacos | Pbsd;;
  10
  11 let asciilower = let auld = Char.code 'A' - Char.code 'a' in
  12                  function
  13                  | ('A'..'Z') as c -> Char.code c - auld |> Char.chr
  14                  | c -> c
  15 ;;
  16
  17 let tempfailureretry f a =
  18   let rec g () =
  19     try f a with Unix.Unix_error (Unix.EINTR, _, _) -> g ()
  20   in g ()
  21 ;;
  22
  23 external measurestr : int -> string -> float = "ml_measure_string";;
  24 external cloexec : Unix.file_descr -> unit = "ml_cloexec";;
  25 external hasdata : Unix.file_descr -> bool = "ml_hasdata";;
  26 external toutf8 : int -> string = "ml_keysymtoutf8";;
  27 external mbtoutf8 : string -> string = "ml_mbtoutf8";;
  28 external spawn : string -> (Unix.file_descr * int) list -> int = "ml_spawn";;
  29 external platform : unit -> (platform * string array) = "ml_platform";;
  30
  31 let now = Unix.gettimeofday;;
  32 let platform, uname = platform ();;
  33 let dolog fmt = Format.ksprintf prerr_endline fmt;;
  34
  35 let exntos = function
  36   | Unix.Unix_error (e, s, a) ->
  37      Printf.sprintf "%s(%s) : %s (%d)" s a (Unix.error_message e) (Obj.magic e)
  38   | exn -> Printexc.to_string exn
  39 ;;
  40
  41 let error fmt = Printf.kprintf (fun s -> failwith s) fmt;;
  42
  43 module IntSet = Set.Make (struct type t = int let compare = (-) end);;
  44
  45 let emptystr s = String.length s = 0;;
  46 let nonemptystr s = String.length s > 0;;
  47 let bound v minv maxv = max minv (min maxv v);;
  48
  49 module Opaque : sig
  50   type t = private string
  51   val of_string : string -> t
  52   val to_string : t -> string
  53 end = struct
  54   type t = string
  55   let of_string s = s
  56   let to_string t = t
  57 end
  58 ;;
  59
  60 let (~<) = Opaque.of_string;;
  61 let (~>) = Opaque.to_string;;
  62
  63 let int_of_string_with_suffix s =
  64   let l = String.length s in
  65   let s1, shift =
  66     if l > 1
  67     then
  68       let p = l-1 in
  69       match s.[p] with
  70       | 'k' | 'K' -> String.sub s 0 p, 10
  71       | 'm' | 'M' -> String.sub s 0 p, 20
  72       | 'g' | 'G' -> String.sub s 0 p, 30
  73       | _ -> s, 0
  74     else s, 0
  75   in
  76   let n = int_of_string s1 in
  77   let m = n lsl shift in
  78   if m < 0 || m < n
  79   then error "value too large"
  80   else m
  81 ;;
  82
  83 let string_with_suffix_of_int n =
  84   if n = 0
  85   then "0"
  86   else
  87     let units = [(30, "G"); (20, "M"); (10, "K")] in
  88     let prettyint n =
  89       let rec loop s n =
  90         let h = n mod 1000 in
  91         let n = n / 1000 in
  92         if n = 0
  93         then string_of_int h ^ s
  94         else loop (Printf.sprintf "_%03d%s" h s) n
  95       in
  96       loop E.s n
  97     in
  98     let rec find = function
  99       | [] -> prettyint n
 100       | (shift, suffix) :: rest ->
 101          if (n land ((1 lsl shift) - 1)) = 0
 102          then prettyint (n lsr shift) ^ suffix
 103          else find rest
 104     in
 105     find units
 106 ;;
 107
 108 let color_of_string s =
 109   Scanf.sscanf s "%d/%d/%d" (fun r g b ->
 110       (float r /. 255.0, float g /. 255.0, float b /. 255.0)
 111     )
 112 ;;
 113
 114 let rgba_of_string s =
 115   Scanf.sscanf
 116     s "%d/%d/%d/%d" (fun r g b a ->
 117       (float r /. 255.0, float g /. 255.0, float b /. 255.0, float a /. 255.0)
 118     )
 119 ;;
 120
 121 let color_to_string (r, g, b) =
 122   let r = truncate (r *. 255.0)
 123   and g = truncate (g *. 255.0)
 124   and b = truncate (b *. 255.0) in
 125   Printf.sprintf "%d/%d/%d" r g b
 126 ;;
 127
 128 let rgba_to_string (r, g, b, a) =
 129   let r = truncate (r *. 255.0)
 130   and g = truncate (g *. 255.0)
 131   and b = truncate (b *. 255.0)
 132   and a = truncate (a *. 255.0) in
 133   Printf.sprintf "%d/%d/%d/%d" r g b a
 134 ;;
 135
 136 let abspath path =
 137   if Filename.is_relative path
 138   then
 139     let cwd = Sys.getcwd () in
 140     if Filename.is_implicit path
 141     then Filename.concat cwd path
 142     else Filename.concat cwd (Filename.basename path)
 143   else path
 144 ;;
 145
 146 module Ne = struct
 147   let index s c = try String.index s c with Not_found -> -1;;
 148   let clo fd f =
 149     try tempfailureretry Unix.close fd
 150     with exn -> f @@ exntos exn
 151   ;;
 152 end;;
 153
 154 let getoptdef def = function
 155   | Some a -> a
 156   | None -> def
 157 ;;
 158
 159 let getenvdef name def =
 160   match Sys.getenv name with
 161   | env -> env
 162   | exception Not_found -> def
 163 ;;
 164
 165 module Re = struct
 166   let crlf = Str.regexp "[\r\n]";;
 167   let percent = Str.regexp "%s";;
 168   let whitespace = Str.regexp "[ \t]";;
 169 end;;
 170
 171 let unit () = ();;
 172
 173 let addchar s c =
 174   let b = Buffer.create (String.length s + 1) in
 175   Buffer.add_string b s;
 176   Buffer.add_char b c;
 177   Buffer.contents b;
 178 ;;
 179
 180 let btod b = if b then 1 else 0;;
 181
 182 let splitatchar s c = let open String in
 183                       match index s c with
 184                       | pos -> sub s 0 pos, sub s (pos+1) (length s - pos - 1)
 185                       | exception Not_found -> s, E.s
 186 ;;
 187
 188 let boundastep h step =
 189   if step < 0
 190   then bound step ~-h 0
 191   else bound step 0 h
 192 ;;
 193
 194 let withoutlastutf8 s =
 195   let len = String.length s in
 196   if len = 0
 197   then s
 198   else
 199     let rec find pos =
 200       if pos = 0
 201       then pos
 202       else
 203         let b = Char.code s.[pos] in
 204         if b land 0b11000000 = 0b11000000
 205         then pos
 206         else find (pos-1)
 207     in
 208     let first =
 209       if Char.code s.[len-1] land 0x80 = 0
 210       then len-1
 211       else find (len-1)
 212     in
 213     String.sub s 0 first;
 214 ;;
 215
 216 let fdcontents fd =
 217   let l = 4096 in
 218   let b = Buffer.create l in
 219   let s = Bytes.create l in
 220   let rec loop () =
 221     let n = tempfailureretry (Unix.read fd s 0) l in
 222     if n = 0
 223     then Buffer.contents b
 224     else (
 225       Buffer.add_subbytes b s 0 n;
 226       loop ()
 227     )
 228   in
 229   loop ()
 230 ;;
 231
 232 let filecontents path =
 233   let fd = Unix.openfile path [Unix.O_RDONLY] 0o0 in
 234   match fdcontents fd with
 235   | exception exn ->
 236      error "failed to read contents of %s: %s" path @@ exntos exn
 237   | s ->
 238      Ne.clo fd @@ error "failed to close descriptor for %s: %s" path;
 239      s
 240 ;;
 241
 242 let getcmdoutput errfun cmd =
 243   let reperror fmt = Printf.kprintf errfun fmt in
 244   let clofail s e = error "failed to close %s: %s" s e in
 245   match Unix.pipe () with
 246   | exception exn ->
 247      reperror "pipe failed: %s" @@ exntos exn;
 248      E.s
 249   | (r, w) ->
 250      match spawn cmd [r, -1; w, 1] with
 251      | exception exn ->
 252         reperror "failed to execute %S: %s" cmd @@ exntos exn;
 253         E.s
 254      | pid ->
 255         Ne.clo w @@ clofail "write end of the pipe";
 256         let s =
 257           match Unix.waitpid [] pid with
 258           | exception exn ->
 259              reperror "waitpid on %S %d failed: %s" cmd pid @@ exntos exn;
 260              E.s
 261           | _pid, Unix.WEXITED 0 ->
 262              begin
 263                match fdcontents r with
 264                | exception exn ->
 265                   reperror "failed to read output of %S: %s" cmd @@ exntos exn;
 266                   E.s
 267                | s ->
 268                   let l = String.length s in
 269                   if l > 0 && s.[l-1] = '\n'
 270                   then String.sub s 0 (l-1)
 271                   else s
 272              end;
 273           | _pid, Unix.WEXITED n ->
 274              reperror "%S exited with error code %d" cmd n;
 275              E.s
 276           | _pid, Unix.WSIGNALED n ->
 277              reperror "%S was killed with signal %d" cmd n;
 278              E.s
 279           | _pid, Unix.WSTOPPED n ->
 280              reperror "%S was stopped by signal %d" cmd n;
 281              E.s
 282         in
 283         Ne.clo r @@ clofail "read end of the pipe";
 284         s
 285 ;;
 286
 287 let geturl =
 288   let re = Str.regexp {|.*\(\(https?\|ftp\|mailto\|file\)://[^ ]+\).*|} in
 289   fun s -> if Str.string_match re s 0
 290            then Str.matched_group 1 s
 291            else E.s
 292 ;;
 293
 294 let substratis s pos subs =
 295   let subslen = String.length subs in
 296   if String.length s - pos >= subslen
 297   then
 298     let rec cmp i = i = subslen || (s.[pos+i] = subs.[i]) && cmp (i+1)
 299     in cmp 0
 300   else false
 301 ;;
 302
 303 let w8 s pos i = Bytes.set s pos (Char.chr (i land 0xff));;
 304 let r8 s pos = Char.code (Bytes.get s pos);;
 305
 306 let w16 s pos i =
 307   w8 s pos i;
 308   w8 s (pos+1) (i lsr 8)
 309 ;;
 310
 311 let w32 s pos i =
 312   w16 s pos i;
 313   w16 s (pos+2) (i lsr 16)
 314 ;;
 315
 316 let r16 s pos =
 317   let rb pos1 = Char.code (Bytes.get s (pos + pos1)) in
 318   (rb 0) lor ((rb 1) lsl 8)
 319 ;;
 320
 321 let r16s s pos =
 322   let i = r16 s pos in
 323   i - ((i land 0x8000) lsl 1)
 324 ;;
 325
 326 let r32 s pos =
 327   let rb pos1 = Char.code (Bytes.get s (pos + pos1)) in
 328   let l = (rb 0) lor ((rb 1) lsl 8)
 329   and u = (rb 2) lor ((rb 3) lsl 8) in
 330   (u lsl 16) lor l
 331 ;;
 332
 333 let r32s =
 334   if Sys.word_size > 32
 335   then fun s pos ->
 336        let rb pos1 = Char.code (Bytes.get s (pos + pos1)) in
 337        let v0 = rb 0 and v1 = rb 1 and v2 = rb 2 and v3 = rb 3 in
 338        let v = v0 lor (v1 lsl 8) lor (v2 lsl 16) lor (v3 lsl 24) in
 339        if v3 land 0x80 = 0
 340        then v
 341        else (v - (1 lsl 32))
 342   else fun _ _ -> error "r32s: not implemented for word_size <= 32"
 343 ;;
 344
 345 let vlog fmt = Format.ksprintf ignore fmt;;
 346
 347 let pipef ?(closew=true) cap f cmd =
 348   match Unix.pipe () with
 349   | exception exn -> dolog "%s cannot create pipe: %S" cap @@ exntos exn
 350   | (r, w) ->
 351      begin match spawn cmd [r, 0; w, -1] with
 352      | exception exn -> dolog "%s: cannot execute %S: %s" cap cmd @@ exntos exn
 353      | _pid -> f w
 354      end;
 355      Ne.clo r (dolog "%s failed to close r: %s" cap);
 356      if closew then Ne.clo w (dolog "%s failed to close w: %s" cap);
 357 ;;
 358
 359 let selstring selcmd s =
 360   pipef "selstring" (fun w ->
 361       try
 362         let l = String.length s in
 363         let bytes = Bytes.unsafe_of_string s in
 364         let n = tempfailureretry (Unix.write w bytes 0) l in
 365         if n != l
 366         then dolog "failed to write %d characters to sel pipe, wrote %d" l n;
 367       with exn -> dolog "failed to write to sel pipe: %s" @@ exntos exn
 368     ) selcmd
 369 ;;