lilypond-texi2html.init

   1 #!/usr/bin/env perl
   2 # -*- coding: utf-8; -*-
   3
   4 ### texi2html customization script for Lilypond
   5 ### Author: Reinhold Kainhofer <reinhold@kainhofer.com>, 2008.
   6 ###         Some code parts copied from texi2html and adapted. These functions
   7 ###         were written mainly by Patrice Dumas
   8 ### License: GPLv2+
   9 ###
  10 ###
  11 ### Features implemented here:
  12 ### -) For split manuals, the main page is index.html.
  13 ### -) All @unnumbered* sections are placed into the same file
  14 ###    (implemented by split_at_numbered_sections)
  15 ### -) Use our custom CSS file, with IE-specific fixes in another CSS file,
  16 ###    impelmented by lilypond_css_lines
  17 ### -) TOC (folded, with the current page highlighted) in an overflown <div>
  18 ###    is added to every page; implemented by:
  19 ###           lilypond_print_element_header -- building of the TOC
  20 ###           lilypond_toc_body -- generation of customized TOC output
  21 ###           lilypond_print_page_head -- start <div id="main">
  22 ###           print_lilypond_page_foot -- closing id=main, output of footer & TOC
  23 ### -) External refs are formatted only as "Text of the node" (not as >>see
  24 ###    "NODE" section "SECTION" in "BOOK"<< like with default texi2html). Also,
  25 ###    the leading "(book-name)" is removed.
  26 ###    Implemented by overriding lilypond_external_ref
  27 ### -) Navigation bars on top/bottom of the page and between sections are not
  28 ###    left-aligned, but use a combination of left/center/right aligned table
  29 ###    cells; For this, I heavily extend the texi2html code to allow for
  30 ###    differently aligned cells and for multi-line tables);
  31 ###    Implemented in lilypond_print_navigation
  32 ### -) Different formatting than the default: example uses the same formatting
  33 ###    as quote.
  34 ### -) Allow translated section titles: All section titles can be translated,
  35 ###    the original (English) title is associated with @translationof. This is
  36 ###    needed, because the file name / anchor is generated from the original
  37 ###    English title, since otherwise language-autoselection would break with
  38 ###    posted links.
  39 ###    Since it is then no longer possible to obtain the file name from the
  40 ###    section title, I keep a sectionname<=>filename/anchor around. This way,
  41 ###    xrefs from other manuals can simply load that map and retrieve the
  42 ###    correct file name for the link. Implemented in:
  43 ###           lilypond_unknown (handling of @translationof, in case
  44 ###                             extract_texi_filenames.py messes up...)
  45 ###           lilypond_element_file_name (correct file name: use the map)
  46 ###           lilypond_element_target_name (correct anchor: use the map)
  47 ###           lilypond_init_map (read in the externally created map from disk)
  48 ###           lilypond_external_href (load the map for xrefs, use the correct
  49 ###                                   link target)
  50 ### -) The HTML anchors for all sections are derived from the node name /
  51 ###    section title (pre-generated in the .xref-map file). Implemented by:
  52 ###           lilypond_element_target_name (adjust section anchors)
  53 ### -) Use the standard footnote format "<sup>nr</sup> text" instead of the
  54 ###    ugly format of texi2html (<h3>(nr)</h3><p>text</p>). Implemented in
  55 ###           makeinfo_like_foot_line_and_ref
  56 ###           makeinfo_like_foot_lines
  57 ###           makeinfo_like_paragraph
  58 ###
  59 ###
  60 ### Useful helper functions:
  61 ### -) texinfo_file_name($node_name): returns a texinfo-compatible file name
  62 ###    for the given string $node_name (whitespace trimmed/replaced by -,
  63 ###    non-standard chars replaced by _xxxx (ascii char code) and forced to
  64 ###    start with a letter by prepending t_g if necessary)
  65
  66
  67 package Texi2HTML::Config;
  68
  69 #############################################################################
  70 ### TRANSLATIONS
  71 #############################################################################
  72
  73 use utf8;
  74 my $LY_LANGUAGES = {};
  75 $LY_LANGUAGES->{'fr'} = {
  76     'Back to Documentation Index' => 'Retour à l\'accueil de la documentation',
  77 };
  78 $LY_LANGUAGES->{'es'} = {
  79     'Back to Documentation Index' => 'Volver al índice de la documentación',
  80 };
  81 $LY_LANGUAGES->{'de'} = {
  82     'Back to Documentation Index' => 'Zur Dokumentationsübersicht',
  83 };
  84 $LY_LANGUAGES->{'ja'} = {
  85     'Back to Documentation Index' => 'ドキュメント インデックスに戻る',
  86 };
  87
  88
  89 sub ly_get_string () {
  90     my $lang = $Texi2HTML::THISDOC{current_lang};
  91     my $string = shift;
  92     if ($lang and $lang ne "en" and $LY_LANGUAGES->{$lang}->{$string}) {
  93         return $LY_LANGUAGES->{$lang}->{$string};
  94     } else {
  95         return $string;
  96     }
  97 }
  98
  99
 100 #############################################################################
 101 ###  SETTINGS FOR TEXI2HTML
 102 #############################################################################
 103
 104 @Texi2HTML::Config::CSS_REFS      = (
 105     {FILENAME => "lilypond-mccarty.css", TITLE => "Patrick McCarty's design"}
 106 );
 107 @Texi2HTML::Config::ALT_CSS_REFS      = (
 108     {FILENAME => "lilypond.css", TITLE => "Andrew Hawryluk's design" },
 109     {FILENAME => "lilypond-blue.css", TITLE => "Kurt Kroon's blue design" },
 110 );
 111 $Texi2HTML::Config::USE_ACCESSKEY = 1;
 112 $Texi2HTML::Config::USE_LINKS     = 1;
 113 $Texi2HTML::Config::USE_REL_REV   = 1;
 114 $Texi2HTML::Config::SPLIT_INDEX   = 0;
 115 $Texi2HTML::Config::SEPARATED_FOOTNOTES = 0; # Print footnotes on same page, not separated
 116 if ($Texi2HTML::Config::SPLIT eq 'section') {
 117   $Texi2HTML::Config::element_file_name    = \&lilypond_element_file_name;
 118 }
 119 $Texi2HTML::Config::element_target_name  = \&lilypond_element_target_name;
 120 $Texi2HTML::Config::print_element_header = \&lilypond_print_element_header;
 121 $Texi2HTML::Config::print_page_foot      = \&print_lilypond_page_foot;
 122 $Texi2HTML::Config::print_navigation     = \&lilypond_print_navigation;
 123 $Texi2HTML::Config::external_ref         = \&lilypond_external_ref;
 124 $Texi2HTML::Config::external_href        = \&lilypond_external_href;
 125 $Texi2HTML::Config::toc_body             = \&lilypond_toc_body;
 126 $Texi2HTML::Config::css_lines            = \&lilypond_css_lines;
 127 $Texi2HTML::Config::unknown              = \&lilypond_unknown;
 128 $Texi2HTML::Config::print_page_head      = \&lilypond_print_page_head;
 129 # $Texi2HTML::Config::foot_line_and_ref    = \&lilypond_foot_line_and_ref;
 130 $Texi2HTML::Config::foot_line_and_ref  = \&makeinfo_like_foot_line_and_ref;
 131 $Texi2HTML::Config::foot_lines         = \&makeinfo_like_foot_lines;
 132 $Texi2HTML::Config::paragraph          = \&makeinfo_like_paragraph;
 133
 134
 135
 136 # Examples should be formatted similar to quotes:
 137 $Texi2HTML::Config::complex_format_map->{'example'} = {
 138   'begin' => q{"<blockquote><pre class=\"example\">"},
 139   'end' => q{"</pre></blockquote>\n"},
 140   'style' => 'code',
 141  };
 142
 143 %Texi2HTML::config::misc_pages_targets = (
 144    'Overview' => 'Overview',
 145    'Contents' => 'Contents',
 146    'About' => 'About'
 147 );
 148
 149
 150 my @section_to_filename;
 151
 152
 153
 154
 155 #############################################################################
 156 ###  DEBUGGING
 157 #############################################################################
 158
 159 use Data::Dumper;
 160 $Data::Dumper::Maxdepth = 2;
 161
 162 sub print_element_info($)
 163 {
 164   my $element = shift;
 165   print "~~~~~~~~~~~~~~~~~~~~~~~~~~~~\n";
 166   print "Element: $element\n";
 167   print Dumper($element);
 168 }
 169
 170
 171
 172
 173
 174 #############################################################################
 175 ###  HELPER FUNCTIONS
 176 #############################################################################
 177
 178 # Convert a given node name to its proper file name (normalization as explained
 179 # in the texinfo manual:
 180 # http://www.gnu.org/software/texinfo/manual/texinfo/html_node/HTML-Xref-Node-Name-Expansion.html
 181 sub texinfo_file_name($)
 182 {
 183   my $text = shift;
 184   my $result = '';
 185   # File name normalization by texinfo:
 186   # 1/2: letters and numbers are left unchanged
 187   # 3/4: multiple, leading and trailing whitespace is removed
 188   $text = main::normalise_space($text);
 189   # 5/6: all remaining spaces are converted to '-', all other 7- or 8-bit
 190   #      chars are replaced by _xxxx (xxxx=ascii character code)
 191   while ($text ne '') {
 192     if ($text =~ s/^([A-Za-z0-9]+)//o) { # number or letter stay unchanged
 193       $result .= $1;
 194     } elsif ($text =~ s/^ //o) { # space -> '-'
 195       $result .= '-';
 196     } elsif ($text =~ s/^(.)//o) { # Otherwise use _xxxx (ascii char code)
 197       my $ccode = ord($1);
 198       if ( $ccode <= 0xFFFF ) {
 199         $result .= sprintf("_%04x", $ccode);
 200       } else {
 201         $result .= sprintf("__%06x", $ccode);
 202       }
 203     }
 204   }
 205   # 7: if name does not begin with a letter, prepend 't_g' (so it starts with a letter)
 206   if ($result !~ /^[a-zA-Z]/) {
 207     $result = 't_g' . $result;
 208   }
 209   # DONE
 210   return $result
 211 }
 212
 213
 214 # Load a file containing a nodename<=>filename map (tab-sepatared, i.e.
 215 # NODENAME\tFILENAME\tANCHOR
 216 # Returns a ref to a hash "Node title" => ["FilenameWithoutExt", "Anchor"]
 217 sub load_map_file ($)
 218 {
 219     my $mapfile = shift;
 220     my $node_map = ();
 221
 222     if (open(XREFFILE, $mapfile)) {
 223         my $line;
 224         while ( $line = <XREFFILE> ) {
 225             # parse the tab-separated entries and insert them into the map:
 226             chomp($line);
 227             my @entries = split(/\t/, $line);
 228             if (scalar (@entries) == 3) {
 229               $node_map->{$entries[0]} = [$entries[1], $entries[2]];
 230             } else {
 231               print STDERR "Invalid entry in the node file $mapfile: $line\n";
 232             }
 233         }
 234         close (XREFFILE);
 235     } else {
 236         print STDERR "WARNING: Unable to load the map file $mapfile\n";
 237     }
 238     return $node_map;
 239 }
 240
 241
 242 # Split the given path into dir and basename (with .texi removed). Used mainly
 243 # to get the path/basename of the original texi input file
 244 sub split_texi_filename ($)
 245 {
 246   my $docu = shift;
 247   my ($docu_dir, $docu_name);
 248   if ($docu =~ /(.*\/)/) {
 249     chop($docu_dir = $1);
 250     $docu_name = $docu;
 251     $docu_name =~ s/.*\///;
 252   } else {
 253      $docu_dir = '.';
 254      $docu_name = $docu;
 255   }
 256   $docu_name =~ s/\.te?x(i|info)?$//;
 257   return ($docu_dir, $docu_name);
 258 }
 259
 260
 261
 262
 263
 264 #############################################################################
 265 ###  CSS HANDLING
 266 #############################################################################
 267
 268 # Include our standard CSS file, not hard-coded CSS code directly in the HTML!
 269 # For IE, conditionally include the lilypond-ie-fixes.css style sheet
 270 sub lilypond_css_lines ($$)
 271 {
 272     my $import_lines = shift;
 273     my $rule_lines = shift;
 274     return if (defined($Texi2HTML::THISDOC{'CSS_LINES'}));
 275     if (@$rule_lines or @$import_lines)
 276     {
 277         $Texi2HTML::THISDOC{'CSS_LINES'} = "<style type=\"text/css\">\n<!--\n";
 278         $Texi2HTML::THISDOC{'CSS_LINES'} .= join('',@$import_lines) . "\n" if (@$import_lines);
 279         $Texi2HTML::THISDOC{'CSS_LINES'} .= join('',@$rule_lines) . "\n" if (@$rule_lines);
 280         $Texi2HTML::THISDOC{'CSS_LINES'} .= "-->\n</style>\n";
 281     }
 282     foreach my $ref (@CSS_REFS)
 283     {
 284         $Texi2HTML::THISDOC{'CSS_LINES'} .= "<link rel=\"stylesheet\" type=\"text/css\" title=\"$ref->{TITLE}\" href=\"$ref->{FILENAME}\">\n";
 285     }
 286     foreach my $ref (@Texi2HTML::Config::ALT_CSS_REFS)
 287     {
 288         $Texi2HTML::THISDOC{'CSS_LINES'} .= "<link rel=\"alternate stylesheet\" type=\"text/css\" href=\"$ref->{FILENAME}\" title=\"$ref->{TITLE}\">\n";
 289     }
 290     $Texi2HTML::THISDOC{'CSS_LINES'} .= "<!--[if lte IE 7]>\n<link href=\"lilypond-ie-fixes.css\" rel=\"stylesheet\" type=\"text/css\">\n<![endif]-->\n";
 291 }
 292
 293
 294
 295
 296
 297 #############################################################################
 298 ###  SPLITTING BASED ON NUMBERED SECTIONS
 299 #############################################################################
 300
 301 my $lastfilename;
 302 my $docnr = 0;
 303 my $node_to_filename_map = ();
 304
 305
 306 # This function makes sure that files are only generated for numbered sections,
 307 # but not for unnumbered ones. It is called after texi2html has done its own
 308 # splitting and simply returns the filename for the node given as first argument
 309 # Nodes with the same filename will be printed out to the same filename, so
 310 # this really all we need. Also, make sure that the file names for sections
 311 # are derived from the section title. We also might want to name the anchors
 312 # according to node titles, which works by simply overriding the id element of
 313 # the $element hash.
 314 # If an external nodename<=>filename/anchor map file is found (loaded in
 315 # the command handler, use the externally created values, otherwise use the
 316 # same logic here.
 317 sub lilypond_element_file_name($$$)
 318 {
 319   my $element = shift;
 320   my $type = shift;
 321   my $docu_name = shift;
 322   my $docu_ext = $Texi2HTML::Config::EXTENSION;
 323
 324   my $node_name = main::remove_texi($element->{'node_ref'}->{'texi'});
 325   # the snippets page does not use nodes for the snippets, so in this case
 326   # we'll have to use the section name!
 327   if ($node_name eq '') {
 328     $node_name = main::remove_texi($element->{'texi'});
 329   }
 330
 331   # If we have an entry in the section<=>filename map, use that one, otherwise
 332   # generate the filename/anchor here. In the latter case, external manuals
 333   # will not be able to retrieve the file name for xrefs!!! Still, I already
 334   # had that code, so I'll leave it in in case something goes wrong with the
 335   # extract_texi_filenames.py script in the lilypond build process!
 336   if (exists ($node_to_filename_map->{$node_name})) {
 337     (my $filename, my $anchor) = @{$node_to_filename_map->{$node_name}};
 338     $filename .= ".$docu_ext" if (defined($docu_ext));
 339
 340     # unnumbered sections (except those at top-level!) always go to the same
 341     # file as the previous numbered section
 342     if (not ($element->{number}) and not ($lastfilename eq '') and ($element->{level} > 1)) {
 343       $filename = $lastfilename;
 344     }
 345     if (($filename eq $lastfilename)) {
 346       $$element{doc_nr} = $docnr;
 347     } else {
 348       $docnr += 1;
 349       $$element{doc_nr} = $docnr;
 350       $lastfilename = $filename;
 351     }
 352     return $filename;
 353
 354   } elsif ($type eq "top" or $type eq "toc" or $type eq "doc" or $type eq "stoc" or $type eq "foot" or $type eq "about") {
 355     return;
 356   } else {
 357     print STDERR "WARNING: Node '$node_name' was NOT found in the map\n"
 358         unless ($node_name eq '') or ($element->{'tag'} eq 'unnumberedsec')
 359                or ($node_name =~ /NOT REALLY USED/);
 360
 361     # Numbered sections will get a filename Node_title, unnumbered sections will use
 362     # the file name of the previous numbered section:
 363     if (($element->{number}) or ($lastfilename eq '') or ($element->{level} == 1)) {
 364       # normalize to the same file name as texinfo
 365       if ($element->{translationof}) {
 366         $node_name = main::remove_texi($element->{translationof});
 367       }
 368       my $filename = texinfo_file_name($node_name);
 369       $filename .= ".$docu_ext" if (defined($docu_ext));
 370       $docnr += 1;
 371       $$element{doc_nr} = $docnr;
 372       $lastfilename = $filename;
 373       return $filename;
 374     } else {
 375       $$element{doc_nr} = $docnr;
 376       return $lastfilename;
 377     }
 378   }
 379
 380   return;
 381 }
 382
 383 sub lilypond_element_target_name($$$)
 384 {
 385   my $element = shift;
 386   my $target = shift;
 387   my $id = shift;
 388   # Target is based on node name (or sec name for secs without node attached)
 389   my $node_name = main::remove_texi($element->{'node_ref'}->{'texi'});
 390   if ($node_name eq '') {
 391     $node_name = main::remove_texi($element->{'texi'});
 392   }
 393
 394   # If we have an entry in the section<=>filename map, use that one, otherwise
 395   # generate the anchor here.
 396   if (exists ($node_to_filename_map->{$node_name})) {
 397     (my $filename, $target) = @{$node_to_filename_map->{$node_name}};
 398   } else {
 399     my $anchor = $node_name;
 400     if ($element->{translationof}) {
 401       $anchor = main::remove_texi($element->{translationof});
 402     }
 403     # normalize to the same file name as texinfo
 404     $target = texinfo_file_name($anchor);
 405   }
 406   # TODO: Once texi2html correctly prints out the target and not the id for
 407   #       the sections, change this back to ($id, $target)
 408   return ($target, $target);
 409 }
 410
 411
 412 ## Load the map file for the corrently processed texi file. We do this
 413 #  using a command init handler, since texi2html does not have any
 414 #  other hooks that are called after THISDOC is filled but before phase 2
 415 #  of the texi2html conversion.
 416 sub lilypond_init_map ()
 417 {
 418     my ($docu_dir, $docu_name) = split_texi_filename ($Texi2HTML::THISDOC{'input_file_name'});
 419     my $map_filename = main::locate_include_file ("${docu_name}.$Texi2HTML::THISDOC{current_lang}.xref-map")
 420         || main::locate_include_file ("${docu_name}.xref-map");
 421     $node_to_filename_map = load_map_file ($map_filename);
 422 }
 423 push @Texi2HTML::Config::command_handler_init, \&lilypond_init_map;
 424
 425
 426
 427 #############################################################################
 428 ###  CLEANER LINK TITLE FOR EXTERNAL REFS
 429 #############################################################################
 430
 431 # The default formatting of external refs returns e.g.
 432 # "(lilypond-internals)Timing_translator", so we remove all (...) from the
 433 # file_and_node argument. Also, we want only a very simple format, so we don't
 434 # even call the default handler!
 435 sub lilypond_external_ref($$$$$$)
 436 {
 437   my $type = shift;
 438   my $section = shift;
 439   my $book = shift;
 440   my $file_node = shift;
 441   my $href = shift;
 442   my $cross_ref = shift;
 443
 444   my $displaytext = '';
 445
 446   # 1) if we have a cross ref name, that's the text to be displayed:
 447   # 2) For the top node, use the (printable) name of the manual, unless we
 448   #    have an explicit cross ref name
 449   # 3) In all other cases use the section name
 450   if ($cross_ref ne '') {
 451     $displaytext = $cross_ref;
 452   } elsif (($section eq '') or ($section eq 'Top')) {
 453     $displaytext = $book;
 454   } else {
 455     $displaytext = $section;
 456   }
 457
 458   $displaytext = &$anchor('', $href, $displaytext) if ($displaytext ne '');
 459   return &$I('%{node_file_href}', { 'node_file_href' => $displaytext });
 460
 461 #  Default: format as "see <a ..>NODE</a> section 'SECTION' in BOOK". We don't want this!
 462 #   return t2h_default_external_ref($type, $section, $book, $file_node, $href, $cross_ref);
 463 }
 464
 465
 466
 467
 468
 469 #############################################################################
 470 ###  HANDLING TRANSLATED SECTIONS: handle @translationof, secname<->filename
 471 ###                  map stored on disk, xrefs in other manuals load that map
 472 #############################################################################
 473
 474
 475 # Try to make use of @translationof to generate files according to the original
 476 # English section title...
 477 sub lilypond_unknown($$$$$)
 478 {
 479     my $macro = shift;
 480     my $line = shift;
 481     my $pass = shift;
 482     my $stack = shift;
 483     my $state = shift;
 484
 485     # the @translationof macro provides the original English section title,
 486     # which should be used for file/anchor naming, while the title will be
 487     # translated to each language
 488     # It is already used by extract_texi_filenames.py, so this should not be
 489     # necessary here at all. Still, I'll leave the code in just in case the
 490     # python script messed up ;-)
 491     if ($pass == 1 and $macro eq "translationof") {
 492       if (ref($state->{'element'}) eq 'HASH') {
 493         $state->{'element'}->{'translationof'} = main::normalise_space($line);
 494       }
 495       return ('', 1, undef, undef);
 496     } else {
 497       return t2h_default_unknown($macro, $line, $pass, $stack, $state);
 498     }
 499 }
 500
 501
 502
 503
 504 my %translated_books = ();
 505 # Construct a href to an external source of information.
 506 # node is the node with texinfo @-commands
 507 # node_id is the node transliterated and transformed as explained in the
 508 #         texinfo manual
 509 # node_xhtml_id is the node transformed such that it is unique and can
 510 #     be used to make an html cross ref as explained in the texinfo manual
 511 # file is the file in '(file)node'
 512 sub lilypond_external_href($$$)
 513 {
 514   my $node = shift;
 515   my $node_id = shift;
 516   my $node_hxmlt_id = shift;
 517   my $file = shift;
 518   my $original_func = \&t2h_default_external_href;
 519
 520   # 1) Keep a hash of book->section_map
 521   # 2) if not file in keys hash => try to load the map (assign empty map if
 522   #    non-existent => will load only once!)
 523   # 3) if node in the section=>(file, anchor) map, replace node_id and
 524   #    node_xhtml_id by the map's values
 525   # 4) call the t2h_default_external_href with these values (or the old ones if not found)
 526
 527   if (($node_id ne '') and defined($file) and ($node_id ne 'Top')) {
 528     my $map_name = $file;
 529     $map_name =~ s/-big-page//;
 530
 531     # Load the map if we haven't done so already
 532     if (!exists($translated_books{$map_name})) {
 533       my ($docu_dir, $docu_name) = split_texi_filename ($Texi2HTML::THISDOC{'input_file_name'});
 534       my $map_filename = main::locate_include_file ("${map_name}.$Texi2HTML::THISDOC{current_lang}.xref-map")
 535           || main::locate_include_file ("${map_name}.xref-map");
 536       $translated_books{$map_name} = load_map_file ($map_filename);
 537     }
 538
 539     # look up translation. use these values instead of the old filename/anchor
 540     my $section_name_map = $translated_books{$map_name};
 541     my $node_text = main::remove_texi($node);
 542     if (defined($section_name_map->{$node_text})) {
 543       ($node_id, $node_hxmlt_id) = @{$section_name_map->{$node_text}};
 544     } else {
 545       print STDERR "WARNING: Unable to find node '$node_text' in book $map_name.\n";
 546     }
 547   }
 548
 549   if (defined $file) {
 550     return &$original_func($node, $node_id, $node_hxmlt_id, $file);
 551   } else {
 552     return &$original_func($node, $node_id, $node_hxmlt_id);
 553   }
 554 }
 555
 556
 557
 558
 559
 560 #############################################################################
 561 ###  CUSTOM TOC FOR EACH PAGE (in a frame on the left)
 562 #############################################################################
 563
 564 my $page_toc_depth = 2;
 565 my @default_toc = [];
 566
 567
 568 # Initialize the toc_depth to 1 if the command-line option -D=short_toc is given
 569 sub lilypond_init_toc_depth ()
 570 {
 571   if (exists($main::value{'short_toc'}) and not exists($main::value{'bigpage'})) {
 572     $page_toc_depth = 1;
 573   }
 574 }
 575 # Set the TOC-depth (depending on a texinfo variable short_toc) in a
 576 # command-handler, so we have them available when creating the pages
 577 push @Texi2HTML::Config::command_handler_process, \&lilypond_init_toc_depth;
 578
 579
 580 # recursively generate the TOC entries for the element and its children (which
 581 # are only shown up to maxlevel. All ancestors of the current element are also
 582 # shown with their immediate children, irrespective of their level.
 583 # Unnumbered entries are only printed out if they are at top-level or 2nd level
 584 # or their parent element is an ancestor of the currently viewed node.
 585 # The conditions to call this method to print the entry for a child node is:
 586 # -) the parent is an ancestor of the current page node
 587 # -) the parent is a numbered element at top-level toplevel (i.e. show numbered
 588 #    and unnumbered 2nd-level children of numbered nodes)
 589 # -) the child element is a numbered node below level maxlevel
 590 sub generate_ly_toc_entries($$$)
 591 {
 592   my $element = shift;
 593   my $element_path = shift;
 594   my $maxlevel = shift;
 595   # Skip undefined sections, plus all sections generated by index splitting
 596   return() if (not defined($element) or exists($element->{'index_page'}));
 597   my @result = ();
 598   my $level = $element->{'toc_level'};
 599   my $is_parent_of_current = $element->{'id'} && $element_path->{$element->{'id'}};
 600   my $ind = '  ' x $level;
 601   my $this_css_class = $is_parent_of_current ? " class=\"toc_current\"" : "";
 602
 603   my $entry = "$ind<li$this_css_class>" . &$anchor ($element->{'tocid'}, "$element->{'file'}#$element->{'target'}",$element->{'text'});
 604
 605   push (@result, $entry);
 606   my $children = $element->{'section_childs'};
 607   if (defined($children) and (ref($children) eq "ARRAY")) {
 608     my $force_children = $is_parent_of_current or ($level == 1 and $element->{'number'});
 609     my @child_result = ();
 610     foreach my $c (@$children) {
 611       my $is_numbered_child = defined ($c->{'number'});
 612       my $below_maxlevel = $c->{'toc_level'} le $maxlevel;
 613       if ($force_children or ($is_numbered_child and $below_maxlevel)) {
 614         my @child_res = generate_ly_toc_entries($c, $element_path, $maxlevel);
 615         push (@child_result, @child_res);
 616       }
 617     }
 618     # if no child nodes were generated, e.g. for the index, where expanded pages
 619     # are ignored, don't generate a list at all...
 620     if (@child_result) {
 621       push (@result, "\n$ind<ul$NO_BULLET_LIST_ATTRIBUTE>\n");
 622       push (@result, @child_result);
 623       push (@result, "$ind</ul>\n");
 624     }
 625   }
 626   push (@result, "$ind</li>\n");
 627   return @result;
 628 }
 629
 630
 631 # Print a customized TOC, containing only the first two levels plus the whole
 632 # path to the current page
 633 sub lilypond_generate_page_toc_body($)
 634 {
 635     my $element = shift;
 636     my $current_element = $element;
 637     my %parentelements;
 638     $parentelements{$element->{'id'}} = 1;
 639     # Find the path to the current element
 640     while ( defined($current_element->{'sectionup'}) and
 641            ($current_element->{'sectionup'} ne $current_element) )
 642     {
 643       $parentelements{$current_element->{'sectionup'}->{'id'}} = 1
 644               if ($current_element->{'sectionup'}->{'id'} ne '');
 645       $current_element = $current_element->{'sectionup'};
 646     }
 647     return () if not defined($current_element);
 648     # Create the toc entries recursively
 649     my @toc_entries = ("<div class=\"contents\">\n", "<ul$NO_BULLET_LIST_ATTRIBUTE>\n");
 650     my $children = $current_element->{'section_childs'};
 651     foreach ( @$children ) {
 652       push (@toc_entries, generate_ly_toc_entries($_, \%parentelements, $page_toc_depth));
 653     }
 654     push (@toc_entries, "</ul>\n");
 655     push (@toc_entries, "</div>\n");
 656     return @toc_entries;
 657 }
 658
 659 sub lilypond_print_toc_div ($$)
 660 {
 661   my $fh = shift;
 662   my $tocref = shift;
 663   my @lines = @$tocref;
 664   # use default TOC if no custom lines have been generated
 665   @lines = @default_toc if (not @lines);
 666   if (@lines) {
 667
 668     print $fh "\n\n<div id=\"tocframe\">\n";
 669
 670     # Remove the leading "GNU LilyPond --- " from the manual title
 671     my $topname = $Texi2HTML::NAME{'Top'};
 672     $topname =~ s/^GNU LilyPond(:| &[mn]dash;) //;
 673
 674     # construct the top-level Docs index (relative path and including language!)
 675     my $lang = $Texi2HTML::THISDOC{current_lang};
 676     if ($lang and $lang ne "en") {
 677       $lang .= ".";
 678     } else {
 679       $lang = "";
 680     }
 681     my $reldir = "";
 682     $reldir = "../" if ($Texi2HTML::Config::SPLIT eq 'section');
 683     my $uplink = $reldir."index.${lang}html";
 684
 685     print $fh "<p class=\"toc_uplink\"><a href=\"$uplink\"
 686          title=\"Documentation Index\">&lt;&lt; " .
 687          &ly_get_string ('Back to Documentation Index') .
 688          "</a></p>\n";
 689
 690     print $fh '<h4 class="toc_header"> ' . &$anchor('',
 691                                     $Texi2HTML::HREF{'Top'},
 692                                     $topname,
 693                                     'title="Start of the manual"'
 694                                    ) . "</h4>\n";
 695     foreach my $line (@lines) {
 696       print $fh $line;
 697     }
 698     print $fh "</div>\n\n";
 699   }
 700 }
 701
 702 # Create the custom TOC for this page (partially folded, current page is
 703 # highlighted) and store it in a global variable. The TOC is written out after
 704 # the html contents (but positioned correctly using CSS), so that browsers with
 705 # css turned off still show the contents first.
 706 our @this_page_toc = ();
 707 sub lilypond_print_element_header
 708 {
 709   my $first_in_page = shift;
 710   my $previous_is_top = shift;
 711   if ($first_in_page and not @this_page_toc) {
 712     if (defined($Texi2HTML::THIS_ELEMENT)) {
 713       # Create the TOC for this page
 714       @this_page_toc = lilypond_generate_page_toc_body($Texi2HTML::THIS_ELEMENT);
 715     }
 716   }
 717   return T2H_DEFAULT_print_element_header( $first_in_page, $previous_is_top);
 718 }
 719
 720 # Generate the HTML output for the TOC
 721 sub lilypond_toc_body($)
 722 {
 723     my $elements_list = shift;
 724     # Generate a default TOC for pages without THIS_ELEMENT
 725     @default_toc = lilypond_generate_page_toc_body(@$elements_list[0]);
 726     return T2H_GPL_toc_body($elements_list);
 727 }
 728
 729 # Print out the TOC in a <div> at the beginning of the page
 730 sub lilypond_print_page_head($)
 731 {
 732     my $fh = shift;
 733     T2H_DEFAULT_print_page_head($fh);
 734     print $fh "<div id=\"main\">\n";
 735 }
 736
 737 # Print out the TOC in a <div> at the end of th page, which will be formatted as a
 738 # sidebar mimicking a TOC frame
 739 sub print_lilypond_page_foot($)
 740 {
 741   my $fh = shift;
 742   my $program_string = &$program_string();
 743 #   print $fh "<p><font size='-1'>$program_string</font><br>$PRE_BODY_CLOSE</p>\n";
 744   print $fh "<!-- FOOTER -->\n\n";
 745   print $fh "<!-- end div#main here -->\n</div>\n\n";
 746
 747   # Print the TOC frame and reset the TOC:
 748   lilypond_print_toc_div ($fh, \@this_page_toc);
 749   @this_page_toc = ();
 750
 751   # Close the page:
 752   print $fh "</body>\n</html>\n";
 753 }
 754
 755
 756
 757
 758
 759 #############################################################################
 760 ###  NICER / MORE FLEXIBLE NAVIGATION PANELS
 761 #############################################################################
 762
 763 sub get_navigation_text
 764 {
 765   my $button = shift;
 766   my $text = $NAVIGATION_TEXT{$button};
 767   if ( ($button eq 'Back') or ($button eq 'FastBack') ) {
 768     $text = $text . $Texi2HTML::NODE{$button} . "&nbsp;";
 769   } elsif ( ($button eq 'Forward') or ($button eq 'FastForward') ) {
 770     $text = "&nbsp;" . $Texi2HTML::NODE{$button} . $text;
 771   } elsif ( $button eq 'Up' ) {
 772     $text = "&nbsp;".$text.":&nbsp;" . $Texi2HTML::NODE{$button} . "&nbsp;";
 773   }
 774   return $text;
 775 }
 776
 777
 778 # Don't automatically create left-aligned table cells for every link, but
 779 # instead create a <td> only on an appropriate '(left|right|center)-aligned-cell-n'
 780 # button text. It's alignment as well as the colspan will be taken from the
 781 # name of the button. Also, add 'newline' button text to create a new table
 782 # row. The texts of the buttons are generated by get_navigation_text and
 783 # will contain the name of the next/previous section/chapter.
 784 sub lilypond_print_navigation
 785 {
 786     my $buttons = shift;
 787     my $vertical = shift;
 788     my $spacing = 1;
 789     my $result = "<table class=\"nav_table\">\n";
 790
 791     $result .= "<tr>" unless $vertical;
 792     my $beginofline = 1;
 793     foreach my $button (@$buttons)
 794     {
 795         $result .= qq{<tr valign="top" align="left">\n} if $vertical;
 796         # Allow (left|right|center)-aligned-cell and newline as buttons!
 797         if ( $button =~ /^(.*)-aligned-cell-(.*)$/ )
 798         {
 799           $result .= qq{</td>} unless $beginofline;
 800           $result .= qq{<td valign="middle" align="$1" colspan="$2">};
 801           $beginofline = 0;
 802         }
 803         elsif ( $button eq 'newline' )
 804         {
 805           $result .= qq{</td>} unless $beginofline;
 806           $result .= qq{</tr>};
 807           $result .= qq{<tr>};
 808           $beginofline = 1;
 809
 810         }
 811         elsif (ref($button) eq 'CODE')
 812         {
 813             $result .= &$button($vertical);
 814         }
 815         elsif (ref($button) eq 'SCALAR')
 816         {
 817             $result .= "$$button" if defined($$button);
 818         }
 819         elsif (ref($button) eq 'ARRAY')
 820         {
 821             my $text = $button->[1];
 822             my $button_href = $button->[0];
 823             # verify that $button_href is simple text and text is a reference
 824             if (defined($button_href) and !ref($button_href)
 825                and defined($text) and (ref($text) eq 'SCALAR') and defined($$text))
 826             {             # use given text
 827                 if ($Texi2HTML::HREF{$button_href})
 828                 {
 829                   my $anchor_attributes = '';
 830                   if ($USE_ACCESSKEY and (defined($BUTTONS_ACCESSKEY{$button_href})) and ($BUTTONS_ACCESSKEY{$button_href} ne ''))
 831                   {
 832                       $anchor_attributes = "accesskey=\"$BUTTONS_ACCESSKEY{$button_href}\"";
 833                   }
 834                   if ($USE_REL_REV and (defined($BUTTONS_REL{$button_href})) and ($BUTTONS_REL{$button_href} ne ''))
 835                   {
 836                       $anchor_attributes .= " rel=\"$BUTTONS_REL{$button_href}\"";
 837                   }
 838                   $result .=  "" .
 839                         &$anchor('',
 840                                     $Texi2HTML::HREF{$button_href},
 841                                     get_navigation_text($$text),
 842                                     $anchor_attributes
 843                                    );
 844                 }
 845                 else
 846                 {
 847                   $result .=  get_navigation_text($$text);
 848                 }
 849             }
 850         }
 851         elsif ($button eq ' ')
 852         {                       # handle space button
 853             $result .=
 854                 ($ICONS && $ACTIVE_ICONS{' '}) ?
 855                     &$button_icon_img($BUTTONS_NAME{$button}, $ACTIVE_ICONS{' '}) :
 856                         $NAVIGATION_TEXT{' '};
 857             #next;
 858         }
 859         elsif ($Texi2HTML::HREF{$button})
 860         {                       # button is active
 861             my $btitle = $BUTTONS_GOTO{$button} ?
 862                 'title="' . $BUTTONS_GOTO{$button} . '"' : '';
 863             if ($USE_ACCESSKEY and (defined($BUTTONS_ACCESSKEY{$button})) and ($BUTTONS_ACCESSKEY{$button} ne ''))
 864             {
 865                 $btitle .= " accesskey=\"$BUTTONS_ACCESSKEY{$button}\"";
 866             }
 867             if ($USE_REL_REV and (defined($BUTTONS_REL{$button})) and ($BUTTONS_REL{$button} ne ''))
 868             {
 869                 $btitle .= " rel=\"$BUTTONS_REL{$button}\"";
 870             }
 871             if ($ICONS && $ACTIVE_ICONS{$button})
 872             {                   # use icon
 873                 $result .= '' .
 874                     &$anchor('',
 875                         $Texi2HTML::HREF{$button},
 876                         &$button_icon_img($BUTTONS_NAME{$button},
 877                                    $ACTIVE_ICONS{$button},
 878                                    $Texi2HTML::SIMPLE_TEXT{$button}),
 879                         $btitle
 880                       );
 881             }
 882             else
 883             {                   # use text
 884                 $result .=
 885                     '[' .
 886                         &$anchor('',
 887                                     $Texi2HTML::HREF{$button},
 888                                     get_navigation_text($button),
 889                                     $btitle
 890                                    ) .
 891                                        ']';
 892             }
 893         }
 894         else
 895         {                       # button is passive
 896             $result .=
 897                 $ICONS && $PASSIVE_ICONS{$button} ?
 898                     &$button_icon_img($BUTTONS_NAME{$button},
 899                                           $PASSIVE_ICONS{$button},
 900                                           $Texi2HTML::SIMPLE_TEXT{$button}) :
 901
 902                                               "[" . get_navigation_text($button) . "]";
 903         }
 904         $result .= "</td>\n" if $vertical;
 905         $result .= "</tr>\n" if $vertical;
 906     }
 907     $result .= "</td>" unless $beginofline;
 908     $result .= "</tr>" unless $vertical;
 909     $result .= "</table>\n";
 910     return $result;
 911 }
 912
 913
 914 @Texi2HTML::Config::SECTION_BUTTONS =
 915     ('left-aligned-cell-1', 'FastBack',
 916      'center-aligned-cell-3', 'Top', 'Contents', 'Index', 'About',
 917      'right-aligned-cell-1', 'FastForward',
 918      'newline',
 919      'left-aligned-cell-2', 'Back',
 920      'center-aligned-cell-1', 'Up',
 921      'right-aligned-cell-2', 'Forward'
 922     );
 923
 924 # buttons for misc stuff
 925 @Texi2HTML::Config::MISC_BUTTONS = ('center-aligned-cell-3', 'Top', 'Contents', 'Index', 'About');
 926
 927 # buttons for chapter file footers
 928 # (and headers but only if SECTION_NAVIGATION is false)
 929 @Texi2HTML::Config::CHAPTER_BUTTONS =
 930     ('left-aligned-cell-1', 'FastBack',
 931      'center-aligned-cell-3', 'Top', 'Contents', 'Index', 'About',
 932      'right-aligned-cell-1', 'FastForward',
 933     );
 934
 935 # buttons for section file footers
 936 @Texi2HTML::Config::SECTION_FOOTER_BUTTONS =
 937     ('left-aligned-cell-1', 'FastBack',
 938      'center-aligned-cell-3', 'Top', 'Contents', 'Index', 'About',
 939      'right-aligned-cell-1', 'FastForward',
 940      'newline',
 941      'left-aligned-cell-2', 'Back',
 942      'center-aligned-cell-1', 'Up',
 943      'right-aligned-cell-2', 'Forward'
 944     );
 945
 946 @Texi2HTML::Config::NODE_FOOTER_BUTTONS =
 947     ('left-aligned-cell-1', 'FastBack',
 948      'center-aligned-cell-3', 'Top', 'Contents', 'Index', 'About',
 949      'right-aligned-cell-1', 'FastForward',
 950      'newline',
 951      'left-aligned-cell-2', 'Back',
 952      'center-aligned-cell-1', 'Up',
 953      'right-aligned-cell-2', 'Forward'
 954     );
 955
 956
 957
 958
 959
 960 #############################################################################
 961 ###  FOOTNOTE FORMATTING
 962 #############################################################################
 963
 964 # Format footnotes in a nicer way: Instead of printing the number in a separate
 965 # (nr) heading line, use the standard way of prepending <sup>nr</sup> immediately
 966 # before the fn text.
 967
 968
 969 # The following code is copied from texi2html's examples/makeinfo.init and
 970 # should be updated when texi2html makes some changes there!
 971
 972 my $makekinfo_like_footnote_absolute_number = 0;
 973
 974 sub makeinfo_like_foot_line_and_ref($$$$$$$$)
 975 {
 976     my $foot_num = shift;
 977     my $relative_num = shift;
 978     my $footid = shift;
 979     my $docid = shift;
 980     my $from_file = shift;
 981     my $footnote_file = shift;
 982     my $lines = shift;
 983     my $state = shift;
 984
 985     $makekinfo_like_footnote_absolute_number++;
 986
 987     # this is a bit obscure, this allows to add an anchor only if formatted
 988     # as part of the document.
 989     $docid = '' if ($state->{'outside_document'} or $state->{'multiple_pass'});
 990
 991     if ($from_file eq $footnote_file)
 992     {
 993         $from_file = $footnote_file = '';
 994     }
 995
 996     my $foot_anchor = "<sup>" . &$anchor($docid, "$footnote_file#$footid", $relative_num) . "</sup>";
 997     $foot_anchor = &$anchor($docid, "$footnote_file#$footid", "($relative_num)") if ($state->{'preformatted'});
 998
 999 #    unshift @$lines, "<li>";
1000 #    push @$lines, "</li>\n";
1001     return ($lines, $foot_anchor);
1002 }
1003
1004 sub makeinfo_like_foot_lines($)
1005 {
1006     my $lines = shift;
1007     unshift @$lines, "<hr>\n<h4>$Texi2HTML::I18n::WORDS->{'Footnotes_Title'}</h4>\n";
1008 #<ol type=\"1\">\n";
1009 #    push @$lines, "</ol>";
1010     return $lines;
1011 }
1012
1013 my %makekinfo_like_paragraph_in_footnote_nr;
1014
1015 sub makeinfo_like_paragraph ($$$$$$$$$$$$$)
1016 {
1017     my $text = shift;
1018     my $align = shift;
1019     my $indent = shift;
1020     my $paragraph_command = shift;
1021     my $paragraph_command_formatted = shift;
1022     my $paragraph_number = shift;
1023     my $format = shift;
1024     my $item_nr = shift;
1025     my $enumerate_style = shift;
1026     my $number = shift;
1027     my $command_stack_at_end = shift;
1028     my $command_stack_at_begin = shift;
1029     my $state = shift;
1030 #print STDERR "format: $format\n" if (defined($format));
1031 #print STDERR "paragraph @$command_stack_at_end; @$command_stack_at_begin\n";
1032     $paragraph_command_formatted = '' if (!defined($paragraph_command_formatted) or
1033           exists($special_list_commands{$format}->{$paragraph_command}));
1034     return '' if ($text =~ /^\s*$/);
1035     foreach my $style(t2h_collect_styles($command_stack_at_begin))
1036     {
1037        $text = t2h_begin_style($style, $text);
1038     }
1039     foreach my $style(t2h_collect_styles($command_stack_at_end))
1040     {
1041        $text = t2h_end_style($style, $text);
1042     }
1043     if (defined($paragraph_number) and defined($$paragraph_number))
1044     {
1045          $$paragraph_number++;
1046          return $text  if (($format eq 'itemize' or $format eq 'enumerate') and
1047             ($$paragraph_number == 1));
1048     }
1049     my $open = '<p';
1050     if ($align)
1051     {
1052         $open .= " align=\"$paragraph_style{$align}\"";
1053     }
1054     my $footnote_text = '';
1055     if (defined($command_stack_at_begin->[0]) and $command_stack_at_begin->[0] eq 'footnote')
1056     {
1057         my $state = $Texi2HTML::THISDOC{'state'};
1058         $makekinfo_like_paragraph_in_footnote_nr{$makekinfo_like_footnote_absolute_number}++;
1059         if ($makekinfo_like_paragraph_in_footnote_nr{$makekinfo_like_footnote_absolute_number} <= 1)
1060         {
1061            $open.=' class="footnote"';
1062            my $document_file = $state->{'footnote_document_file'};
1063            if ($document_file eq $state->{'footnote_footnote_file'})
1064            {
1065                $document_file = '';
1066            }
1067            my $docid = $state->{'footnote_place_id'};
1068            my $doc_state = $state->{'footnote_document_state'};
1069            $docid = '' if ($doc_state->{'outside_document'} or $doc_state->{'multiple_pass'});
1070            my $foot_label = &$anchor($state->{'footnote_footnote_id'},
1071                  $document_file . "#$state->{'footnote_place_id'}",
1072                  "$state->{'footnote_number_in_page'}");
1073            $footnote_text = "<small>[${foot_label}]</small> ";
1074         }
1075     }
1076     return $open.'>'.$footnote_text.$text.'</p>';
1077 }
1078
1079
1080 #############################################################################
1081 ###  OTHER SETTINGS
1082 #############################################################################
1083
1084 # For split pages, use index.html as start page!
1085 if ($Texi2HTML::Config::SPLIT eq 'section') {
1086   $Texi2HTML::Config::TOP_FILE = 'index.html';
1087 }
1088
1089
1090 return 1;