arch/parisc/kernel/syscall.S

   1 /*
   2  * Linux/PA-RISC Project (http://www.parisc-linux.org/)
   3  *
   4  * System call entry code Copyright (c) Matthew Wilcox 1999 <willy@bofh.ai>
   5  * Licensed under the GNU GPL.
   6  * thanks to Philipp Rumpf, Mike Shaver and various others
   7  * sorry about the wall, puffin..
   8  */
   9
  10 #include <asm/offsets.h>
  11 #include <asm/unistd.h>
  12 #include <asm/errno.h>
  13 #include <asm/psw.h>
  14 #include <asm/thread_info.h>
  15
  16 #include <asm/assembly.h>
  17 #include <asm/processor.h>
  18
  19         /* We fill the empty parts of the gateway page with
  20          * something that will kill the kernel or a
  21          * userspace application.
  22          */
  23 #define KILL_INSN       break   0,0
  24
  25 #include <linux/config.h> /* for CONFIG_SMP */
  26
  27 #ifdef __LP64__
  28         .level          2.0w
  29 #else
  30         .level          1.1
  31 #endif
  32
  33 #ifndef __LP64__
  34         .macro fixup_branch,lbl
  35         b           \lbl
  36         .endm
  37 #else
  38         .macro fixup_branch,lbl
  39         ldil        L%\lbl, %r1
  40         ldo         R%\lbl(%r1), %r1
  41         bv,n        %r0(%r1)
  42         .endm
  43 #endif
  44
  45         .text
  46
  47         .import syscall_exit,code
  48         .import syscall_exit_rfi,code
  49         .export linux_gateway_page
  50
  51         /* Linux gateway page is aliased to virtual page 0 in the kernel
  52          * address space. Since it is a gateway page it cannot be
  53          * dereferenced, so null pointers will still fault. We start
  54          * the actual entry point at 0x100. We put break instructions
  55          * at the beginning of the page to trap null indirect function
  56          * pointers.
  57          */
  58
  59         .align 4096
  60 linux_gateway_page:
  61
  62         /* ADDRESS 0x00 to 0xb0 = 176 bytes / 4 bytes per insn = 44 insns */
  63         .rept 44
  64         KILL_INSN
  65         .endr
  66
  67         /* ADDRESS 0xb0 to 0xb4, lws uses 1 insns for entry */
  68         /* Light-weight-syscall entry must always be located at 0xb0 */
  69         /* WARNING: Keep this number updated with table size changes */
  70 #define __NR_lws_entries (2)
  71
  72 lws_entry:
  73         /* Unconditional branch to lws_start, located on the
  74            same gateway page */
  75         b,n     lws_start
  76
  77         /* Fill from 0xb4 to 0xe0 */
  78         .rept 11
  79         KILL_INSN
  80         .endr
  81
  82         /* This function MUST be located at 0xe0 for glibc's threading
  83         mechanism to work. DO NOT MOVE THIS CODE EVER! */
  84 set_thread_pointer:
  85         gate    .+8, %r0                /* increase privilege */
  86         depi    3, 31, 2, %r31          /* Ensure we return into user mode. */
  87         be      0(%sr7,%r31)            /* return to user space */
  88         mtctl   %r26, %cr27             /* move arg0 to the control register */
  89
  90         /* Increase the chance of trapping if random jumps occur to this
  91         address, fill from 0xf0 to 0x100 */
  92         .rept 4
  93         KILL_INSN
  94         .endr
  95
  96 /* This address must remain fixed at 0x100 for glibc's syscalls to work */
  97         .align 256
  98 linux_gateway_entry:
  99         gate    .+8, %r0                        /* become privileged */
 100         mtsp    %r0,%sr4                        /* get kernel space into sr4 */
 101         mtsp    %r0,%sr5                        /* get kernel space into sr5 */
 102         mtsp    %r0,%sr6                        /* get kernel space into sr6 */
 103         mfsp    %sr7,%r1                        /* save user sr7 */
 104         mtsp    %r1,%sr3                        /* and store it in sr3 */
 105
 106 #ifdef __LP64__
 107         /* for now we can *always* set the W bit on entry to the syscall
 108          * since we don't support wide userland processes.  We could
 109          * also save the current SM other than in r0 and restore it on
 110          * exit from the syscall, and also use that value to know
 111          * whether to do narrow or wide syscalls. -PB
 112          */
 113         ssm     PSW_SM_W, %r1
 114         extrd,u %r1,PSW_W_BIT,1,%r1
 115         /* sp must be aligned on 4, so deposit the W bit setting into
 116          * the bottom of sp temporarily */
 117         or,ev   %r1,%r30,%r30
 118         b,n     1f
 119         /* The top halves of argument registers must be cleared on syscall
 120          * entry from narrow executable.
 121          */
 122         depdi   0, 31, 32, %r26
 123         depdi   0, 31, 32, %r25
 124         depdi   0, 31, 32, %r24
 125         depdi   0, 31, 32, %r23
 126         depdi   0, 31, 32, %r22
 127         depdi   0, 31, 32, %r21
 128 1:
 129 #endif
 130         mfctl   %cr30,%r1
 131         xor     %r1,%r30,%r30                   /* ye olde xor trick */
 132         xor     %r1,%r30,%r1
 133         xor     %r1,%r30,%r30
 134
 135         ldo     THREAD_SZ_ALGN+FRAME_SIZE(%r30),%r30  /* set up kernel stack */
 136
 137         /* N.B.: It is critical that we don't set sr7 to 0 until r30
 138          *       contains a valid kernel stack pointer. It is also
 139          *       critical that we don't start using the kernel stack
 140          *       until after sr7 has been set to 0.
 141          */
 142
 143         mtsp    %r0,%sr7                        /* get kernel space into sr7 */
 144         STREGM  %r1,FRAME_SIZE(%r30)            /* save r1 (usp) here for now */
 145         mfctl   %cr30,%r1                       /* get task ptr in %r1 */
 146         LDREG   TI_TASK(%r1),%r1
 147
 148         /* Save some registers for sigcontext and potential task
 149            switch (see entry.S for the details of which ones are
 150            saved/restored).  TASK_PT_PSW is zeroed so we can see whether
 151            a process is on a syscall or not.  For an interrupt the real
 152            PSW value is stored.  This is needed for gdb and sys_ptrace. */
 153         STREG   %r0,  TASK_PT_PSW(%r1)
 154         STREG   %r2,  TASK_PT_GR2(%r1)          /* preserve rp */
 155         STREG   %r19, TASK_PT_GR19(%r1)
 156
 157         LDREGM  -FRAME_SIZE(%r30), %r2          /* get users sp back */
 158 #ifdef __LP64__
 159         extrd,u %r2,63,1,%r19                   /* W hidden in bottom bit */
 160 #if 0
 161         xor     %r19,%r2,%r2                    /* clear bottom bit */
 162         depd,z  %r19,1,1,%r19
 163         std     %r19,TASK_PT_PSW(%r1)
 164 #endif
 165 #endif
 166         STREG   %r2,  TASK_PT_GR30(%r1)         /* ... and save it */
 167
 168         STREG   %r20, TASK_PT_GR20(%r1)
 169         STREG   %r21, TASK_PT_GR21(%r1)
 170         STREG   %r22, TASK_PT_GR22(%r1)
 171         STREG   %r23, TASK_PT_GR23(%r1)         /* 4th argument */
 172         STREG   %r24, TASK_PT_GR24(%r1)         /* 3rd argument */
 173         STREG   %r25, TASK_PT_GR25(%r1)         /* 2nd argument */
 174         STREG   %r26, TASK_PT_GR26(%r1)         /* 1st argument */
 175         STREG   %r27, TASK_PT_GR27(%r1)         /* user dp */
 176         STREG   %r28, TASK_PT_GR28(%r1)         /* return value 0 */
 177         STREG   %r28, TASK_PT_ORIG_R28(%r1)     /* return value 0 (saved for signals) */
 178         STREG   %r29, TASK_PT_GR29(%r1)         /* return value 1 */
 179         STREG   %r31, TASK_PT_GR31(%r1)         /* preserve syscall return ptr */
 180
 181         ldo     TASK_PT_FR0(%r1), %r27          /* save fpregs from the kernel */
 182         save_fp %r27                            /* or potential task switch  */
 183
 184         mfctl   %cr11, %r27                     /* i.e. SAR */
 185         STREG   %r27, TASK_PT_SAR(%r1)
 186
 187         loadgp
 188
 189 #ifdef __LP64__
 190         ldo     -16(%r30),%r29                  /* Reference param save area */
 191         copy    %r19,%r2                        /* W bit back to r2 */
 192 #else
 193         /* no need to save these on stack in wide mode because the first 8
 194          * args are passed in registers */
 195         stw     %r22, -52(%r30)                 /* 5th argument */
 196         stw     %r21, -56(%r30)                 /* 6th argument */
 197 #endif
 198
 199         /* Are we being ptraced? */
 200         mfctl   %cr30, %r1
 201         LDREG   TI_TASK(%r1),%r1
 202         LDREG   TASK_PTRACE(%r1), %r1
 203         bb,<,n  %r1,31,.Ltracesys
 204
 205         /* Note!  We cannot use the syscall table that is mapped
 206         nearby since the gateway page is mapped execute-only. */
 207
 208 #ifdef __LP64__
 209         ldil    L%sys_call_table, %r1
 210         or,=    %r2,%r2,%r2
 211         addil   L%(sys_call_table64-sys_call_table), %r1
 212         ldo     R%sys_call_table(%r1), %r19
 213         or,=    %r2,%r2,%r2
 214         ldo     R%sys_call_table64(%r1), %r19
 215 #else
 216         ldil    L%sys_call_table, %r1
 217         ldo     R%sys_call_table(%r1), %r19
 218 #endif
 219         comiclr,>>=     __NR_Linux_syscalls, %r20, %r0
 220         b,n     .Lsyscall_nosys
 221
 222         LDREGX  %r20(%r19), %r19
 223
 224         /* If this is a sys_rt_sigreturn call, and the signal was received
 225          * when not in_syscall, then we want to return via syscall_exit_rfi,
 226          * not syscall_exit.  Signal no. in r20, in_syscall in r25 (see
 227          * trampoline code in signal.c).
 228          */
 229         ldi     __NR_rt_sigreturn,%r2
 230         comb,=  %r2,%r20,.Lrt_sigreturn
 231 .Lin_syscall:
 232         ldil    L%syscall_exit,%r2
 233         be      0(%sr7,%r19)
 234         ldo     R%syscall_exit(%r2),%r2
 235 .Lrt_sigreturn:
 236         comib,<> 0,%r25,.Lin_syscall
 237         ldil    L%syscall_exit_rfi,%r2
 238         be      0(%sr7,%r19)
 239         ldo     R%syscall_exit_rfi(%r2),%r2
 240
 241         /* Note!  Because we are not running where we were linked, any
 242         calls to functions external to this file must be indirect.  To
 243         be safe, we apply the opposite rule to functions within this
 244         file, with local labels given to them to ensure correctness. */
 245
 246 .Lsyscall_nosys:
 247 syscall_nosys:
 248         ldil    L%syscall_exit,%r1
 249         be      R%syscall_exit(%sr7,%r1)
 250         ldo     -ENOSYS(%r0),%r28                  /* set errno */
 251
 252
 253 /* Warning! This trace code is a virtual duplicate of the code above so be
 254  * sure to maintain both! */
 255 .Ltracesys:
 256 tracesys:
 257         /* Need to save more registers so the debugger can see where we
 258          * are.  This saves only the lower 8 bits of PSW, so that the C
 259          * bit is still clear on syscalls, and the D bit is set if this
 260          * full register save path has been executed.  We check the D
 261          * bit on syscall_return_rfi to determine which registers to
 262          * restore.  An interrupt results in a full PSW saved with the
 263          * C bit set, a non-straced syscall entry results in C and D clear
 264          * in the saved PSW.
 265          */
 266         ldo     -THREAD_SZ_ALGN-FRAME_SIZE(%r30),%r1      /* get task ptr */
 267         LDREG   TI_TASK(%r1), %r1
 268         ssm     0,%r2
 269         STREG   %r2,TASK_PT_PSW(%r1)            /* Lower 8 bits only!! */
 270         mfsp    %sr0,%r2
 271         STREG   %r2,TASK_PT_SR0(%r1)
 272         mfsp    %sr1,%r2
 273         STREG   %r2,TASK_PT_SR1(%r1)
 274         mfsp    %sr2,%r2
 275         STREG   %r2,TASK_PT_SR2(%r1)
 276         mfsp    %sr3,%r2
 277         STREG   %r2,TASK_PT_SR3(%r1)
 278         STREG   %r2,TASK_PT_SR4(%r1)
 279         STREG   %r2,TASK_PT_SR5(%r1)
 280         STREG   %r2,TASK_PT_SR6(%r1)
 281         STREG   %r2,TASK_PT_SR7(%r1)
 282         STREG   %r2,TASK_PT_IASQ0(%r1)
 283         STREG   %r2,TASK_PT_IASQ1(%r1)
 284         LDREG   TASK_PT_GR31(%r1),%r2
 285         STREG   %r2,TASK_PT_IAOQ0(%r1)
 286         ldo     4(%r2),%r2
 287         STREG   %r2,TASK_PT_IAOQ1(%r1)
 288         ldo     TASK_REGS(%r1),%r2
 289         /* reg_save %r2 */
 290         STREG   %r3,PT_GR3(%r2)
 291         STREG   %r4,PT_GR4(%r2)
 292         STREG   %r5,PT_GR5(%r2)
 293         STREG   %r6,PT_GR6(%r2)
 294         STREG   %r7,PT_GR7(%r2)
 295         STREG   %r8,PT_GR8(%r2)
 296         STREG   %r9,PT_GR9(%r2)
 297         STREG   %r10,PT_GR10(%r2)
 298         STREG   %r11,PT_GR11(%r2)
 299         STREG   %r12,PT_GR12(%r2)
 300         STREG   %r13,PT_GR13(%r2)
 301         STREG   %r14,PT_GR14(%r2)
 302         STREG   %r15,PT_GR15(%r2)
 303         STREG   %r16,PT_GR16(%r2)
 304         STREG   %r17,PT_GR17(%r2)
 305         STREG   %r18,PT_GR18(%r2)
 306         /* Finished saving things for the debugger */
 307
 308         ldil    L%syscall_trace,%r1
 309         ldil    L%tracesys_next,%r2
 310         be      R%syscall_trace(%sr7,%r1)
 311         ldo     R%tracesys_next(%r2),%r2
 312
 313 tracesys_next:
 314         ldil    L%sys_call_table,%r1
 315         ldo     R%sys_call_table(%r1), %r19
 316
 317         ldo     -THREAD_SZ_ALGN-FRAME_SIZE(%r30),%r1      /* get task ptr */
 318         LDREG   TI_TASK(%r1), %r1
 319         LDREG   TASK_PT_GR20(%r1), %r20
 320         LDREG   TASK_PT_GR26(%r1), %r26         /* Restore the users args */
 321         LDREG   TASK_PT_GR25(%r1), %r25
 322         LDREG   TASK_PT_GR24(%r1), %r24
 323         LDREG   TASK_PT_GR23(%r1), %r23
 324 #ifdef __LP64__
 325         LDREG   TASK_PT_GR22(%r1), %r22
 326         LDREG   TASK_PT_GR21(%r1), %r21
 327         ldo     -16(%r30),%r29                  /* Reference param save area */
 328 #endif
 329
 330         comiclr,>>=     __NR_Linux_syscalls, %r20, %r0
 331         b,n     .Lsyscall_nosys
 332
 333         LDREGX  %r20(%r19), %r19
 334
 335         /* If this is a sys_rt_sigreturn call, and the signal was received
 336          * when not in_syscall, then we want to return via syscall_exit_rfi,
 337          * not syscall_exit.  Signal no. in r20, in_syscall in r25 (see
 338          * trampoline code in signal.c).
 339          */
 340         ldi     __NR_rt_sigreturn,%r2
 341         comb,=  %r2,%r20,.Ltrace_rt_sigreturn
 342 .Ltrace_in_syscall:
 343         ldil    L%tracesys_exit,%r2
 344         be      0(%sr7,%r19)
 345         ldo     R%tracesys_exit(%r2),%r2
 346
 347         /* Do *not* call this function on the gateway page, because it
 348         makes a direct call to syscall_trace. */
 349
 350 tracesys_exit:
 351         ldo     -THREAD_SZ_ALGN-FRAME_SIZE(%r30),%r1      /* get task ptr */
 352         LDREG   TI_TASK(%r1), %r1
 353 #ifdef __LP64__
 354         ldo     -16(%r30),%r29                  /* Reference param save area */
 355 #endif
 356         bl      syscall_trace, %r2
 357         STREG   %r28,TASK_PT_GR28(%r1)          /* save return value now */
 358         ldo     -THREAD_SZ_ALGN-FRAME_SIZE(%r30),%r1      /* get task ptr */
 359         LDREG   TI_TASK(%r1), %r1
 360         LDREG   TASK_PT_GR28(%r1), %r28         /* Restore return val. */
 361
 362         ldil    L%syscall_exit,%r1
 363         be,n    R%syscall_exit(%sr7,%r1)
 364
 365 .Ltrace_rt_sigreturn:
 366         comib,<> 0,%r25,.Ltrace_in_syscall
 367         ldil    L%tracesys_sigexit,%r2
 368         be      0(%sr7,%r19)
 369         ldo     R%tracesys_sigexit(%r2),%r2
 370
 371 tracesys_sigexit:
 372         ldo     -THREAD_SZ_ALGN-FRAME_SIZE(%r30),%r1      /* get task ptr */
 373         LDREG   0(%r1), %r1
 374 #ifdef __LP64__
 375         ldo     -16(%r30),%r29                  /* Reference param save area */
 376 #endif
 377         bl      syscall_trace, %r2
 378         nop
 379
 380         ldil    L%syscall_exit_rfi,%r1
 381         be,n    R%syscall_exit_rfi(%sr7,%r1)
 382
 383
 384         /*********************************************************
 385                 Light-weight-syscall code
 386
 387                 r20 - lws number
 388                 r26,r25,r24,r23,r22 - Input registers
 389                 r28 - Function return register
 390                 r21 - Error code.
 391
 392                 Scracth: Any of the above that aren't being
 393                 currently used, including r1.
 394
 395                 Return pointer: r31 (Not usable)
 396
 397                 Error codes returned by entry path:
 398
 399                 ENOSYS - r20 was an invalid LWS number.
 400
 401         *********************************************************/
 402 lws_start:
 403         /* Gate and ensure we return to userspace */
 404         gate    .+8, %r0
 405         depi    3, 31, 2, %r31  /* Ensure we return to userspace */
 406
 407 #ifdef __LP64__
 408         /* FIXME: If we are a 64-bit kernel just
 409          *        turn this on unconditionally.
 410          */
 411         ssm     PSW_SM_W, %r1
 412         extrd,u %r1,PSW_W_BIT,1,%r1
 413         /* sp must be aligned on 4, so deposit the W bit setting into
 414          * the bottom of sp temporarily */
 415         or,ev   %r1,%r30,%r30
 416
 417         /* Clip LWS number to a 32-bit value always */
 418         depdi   0, 31, 32, %r20
 419 #endif
 420
 421         /* Is the lws entry number valid? */
 422         comiclr,>>=     __NR_lws_entries, %r20, %r0
 423         b,n     lws_exit_nosys
 424
 425         /* WARNING: Trashing sr2 and sr3 */
 426         mfsp    %sr7,%r1                        /* get userspace into sr3 */
 427         mtsp    %r1,%sr3
 428         mtsp    %r0,%sr2                        /* get kernel space into sr2 */
 429
 430         /* Load table start */
 431         ldil    L%lws_table, %r1
 432         ldo     R%lws_table(%r1), %r28  /* Scratch use of r28 */
 433         LDREGX  %r20(%sr2,r28), %r21    /* Scratch use of r21 */
 434
 435         /* Jump to lws, lws table pointers already relocated */
 436         be,n    0(%sr2,%r21)
 437
 438 lws_exit_nosys:
 439         ldo     -ENOSYS(%r0),%r21                  /* set errno */
 440         /* Fall through: Return to userspace */
 441
 442 lws_exit:
 443 #ifdef __LP64__
 444         /* decide whether to reset the wide mode bit
 445          *
 446          * For a syscall, the W bit is stored in the lowest bit
 447          * of sp.  Extract it and reset W if it is zero */
 448         extrd,u,*<>     %r30,63,1,%r1
 449         rsm     PSW_SM_W, %r0
 450         /* now reset the lowest bit of sp if it was set */
 451         xor     %r30,%r1,%r30
 452 #endif
 453         be,n    0(%sr3, %r31)
 454
 455
 456
 457         /***************************************************
 458                 Implementing CAS as an atomic operation:
 459
 460                 %r26 - Address to examine
 461                 %r25 - Old value to check (old)
 462                 %r24 - New value to set (new)
 463                 %r28 - Return prev through this register.
 464                 %r21 - Kernel error code
 465
 466                 If debugging is DISabled:
 467
 468                 %r21 has the following meanings:
 469
 470                 EAGAIN - CAS is busy, ldcw failed, try again.
 471                 EFAULT - Read or write failed.
 472
 473                 If debugging is enabled:
 474
 475                 EDEADLOCK - CAS called recursively.
 476                 EAGAIN && r28 == 1 - CAS is busy. Lock contended.
 477                 EAGAIN && r28 == 2 - CAS is busy. ldcw failed.
 478                 EFAULT - Read or write failed.
 479
 480                 Scratch: r20, r28, r1
 481
 482         ****************************************************/
 483
 484         /* Do not enable LWS debugging */
 485 #define ENABLE_LWS_DEBUG 0
 486
 487         /* ELF64 Process entry path */
 488 lws_compare_and_swap64:
 489 #ifdef __LP64__
 490         b,n     lws_compare_and_swap
 491 #else
 492         /* If we are not a 64-bit kernel, then we don't
 493          * implement having 64-bit input registers
 494          */
 495         b,n     lws_exit_nosys
 496 #endif
 497
 498         /* ELF32 Process entry path */
 499 lws_compare_and_swap32:
 500 #ifdef __LP64__
 501         /* Clip all the input registers */
 502         depdi   0, 31, 32, %r26
 503         depdi   0, 31, 32, %r25
 504         depdi   0, 31, 32, %r24
 505 #endif
 506
 507 lws_compare_and_swap:
 508 #ifdef CONFIG_SMP
 509         /* Load start of lock table */
 510         ldil    L%lws_lock_start, %r20
 511         ldo     R%lws_lock_start(%r20), %r28
 512
 513         /* Extract four bits from r26 and hash lock (Bits 4-7) */
 514         extru  %r26, 27, 4, %r20
 515
 516         /* Find lock to use, the hash is either one of 0 to
 517            15, multiplied by 16 (keep it 16-byte aligned)
 518            and add to the lock table offset. */
 519         shlw    %r20, 4, %r20
 520         add     %r20, %r28, %r20
 521
 522 # ifdef ENABLE_LWS_DEBUG
 523         /*
 524                 DEBUG, check for deadlock!
 525                 If the thread register values are the same
 526                 then we were the one that locked it last and
 527                 this is a recurisve call that will deadlock.
 528                 We *must* giveup this call and fail.
 529         */
 530         ldw     4(%sr2,%r20), %r28                      /* Load thread register */
 531         mfctl   %cr27, %r21                             /* Get current thread register */
 532         cmpb,<>,n       %r21, %r28, cas_lock            /* Called recursive? */
 533         b       lws_exit                                /* Return error! */
 534         ldo     -EDEADLOCK(%r0), %r21
 535 cas_lock:
 536         cmpb,=,n        %r0, %r28, cas_nocontend        /* Is nobody using it? */
 537         ldo     1(%r0), %r28                            /* 1st case */
 538         b       lws_exit                                /* Contended... */
 539         ldo     -EAGAIN(%r0), %r21                      /* Spin in userspace */
 540 cas_nocontend:
 541 # endif
 542 /* ENABLE_LWS_DEBUG */
 543
 544         ldcw    0(%sr2,%r20), %r28                      /* Try to acquire the lock */
 545         cmpb,<>,n       %r0, %r28, cas_action           /* Did we get it? */
 546 cas_wouldblock:
 547         ldo     2(%r0), %r28                            /* 2nd case */
 548         b       lws_exit                                /* Contended... */
 549         ldo     -EAGAIN(%r0), %r21                      /* Spin in userspace */
 550 #endif
 551 /* CONFIG_SMP */
 552
 553         /*
 554                 prev = *addr;
 555                 if ( prev == old )
 556                   *addr = new;
 557                 return prev;
 558         */
 559
 560         /* NOTES:
 561                 This all works becuse intr_do_signal
 562                 and schedule both check the return iasq
 563                 and see that we are on the kernel page
 564                 so this process is never scheduled off
 565                 or is ever sent any signal of any sort,
 566                 thus it is wholly atomic from usrspaces
 567                 perspective
 568         */
 569 cas_action:
 570 #if defined CONFIG_SMP && defined ENABLE_LWS_DEBUG
 571         /* DEBUG */
 572         mfctl   %cr27, %r1
 573         stw     %r1, 4(%sr2,%r20)
 574 #endif
 575         /* The load and store could fail */
 576 1:      ldw     0(%sr3,%r26), %r28
 577         sub,<>  %r28, %r25, %r0
 578 2:      stw     %r24, 0(%sr3,%r26)
 579 #ifdef CONFIG_SMP
 580         /* Free lock */
 581         stw     %r20, 0(%sr2,%r20)
 582 # ifdef ENABLE_LWS_DEBUG
 583         /* Clear thread register indicator */
 584         stw     %r0, 4(%sr2,%r20)
 585 # endif
 586 #endif
 587         /* Return to userspace, set no error */
 588         b       lws_exit
 589         copy    %r0, %r21
 590
 591 3:
 592         /* Error occured on load or store */
 593 #ifdef CONFIG_SMP
 594         /* Free lock */
 595         stw     %r20, 0(%sr2,%r20)
 596 # ifdef ENABLE_LWS_DEBUG
 597         stw     %r0, 4(%sr2,%r20)
 598 # endif
 599 #endif
 600         b       lws_exit
 601         ldo     -EFAULT(%r0),%r21       /* set errno */
 602         nop
 603         nop
 604         nop
 605         nop
 606
 607         /* Two exception table entries, one for the load,
 608            the other for the store. Either return -EFAULT.
 609            Each of the entries must be relocated. */
 610         .section __ex_table,"aw"
 611 #ifdef __LP64__
 612         /* Pad the address calculation */
 613         .word   0,(2b - linux_gateway_page)
 614         .word   0,(3b - linux_gateway_page)
 615 #else
 616         .word   (2b - linux_gateway_page)
 617         .word   (3b - linux_gateway_page)
 618 #endif
 619         .previous
 620
 621         .section __ex_table,"aw"
 622 #ifdef __LP64__
 623         /* Pad the address calculation */
 624         .word   0,(1b - linux_gateway_page)
 625         .word   0,(3b - linux_gateway_page)
 626 #else
 627         .word   (1b - linux_gateway_page)
 628         .word   (3b - linux_gateway_page)
 629 #endif
 630         .previous
 631
 632 end_compare_and_swap:
 633
 634         /* Make sure nothing else is placed on this page */
 635         .align 4096
 636         .export end_linux_gateway_page
 637 end_linux_gateway_page:
 638
 639         /* Relocate symbols assuming linux_gateway_page is mapped
 640            to virtual address 0x0 */
 641 #ifdef __LP64__
 642         /* FIXME: The code will always be on the gateay page
 643                   and thus it will be on the first 4k, the
 644                   assembler seems to think that the final
 645                   subtraction result is only a word in
 646                   length, so we pad the value.
 647         */
 648 #define LWS_ENTRY(_name_) .word 0,(lws_##_name_ - linux_gateway_page)
 649 #else
 650 #define LWS_ENTRY(_name_) .word  (lws_##_name_ - linux_gateway_page)
 651 #endif
 652
 653         .align 4096
 654         /* Light-weight-syscall table */
 655         /* Start of lws table. */
 656         .export lws_table
 657 .Llws_table:
 658 lws_table:
 659         LWS_ENTRY(compare_and_swap32)   /* 0 - ELF32 Atomic compare and swap */
 660         LWS_ENTRY(compare_and_swap64)   /* 1 - ELF64 Atomic compare and swap */
 661         /* End of lws table */
 662
 663         .align 4096
 664         .export sys_call_table
 665 .Lsys_call_table:
 666 sys_call_table:
 667 #include "syscall_table.S"
 668
 669 #ifdef __LP64__
 670         .align 4096
 671         .export sys_call_table64
 672 .Lsys_call_table64:
 673 sys_call_table64:
 674 #define SYSCALL_TABLE_64BIT
 675 #include "syscall_table.S"
 676 #endif
 677
 678 #ifdef CONFIG_SMP
 679         /*
 680                 All light-weight-syscall atomic operations
 681                 will use this set of locks
 682         */
 683         .section .data
 684         .align 4096
 685         .export lws_lock_start
 686 .Llws_lock_start:
 687 lws_lock_start:
 688         /* lws locks */
 689         .align 16
 690         .rept 16
 691         /* Keep locks aligned at 16-bytes */
 692         .word 1
 693         .word 0
 694         .word 0
 695         .word 0
 696         .endr
 697         .previous
 698 #endif
 699 /* CONFIG_SMP for lws_lock_start */
 700
 701 .end
 702
 703