| blob | bc2121fa9132cc9cad2209cacee3896fdbeb5370 |
1 /*
2 * Helper macros to support writing architecture specific
3 * linker scripts.
4 *
5 * A minimal linker scripts has following content:
6 * [This is a sample, architectures may have special requiriements]
7 *
8 * OUTPUT_FORMAT(...)
9 * OUTPUT_ARCH(...)
10 * ENTRY(...)
11 * SECTIONS
12 * {
13 * . = START;
14 * __init_begin = .;
15 * HEAD_TEXT_SECTION
16 * INIT_TEXT_SECTION(PAGE_SIZE)
17 * INIT_DATA_SECTION(...)
18 * PERCPU_SECTION(CACHELINE_SIZE)
19 * __init_end = .;
20 *
21 * _stext = .;
22 * TEXT_SECTION = 0
23 * _etext = .;
24 *
25 * _sdata = .;
26 * RO_DATA_SECTION(PAGE_SIZE)
27 * RW_DATA_SECTION(...)
28 * _edata = .;
29 *
30 * EXCEPTION_TABLE(...)
31 * NOTES
32 *
33 * BSS_SECTION(0, 0, 0)
34 * _end = .;
35 *
36 * STABS_DEBUG
37 * DWARF_DEBUG
38 *
39 * DISCARDS // must be the last
40 * }
41 *
42 * [__init_begin, __init_end] is the init section that may be freed after init
43 * [_stext, _etext] is the text section
44 * [_sdata, _edata] is the data section
45 *
46 * Some of the included output section have their own set of constants.
47 * Examples are: [__initramfs_start, __initramfs_end] for initramfs and
48 * [__nosave_begin, __nosave_end] for the nosave data
49 */
51 #ifndef LOAD_OFFSET
52 #define LOAD_OFFSET 0
53 #endif
55 #include <linux/export.h>
57 /* Align . to a 8 byte boundary equals to maximum function alignment. */
58 #define ALIGN_FUNCTION() . = ALIGN(8)
60 /*
61 * Align to a 32 byte boundary equal to the
62 * alignment gcc 4.5 uses for a struct
63 */
64 #define STRUCT_ALIGNMENT 32
65 #define STRUCT_ALIGN() . = ALIGN(STRUCT_ALIGNMENT)
67 /* The actual configuration determine if the init/exit sections
68 * are handled as text/data or they can be discarded (which
69 * often happens at runtime)
70 */
71 #ifdef CONFIG_HOTPLUG_CPU
72 #define CPU_KEEP(sec) *(.cpu##sec)
73 #define CPU_DISCARD(sec)
74 #else
75 #define CPU_KEEP(sec)
76 #define CPU_DISCARD(sec) *(.cpu##sec)
77 #endif
79 #if defined(CONFIG_MEMORY_HOTPLUG)
80 #define MEM_KEEP(sec) *(.mem##sec)
81 #define MEM_DISCARD(sec)
82 #else
83 #define MEM_KEEP(sec)
84 #define MEM_DISCARD(sec) *(.mem##sec)
85 #endif
87 #ifdef CONFIG_FTRACE_MCOUNT_RECORD
88 #define MCOUNT_REC() . = ALIGN(8); \
89 VMLINUX_SYMBOL(__start_mcount_loc) = .; \
90 *(__mcount_loc) \
91 VMLINUX_SYMBOL(__stop_mcount_loc) = .;
92 #else
93 #define MCOUNT_REC()
94 #endif
96 #ifdef CONFIG_TRACE_BRANCH_PROFILING
97 #define LIKELY_PROFILE() VMLINUX_SYMBOL(__start_annotated_branch_profile) = .; \
98 *(_ftrace_annotated_branch) \
99 VMLINUX_SYMBOL(__stop_annotated_branch_profile) = .;
100 #else
101 #define LIKELY_PROFILE()
102 #endif
104 #ifdef CONFIG_PROFILE_ALL_BRANCHES
105 #define BRANCH_PROFILE() VMLINUX_SYMBOL(__start_branch_profile) = .; \
106 *(_ftrace_branch) \
107 VMLINUX_SYMBOL(__stop_branch_profile) = .;
108 #else
109 #define BRANCH_PROFILE()
110 #endif
112 #ifdef CONFIG_EVENT_TRACING
113 #define FTRACE_EVENTS() . = ALIGN(8); \
114 VMLINUX_SYMBOL(__start_ftrace_events) = .; \
115 *(_ftrace_events) \
116 VMLINUX_SYMBOL(__stop_ftrace_events) = .;
117 #else
118 #define FTRACE_EVENTS()
119 #endif
121 #ifdef CONFIG_TRACING
122 #define TRACE_PRINTKS() VMLINUX_SYMBOL(__start___trace_bprintk_fmt) = .; \
124 VMLINUX_SYMBOL(__stop___trace_bprintk_fmt) = .;
125 #define TRACEPOINT_STR() VMLINUX_SYMBOL(__start___tracepoint_str) = .; \
127 VMLINUX_SYMBOL(__stop___tracepoint_str) = .;
128 #else
129 #define TRACE_PRINTKS()
130 #define TRACEPOINT_STR()
131 #endif
133 #ifdef CONFIG_FTRACE_SYSCALLS
134 #define TRACE_SYSCALLS() . = ALIGN(8); \
135 VMLINUX_SYMBOL(__start_syscalls_metadata) = .; \
136 *(__syscalls_metadata) \
137 VMLINUX_SYMBOL(__stop_syscalls_metadata) = .;
138 #else
139 #define TRACE_SYSCALLS()
140 #endif
142 #ifdef CONFIG_CLKSRC_OF
143 #define CLKSRC_OF_TABLES() . = ALIGN(8); \
144 VMLINUX_SYMBOL(__clksrc_of_table) = .; \
145 *(__clksrc_of_table) \
146 *(__clksrc_of_table_end)
147 #else
148 #define CLKSRC_OF_TABLES()
149 #endif
151 #ifdef CONFIG_IRQCHIP
152 #define IRQCHIP_OF_MATCH_TABLE() \
153 . = ALIGN(8); \
154 VMLINUX_SYMBOL(__irqchip_begin) = .; \
155 *(__irqchip_of_table) \
156 *(__irqchip_of_end)
157 #else
158 #define IRQCHIP_OF_MATCH_TABLE()
159 #endif
161 #ifdef CONFIG_COMMON_CLK
162 #define CLK_OF_TABLES() . = ALIGN(8); \
163 VMLINUX_SYMBOL(__clk_of_table) = .; \
164 *(__clk_of_table) \
165 *(__clk_of_table_end)
166 #else
167 #define CLK_OF_TABLES()
168 #endif
170 #define KERNEL_DTB() \
171 STRUCT_ALIGN(); \
172 VMLINUX_SYMBOL(__dtb_start) = .; \
173 *(.dtb.init.rodata) \
174 VMLINUX_SYMBOL(__dtb_end) = .;
176 /* .data section */
177 #define DATA_DATA \
178 *(.data) \
179 *(.ref.data) \
181 MEM_KEEP(init.data) \
182 MEM_KEEP(exit.data) \
183 *(.data.unlikely) \
184 STRUCT_ALIGN(); \
185 *(__tracepoints) \
187 . = ALIGN(8); \
188 VMLINUX_SYMBOL(__start___jump_table) = .; \
189 *(__jump_table) \
190 VMLINUX_SYMBOL(__stop___jump_table) = .; \
191 . = ALIGN(8); \
192 VMLINUX_SYMBOL(__start___verbose) = .; \
193 *(__verbose) \
194 VMLINUX_SYMBOL(__stop___verbose) = .; \
195 LIKELY_PROFILE() \
196 BRANCH_PROFILE() \
197 TRACE_PRINTKS() \
198 TRACEPOINT_STR()
200 /*
201 * Data section helpers
202 */
203 #define NOSAVE_DATA \
204 . = ALIGN(PAGE_SIZE); \
205 VMLINUX_SYMBOL(__nosave_begin) = .; \
206 *(.data..nosave) \
207 . = ALIGN(PAGE_SIZE); \
208 VMLINUX_SYMBOL(__nosave_end) = .;
210 #define PAGE_ALIGNED_DATA(page_align) \
211 . = ALIGN(page_align); \
212 *(.data..page_aligned)
214 #define READ_MOSTLY_DATA(align) \
215 . = ALIGN(align); \
216 *(.data..read_mostly) \
217 . = ALIGN(align);
219 #define CACHELINE_ALIGNED_DATA(align) \
220 . = ALIGN(align); \
221 *(.data..cacheline_aligned)
223 #define INIT_TASK_DATA(align) \
224 . = ALIGN(align); \
225 *(.data..init_task)
227 /*
228 * Read only Data
229 */
230 #define RO_DATA_SECTION(align) \
231 . = ALIGN((align)); \
232 .rodata : AT(ADDR(.rodata) - LOAD_OFFSET) { \
233 VMLINUX_SYMBOL(__start_rodata) = .; \
234 *(.rodata) *(.rodata.*) \
236 . = ALIGN(8); \
237 VMLINUX_SYMBOL(__start___tracepoints_ptrs) = .; \
239 VMLINUX_SYMBOL(__stop___tracepoints_ptrs) = .; \
241 } \
242 \
243 .rodata1 : AT(ADDR(.rodata1) - LOAD_OFFSET) { \
244 *(.rodata1) \
245 } \
246 \
247 BUG_TABLE \
248 \
250 .pci_fixup : AT(ADDR(.pci_fixup) - LOAD_OFFSET) { \
251 VMLINUX_SYMBOL(__start_pci_fixups_early) = .; \
252 *(.pci_fixup_early) \
253 VMLINUX_SYMBOL(__end_pci_fixups_early) = .; \
254 VMLINUX_SYMBOL(__start_pci_fixups_header) = .; \
255 *(.pci_fixup_header) \
256 VMLINUX_SYMBOL(__end_pci_fixups_header) = .; \
257 VMLINUX_SYMBOL(__start_pci_fixups_final) = .; \
258 *(.pci_fixup_final) \
259 VMLINUX_SYMBOL(__end_pci_fixups_final) = .; \
260 VMLINUX_SYMBOL(__start_pci_fixups_enable) = .; \
261 *(.pci_fixup_enable) \
262 VMLINUX_SYMBOL(__end_pci_fixups_enable) = .; \
263 VMLINUX_SYMBOL(__start_pci_fixups_resume) = .; \
264 *(.pci_fixup_resume) \
265 VMLINUX_SYMBOL(__end_pci_fixups_resume) = .; \
266 VMLINUX_SYMBOL(__start_pci_fixups_resume_early) = .; \
267 *(.pci_fixup_resume_early) \
268 VMLINUX_SYMBOL(__end_pci_fixups_resume_early) = .; \
269 VMLINUX_SYMBOL(__start_pci_fixups_suspend) = .; \
270 *(.pci_fixup_suspend) \
271 VMLINUX_SYMBOL(__end_pci_fixups_suspend) = .; \
272 } \
273 \
275 .builtin_fw : AT(ADDR(.builtin_fw) - LOAD_OFFSET) { \
276 VMLINUX_SYMBOL(__start_builtin_fw) = .; \
277 *(.builtin_fw) \
278 VMLINUX_SYMBOL(__end_builtin_fw) = .; \
279 } \
280 \
281 TRACEDATA \
282 \
284 __ksymtab : AT(ADDR(__ksymtab) - LOAD_OFFSET) { \
285 VMLINUX_SYMBOL(__start___ksymtab) = .; \
286 *(SORT(___ksymtab+*)) \
287 VMLINUX_SYMBOL(__stop___ksymtab) = .; \
288 } \
289 \
291 __ksymtab_gpl : AT(ADDR(__ksymtab_gpl) - LOAD_OFFSET) { \
292 VMLINUX_SYMBOL(__start___ksymtab_gpl) = .; \
293 *(SORT(___ksymtab_gpl+*)) \
294 VMLINUX_SYMBOL(__stop___ksymtab_gpl) = .; \
295 } \
296 \
298 __ksymtab_unused : AT(ADDR(__ksymtab_unused) - LOAD_OFFSET) { \
299 VMLINUX_SYMBOL(__start___ksymtab_unused) = .; \
300 *(SORT(___ksymtab_unused+*)) \
301 VMLINUX_SYMBOL(__stop___ksymtab_unused) = .; \
302 } \
303 \
305 __ksymtab_unused_gpl : AT(ADDR(__ksymtab_unused_gpl) - LOAD_OFFSET) { \
306 VMLINUX_SYMBOL(__start___ksymtab_unused_gpl) = .; \
307 *(SORT(___ksymtab_unused_gpl+*)) \
308 VMLINUX_SYMBOL(__stop___ksymtab_unused_gpl) = .; \
309 } \
310 \
312 __ksymtab_gpl_future : AT(ADDR(__ksymtab_gpl_future) - LOAD_OFFSET) { \
313 VMLINUX_SYMBOL(__start___ksymtab_gpl_future) = .; \
314 *(SORT(___ksymtab_gpl_future+*)) \
315 VMLINUX_SYMBOL(__stop___ksymtab_gpl_future) = .; \
316 } \
317 \
319 __kcrctab : AT(ADDR(__kcrctab) - LOAD_OFFSET) { \
320 VMLINUX_SYMBOL(__start___kcrctab) = .; \
321 *(SORT(___kcrctab+*)) \
322 VMLINUX_SYMBOL(__stop___kcrctab) = .; \
323 } \
324 \
326 __kcrctab_gpl : AT(ADDR(__kcrctab_gpl) - LOAD_OFFSET) { \
327 VMLINUX_SYMBOL(__start___kcrctab_gpl) = .; \
328 *(SORT(___kcrctab_gpl+*)) \
329 VMLINUX_SYMBOL(__stop___kcrctab_gpl) = .; \
330 } \
331 \
333 __kcrctab_unused : AT(ADDR(__kcrctab_unused) - LOAD_OFFSET) { \
334 VMLINUX_SYMBOL(__start___kcrctab_unused) = .; \
335 *(SORT(___kcrctab_unused+*)) \
336 VMLINUX_SYMBOL(__stop___kcrctab_unused) = .; \
337 } \
338 \
340 __kcrctab_unused_gpl : AT(ADDR(__kcrctab_unused_gpl) - LOAD_OFFSET) { \
341 VMLINUX_SYMBOL(__start___kcrctab_unused_gpl) = .; \
342 *(SORT(___kcrctab_unused_gpl+*)) \
343 VMLINUX_SYMBOL(__stop___kcrctab_unused_gpl) = .; \
344 } \
345 \
347 __kcrctab_gpl_future : AT(ADDR(__kcrctab_gpl_future) - LOAD_OFFSET) { \
348 VMLINUX_SYMBOL(__start___kcrctab_gpl_future) = .; \
349 *(SORT(___kcrctab_gpl_future+*)) \
350 VMLINUX_SYMBOL(__stop___kcrctab_gpl_future) = .; \
351 } \
352 \
354 __ksymtab_strings : AT(ADDR(__ksymtab_strings) - LOAD_OFFSET) { \
355 *(__ksymtab_strings) \
356 } \
357 \
359 __init_rodata : AT(ADDR(__init_rodata) - LOAD_OFFSET) { \
360 *(.ref.rodata) \
361 MEM_KEEP(init.rodata) \
362 MEM_KEEP(exit.rodata) \
363 } \
364 \
366 __param : AT(ADDR(__param) - LOAD_OFFSET) { \
367 VMLINUX_SYMBOL(__start___param) = .; \
368 *(__param) \
369 VMLINUX_SYMBOL(__stop___param) = .; \
370 } \
371 \
373 __modver : AT(ADDR(__modver) - LOAD_OFFSET) { \
374 VMLINUX_SYMBOL(__start___modver) = .; \
375 *(__modver) \
376 VMLINUX_SYMBOL(__stop___modver) = .; \
377 . = ALIGN((align)); \
378 VMLINUX_SYMBOL(__end_rodata) = .; \
379 } \
380 . = ALIGN((align));
382 /* RODATA & RO_DATA provided for backward compatibility.
383 * All archs are supposed to use RO_DATA() */
384 #define RODATA RO_DATA_SECTION(4096)
385 #define RO_DATA(align) RO_DATA_SECTION(align)
387 #define SECURITY_INIT \
388 .security_initcall.init : AT(ADDR(.security_initcall.init) - LOAD_OFFSET) { \
389 VMLINUX_SYMBOL(__security_initcall_start) = .; \
390 *(.security_initcall.init) \
391 VMLINUX_SYMBOL(__security_initcall_end) = .; \
392 }
394 /* .text section. Map to function alignment to avoid address changes
395 * during second ld run in second ld pass when generating System.map */
396 #define TEXT_TEXT \
397 ALIGN_FUNCTION(); \
398 *(.text.hot) \
399 *(.text) \
400 *(.ref.text) \
401 MEM_KEEP(init.text) \
402 MEM_KEEP(exit.text) \
403 *(.text.unlikely)
406 /* sched.text is aling to function alignment to secure we have same
407 * address even at second ld pass when generating System.map */
408 #define SCHED_TEXT \
409 ALIGN_FUNCTION(); \
410 VMLINUX_SYMBOL(__sched_text_start) = .; \
411 *(.sched.text) \
412 VMLINUX_SYMBOL(__sched_text_end) = .;
414 /* spinlock.text is aling to function alignment to secure we have same
415 * address even at second ld pass when generating System.map */
416 #define LOCK_TEXT \
417 ALIGN_FUNCTION(); \
418 VMLINUX_SYMBOL(__lock_text_start) = .; \
419 *(.spinlock.text) \
420 VMLINUX_SYMBOL(__lock_text_end) = .;
422 #define KPROBES_TEXT \
423 ALIGN_FUNCTION(); \
424 VMLINUX_SYMBOL(__kprobes_text_start) = .; \
425 *(.kprobes.text) \
426 VMLINUX_SYMBOL(__kprobes_text_end) = .;
428 #define ENTRY_TEXT \
429 ALIGN_FUNCTION(); \
430 VMLINUX_SYMBOL(__entry_text_start) = .; \
431 *(.entry.text) \
432 VMLINUX_SYMBOL(__entry_text_end) = .;
434 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
435 #define IRQENTRY_TEXT \
436 ALIGN_FUNCTION(); \
437 VMLINUX_SYMBOL(__irqentry_text_start) = .; \
438 *(.irqentry.text) \
439 VMLINUX_SYMBOL(__irqentry_text_end) = .;
440 #else
441 #define IRQENTRY_TEXT
442 #endif
444 /* Section used for early init (in .S files) */
445 #define HEAD_TEXT *(.head.text)
447 #define HEAD_TEXT_SECTION \
448 .head.text : AT(ADDR(.head.text) - LOAD_OFFSET) { \
449 HEAD_TEXT \
450 }
452 /*
453 * Exception table
454 */
455 #define EXCEPTION_TABLE(align) \
456 . = ALIGN(align); \
457 __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) { \
458 VMLINUX_SYMBOL(__start___ex_table) = .; \
459 *(__ex_table) \
460 VMLINUX_SYMBOL(__stop___ex_table) = .; \
461 }
463 /*
464 * Init task
465 */
466 #define INIT_TASK_DATA_SECTION(align) \
467 . = ALIGN(align); \
468 .data..init_task : AT(ADDR(.data..init_task) - LOAD_OFFSET) { \
469 INIT_TASK_DATA(align) \
470 }
472 #ifdef CONFIG_CONSTRUCTORS
473 #define KERNEL_CTORS() . = ALIGN(8); \
474 VMLINUX_SYMBOL(__ctors_start) = .; \
475 *(.ctors) \
476 *(.init_array) \
477 VMLINUX_SYMBOL(__ctors_end) = .;
478 #else
479 #define KERNEL_CTORS()
480 #endif
482 /* init and exit section handling */
483 #define INIT_DATA \
484 *(.init.data) \
485 MEM_DISCARD(init.data) \
486 KERNEL_CTORS() \
487 MCOUNT_REC() \
488 *(.init.rodata) \
489 FTRACE_EVENTS() \
490 TRACE_SYSCALLS() \
491 MEM_DISCARD(init.rodata) \
492 CLK_OF_TABLES() \
493 CLKSRC_OF_TABLES() \
494 KERNEL_DTB() \
495 IRQCHIP_OF_MATCH_TABLE()
497 #define INIT_TEXT \
498 *(.init.text) \
499 MEM_DISCARD(init.text)
501 #define EXIT_DATA \
502 *(.exit.data) \
503 MEM_DISCARD(exit.data) \
504 MEM_DISCARD(exit.rodata)
506 #define EXIT_TEXT \
507 *(.exit.text) \
508 MEM_DISCARD(exit.text)
510 #define EXIT_CALL \
511 *(.exitcall.exit)
513 /*
514 * bss (Block Started by Symbol) - uninitialized data
515 * zeroed during startup
516 */
517 #define SBSS(sbss_align) \
518 . = ALIGN(sbss_align); \
519 .sbss : AT(ADDR(.sbss) - LOAD_OFFSET) { \
520 *(.sbss) \
521 *(.scommon) \
522 }
524 /*
525 * Allow archectures to redefine BSS_FIRST_SECTIONS to add extra
526 * sections to the front of bss.
527 */
528 #ifndef BSS_FIRST_SECTIONS
529 #define BSS_FIRST_SECTIONS
530 #endif
532 #define BSS(bss_align) \
533 . = ALIGN(bss_align); \
534 .bss : AT(ADDR(.bss) - LOAD_OFFSET) { \
535 BSS_FIRST_SECTIONS \
536 *(.bss..page_aligned) \
537 *(.dynbss) \
538 *(.bss) \
539 *(COMMON) \
540 }
542 /*
543 * DWARF debug sections.
544 * Symbols in the DWARF debugging sections are relative to
545 * the beginning of the section so we begin them at 0.
546 */
547 #define DWARF_DEBUG \
549 .debug 0 : { *(.debug) } \
550 .line 0 : { *(.line) } \
552 .debug_srcinfo 0 : { *(.debug_srcinfo) } \
553 .debug_sfnames 0 : { *(.debug_sfnames) } \
555 .debug_aranges 0 : { *(.debug_aranges) } \
556 .debug_pubnames 0 : { *(.debug_pubnames) } \
558 .debug_info 0 : { *(.debug_info \
559 .gnu.linkonce.wi.*) } \
560 .debug_abbrev 0 : { *(.debug_abbrev) } \
561 .debug_line 0 : { *(.debug_line) } \
562 .debug_frame 0 : { *(.debug_frame) } \
563 .debug_str 0 : { *(.debug_str) } \
564 .debug_loc 0 : { *(.debug_loc) } \
565 .debug_macinfo 0 : { *(.debug_macinfo) } \
567 .debug_weaknames 0 : { *(.debug_weaknames) } \
568 .debug_funcnames 0 : { *(.debug_funcnames) } \
569 .debug_typenames 0 : { *(.debug_typenames) } \
570 .debug_varnames 0 : { *(.debug_varnames) } \
572 /* Stabs debugging sections. */
573 #define STABS_DEBUG \
574 .stab 0 : { *(.stab) } \
575 .stabstr 0 : { *(.stabstr) } \
576 .stab.excl 0 : { *(.stab.excl) } \
577 .stab.exclstr 0 : { *(.stab.exclstr) } \
578 .stab.index 0 : { *(.stab.index) } \
579 .stab.indexstr 0 : { *(.stab.indexstr) } \
580 .comment 0 : { *(.comment) }
582 #ifdef CONFIG_GENERIC_BUG
583 #define BUG_TABLE \
584 . = ALIGN(8); \
585 __bug_table : AT(ADDR(__bug_table) - LOAD_OFFSET) { \
586 VMLINUX_SYMBOL(__start___bug_table) = .; \
587 *(__bug_table) \
588 VMLINUX_SYMBOL(__stop___bug_table) = .; \
589 }
590 #else
591 #define BUG_TABLE
592 #endif
594 #ifdef CONFIG_PM_TRACE
595 #define TRACEDATA \
596 . = ALIGN(4); \
597 .tracedata : AT(ADDR(.tracedata) - LOAD_OFFSET) { \
598 VMLINUX_SYMBOL(__tracedata_start) = .; \
599 *(.tracedata) \
600 VMLINUX_SYMBOL(__tracedata_end) = .; \
601 }
602 #else
603 #define TRACEDATA
604 #endif
606 #define NOTES \
607 .notes : AT(ADDR(.notes) - LOAD_OFFSET) { \
608 VMLINUX_SYMBOL(__start_notes) = .; \
609 *(.note.*) \
610 VMLINUX_SYMBOL(__stop_notes) = .; \
611 }
613 #define INIT_SETUP(initsetup_align) \
614 . = ALIGN(initsetup_align); \
615 VMLINUX_SYMBOL(__setup_start) = .; \
616 *(.init.setup) \
617 VMLINUX_SYMBOL(__setup_end) = .;
619 #define INIT_CALLS_LEVEL(level) \
620 VMLINUX_SYMBOL(__initcall##level##_start) = .; \
621 *(.initcall##level##.init) \
622 *(.initcall##level##s.init) \
624 #define INIT_CALLS \
625 VMLINUX_SYMBOL(__initcall_start) = .; \
626 *(.initcallearly.init) \
627 INIT_CALLS_LEVEL(0) \
628 INIT_CALLS_LEVEL(1) \
629 INIT_CALLS_LEVEL(2) \
630 INIT_CALLS_LEVEL(3) \
631 INIT_CALLS_LEVEL(4) \
632 INIT_CALLS_LEVEL(5) \
633 INIT_CALLS_LEVEL(rootfs) \
634 INIT_CALLS_LEVEL(6) \
635 INIT_CALLS_LEVEL(7) \
636 VMLINUX_SYMBOL(__initcall_end) = .;
638 #define CON_INITCALL \
639 VMLINUX_SYMBOL(__con_initcall_start) = .; \
640 *(.con_initcall.init) \
641 VMLINUX_SYMBOL(__con_initcall_end) = .;
643 #define SECURITY_INITCALL \
644 VMLINUX_SYMBOL(__security_initcall_start) = .; \
645 *(.security_initcall.init) \
646 VMLINUX_SYMBOL(__security_initcall_end) = .;
648 #ifdef CONFIG_BLK_DEV_INITRD
649 #define INIT_RAM_FS \
650 . = ALIGN(4); \
651 VMLINUX_SYMBOL(__initramfs_start) = .; \
652 *(.init.ramfs) \
653 . = ALIGN(8); \
654 *(.init.ramfs.info)
655 #else
656 #define INIT_RAM_FS
657 #endif
659 /*
660 * Default discarded sections.
661 *
662 * Some archs want to discard exit text/data at runtime rather than
663 * link time due to cross-section references such as alt instructions,
664 * bug table, eh_frame, etc. DISCARDS must be the last of output
665 * section definitions so that such archs put those in earlier section
666 * definitions.
667 */
668 #define DISCARDS \
669 /DISCARD/ : { \
670 EXIT_TEXT \
671 EXIT_DATA \
672 EXIT_CALL \
673 *(.discard) \
674 *(.discard.*) \
675 }
677 /**
678 * PERCPU_INPUT - the percpu input sections
679 * @cacheline: cacheline size
680 *
681 * The core percpu section names and core symbols which do not rely
682 * directly upon load addresses.
683 *
684 * @cacheline is used to align subsections to avoid false cacheline
685 * sharing between subsections for different purposes.
686 */
687 #define PERCPU_INPUT(cacheline) \
688 VMLINUX_SYMBOL(__per_cpu_start) = .; \
689 *(.data..percpu..first) \
690 . = ALIGN(PAGE_SIZE); \
691 *(.data..percpu..page_aligned) \
692 . = ALIGN(cacheline); \
693 *(.data..percpu..readmostly) \
694 . = ALIGN(cacheline); \
695 *(.data..percpu) \
696 *(.data..percpu..shared_aligned) \
697 VMLINUX_SYMBOL(__per_cpu_end) = .;
699 /**
700 * PERCPU_VADDR - define output section for percpu area
701 * @cacheline: cacheline size
702 * @vaddr: explicit base address (optional)
703 * @phdr: destination PHDR (optional)
704 *
705 * Macro which expands to output section for percpu area.
706 *
707 * @cacheline is used to align subsections to avoid false cacheline
708 * sharing between subsections for different purposes.
709 *
710 * If @vaddr is not blank, it specifies explicit base address and all
711 * percpu symbols will be offset from the given address. If blank,
712 * @vaddr always equals @laddr + LOAD_OFFSET.
713 *
714 * @phdr defines the output PHDR to use if not blank. Be warned that
715 * output PHDR is sticky. If @phdr is specified, the next output
716 * section in the linker script will go there too. @phdr should have
717 * a leading colon.
718 *
719 * Note that this macros defines __per_cpu_load as an absolute symbol.
720 * If there is no need to put the percpu section at a predetermined
721 * address, use PERCPU_SECTION.
722 */
723 #define PERCPU_VADDR(cacheline, vaddr, phdr) \
724 VMLINUX_SYMBOL(__per_cpu_load) = .; \
725 .data..percpu vaddr : AT(VMLINUX_SYMBOL(__per_cpu_load) \
726 - LOAD_OFFSET) { \
727 PERCPU_INPUT(cacheline) \
728 } phdr \
729 . = VMLINUX_SYMBOL(__per_cpu_load) + SIZEOF(.data..percpu);
731 /**
732 * PERCPU_SECTION - define output section for percpu area, simple version
733 * @cacheline: cacheline size
734 *
735 * Align to PAGE_SIZE and outputs output section for percpu area. This
736 * macro doesn't manipulate @vaddr or @phdr and __per_cpu_load and
737 * __per_cpu_start will be identical.
738 *
739 * This macro is equivalent to ALIGN(PAGE_SIZE); PERCPU_VADDR(@cacheline,,)
740 * except that __per_cpu_load is defined as a relative symbol against
741 * .data..percpu which is required for relocatable x86_32 configuration.
742 */
743 #define PERCPU_SECTION(cacheline) \
744 . = ALIGN(PAGE_SIZE); \
745 .data..percpu : AT(ADDR(.data..percpu) - LOAD_OFFSET) { \
746 VMLINUX_SYMBOL(__per_cpu_load) = .; \
747 PERCPU_INPUT(cacheline) \
748 }
751 /*
752 * Definition of the high level *_SECTION macros
753 * They will fit only a subset of the architectures
754 */
757 /*
758 * Writeable data.
759 * All sections are combined in a single .data section.
760 * The sections following CONSTRUCTORS are arranged so their
761 * typical alignment matches.
762 * A cacheline is typical/always less than a PAGE_SIZE so
763 * the sections that has this restriction (or similar)
764 * is located before the ones requiring PAGE_SIZE alignment.
765 * NOSAVE_DATA starts and ends with a PAGE_SIZE alignment which
766 * matches the requirement of PAGE_ALIGNED_DATA.
767 *
768 * use 0 as page_align if page_aligned data is not used */
769 #define RW_DATA_SECTION(cacheline, pagealigned, inittask) \
770 . = ALIGN(PAGE_SIZE); \
771 .data : AT(ADDR(.data) - LOAD_OFFSET) { \
772 INIT_TASK_DATA(inittask) \
773 NOSAVE_DATA \
774 PAGE_ALIGNED_DATA(pagealigned) \
775 CACHELINE_ALIGNED_DATA(cacheline) \
776 READ_MOSTLY_DATA(cacheline) \
777 DATA_DATA \
778 CONSTRUCTORS \
779 }
781 #define INIT_TEXT_SECTION(inittext_align) \
782 . = ALIGN(inittext_align); \
783 .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) { \
784 VMLINUX_SYMBOL(_sinittext) = .; \
785 INIT_TEXT \
786 VMLINUX_SYMBOL(_einittext) = .; \
787 }
789 #define INIT_DATA_SECTION(initsetup_align) \
790 .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) { \
791 INIT_DATA \
792 INIT_SETUP(initsetup_align) \
793 INIT_CALLS \
794 CON_INITCALL \
795 SECURITY_INITCALL \
796 INIT_RAM_FS \
797 }
799 #define BSS_SECTION(sbss_align, bss_align, stop_align) \
800 . = ALIGN(sbss_align); \
801 VMLINUX_SYMBOL(__bss_start) = .; \
802 SBSS(sbss_align) \
803 BSS(bss_align) \
804 . = ALIGN(stop_align); \
805 VMLINUX_SYMBOL(__bss_stop) = .;