configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ([2.67])
   5
   6 m4_include([m4/version.m4])
   7
   8 AC_INIT([libquvi], m4_esyscmd([./gen-ver.sh -c | tr -d '\n']),
   9         [http://quvi.sf.net/bugs/],[],[http://quvi.sf.net/])
  10
  11 AC_DEFINE_UNQUOTED([BUILD_OPTS], "$@",
  12   [Define to configure invocation command line options])
  13
  14 # Interface
  15 LT_CUR=libquvi_lt_cur
  16 LT_REV=libquvi_lt_rev
  17 LT_AGE=libquvi_lt_age
  18 AC_SUBST([LT_CUR])
  19 AC_SUBST([LT_REV])
  20 AC_SUBST([LT_AGE])
  21
  22 AC_CONFIG_SRCDIR([src/api/new.c])
  23 AC_CONFIG_HEADERS([config.h])
  24 AC_CONFIG_AUX_DIR([config.aux])
  25 AC_CONFIG_MACRO_DIR([m4])
  26
  27 AC_CANONICAL_TARGET
  28 AC_USE_SYSTEM_EXTENSIONS
  29
  30 AC_DEFINE_UNQUOTED([CANONICAL_TARGET], "$target",
  31   [Define to canonical target])
  32 AC_DEFINE_UNQUOTED([CANONICAL_BUILD], "$build",
  33   [Define to canonical build])
  34 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host",
  35   [Define to canonical host])
  36
  37 AM_INIT_AUTOMAKE([1.11.1 -Wall -Werror dist-xz no-dist-gzip tar-ustar])
  38 AM_SILENT_RULES([yes])
  39 #AM_PROG_AR
  40
  41 AM_GNU_GETTEXT_VERSION([0.18.1])
  42 AM_GNU_GETTEXT([external])
  43 # GETTEXT_PACKAGE is used by glib.
  44 AC_DEFINE([GETTEXT_PACKAGE], [PACKAGE], [Define to the gettext package name])
  45 AC_SUBST([GETTEXT_PACKAGE], [PACKAGE])
  46
  47 LT_INIT([disable-static])
  48 LT_PREREQ([2.2.6])
  49
  50 # Checks for programs.
  51 AC_PROG_CC
  52 AM_PROG_CC_C_O
  53
  54 AC_PATH_PROG([DOXYGEN], [doxygen], [no])
  55 AM_CONDITIONAL([HAVE_DOXYGEN], [test x"$DOXYGEN" != "xno"])
  56 AC_SUBST([DOXYGEN])
  57
  58 AC_PATH_PROG([A2X], [a2x], [no])
  59 AM_CONDITIONAL([HAVE_A2X], [test x"$A2X" != "xno"])
  60 AC_SUBST([A2X])
  61
  62 AC_PATH_PROG([DATE], [date], [no])
  63 AS_IF([test "$DATE" != x"$xno"], [build_time=`$DATE +"%F %T %z"`])
  64 AC_DEFINE_UNQUOTED([BUILD_TIME], ["$build_time"], [We have build time])
  65
  66 BUILD_TIME="$build_time"
  67 AC_SUBST([BUILD_TIME])
  68
  69 AC_PATH_PROG([VALGRIND], [valgrind], [no])
  70 AM_CONDITIONAL([HAVE_VALGRIND], [test x"$VALGRIND" != "xno"])
  71 AC_SUBST([VALGRIND])
  72
  73 # Checks for libraries.
  74 PKG_CHECK_MODULES([liblua], [lua >= 5.1], [], [
  75   PKG_CHECK_MODULES([liblua], [lua51 >= 5.1], [], [
  76     PKG_CHECK_MODULES([liblua], [lua5.1 >= 5.1], [], [
  77       PKG_CHECK_MODULES(liblua, [lua-5.1 >= 5.1])])
  78   ])
  79 ])
  80 PKG_CHECK_MODULES([libproxy], [libproxy-1.0 >= 0.3.1])
  81 PKG_CHECK_MODULES([libcurl], [libcurl >= 7.21])
  82 PKG_CHECK_MODULES([glib], [glib-2.0 >= 2.24])
  83 AM_PATH_LIBGCRYPT
  84
  85 # Checks for scripts.
  86 pkg_scripts=libquvi-scripts-0.9
  87
  88 AC_ARG_WITH([scriptsdir],
  89   [AS_HELP_STRING([--with-scriptsdir=DIR],
  90     [Set libquvi-scripts directory to DIR. This negates the
  91     libquvi-scripts check.  DIR is assumed to contain the files
  92     installed with libquvi-scripts to the
  93       $prefix/share/libquvi-scripts/ directory.])],
  94   [scriptsdir=$withval
  95    versionfile=$scriptsdir/version],
  96   [PKG_CHECK_MODULES([libquvi_scripts], ["$pkg_scripts" >= 0.9])
  97     scriptsdir=`$PKG_CONFIG --variable scriptsdir $pkg_scripts 2>/dev/null`
  98     versionfile=`$PKG_CONFIG --variable versionfile $pkg_scripts 2>/dev/null`
  99     scriptsmodver=`$PKG_CONFIG --modversion $pkg_scripts 2>/dev/null`])
 100
 101 AS_IF([test -z "$scriptsdir"], [
 102   AC_MSG_ERROR([scriptsdir: variable not found])])
 103
 104 AS_IF([ ! test -d "$scriptsdir"], [
 105   AC_MSG_ERROR([$scriptsdir: does not exist or is not a directory])])
 106
 107 AS_IF([test -z "$versionfile"], [
 108   AC_MSG_ERROR([versionfile: variable not found])])
 109
 110 AS_IF([ ! test -f "$versionfile"], [
 111   AC_MSG_WARN([$versionfile: does not exist or is not not a regular file])])
 112
 113 AC_DEFINE_UNQUOTED([SCRIPTSDIR], ["$scriptsdir"], [We have scriptsdir])
 114 AC_DEFINE_UNQUOTED([VERSIONFILE], ["$versionfile"], [We have versionfile])
 115
 116 scriptsver=`head -n1 "$versionfile" 2>/dev/null`
 117
 118 # Checks for header files.
 119 AC_CHECK_HEADERS([stdint.h string.h])
 120
 121 # Checks for typedefs, structures, and compiler characteristics.
 122 AC_TYPE_UINT32_T
 123 AC_TYPE_UINT64_T
 124 AC_TYPE_UINT8_T
 125
 126 # Checks for library functions.
 127 AC_CHECK_FUNCS([strrchr])
 128
 129 # Version.
 130 VN=`$srcdir/gen-ver.sh`
 131 AC_DEFINE_UNQUOTED([VN], ["$VN"], [We have version number from gen-ver.sh])
 132
 133 VN_C=`$srcdir/gen-ver.sh -c`
 134 AC_SUBST([VN_C])
 135
 136 # Version: Major/Minor -pair, used to find the libquvi scripts.
 137 # e.g. $prefix/share/libquvi-scripts/$maj.$min/
 138 VERSION_MM=`$srcdir/gen-ver.sh -c -m`
 139 AC_DEFINE_UNQUOTED([VERSION_MM], "$VERSION_MM", [Version major/minor])
 140
 141 # --with-manual
 142 AC_ARG_WITH([manual],
 143   [AS_HELP_STRING([--with-manual],
 144     [install manual pages @<:@default=yes@:>@])],
 145   [],
 146   [with_manual=yes])
 147 AM_CONDITIONAL([WITH_MANUAL], [test x"$with_manual" != "xno"])
 148
 149 AC_CONFIG_FILES([
 150   Makefile
 151   doc/man3/Makefile
 152   doc/man7/Makefile
 153   doc/dox/Makefile
 154   doc/dox/Doxyfile
 155   doc/Makefile
 156   examples/Makefile
 157   examples/lib/Makefile
 158   src/misc/Makefile
 159   src/gcrypt/Makefile
 160   src/curl/Makefile
 161   src/net/Makefile
 162   src/api/Makefile
 163   src/api/doxy/main.dp
 164   src/lua/Makefile
 165   src/quvi-0.9/quvi/Makefile
 166   src/quvi-0.9/Makefile
 167   src/Makefile
 168   tests/Makefile
 169   tests/lib/Makefile
 170   libquvi-0.9.pc
 171   po/Makefile.in])
 172 AC_OUTPUT
 173
 174 AC_MSG_NOTICE([
 175   version         ${VERSION}
 176   prefix          ${prefix}
 177   compiler        ${CC}
 178   cflags          ${CFLAGS}
 179 System types
 180   target          ${target}
 181   build           ${build}
 182   host            ${host}
 183 Install options
 184   with
 185   - manual        ${with_manual}
 186 libquvi-scripts
 187   .pc modversion  ${scriptsmodver}
 188   versionfile     ${versionfile}
 189     version       ${scriptsver}
 190   scriptsdir      ${scriptsdir}])