configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ([2.67])
   5
   6 m4_include([m4/version.m4])
   7
   8 AC_INIT([libquvi], m4_esyscmd([./gen-ver.sh -c | tr -d '\n']),
   9         [http://quvi.sf.net/bugs/],[],[http://quvi.sf.net/])
  10
  11 AC_DEFINE_UNQUOTED([BUILD_OPTS], "$@",
  12   [Define to configure invocation command line options])
  13
  14 # Interface
  15 LT_CUR=libquvi_lt_cur
  16 LT_REV=libquvi_lt_rev
  17 LT_AGE=libquvi_lt_age
  18 AC_SUBST([LT_CUR])
  19 AC_SUBST([LT_REV])
  20 AC_SUBST([LT_AGE])
  21
  22 AC_CONFIG_SRCDIR([src/api/new.c])
  23 AC_CONFIG_HEADERS([config.h])
  24 AC_CONFIG_AUX_DIR([config.aux])
  25 AC_CONFIG_MACRO_DIR([m4])
  26
  27 AC_CANONICAL_TARGET
  28 AC_USE_SYSTEM_EXTENSIONS
  29
  30 AC_DEFINE_UNQUOTED([CANONICAL_TARGET], "$target",
  31   [Define to canonical target])
  32 AC_DEFINE_UNQUOTED([CANONICAL_BUILD], "$build",
  33   [Define to canonical build])
  34 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host",
  35   [Define to canonical host])
  36
  37 AM_INIT_AUTOMAKE([1.11.1 -Wall -Werror dist-xz no-dist-gzip tar-ustar])
  38 AM_SILENT_RULES([yes])
  39 #AM_PROG_AR
  40
  41 AM_GNU_GETTEXT_VERSION([0.18.1])
  42 AM_GNU_GETTEXT([external])
  43 # GETTEXT_PACKAGE is used by glib.
  44 AC_DEFINE([GETTEXT_PACKAGE], [PACKAGE], [Define to the gettext package name])
  45 AC_SUBST([GETTEXT_PACKAGE], [PACKAGE])
  46
  47 LT_INIT([disable-static])
  48 LT_PREREQ([2.2.6])
  49
  50 # Checks for programs.
  51 AC_PROG_CC
  52 AM_PROG_CC_C_O
  53
  54 AC_PATH_PROG([DOXYGEN], [doxygen], [no])
  55 AM_CONDITIONAL([HAVE_DOXYGEN], [test x"$DOXYGEN" != "xno"])
  56 AC_SUBST([DOXYGEN])
  57
  58 AC_PATH_PROG([A2X], [a2x], [no])
  59 AM_CONDITIONAL([HAVE_A2X], [test x"$A2X" != "xno"])
  60 AC_SUBST([A2X])
  61
  62 AC_PATH_PROG([DATE], [date], [no])
  63 AS_IF([test "$DATE" != x"$xno"], [build_time=`$DATE +"%F %T %z"`])
  64 AC_DEFINE_UNQUOTED([BUILD_TIME], ["$build_time"], [We have build time])
  65
  66 BUILD_TIME="$build_time"
  67 AC_SUBST([BUILD_TIME])
  68
  69 AC_PATH_PROG([VALGRIND], [valgrind], [no])
  70 AM_CONDITIONAL([HAVE_VALGRIND], [test x"$VALGRIND" != "xno"])
  71 AC_SUBST([VALGRIND])
  72
  73 # Checks for libraries.
  74 PKG_CHECK_MODULES([liblua], [lua >= 5.1], [], [
  75   PKG_CHECK_MODULES([liblua], [lua51 >= 5.1], [], [
  76     PKG_CHECK_MODULES([liblua], [lua5.1 >= 5.1], [], [
  77       PKG_CHECK_MODULES(liblua, [lua-5.1 >= 5.1])])
  78   ])
  79 ])
  80 PKG_CHECK_MODULES([libproxy], [libproxy-1.0 >= 0.3.1])
  81 PKG_CHECK_MODULES([libcurl], [libcurl >= 7.21])
  82 PKG_CHECK_MODULES([glib], [glib-2.0 >= 2.24])
  83
  84 # Checks for scripts.
  85 pkg_scripts=libquvi-scripts-0.9
  86
  87 AC_ARG_WITH([scriptsdir],
  88   [AS_HELP_STRING([--with-scriptsdir=DIR],
  89     [Set libquvi-scripts directory to DIR. This negates the
  90     libquvi-scripts check.  DIR is assumed to contain the files
  91     installed with libquvi-scripts to the
  92       $prefix/share/libquvi-scripts/ directory.])],
  93   [scriptsdir=$withval
  94    versionfile=$scriptsdir/version],
  95   [PKG_CHECK_MODULES([libquvi_scripts], ["$pkg_scripts" >= 0.9])
  96     scriptsdir=`$PKG_CONFIG --variable scriptsdir $pkg_scripts 2>/dev/null`
  97     versionfile=`$PKG_CONFIG --variable versionfile $pkg_scripts 2>/dev/null`
  98     scriptsmodver=`$PKG_CONFIG --modversion $pkg_scripts 2>/dev/null`])
  99
 100 AS_IF([test -z "$scriptsdir"], [
 101   AC_MSG_ERROR([scriptsdir: variable not found])])
 102
 103 AS_IF([ ! test -d "$scriptsdir"], [
 104   AC_MSG_ERROR([$scriptsdir: does not exist or is not a directory])])
 105
 106 AS_IF([test -z "$versionfile"], [
 107   AC_MSG_ERROR([versionfile: variable not found])])
 108
 109 AS_IF([ ! test -f "$versionfile"], [
 110   AC_MSG_WARN([$versionfile: does not exist or is not not a regular file])])
 111
 112 AC_DEFINE_UNQUOTED([SCRIPTSDIR], ["$scriptsdir"], [We have scriptsdir])
 113 AC_DEFINE_UNQUOTED([VERSIONFILE], ["$versionfile"], [We have versionfile])
 114
 115 scriptsver=`head -n1 "$versionfile" 2>/dev/null`
 116
 117 # Checks for header files.
 118 AC_CHECK_HEADERS([stdint.h string.h])
 119
 120 # Checks for typedefs, structures, and compiler characteristics.
 121 AC_TYPE_UINT32_T
 122 AC_TYPE_UINT64_T
 123 AC_TYPE_UINT8_T
 124
 125 # Checks for library functions.
 126 AC_CHECK_FUNCS([strrchr])
 127
 128 # Version.
 129 VN=`$srcdir/gen-ver.sh`
 130 AC_DEFINE_UNQUOTED([VN], ["$VN"], [We have version number from gen-ver.sh])
 131
 132 VN_C=`$srcdir/gen-ver.sh -c`
 133 AC_SUBST([VN_C])
 134
 135 # Version: Major/Minor -pair, used to find the libquvi scripts.
 136 # e.g. $prefix/share/libquvi-scripts/$maj.$min/
 137 VERSION_MM=`$srcdir/gen-ver.sh -c -m`
 138 AC_DEFINE_UNQUOTED([VERSION_MM], "$VERSION_MM", [Version major/minor])
 139
 140 # --with-manual
 141 AC_ARG_WITH([manual],
 142   [AS_HELP_STRING([--with-manual],
 143     [install manual pages @<:@default=yes@:>@])],
 144   [],
 145   [with_manual=yes])
 146 AM_CONDITIONAL([WITH_MANUAL], [test x"$with_manual" != "xno"])
 147
 148 AC_CONFIG_FILES([
 149   Makefile
 150   doc/man3/Makefile
 151   doc/dox/Makefile
 152   doc/dox/Doxyfile
 153   doc/Makefile
 154   examples/Makefile
 155   examples/lib/Makefile
 156   src/misc/Makefile
 157   src/curl/Makefile
 158   src/net/Makefile
 159   src/api/Makefile
 160   src/api/doxy/main.dp
 161   src/lua/Makefile
 162   src/quvi-0.9/quvi/Makefile
 163   src/quvi-0.9/Makefile
 164   src/Makefile
 165   tests/Makefile
 166   tests/lib/Makefile
 167   libquvi-0.9.pc
 168   po/Makefile.in])
 169 AC_OUTPUT
 170
 171 AC_MSG_NOTICE([
 172   version         ${VERSION}
 173   prefix          ${prefix}
 174   compiler        ${CC}
 175   cflags          ${CFLAGS}
 176 System types
 177   target          ${target}
 178   build           ${build}
 179   host            ${host}
 180 Install options
 181   with
 182   - manual        ${with_manual}
 183 libquvi-scripts
 184   .pc modversion  ${scriptsmodver}
 185   versionfile     ${versionfile}
 186     version       ${scriptsver}
 187   scriptsdir      ${scriptsdir}])