arch/arm/mm/proc-fa526.S

   1 /*
   2  *  linux/arch/arm/mm/proc-fa526.S: MMU functions for FA526
   3  *
   4  *  Copyright (C) 2005 Faraday Corp.
   5  *
   6  * This program is free software; you can redistribute it and/or modify
   7  * it under the terms of the GNU General Public License as published by
   8  * the Free Software Foundation; either version 2 of the License, or
   9  * (at your option) any later version.
  10  *
  11  * This program is distributed in the hope that it will be useful,
  12  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  13  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14  * GNU General Public License for more details.
  15  *
  16  * You should have received a copy of the GNU General Public License
  17  * along with this program; if not, write to the Free Software
  18  * Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  19  *
  20  *
  21  * These are the low level assembler for performing cache and TLB
  22  * functions on the fa526.
  23  *
  24  *  Written by : Luke Lee
  25  */
  26 #include <linux/linkage.h>
  27 #include <linux/config.h>
  28 #include <linux/init.h>
  29 #include <asm/assembler.h>
  30 #include <asm/pgtable.h>
  31 #include <asm/procinfo.h>
  32 #include <asm/hardware.h>
  33 #include <asm/page.h>
  34 #include <asm/ptrace.h>
  35 #include <asm/system.h>
  36 #include "proc-macros.S"
  37
  38 #define CACHE_DLINESIZE    16
  39
  40         .text
  41 /*
  42  * cpu_fa526_proc_init()
  43  */
  44 ENTRY(cpu_fa526_proc_init)
  45         /* MMU is already ON here, ICACHE, DCACHE conditionally disabled */
  46
  47         mov     r0, #1
  48         nop
  49         nop
  50         mcr     p15, 0, r0, c1, c1, 0           @ turn-on ECR
  51         nop
  52         nop
  53
  54         mrc     p15, 0, r0, c1, c0, 0           @ read ctrl register
  55
  56 #ifdef CONFIG_CPU_FA_BTB
  57         orr     r0, r0, #CR_Z
  58 #else
  59         bic     r0, r0, #CR_Z
  60 #endif
  61 #ifdef CONFIG_CPU_FA_WB_DISABLE
  62         mov     r1, #0
  63         mcr     p15, 0, r1, c7, c10, 4          @ drain write buffer
  64         nop
  65         nop
  66         bic     r0, r0, #CR_W
  67 #else
  68         orr     r0, r0, #CR_W
  69 #endif
  70 #ifdef CONFIG_CPU_DCACHE_DISABLE
  71         bic     r0, r0, #CR_C
  72 #else
  73         orr     r0, r0, #CR_C
  74 #endif
  75 #ifdef CONFIG_CPU_ICACHE_DISABLE
  76         bic     r0, r0, #CR_I
  77 #else
  78         orr     r0, r0, #CR_I
  79 #endif
  80
  81         nop
  82         nop
  83         mcr     p15, 0, r0, c1, c0, 0
  84         nop
  85         nop
  86
  87         mov     r5, lr
  88         bl      fa_initialize_cache_info        @ destroy r0~r4
  89         mov     pc, r5                          @ return
  90
  91
  92 /*
  93  * cpu_fa526_proc_fin()
  94  */
  95 ENTRY(cpu_fa526_proc_fin)
  96         stmfd   sp!, {lr}
  97         mov     ip, #PSR_F_BIT | PSR_I_BIT | SVC_MODE
  98         msr     cpsr_c, ip
  99
 100         bl      fa_flush_kern_cache_all
 101         mrc     p15, 0, r0, c1, c0, 0           @ ctrl register
 102         bic     r0, r0, #0x1000                 @ ...i............
 103         bic     r0, r0, #0x000e                 @ ............wca.
 104         mcr     p15, 0, r0, c1, c0, 0           @ disable caches
 105
 106         nop
 107         nop
 108         ldmfd   sp!, {pc}
 109
 110 /*
 111  * cpu_fa526_reset(loc)
 112  *
 113  * Perform a soft reset of the system.  Put the CPU into the
 114  * same state as it would be if it had been reset, and branch
 115  * to what would be the reset vector.
 116  *
 117  * loc: location to jump to for soft reset
 118  */
 119         .align  4
 120 ENTRY(cpu_fa526_reset)
 121         mov     ip, #0
 122         mcr     p15, 0, ip, c7, c7, 0           @ invalidate I,D caches
 123 #ifndef CONFIG_CPU_FA_WB_DISABLE
 124         mcr     p15, 0, ip, c7, c10, 4          @ drain WB
 125 #endif
 126         mcr     p15, 0, ip, c8, c7, 0           @ invalidate I & D TLBs
 127         mrc     p15, 0, ip, c1, c0, 0           @ ctrl register
 128         bic     ip, ip, #0x000f                 @ ............wcam
 129         bic     ip, ip, #0x1100                 @ ...i...s........
 130
 131         bic     ip, ip, #0x0800                 @ BTB off
 132         mcr     p15, 0, ip, c1, c0, 0           @ ctrl register
 133         nop
 134         nop
 135         mov     pc, r0
 136
 137 /*
 138  * cpu_fa526_do_idle()
 139  */
 140         .align  4
 141 ENTRY(cpu_fa526_do_idle)
 142
 143 #ifdef CONFIG_CPU_FA_IDLE
 144         nop
 145         nop
 146         mcr     p15, 0, r0, c7, c0, 4           @ Wait for interrupt (IDLE mode)
 147 #endif
 148         mov     pc, lr
 149
 150
 151 ENTRY(cpu_fa526_dcache_clean_area)
 152
 153 #ifndef CONFIG_CPU_DCACHE_DISABLE
 154 #ifndef CONFIG_CPU_DCACHE_WRITETHROUGH
 155 1:      mcr     p15, 0, r0, c7, c10, 1          @ clean D entry
 156         add     r0, r0, #CACHE_DLINESIZE
 157         subs    r1, r1, #CACHE_DLINESIZE
 158         bhi     1b
 159 #endif
 160 #endif
 161         mov     pc, lr
 162
 163
 164 /* =============================== PageTable ============================== */
 165
 166 /*
 167  * cpu_fa526_switch_mm(pgd)
 168  *
 169  * Set the translation base pointer to be as described by pgd.
 170  *
 171  * pgd: new page tables
 172  */
 173         .align  4
 174
 175         .globl  fault_address
 176 fault_address:
 177         .long   0
 178
 179 ENTRY(cpu_fa526_switch_mm)
 180
 181         mov     ip, #0
 182 #ifndef CONFIG_CPU_DCACHE_DISABLE
 183 #ifdef CONFIG_CPU_DCACHE_WRITETHROUGH
 184         mcr     p15, 0, ip, c7, c6, 0           @ invalidate D cache
 185 #else
 186         mcr     p15, 0, ip, c7, c14, 0          @ Clean and invalidate whole DCache
 187 #endif
 188 #endif /*CONFIG_CPU_DCACHE_DISABLE*/
 189
 190 #ifndef CONFIG_CPU_ICACHE_DISABLE
 191         mcr     p15, 0, ip, c7, c5, 0           @ invalidate I cache
 192 #endif
 193
 194 #ifndef CONFIG_CPU_FA_WB_DISABLE
 195         mcr     p15, 0, ip, c7, c10, 4          @ drain WB
 196 #endif
 197
 198 #ifdef CONFIG_CPU_FA_BTB
 199         mcr     p15, 0, ip, c7, c5, 6           @ invalidate BTB since mm changed
 200         nop
 201         nop
 202 #endif
 203         bic     r0, r0, #0xff                   @ clear bits [7:0]
 204         bic     r0, r0, #0x3f00                 @ clear bits [13:8]
 205         mcr     p15, 0, r0, c2, c0, 0           @ load page table pointer
 206         mcr     p15, 0, ip, c8, c7, 0           @ invalidate UTLB
 207         nop
 208         nop
 209         mov     pc, lr
 210
 211 /*
 212  * cpu_fa526_set_pte(ptep, pte)
 213  *
 214  * Set a PTE and flush it out
 215  */
 216         .align  4
 217 ENTRY(cpu_fa526_set_pte)
 218         str     r1, [r0], #-2048                @ linux version
 219
 220         eor     r1, r1, #L_PTE_PRESENT | L_PTE_YOUNG | L_PTE_WRITE | L_PTE_DIRTY
 221
 222         bic     r2, r1, #PTE_SMALL_AP_MASK
 223         bic     r2, r2, #PTE_TYPE_MASK
 224         orr     r2, r2, #PTE_TYPE_SMALL
 225
 226         tst     r1, #L_PTE_USER                 @ User?
 227         orrne   r2, r2, #PTE_SMALL_AP_URO_SRW
 228
 229         tst     r1, #L_PTE_WRITE | L_PTE_DIRTY  @ Write and Dirty?
 230         orreq   r2, r2, #PTE_SMALL_AP_UNO_SRW
 231
 232         tst     r1, #L_PTE_PRESENT | L_PTE_YOUNG        @ Present and Young?
 233         movne   r2, #0
 234
 235 #ifdef CONFIG_CPU_DCACHE_WRITETHROUGH
 236         eor     r3, r2, #0x0a                   @ C & small page?  1010
 237         tst     r3, #0x0b                       @                  1011
 238         biceq   r2, r2, #4
 239 #endif
 240         str     r2, [r0]                        @ hardware version
 241
 242         mov     r2, #0
 243         mcr     p15, 0, r2, c7, c10, 0          @ clean D cache all
 244
 245 #ifndef CONFIG_CPU_FA_WB_DISABLE
 246         mcr     p15, 0, r2, c7, c10, 4          @ drain WB
 247 #endif
 248 #ifdef CONFIG_CPU_FA_BTB
 249         mcr     p15, 0, r2, c7, c5, 6           @ invalidate BTB
 250         nop
 251         nop
 252 #endif
 253         mov     pc, lr
 254
 255         __INIT
 256
 257         .type   __fa526_setup, #function
 258 __fa526_setup:
 259         /* On return of this routine, r0 must carry correct flags for CFG register */
 260         mov     r0, #0
 261         mcr     p15, 0, r0, c7, c7              @ invalidate I,D caches on v4
 262         mcr     p15, 0, r0, c7, c10, 4          @ drain write buffer on v4
 263         mcr     p15, 0, r0, c8, c7              @ invalidate I,D TLBs on v4
 264
 265         mcr     p15, 0, r0, c7, c5, 5           @ invalidate IScratchpad RAM
 266
 267         mov     r0, #1
 268         mcr     p15, 0, r0, c1, c1, 0           @ turn-on ECR
 269
 270         mrc     p15, 0, r0, c9, c1, 0           @ DScratchpad
 271         bic     r0, r0, #1
 272         mcr     p15, 0, r0, c9, c1, 0
 273         mrc     p15, 0, r0, c9, c1, 1           @ IScratchpad
 274         bic     r0, r0, #1
 275         mcr     p15, 0, r0, c9, c1, 1
 276
 277         mov     r0, #0
 278         mcr     p15, 0, r0, c1, c1, 0           @ turn-off ECR
 279
 280 #ifdef CONFIG_CPU_FA_BTB
 281         mcr     p15, 0, r0, c7, c5, 6           @ invalidate BTB All
 282         nop
 283         nop
 284 #endif
 285
 286         mov     r0, #0x1f                       @ Domains 0, 1 = manager, 2 = client
 287         mcr     p15, 0, r0, c3, c0              @ load domain access register
 288
 289         mrc     p15, 0, r0, c1, c0              @ get control register v4
 290 #if 1
 291         /*
 292         ldr     r5, fa526_cr1_clear
 293         bic     r0, r0, r5
 294         ldr     r5, fa526_cr1_set
 295         orr     r0, r0, r5
 296         */
 297         ldr     r0, fa526_victor_set
 298 #else
 299         bic     r0, r0, #0x0e00
 300         bic     r0, r0, #0x0002
 301         bic     r0, r0, #0x000c
 302         bic     r0, r0, #0x1000                 @ ...0 000. .... 000.
 303         orr     r0, r0, #0x0011
 304         orr     r0, r0, #0x2100                 @ ..1. ...1 ..11 ...1
 305
 306 #ifndef CONFIG_CPU_DCACHE_DISABLE
 307         orr     r0, r0, #0x0004                 @ .... .... .... .1..
 308 #endif
 309 #ifndef CONFIG_CPU_ICACHE_DISABLE
 310         orr     r0, r0, #0x1000                 @ ...1 .... .... ....
 311 #endif
 312 #endif
 313
 314 #ifdef CONFIG_CPU_FA_BTB
 315         orr     r0, r0, #CR_Z
 316 #else
 317         bic     r0, r0, #CR_Z
 318 #endif
 319 /*
 320 #ifdef CONFIG_CPU_FA_WB_DISABLE
 321         mov     r12, #0
 322         mcr     p15, 0, r12, c7, c10, 4         @ drain write buffer
 323         nop
 324         nop
 325         bic     r0, r0, #CR_W                   @ .... .... .... 1...
 326 #else
 327         orr     r0, r0, #CR_W
 328 #endif
 329 */
 330
 331         mov     pc, lr
 332         .size   __fa526_setup, . - __fa526_setup
 333
 334         /*
 335          * .RVI ZFRS BLDP WCAM
 336          * ..11 0001 .111 1101
 337          *
 338          */
 339         .type   fa526_cr1_clear, #object
 340         .type   fa526_cr1_set, #object
 341 fa526_cr1_clear:
 342         .word   0x3f3f
 343 fa526_cr1_set:
 344         .word   0x317D
 345 fa526_victor_set:
 346         .word   0x3177
 347
 348         __INITDATA
 349
 350 /*
 351  * Purpose : Function pointers used to access above functions - all calls
 352  *           come through these
 353  */
 354         .type   fa526_processor_functions, #object
 355 fa526_processor_functions:
 356         .word   v4_early_abort
 357         .word   cpu_fa526_proc_init
 358         .word   cpu_fa526_proc_fin
 359         .word   cpu_fa526_reset
 360         .word   cpu_fa526_do_idle
 361         .word   cpu_fa526_dcache_clean_area
 362         .word   cpu_fa526_switch_mm
 363         .word   cpu_fa526_set_pte
 364         .size   fa526_processor_functions, . - fa526_processor_functions
 365
 366         .section ".rodata"
 367
 368         .type   cpu_arch_name, #object
 369 cpu_arch_name:
 370         .asciz  "armv4"
 371         .size   cpu_arch_name, . - cpu_arch_name
 372
 373         .type   cpu_elf_name, #object
 374 cpu_elf_name:
 375         .asciz  "v4"
 376         .size   cpu_elf_name, . - cpu_elf_name
 377
 378         .type   cpu_fa526_name, #object
 379 cpu_fa526_name:
 380         .ascii  "FA526"
 381 #ifndef CONFIG_CPU_ICACHE_DISABLE
 382         .ascii  "i"
 383 #endif
 384 #ifndef CONFIG_CPU_DCACHE_DISABLE
 385         .ascii  "d"
 386 #ifdef CONFIG_CPU_DCACHE_WRITETHROUGH
 387         .ascii  "(wt)"
 388 #else
 389         .ascii  "(wb)"
 390 #endif
 391 #endif
 392         .ascii  "\0"
 393         .size   cpu_fa526_name, . - cpu_fa526_name
 394
 395         .align
 396
 397         .section ".proc.info", #alloc, #execinstr
 398
 399 #ifdef CONFIG_CPU_DCACHE_WRITETHROUGH
 400 #define __PMD_SECT_BUFFERABLE   0
 401 #else
 402 #define __PMD_SECT_BUFFERABLE   PMD_SECT_BUFFERABLE
 403 #endif
 404
 405         .type   __fa526_proc_info,#object
 406 __fa526_proc_info:
 407         .long   0x66015261
 408         .long   0xff01fff1
 409 #if 0
 410         .long   PMD_TYPE_SECT | \
 411                 __PMD_SECT_BUFFERABLE | \
 412                 PMD_SECT_CACHEABLE | \
 413                 PMD_BIT4 | \
 414                 PMD_SECT_AP_WRITE | \
 415                 PMD_SECT_AP_READ
 416 #else
 417         .long   0x00000812
 418 #endif
 419         b       __fa526_setup
 420         .long   cpu_arch_name
 421         .long   cpu_elf_name
 422         .long   HWCAP_SWP | HWCAP_HALF
 423         .long   cpu_fa526_name
 424         .long   fa526_processor_functions
 425         .long   fa_tlb_fns
 426         .long   fa_user_fns
 427         .long   fa_cache_fns
 428         .size   __fa526_proc_info, . - __fa526_proc_info
 429
 430