configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ([2.68])
   5
   6 m4_include([m4/version.m4])
   7
   8 AC_INIT([libquvi], [_LIBQUVI_VERSION],
   9   [http://sourceforge.net/apps/trac/quvi/], [],
  10   [http://quvi.sourceforge.net/])
  11
  12 # Interface:
  13 LIBQUVI_CURRENT=_LIBQUVI_CURRENT
  14 LIBQUVI_REVISION=_LIBQUVI_REVISION
  15 LIBQUVI_AGE=_LIBQUVI_AGE
  16 AC_SUBST([LIBQUVI_CURRENT])
  17 AC_SUBST([LIBQUVI_REVISION])
  18 AC_SUBST([LIBQUVI_AGE])
  19
  20 AC_CONFIG_SRCDIR([src/libquvi/quvi_api.c])
  21 AC_CONFIG_HEADERS([config.h])
  22 AC_CONFIG_AUX_DIR([config.aux])
  23 AC_CONFIG_MACRO_DIR([m4])
  24
  25 AC_CANONICAL_SYSTEM
  26 AC_GNU_SOURCE
  27
  28 AC_DEFINE_UNQUOTED([CANONICAL_TARGET], "$target", [...])
  29 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [...])
  30
  31 AM_INIT_AUTOMAKE([-Wall -Werror foreign dist-bzip2 dist-xz])
  32 AM_SILENT_RULES([yes])
  33
  34 LT_INIT()
  35 LT_PREREQ([2.2])
  36
  37 # Checks for programs.
  38 AC_PROG_CC
  39
  40 AC_PATH_PROGS([ND], [naturaldocs NaturalDocs], [],
  41   [$ND_PATH$PATH_SEPARATOR$PATH])
  42 AM_CONDITIONAL([HAVE_ND], [test -n "$ND"])
  43
  44 # Checks for libraries.
  45 PKG_CHECK_MODULES([liblua], [lua >= 5.1], [], [
  46   PKG_CHECK_MODULES([liblua], [lua51 >= 5.1], [], [
  47     PKG_CHECK_MODULES([liblua], [lua5.1 >= 5.1], [], [
  48       PKG_CHECK_MODULES(liblua, [lua-5.1 >= 5.1])])
  49   ])
  50 ])
  51 PKG_CHECK_MODULES([libcurl], [libcurl >= 7.18.2])
  52 AM_ICONV
  53
  54 # Checks for scripts.
  55 PKG_CHECK_MODULES([libquvi_scripts], [libquvi-scripts >= 0.4.0])
  56
  57 scriptsdir=`$PKG_CONFIG --variable scriptsdir libquvi-scripts 2>/dev/null`
  58 versionfile=`$PKG_CONFIG --variable versionfile libquvi-scripts 2>/dev/null`
  59 scriptsmodver=`$PKG_CONFIG --modversion libquvi-scripts 2>/dev/null`
  60
  61 AS_IF([test -z "$scriptsdir"], [
  62   AC_MSG_ERROR([libquvi-scripts.pc: scriptsdir: variable not found])])
  63
  64 AS_IF([test -z "$versionfile"], [
  65   AC_MSG_ERROR([libquvi-scripts.pc: versionfile: variable not found])])
  66
  67 AC_DEFINE_UNQUOTED([SCRIPTSDIR], ["$scriptsdir"], [We have scriptsdir])
  68 AC_DEFINE_UNQUOTED([VERSIONFILE], ["$versionfile"], [We have versionfile])
  69
  70 AC_ARG_WITH([soup],
  71   AS_HELP_STRING([--with-soup], [Build (examples) with libsoup]))
  72
  73 AS_IF([test "x$with_soup" = "xyes"], [
  74   # Either libsoup-gnome or libsoup.
  75   PKG_CHECK_MODULES([libsoup_gnome], [libsoup-gnome-2.4 >= 2.26], [
  76     AC_DEFINE([HAVE_LIBSOUP_GNOME], [1], [Have libsoup-gnome])
  77     libsoup_CFLAGS="$libsoup_gnome_CFLAGS"
  78     libsoup_LIBS="$libsoup_gnome_LIBS"], [
  79       PKG_CHECK_MODULES([libsoup], [libsoup-2.4 >= 2.26])])
  80   AC_SUBST([libsoup_CFLAGS])
  81   AC_SUBST([libsoup_LIBS])
  82 ])
  83
  84 AM_CONDITIONAL([WITH_SOUP], [test x"$with_soup" = "xyes"])
  85
  86 ND_FORMAT=HTML
  87 AC_ARG_WITH([nd-output],
  88   [AS_HELP_STRING([--with-nd-output=FORMAT],
  89     [NaturalDocs output format (HTML or FramedHTML)])], [
  90     AS_IF([test -z "$ND"], [
  91       AC_MSG_ERROR([NaturalDocs not found. No use in setting output format])])
  92     case $withval in
  93       HTML|FramedHTML)
  94         ND_FORMAT=$withval ;;
  95       *)
  96         AC_MSG_ERROR([NaturalDocs does not support $withval output format]) ;;
  97     esac
  98   ])
  99 AC_SUBST([ND_FORMAT])
 100
 101 # Checks for header files.
 102 AC_CHECK_HEADERS(
 103   [memory.h stdarg.h stddef.h stdint.h stdlib.h string.h unistd.h])
 104
 105 # Checks for typedefs, structures, and compiler characteristics.
 106 AC_CHECK_TYPES([ptrdiff_t])
 107 AC_TYPE_UINT32_T
 108 AC_TYPE_UINT64_T
 109 AC_TYPE_UINT8_T
 110 AC_TYPE_SIZE_T
 111
 112 # Checks for library functions.
 113 AC_CHECK_FUNCS([getcwd memset strdup strerror strrchr strstr])
 114 AC_FUNC_REALLOC
 115 AC_FUNC_MALLOC
 116
 117 have_asprintf=no
 118 AC_CHECK_FUNCS([vasprintf], [
 119   AC_CHECK_FUNCS([asprintf], [have_asprintf=yes])])
 120 AM_CONDITIONAL([NO_ASPRINTF], [test x"$have_asprintf" != "xyes"])
 121
 122 # Version.
 123 VN=`$srcdir/gen-ver.sh $srcdir`
 124 AC_DEFINE_UNQUOTED([VN], ["$VN"], [We have version number from gen-ver.sh])
 125
 126 # --with-examples
 127 AC_ARG_WITH([examples],
 128   [AS_HELP_STRING([--with-examples],
 129     [build examples @<:@default=no@:>@])],
 130   [],
 131   [with_examples=no])
 132 AM_CONDITIONAL([WITH_EXAMPLES], [test x"$with_examples" != "xno"])
 133
 134 # --with-manual
 135 AC_ARG_WITH([manual],
 136   [AS_HELP_STRING([--with-manual],
 137     [install manual pages @<:@default=yes@:>@])],
 138   [],
 139   [with_manual=yes])
 140 AM_CONDITIONAL([WITH_MANUAL], [test x"$with_manual" != "xno"])
 141
 142 AC_CONFIG_FILES([
 143   Makefile
 144   doc/Makefile
 145   doc/man3/Makefile
 146   examples/Makefile
 147   src/Makefile
 148   src/libquvi/Makefile
 149   src/libquvi/quvi/Makefile
 150   libquvi.pc])
 151 AC_OUTPUT
 152
 153 AC_MSG_NOTICE([
 154   version:        ${VERSION} (${VN})
 155   host setup:     ${host}
 156   prefix:         ${prefix}
 157   cflags:         ${CFLAGS}
 158   compiler:       ${CC}
 159 libquvi-scripts.pc:
 160   modversion:     ${scriptsmodver}
 161   scriptsdir:     ${scriptsdir}
 162   versionfile:    ${versionfile}
 163 Options:
 164   build libquvi:  shared=${enable_shared} static=${enable_static}
 165   build examples: ${with_examples}
 166   install manual: ${with_manual}])