wsi.ml

   1 type cursor =
   2     | CURSOR_INHERIT
   3     | CURSOR_INFO
   4     | CURSOR_CYCLE
   5     | CURSOR_CROSSHAIR
   6     | CURSOR_TEXT
   7 ;;
   8
   9 external cloexec : Unix.file_descr -> unit = "ml_cloexec";;
  10 external glx : int -> unit = "ml_glx";;
  11 external swapb : unit -> unit = "ml_swapb";;
  12 external hasdata : Unix.file_descr -> bool = "ml_hasdata";;
  13 external toutf8 : int -> string = "ml_keysymtoutf8";;
  14
  15 let dolog fmt = Format.kprintf prerr_endline fmt;;
  16 let vlog fmt = Format.kprintf ignore fmt;;
  17
  18 let onot = object
  19   method display         = ()
  20   method expose          = ()
  21   method reshape _ _     = ()
  22   method mouse _ _ _ _ _ = ()
  23   method motion _ _      = ()
  24   method pmotion _ _     = ()
  25   method key _ _         = ()
  26   method enter _ _       = ()
  27   method leave           = ()
  28   method quit            = exit 0
  29 end;;
  30
  31 class type t = object
  32   method display : unit
  33   method expose  : unit
  34   method reshape : int -> int -> unit
  35   method mouse   : int -> bool -> int -> int -> int -> unit
  36   method motion  : int -> int -> unit
  37   method pmotion : int -> int -> unit
  38   method key     : int -> int -> unit
  39   method enter   : int -> int -> unit
  40   method leave   : unit
  41   method quit    : unit
  42 end;;
  43
  44 type state =
  45     { mutable mink       : int
  46     ; mutable maxk       : int
  47     ; mutable keymap     : int array array
  48     ; fifo               : (string -> unit) Queue.t
  49     ; mutable seq        : int
  50     ; mutable protoatom  : int
  51     ; mutable deleatom   : int
  52     ; mutable idbase     : int
  53     ; mutable fullscreen : (int -> unit)
  54     ; mutable setwmname  : (string -> unit)
  55     ; mutable stringatom : int
  56     ; mutable t          : t
  57     ; mutable sock       : Unix.file_descr
  58     ; mutable w          : int
  59     ; mutable h          : int
  60     ; mutable fs         : bool
  61     }
  62 ;;
  63
  64 let state =
  65   { mink       = max_int
  66   ; maxk       = min_int
  67   ; keymap     = [||]
  68   ; fifo       = Queue.create ()
  69   ; seq        = 0
  70   ; protoatom  = -1
  71   ; deleatom   = -1
  72   ; idbase     = -1
  73   ; fullscreen = (fun _ -> ())
  74   ; setwmname  = (fun _ -> ())
  75   ; sock       = Unix.stdin
  76   ; t          = onot
  77   ; w          = -1
  78   ; h          = -1
  79   ; fs         = false
  80   ; stringatom = 31
  81   }
  82 ;;
  83
  84 let w8 s pos i = String.set s pos (Char.chr (i land 0xff));;
  85
  86 let w16 s pos i =
  87   w8 s pos i;
  88   w8 s (pos+1) (i lsr 8);
  89 ;;
  90
  91 let w32 s pos i =
  92   w16 s pos i;
  93   w16 s (pos+2) (i lsr 16);
  94 ;;
  95
  96 let r16 s pos =
  97   let rb pos1 = Char.code (String.get s (pos + pos1)) in
  98   (rb 0) lor ((rb 1) lsl 8)
  99 ;;
 100
 101 let r16s s pos =
 102   let i = r16 s pos in
 103   i - ((i land 0x8000) lsl 1);
 104 ;;
 105
 106 let r8 s pos = Char.code (String.get s pos);;
 107
 108 let r32 s pos =
 109   let rb pos1 = Char.code (String.get s (pos + pos1)) in
 110   let l = (rb 0) lor ((rb 1) lsl 8)
 111   and u = (rb 2) lor ((rb 3) lsl 8) in
 112   (u lsl 16) lor l
 113 ;;
 114
 115 let error fmt = Printf.kprintf failwith fmt;;
 116
 117 let readstr sock n =
 118   let s = String.create n in
 119   let rec loop pos n =
 120     let m = Unix.read sock s pos n in
 121     if n != m
 122     then (
 123       ignore (Unix.select [sock] [] [] 0.01);
 124       loop (pos + m) (n - m)
 125     )
 126   in
 127   loop 0 n;
 128   s;
 129 ;;
 130
 131 let sendstr1 s pos len sock =
 132   vlog "%d => %S" state.seq s;
 133   state.seq <- state.seq + 1;
 134   let n = Unix.send sock s pos len [] in
 135   if n != len
 136   then error "send %d returned %d" len n;
 137 ;;
 138
 139 let updkmap sock resp =
 140   let syms = r8 resp 1 in
 141   let len = r32 resp 4 in
 142   let data =
 143     if len > 0
 144     then readstr sock (4*len)
 145     else ""
 146   in
 147   let m = len / syms in
 148   state.keymap <- Array.make_matrix
 149     (state.maxk - state.mink) syms 0xffffff;
 150   let rec loop i = if i = m then () else
 151       let k = i*4*syms in
 152       let rec loop2 k l = if l = syms then () else
 153           let v = r32 data k in
 154           state.keymap.(i).(l) <- v;
 155           loop2 (k+4) (l+1)
 156       in
 157       loop2 k 0;
 158       loop (i+1);
 159   in
 160   loop 0;
 161 ;;
 162
 163 let sendwithrep sock s f =
 164   Queue.push f state.fifo;
 165   sendstr1 s 0 (String.length s) sock;
 166 ;;
 167
 168 let padcatl ss =
 169   let b = Buffer.create 16 in
 170   List.iter (Buffer.add_string b) ss;
 171   let bl = Buffer.length b in
 172   let pl = bl land 3 in
 173   if pl != 0
 174   then (
 175     let pad = "123" in
 176     Buffer.add_substring b pad 0 (4 - pl);
 177   );
 178   Buffer.contents b;
 179 ;;
 180
 181 let padcat s1 s2 = padcatl [s1; s2];;
 182
 183 let internreq name onlyifexists =
 184   let s = "\016\000\000\000\000\000\000\000" in
 185   let s = padcat s name in
 186   w8 s 1 (if onlyifexists then 1 else 0);
 187   w16 s 2 (String.length s / 4);
 188   w16 s 4 (String.length name);
 189   s;
 190 ;;
 191
 192 let sendintern sock s onlyifexists f =
 193   let s = internreq s onlyifexists in
 194   sendwithrep sock s f;
 195 ;;
 196
 197 let createwindowreq wid parent x y w h bw mask =
 198   let s = "\001\000\009\000wwwwppppxxyywwhhbwccvvvvmmmmeeee" in
 199   w32 s 4 wid;
 200   w32 s 8 parent;
 201   w16 s 12 x;
 202   w16 s 14 y;
 203   w16 s 16 w;
 204   w16 s 18 h;
 205   w16 s 20 bw;
 206   w16 s 22 1;
 207   w32 s 24 0;
 208   w32 s 28 0x800;                       (* eventmask *)
 209   w32 s 32 mask;
 210   s;
 211 ;;
 212
 213 let getgeometryreq wid =
 214   let s = "\014u\002\000dddd" in
 215   w32 s 4 wid;
 216   s;
 217 ;;
 218
 219 let mapreq wid =
 220   let s = "\008u\002\000wwww" in
 221   w32 s 4 wid;
 222   s;
 223 ;;
 224
 225 let getkeymapreq first count =
 226   let s = "\101u\002\000fcuu" in
 227   w8 s 4 first;
 228   w8 s 5 count;
 229   s;
 230 ;;
 231
 232 let changepropreq wid prop typ format props =
 233   let s = "\018\000llwwwwppppttttfuuuLLLL" in
 234   let s = padcat s props in
 235   w16 s 2 (String.length s / 4);
 236   w32 s 4 wid;
 237   w32 s 8 prop;
 238   w32 s 12 typ;
 239   w8 s 16 format;
 240   let ful = String.length props / (match format with
 241     | 8 -> 1
 242     | 16 -> 2
 243     | 32 -> 4
 244     | n -> error "no idea what %d means" n)
 245   in
 246   w32 s 20 ful;
 247   s;
 248 ;;
 249
 250 let openfontreq fid name =
 251   let s = "\045ullffffnnuu" in
 252   let s = padcat s name in
 253   w16 s 2 (String.length s / 4);
 254   w32 s 4 fid;
 255   w16 s 8 (String.length name);
 256   s;
 257 ;;
 258
 259 let createglyphcursorreq fid cid cindex =
 260   let s = "\094u\008\000ccccffffffffssmmrrggbbRRGGBB" in
 261   w32 s 4 cid;
 262   w32 s 8 fid;
 263   w32 s 12 fid;
 264   w16 s 16 cindex;
 265   w16 s 18 (cindex+1);
 266   w16 s 20 0;
 267   w16 s 22 0;
 268   w16 s 24 0;
 269   w16 s 26 0xffff;
 270   w16 s 28 0xffff;
 271   w16 s 30 0xffff;
 272   s;
 273 ;;
 274
 275 let mapwindowreq wid =
 276   let s = "\008u\002\000wwww" in
 277   w32 s 4 wid;
 278   s;
 279 ;;
 280
 281 let changewindowattributesreq wid mask attrs =
 282   let s = "\002ullwwwwmmmm" in
 283   let s = padcat s attrs in
 284   w16 s 2 (String.length s / 4);
 285   w32 s 4 wid;
 286   w32 s 8 mask;
 287   s;
 288 ;;
 289
 290 let configurewindowreq wid mask values =
 291   let s = "\012ullwwwwmmuu" in
 292   let s = padcat s values in
 293   w16 s 2 (String.length s / 4);
 294   w32 s 4 wid;
 295   w16 s 8 mask;
 296   s;
 297 ;;
 298
 299 let s32 n =
 300   let s = "1234" in
 301   w32 s 0 n;
 302   s;
 303 ;;
 304
 305 let clientmessage format seq wid typ data =
 306   let s = "\033fsswwwwtttt" in
 307   let s = padcat s data in
 308   w8 s 1 format;
 309   w16 s 2 seq;
 310   w32 s 4 wid;
 311   w32 s 8 typ;
 312   s;
 313 ;;
 314
 315 let sendeventreq propagate destwid mask data =
 316   let s = "\025p\011\000wwwwmmmm" in
 317   let s = padcat s data in
 318   w8 s 1 propagate;
 319   w32 s 4 destwid;
 320   w32 s 8 mask;
 321   s;
 322 ;;
 323
 324 let getkeysym code mask =
 325   let index = (mask land 1) lxor ((mask land 2) lsr 1) in
 326   let keysym = state.keymap.(code-state.mink).(index) in
 327   if index = 1 && keysym = 0
 328   then state.keymap.(code-state.mink).(0)
 329   else keysym
 330 ;;
 331
 332 let rec readresp sock =
 333   let resp = readstr sock 32 in
 334   let opcode = r8 resp 0 in
 335   match opcode land lnot 0x80 with
 336   | 0 ->                                (* error *)
 337       let s = resp in
 338       let code = r8 s 1
 339       and serial = r16 s 2
 340       and resid = r32 resp 4
 341       and min = r16 s 8
 342       and maj = r8 s 10 in
 343       error "code=%d serial=%d resid=%#x min=%d maj=%d\n%S"
 344         code serial resid min maj resp;
 345
 346   | 1 ->                                (* response *)
 347       let rep = Queue.pop state.fifo in
 348       rep resp;
 349
 350   | 2 ->                                (* key press *)
 351       if Array.length state.keymap > 0
 352       then
 353         let code = r8 resp  1 in
 354         let mask = r16 resp 28 in
 355         let keysym = getkeysym code mask in
 356         vlog "keysym = %x %c" keysym (Char.unsafe_chr keysym);
 357         state.t#key keysym mask;
 358
 359   | 3 ->                                (* key release *)
 360       if Array.length state.keymap > 0
 361       then
 362         let code = r8 resp 1 in
 363         let mask = r16 resp 28 in
 364         let keysym = getkeysym code mask in
 365         vlog "release keysym = %x %c mask %#x"
 366           keysym (Char.unsafe_chr keysym) mask
 367
 368   | 4 ->                                (* buttonpress *)
 369       let n = r8 resp 1
 370       and x = r16s resp 24
 371       and y = r16s resp 26
 372       and m = r16 resp 28 in
 373       state.t#mouse n true x y m;
 374       vlog "press %d" n
 375
 376   | 5 ->                                (* buttonrelease *)
 377       let n = r8 resp 1
 378       and x = r16s resp 24
 379       and y = r16s resp 26
 380       and m = r16 resp 28 in
 381       state.t#mouse n false x y m;
 382       vlog "release %d %d %d" n x y
 383
 384   | 6 ->                                (* motion *)
 385       let x = r16s resp 24 in
 386       let y = r16s resp 26 in
 387       let m = r16 resp 28 in
 388       if m land 0x1f00 = 0
 389       then state.t#pmotion x y
 390       else state.t#motion x y;
 391       vlog "move %dx%d => %d" x y m
 392
 393   | 7 ->                                (* enter *)
 394       let x = r16s resp 24
 395       and y = r16s resp 26 in
 396       state.t#enter x y;
 397       vlog "enter %d %d" x y
 398
 399   | 8 ->                                (* leave *)
 400       state.t#leave
 401
 402   | 18 -> vlog "unmap";
 403
 404   | 19 ->                               (* map *)
 405       vlog "map";
 406
 407   | 12 ->                               (* exposure *)
 408       vlog "exposure";
 409       state.t#expose
 410
 411   | 15 ->                               (* visibility *)
 412       let vis = r8 resp 8 in
 413       if vis != 2 then state.t#display;
 414       vlog "visibility %d" vis;
 415
 416   | 34 ->                               (* mapping *)
 417       state.keymap <- [||];
 418       let s = getkeymapreq state.mink (state.maxk-state.mink-1) in
 419       sendwithrep sock s (updkmap sock);
 420
 421   | 33 ->                               (* clientmessage *)
 422       let atom = r32 resp 8 in
 423       if atom = state.protoatom
 424       then (
 425         let atom = r32 resp 12 in
 426         if atom = state.deleatom
 427         then state.t#quit;
 428       );
 429       vlog "atom %#x" atom
 430
 431   | 21 ->                               (* reparent *)
 432       vlog "reparent"
 433
 434   | 22 ->                               (* configure *)
 435       let w = r16 resp 20
 436       and h = r16 resp 22 in
 437       vlog "configure %d %d %d %d" state.w state.h w h;
 438       if w != state.w || h != state.h
 439       then (
 440         state.w <- w;
 441         state.h <- h;
 442         state.t#reshape w h;
 443       );
 444
 445   | n ->
 446       dolog "event %d %S" n resp
 447 ;;
 448
 449 let readresp sock =
 450   let rec loop () =
 451     readresp sock;
 452     if hasdata sock then loop ();
 453   in
 454   loop ();
 455 ;;
 456
 457 let sendstr s ?(pos=0) ?(len=String.length s) sock =
 458   sendstr1 s pos len sock;
 459   if hasdata sock then readresp sock;
 460 ;;
 461
 462 let hexstr s =
 463   let b = Buffer.create 16 in
 464   String.iter (fun c ->
 465     Buffer.add_string b (Printf.sprintf "%02x" (Char.code c))) s;
 466   Buffer.contents b;
 467 ;;
 468
 469 let reshape w h =
 470   if state.fs
 471   then
 472     state.fullscreen state.idbase
 473   ;
 474   let s = "wwuuhhuu" in
 475   w32 s 0 w;
 476   w32 s 4 h;
 477   let s = configurewindowreq state.idbase 0x000c s in
 478   vlog "reshape %d %s %d" state.seq (hexstr s) (String.length s);
 479   sendstr s state.sock;
 480 ;;
 481
 482 let setup sock screennum w h =
 483   let s = readstr sock 2 in
 484   let n = String.length s in
 485   if n != 2
 486   then error "failed to read X connection setup response n=%d" n;
 487   match s.[0] with
 488   | '\000' ->
 489       let reasonlen = r8 s 1 in
 490       let s = readstr sock 6 in
 491       let maj = r16 s 0
 492       and min = r16 s 2
 493       and add = r16 s 4 in
 494       let len = add*4 in
 495       let data = readstr sock len in
 496       let reason = String.sub data 0 reasonlen in
 497       error "X connection failed maj=%d min=%d reason=%S"
 498         maj min reason
 499
 500   | '\002' -> failwith "X connection setup failed: authentication required";
 501
 502   | '\001' ->
 503       let s       = readstr sock 38 in
 504       let maj     = r16 s 0
 505       and min     = r16 s 2
 506       and add     = r16 s 4
 507       and idbase  = r32 s 10
 508       and idmask  = r32 s 14
 509       and vlen    = r16 s 22
 510       and screens = r8 s 26
 511       and formats = r8 s 27
 512       and minkk   = r8 s 32
 513       and maxkk   = r8 s 33 in
 514       let data = readstr sock (4*add-32) in
 515       let vendor = String.sub data 0 vlen in
 516       let pos = ((vlen+3) land lnot 3) + formats*8 in
 517
 518       if screennum >= screens
 519       then error "invalid screen %d, max %d" screennum (screens-1);
 520
 521       let pos =
 522         let s = data in
 523         let rec findscreen n pos = if n = screennum then pos else
 524             let pos =
 525               let ndepths = r8 s (pos+39) in
 526               let rec skipdepths n pos = if n = ndepths then pos else
 527                   let pos =
 528                     let nvisiuals = r16 s (pos+2) in
 529                     pos + nvisiuals*24 + 8
 530                   in
 531                   skipdepths (n+1) pos
 532               in
 533               skipdepths n (pos+40)
 534             in
 535             findscreen (n+1) pos
 536         in
 537         findscreen 0 pos
 538       in
 539       let root = r32 data pos in
 540       let rootw = r16 data (pos+20)
 541       and rooth = r16 data (pos+22) in
 542       state.mink <- minkk;
 543       state.maxk <- maxkk;
 544       state.idbase <- idbase;
 545       vlog "vendor = %S, maj=%d min=%d" vendor maj min;
 546       vlog "screens = %d formats = %d" screens formats;
 547       vlog "minkk = %d maxkk = %d" minkk maxkk;
 548       vlog "idbase = %#x idmask = %#x" idbase idmask;
 549       vlog "root=%#x %dx%d" root rootw rooth;
 550
 551       let mask = 0
 552         + 0x00000001                    (* KeyPress *)
 553         (* + 0x00000002 *)              (* KeyRelease *)
 554         + 0x00000004                    (* ButtonPress *)
 555         + 0x00000008                    (* ButtonRelease *)
 556         + 0x00000010                    (* EnterWindow *)
 557         + 0x00000020                    (* LeaveWindow *)
 558         + 0x00000040                    (* PointerMotion *)
 559         (* + 0x00000080 *)              (* PointerMotionHint *)
 560         (* + 0x00000100 *)              (* Button1Motion *)
 561         (* + 0x00000200 *)              (* Button2Motion *)
 562         (* + 0x00000400 *)              (* Button3Motion *)
 563         (* + 0x00000800 *)              (* Button4Motion *)
 564         (* + 0x00001000 *)              (* Button5Motion *)
 565         + 0x00002000                    (* ButtonMotion *)
 566         (* + 0x00004000 *)              (* KeymapState *)
 567         + 0x00008000                    (* Exposure *)
 568         + 0x00010000                    (* VisibilityChange *)
 569         + 0x00020000                    (* StructureNotify *)
 570         (* + 0x00040000 *)              (* ResizeRedirect *)
 571         (* + 0x00080000 *)              (* SubstructureNotify *)
 572         (* + 0x00100000 *)              (* SubstructureRedirect *)
 573         (* + 0x00200000 *)              (* FocusChange *)
 574         (* + 0x00400000 *)              (* PropertyChange *)
 575         (* + 0x00800000 *)              (* ColormapChange *)
 576         (* + 0x01000000 *)              (* OwnerGrabButton *)
 577       in
 578       let wid = state.idbase in
 579       let s = createwindowreq wid root 0 0 w h 0 mask in
 580       sendstr s sock;
 581
 582       let s = mapreq wid in
 583       sendstr s sock;
 584
 585       let s = getkeymapreq state.mink (state.maxk-state.mink) in
 586       sendwithrep sock s (updkmap sock);
 587
 588       sendintern sock "WM_PROTOCOLS" false (fun resp ->
 589         state.protoatom <- r32 resp 8;
 590         sendintern sock "WM_DELETE_WINDOW" false (fun resp ->
 591           state.deleatom <- r32 resp 8;
 592           let s = s32 state.deleatom in
 593           let s = changepropreq wid state.protoatom 4 32 s in
 594           sendstr s sock;
 595         );
 596       );
 597
 598       sendintern sock "WM_CLASS" false (fun resp ->
 599         let atom = r32 resp 8 in
 600         let llpp = "llpp\000llpp\000" in
 601         let s = changepropreq wid atom 31 8 llpp in
 602         sendstr s sock;
 603       );
 604
 605       let s = openfontreq (wid+1) "cursor" in
 606       sendstr s sock;
 607
 608       Array.iteri (fun i glyphindex ->
 609         let s = createglyphcursorreq (wid+1) (wid+2+i) glyphindex in
 610         sendstr s sock;
 611       ) [|34;48;50;58;128;152|];
 612
 613       sendintern sock "UTF8_STRING" true (fun resp ->
 614         let atom = r32 resp 8 in
 615         if atom != 0
 616         then state.stringatom <- atom;
 617       );
 618
 619       let setwmname s =
 620         let s = changepropreq state.idbase 39 state.stringatom 8 s in
 621         sendstr s state.sock;
 622       in
 623       state.setwmname <- setwmname;
 624       sendintern sock "_NET_WM_NAME" true (fun resp ->
 625         let atom = r32 resp 8 in
 626         if atom != 0
 627         then state.setwmname <- (fun s ->
 628           setwmname s;
 629           let s = changepropreq state.idbase atom state.stringatom 8 s in
 630           sendstr s state.sock;
 631         );
 632       );
 633
 634       sendintern sock "_NET_WM_STATE" true (fun resp ->
 635         let nwmsatom = r32 resp 8 in
 636         if nwmsatom != 0
 637         then
 638           sendintern sock "_NET_WM_STATE_FULLSCREEN" true (fun resp ->
 639             let fsatom = r32 resp 8 in
 640             if fsatom != 0
 641             then
 642               state.fullscreen <-
 643                 (fun wid ->
 644                   let data = String.make 20 '\000' in
 645                   state.fs <- not state.fs;
 646                   w32 data 0 (if state.fs then 1 else 0);
 647                   w32 data 4 fsatom;
 648
 649                   let cm = clientmessage 32 0 wid nwmsatom data in
 650                   let s = sendeventreq 0 root 0x180000 cm in
 651                   sendstr s sock;
 652                 );
 653           );
 654       );
 655       let s = getgeometryreq wid in
 656       let completed = ref false in
 657       sendwithrep sock s (fun resp ->
 658         glx wid;
 659         let w = r16 resp 16
 660         and h = r16 resp 18 in
 661         state.w <- w;
 662         state.h <- h;
 663         completed := true;
 664       );
 665       let now = Unix.gettimeofday in
 666       let deadline = now () +. 2.0 in
 667       let rec readtillcompletion () =
 668         let r, _, _ = Unix.select [sock] [] [] (deadline -. now ()) in
 669         match r with
 670         | [] -> readtillcompletion ()
 671         | _ ->
 672             readresp sock;
 673             if not !completed
 674             then readtillcompletion ()
 675       in
 676       readtillcompletion ();
 677
 678   | c ->
 679       error "unknown conection setup response %d" (Char.code c)
 680 ;;
 681
 682 let getauth haddr dnum =
 683   let haddr =
 684     if haddr = "localhost" || String.length haddr = 0
 685     then
 686       try Unix.gethostname ()
 687       with exn ->
 688         dolog "failed to resolve `%S': %s" haddr (Printexc.to_string exn);
 689         haddr
 690     else haddr
 691   in
 692   let readauth ic =
 693     let input_string ic len =
 694       let s = String.create len in
 695       really_input ic s 0 len;
 696       s;
 697     in
 698     let r16 s =
 699       let rb pos = Char.code (String.get s pos) in
 700       (rb 1) lor ((rb 0) lsl 8)
 701     in
 702     let rec find () =
 703       let rs () =
 704         let s = input_string ic 2 in
 705         let n = r16 s in
 706         input_string ic n
 707       in
 708       let family = input_string ic 2 in
 709       let addr = rs () in
 710       let nums = rs () in
 711       let num = int_of_string nums in
 712       let name = rs () in
 713       let data = rs () in
 714
 715       vlog "family %S addr %S(%S) num %d(%d) name %S data %S"
 716         family addr haddr num dnum name data;
 717       if addr = haddr && num = dnum
 718       then name, data
 719       else find ()
 720     in
 721     let name, data =
 722       try find () with _ -> "", ""
 723     in
 724     close_in ic;
 725     name, data;
 726   in
 727   let path =
 728     try Sys.getenv "XAUTHORITY"
 729     with Not_found ->
 730       try Filename.concat (Sys.getenv "HOME") ".Xauthority"
 731       with Not_found -> ""
 732   in
 733   let opt =
 734     try
 735       if String.length path = 0
 736       then None
 737       else Some (open_in_bin path)
 738     with exn ->
 739       dolog "failed to open X authority file `%S' : %s"
 740         path
 741         (Printexc.to_string exn);
 742       None
 743   in
 744   match opt with
 745   | None -> "", ""
 746   | Some ic -> readauth ic
 747 ;;
 748
 749 let init t w h =
 750   let d =
 751     try Sys.getenv "DISPLAY"
 752     with exn ->
 753       error "Could not get DISPLAY evironment variable: %s"
 754         (Printexc.to_string exn)
 755   in
 756   let colonpos = String.index d ':' in
 757   let host = String.sub d 0 colonpos in
 758   let dispnum, screennum =
 759     try
 760       let dotpos = String.index_from d (colonpos + 1) '.' in
 761       let disp = String.sub d (colonpos + 1) (dotpos - colonpos - 1) in
 762       let screen = String.sub d (dotpos + 1) (String.length d - dotpos - 1) in
 763       int_of_string disp, int_of_string screen
 764     with Not_found ->
 765       let disp = String.sub d (colonpos + 1) (String.length d - colonpos - 1) in
 766       int_of_string disp, 0
 767   in
 768   let aname, adata = getauth host dispnum in
 769   let fd =
 770     if String.length host = 0 || host = "unix"
 771     then
 772       let addr = Unix.ADDR_UNIX ("/tmp/.X11-unix/X" ^ string_of_int dispnum) in
 773       let fd = Unix.socket Unix.PF_UNIX Unix.SOCK_STREAM 0 in
 774       Unix.connect fd addr;
 775       fd
 776     else
 777       let h = Unix.gethostbyname host in
 778       let addr = h.Unix.h_addr_list.(0) in
 779       let port = 6000 + dispnum in
 780       let fd = Unix.socket Unix.PF_INET Unix.SOCK_STREAM 0 in
 781       Unix.connect fd (Unix.ADDR_INET (addr, port));
 782       fd
 783   in
 784   cloexec fd;
 785   let s = "luMMmmnndduu" in
 786   let s = padcat s aname in
 787   let s = padcat s adata in
 788   w16 s 2 11;
 789   w16 s 4 0;
 790   w16 s 6 (String.length aname);
 791   w16 s 8 (String.length adata);
 792   sendstr1 s 0 (String.length s) fd;
 793   state.sock <- fd;
 794   setup fd screennum w h;
 795   state.t <- t;
 796   fd, state.w, state.h;
 797 ;;
 798
 799 let settitle s =
 800   state.setwmname s;
 801 ;;
 802
 803 let setcursor cursor =
 804   let n =
 805     match cursor with
 806     | CURSOR_INHERIT -> -1
 807     | CURSOR_INFO -> 3
 808     | CURSOR_CYCLE -> 2
 809     | CURSOR_CROSSHAIR -> 0
 810     | CURSOR_TEXT -> 5
 811   in
 812   let s = s32 (if n = -1 then 0 else state.idbase+2+n) in
 813   let s = changewindowattributesreq state.idbase (*cursor*)0x4000 s in
 814   sendstr s state.sock;
 815 ;;
 816
 817 let fullscreen () =
 818   state.fullscreen state.idbase;
 819 ;;
 820
 821 let metamask = 0x40;;
 822 let altmask = 8;;
 823 let shiftmask = 1;;
 824 let ctrlmask = 4;;
 825
 826 let withalt mask = mask land altmask != 0;;
 827 let withctrl mask = mask land ctrlmask != 0;;
 828 let withshift mask = mask land shiftmask != 0;;
 829 let withmeta mask = mask land metamask != 0;;
 830 let withnone mask = mask land (altmask + ctrlmask + shiftmask + metamask) = 0;;
 831
 832 let xlatt, xlatf =
 833   let t = Hashtbl.create 20
 834   and f = Hashtbl.create 20 in
 835   let add n nl k =
 836     List.iter (fun s -> Hashtbl.add t s k) (n::nl);
 837     Hashtbl.add f k n
 838   in
 839   let addc c =
 840     let s = String.create 1 in
 841     s.[0] <- c;
 842     add s [] (Char.code c)
 843   in
 844   let addcr a b =
 845     let an = Char.code a and bn = Char.code b in
 846     for i = an to bn do addc (Char.chr i) done;
 847   in
 848   addcr '0' '9';
 849   addcr 'a' 'z';
 850   addcr 'A' 'Z';
 851   String.iter addc "`~!@#$%^&*()-_=+\\|[{]};:,./<>?";
 852   for i = 0 to 29 do add ("f" ^ string_of_int (i+1)) [] (0xffbe + i) done;
 853   add "space" [] 0x20;
 854   add "return" ["ret"; "enter"] 0xff0d;
 855   add "tab" [] 0xff09;
 856   add "left" [] 0xff51;
 857   add "right" [] 0xff53;
 858   add "home" [] 0xff50;
 859   add "end" [] 0xff57;
 860   add "insert" ["ins"] 0xff63;
 861   add "delete" ["del"] 0xffff;
 862   add "escape" ["esc"] 0xff1b;
 863   add "pgup" ["pageup"] 0xff55;
 864   add "pgdown" ["pagedown"] 0xff56;
 865   add "backspace" [] 0xff08;
 866   add "up" [] 0xff52;
 867   add "down" [] 0xff54;
 868   t, f;
 869 ;;
 870
 871 let keyname k =
 872   try Hashtbl.find xlatf k
 873   with Not_found -> Printf.sprintf "%#x" k;
 874 ;;
 875
 876 let namekey name =
 877   try Hashtbl.find xlatt name
 878   with Not_found ->
 879     if String.length name = 1
 880     then Char.code name.[0]
 881     else int_of_string name;
 882 ;;