utils.ml

   1 module E = struct
   2   let s = "";;
   3   let b = Bytes.of_string s;;
   4   let a = [||];;
   5 end;;
   6
   7 type platform = | Punknown | Plinux | Posx | Psun | Pbsd | Pcygwin;;
   8
   9 let tempfailureretry f a =
  10   let rec g () =
  11     try f a with Unix.Unix_error (Unix.EINTR, _, _) -> g ()
  12   in g ()
  13 ;;
  14
  15 external cloexec : Unix.file_descr -> unit = "ml_cloexec";;
  16 external hasdata : Unix.file_descr -> bool = "ml_hasdata";;
  17 external toutf8 : int -> string = "ml_keysymtoutf8";;
  18 external mbtoutf8 : string -> string = "ml_mbtoutf8";;
  19 external popen : string -> (Unix.file_descr * int) list -> int = "ml_popen";;
  20 external platform : unit -> (platform * string array)  = "ml_platform";;
  21
  22 let now = Unix.gettimeofday;;
  23 let platform, uname = platform ();;
  24 let dolog fmt = Format.ksprintf prerr_endline fmt;;
  25
  26 let exntos = function
  27   | Unix.Unix_error (e, s, a) -> Printf.sprintf "%s(%s) : %s (%d)"
  28       s a (Unix.error_message e) (Obj.magic e)
  29   | exn -> Printexc.to_string exn;
  30 ;;
  31
  32 let error fmt = Printf.kprintf failwith fmt;;
  33
  34 module IntSet = Set.Make (struct type t = int let compare = (-) end);;
  35
  36 let emptystr s = String.length s = 0;;
  37 let nonemptystr s = String.length s > 0;;
  38 let bound v minv maxv = max minv (min maxv v);;
  39
  40 let popen cmd fda =
  41   if platform = Pcygwin
  42   then failwith "popen not implemented under cygwin yet"
  43   else popen cmd fda;
  44 ;;
  45
  46 module Opaque :
  47 sig
  48   type t =  private string
  49   val of_string : string -> t
  50   val to_string : t -> string
  51 end
  52   =
  53 struct
  54   type t = string
  55   let of_string s = s
  56   let to_string t = t
  57 end
  58 ;;
  59
  60 let (~<) = Opaque.of_string;;
  61 let (~>) = Opaque.to_string;;
  62
  63 let int_of_string_with_suffix s =
  64   let l = String.length s in
  65   let s1, shift =
  66     if l > 1
  67     then
  68       let suffix = Char.lowercase s.[l-1] in
  69       match suffix with
  70       | 'k' -> String.sub s 0 (l-1), 10
  71       | 'm' -> String.sub s 0 (l-1), 20
  72       | 'g' -> String.sub s 0 (l-1), 30
  73       | _ -> s, 0
  74     else s, 0
  75   in
  76   let n = int_of_string s1 in
  77   let m = n lsl shift in
  78   if m < 0 || m < n
  79   then error "value too large"
  80   else m
  81 ;;
  82
  83 let string_with_suffix_of_int n =
  84   if n = 0
  85   then "0"
  86   else
  87     let units = [(30, "G"); (20, "M"); (10, "K")] in
  88     let prettyint n =
  89       let rec loop s n =
  90         let h = n mod 1000 in
  91         let n = n / 1000 in
  92         if n = 0
  93         then string_of_int h ^ s
  94         else (
  95           let s = Printf.sprintf "_%03d%s" h s in
  96           loop s n
  97         )
  98       in
  99       loop E.s n
 100     in
 101     let rec find = function
 102       | [] -> prettyint n
 103       | (shift, suffix) :: rest ->
 104           if (n land ((1 lsl shift) - 1)) = 0
 105           then prettyint (n lsr shift) ^ suffix
 106           else find rest
 107     in
 108     find units
 109 ;;
 110
 111 let color_of_string s =
 112   Scanf.sscanf s "%d/%d/%d" (fun r g b ->
 113     (float r /. 256.0, float g /. 256.0, float b /. 256.0)
 114   )
 115 ;;
 116
 117 let color_to_string (r, g, b) =
 118   let r = truncate (r *. 256.0)
 119   and g = truncate (g *. 256.0)
 120   and b = truncate (b *. 256.0) in
 121   Printf.sprintf "%d/%d/%d" r g b
 122 ;;
 123
 124 let abspath path =
 125   if Filename.is_relative path
 126   then
 127     let cwd = Sys.getcwd () in
 128     if Filename.is_implicit path
 129     then Filename.concat cwd path
 130     else Filename.concat cwd (Filename.basename path)
 131   else
 132     path
 133 ;;
 134
 135 let nindex s c =
 136   try String.index s c
 137   with Not_found -> -1
 138 ;;
 139
 140 module Ne = struct
 141   let clo fd f =
 142     try tempfailureretry Unix.close fd
 143     with exn -> f (exntos exn)
 144   ;;
 145 end;;
 146
 147 let getenvwithdef name def =
 148   match Sys.getenv name with
 149   | env -> env
 150   | exception Not_found -> def
 151 ;;
 152
 153 let newlinere = Str.regexp "[\r\n]";;
 154 let percentsre = Str.regexp "%s";;
 155
 156 let unit () = ();;
 157
 158 let addchar s c =
 159   let b = Buffer.create (String.length s + 1) in
 160   Buffer.add_string b s;
 161   Buffer.add_char b c;
 162   Buffer.contents b;
 163 ;;
 164
 165 let btod b = if b then 1 else 0;;
 166
 167 let splitatspace =
 168   let r = Str.regexp " " in
 169   fun s -> Str.bounded_split r s 2;
 170 ;;
 171
 172 let boundastep h step =
 173   if step < 0
 174   then bound step ~-h 0
 175   else bound step 0 h
 176 ;;
 177
 178 let withoutlastutf8 s =
 179   let len = String.length s in
 180   if len = 0
 181   then s
 182   else
 183     let rec find pos =
 184       if pos = 0
 185       then pos
 186       else
 187         let b = Char.code s.[pos] in
 188         if b land 0b11000000 = 0b11000000
 189         then pos
 190         else find (pos-1)
 191     in
 192     let first =
 193       if Char.code s.[len-1] land 0x80 = 0
 194       then len-1
 195       else find (len-1)
 196     in
 197     String.sub s 0 first;
 198 ;;
 199
 200 let fdcontents fd =
 201   let l = 4096 in
 202   let b = Buffer.create l in
 203   let s = Bytes.create l in
 204   let rec loop () =
 205     let n = tempfailureretry (Unix.read fd s 0) l in
 206     if n = 0
 207     then Buffer.contents b
 208     else (
 209       Buffer.add_subbytes b s 0 n;
 210       loop ()
 211     )
 212   in
 213   loop ()
 214 ;;
 215
 216 let filecontents path =
 217   let fd = Unix.openfile path [Unix.O_RDONLY] 0o0 in
 218   match fdcontents fd with
 219   | (exception exn) ->
 220       error "failed to read contents of %s: %s" path @@ exntos exn
 221   | s ->
 222       Ne.clo fd @@ error "failed to close descriptor for %s: %s" path;
 223       s
 224 ;;
 225
 226 let getcmdoutput errfun cmd =
 227   let reperror fmt = Printf.kprintf errfun fmt in
 228   let clofail s e = error "failed to close %s: %s" s e in
 229   match Unix.pipe () with
 230   | (exception exn) ->
 231      reperror "pipe failed: %s" (exntos exn);
 232      E.s
 233   | (r, w) ->
 234      match popen cmd [r, -1; w, 1] with
 235      | (exception exn) ->
 236         reperror "failed to execute %S: %s" cmd (exntos exn);
 237         E.s
 238      | pid ->
 239         Ne.clo w @@ clofail "write end of the pipe";
 240         let s =
 241           match Unix.waitpid [] pid with
 242           | (exception exn) ->
 243              reperror "waitpid on %S %d failed: %s" cmd pid (exntos exn);
 244              E.s
 245           | _pid, Unix.WEXITED 0 ->
 246              begin
 247                match fdcontents r with
 248                | (exception exn) ->
 249                   reperror "failed to read output of %S: %s" cmd (exntos exn);
 250                   E.s
 251                | s ->
 252                   let l = String.length s in
 253                   if l > 0 && s.[l-1] = '\n'
 254                   then String.sub s 0 (l-1)
 255                   else s
 256              end;
 257           | _pid, Unix.WEXITED n ->
 258              reperror "%S exited with error code %d" cmd n;
 259              E.s
 260           | _pid, Unix.WSIGNALED n ->
 261              reperror "%S was killed with signal %d" cmd n;
 262              E.s
 263           | _pid, Unix.WSTOPPED n ->
 264              reperror "%S was stopped by signal %d" cmd n;
 265              E.s
 266         in
 267         Ne.clo r @@ clofail "read end of the pipe";
 268         s
 269 ;;
 270
 271 let geturl s =
 272   let colonpos = try String.index s ':' with Not_found -> -1 in
 273   let len = String.length s in
 274   if colonpos >= 0 && colonpos + 3 < len
 275   then (
 276     if s.[colonpos+1] = '/' && s.[colonpos+2] = '/'
 277     then
 278       let schemestartpos =
 279         try String.rindex_from s colonpos ' '
 280         with Not_found -> -1
 281       in
 282       let scheme =
 283         String.sub s (schemestartpos+1) (colonpos-1-schemestartpos)
 284       in
 285       match scheme with
 286       | "http" | "https" | "ftp" | "mailto" | "file" ->
 287           let epos =
 288             try String.index_from s colonpos ' '
 289             with Not_found -> len
 290           in
 291           String.sub s (schemestartpos+1) (epos-1-schemestartpos)
 292       | _ -> E.s
 293     else E.s
 294   )
 295   else E.s
 296 ;;