configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_PREREQ(2.60)
   3 AC_INIT(libpwmd, 8.0.0-dev, [Ben Kibbey bjk@luxsci.net])
   4 AC_CONFIG_MACRO_DIR([m4])
   5 AC_CONFIG_AUX_DIR(build)
   6 AC_CANONICAL_TARGET
   7 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
   8 AC_PROG_MAKE_SET
   9 #AC_DISABLE_SHARED
  10 AC_USE_SYSTEM_EXTENSIONS
  11 AC_PROG_LIBTOOL
  12 AC_CONFIG_SRCDIR([src/libpwmd.c])
  13 AM_CONFIG_HEADER([config.h])
  14 AM_GNU_GETTEXT([external])
  15 AM_GNU_GETTEXT_VERSION([0.16.1])
  16
  17 VER_MAJOR="`echo "$VERSION" | sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\1/'`"
  18 VER_MINOR="`echo "$VERSION" | sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\2/'`"
  19 VER_PATCH="`echo "$VERSION" | sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\3/'`"
  20 AC_SUBST(VER_MAJOR)
  21 AC_SUBST(VER_MINOR)
  22 AC_SUBST(VER_PATCH)
  23 VER_MAJOR_HEX=`printf "%02X" $VER_MAJOR`
  24 VER_MINOR_HEX=`printf "%02X" $VER_MINOR`
  25 VER_PATCH_HEX=`printf "%02X" $VER_PATCH`
  26 AC_SUBST(VER_MAJOR_HEX)
  27 AC_SUBST(VER_MINOR_HEX)
  28 AC_SUBST(VER_PATCH_HEX)
  29 VER_STRING="\"$VERSION\""
  30 AC_SUBST(VER_STRING)
  31 LIBTOOL_CUR=1
  32 LIBTOOL_REV=0
  33 LIBTOOL_AGE=0
  34 AC_SUBST(LIBTOOL_CUR)
  35 AC_SUBST(LIBTOOL_REV)
  36 AC_SUBST(LIBTOOL_AGE)
  37
  38 case "$target_os" in
  39     darwin*)
  40         LDFLAGS="$LDFLAGS -flat_namespace -L/sw/lib"
  41         CPPFLAGS="$CPPFLAGS -I/sw/include -L/sw/lib"
  42         ;;
  43     linux*)
  44         case "$target_cpu" in
  45             x86_64*)
  46                 LDFLAGS="$LDFLAGS -lrt"
  47                 ;;
  48             *)
  49                 ;;
  50         esac
  51         ;;
  52     *)
  53         ;;
  54 esac
  55
  56 dnl Checks for programs.
  57 AC_PROG_CC_C99
  58
  59 if test "$ac_cv_prog_cc_c99" = "no"; then
  60     AC_MSG_ERROR("Unable to find a C99 compatible compiler.")
  61 fi
  62
  63 dnl Borrowed from libssh2!
  64 dnl ************************************************************
  65 dnl Enable hiding of internal symbols in library to reduce its size and
  66 dnl speed dynamic linking of applications.  This currently is only supported
  67 dnl on gcc >= 4.0 and SunPro C.
  68 dnl
  69 AC_MSG_CHECKING([whether to enable hidden symbols in the library])
  70 AC_ARG_ENABLE(hidden-symbols,
  71 AC_HELP_STRING([--enable-hidden-symbols],[Hide internal symbols in library])
  72 AC_HELP_STRING([--disable-hidden-symbols],[Leave all symbols with default visibility in library]),
  73 [ case "$enableval" in
  74   no)
  75        AC_MSG_RESULT(no)
  76        ;;
  77   *)
  78        AC_MSG_CHECKING([whether $CC supports it])
  79        if test "$GCC" = yes ; then
  80          if $CC --help --verbose 2>&1 | grep fvisibility= > /dev/null ; then
  81            AC_MSG_RESULT(yes)
  82            AC_DEFINE(LIBPWMD_API, [__attribute__ ((visibility ("default")))], [to make a symbol visible])
  83            CFLAGS="$CFLAGS -fvisibility=hidden"
  84          else
  85             AC_MSG_RESULT(no)
  86           fi
  87
  88        else
  89          dnl Test for SunPro cc
  90          if $CC 2>&1 | grep flags >/dev/null && $CC -flags | grep xldscope= >/dev/null ; then
  91            AC_MSG_RESULT(yes)
  92            AC_DEFINE(LIBPWMD_API, [__global], [to make a symbol visible])
  93            CFLAGS="$CFLAGS -xldscope=hidden"
  94          else
  95            AC_MSG_RESULT(no)
  96          fi
  97        fi
  98        ;;
  99   esac ],
 100        AC_MSG_RESULT(no)
 101 )
 102
 103 dnl Checks for header files.
 104 AC_HEADER_STDC
 105 AC_HEADER_SYS_WAIT
 106 AC_CHECK_HEADERS([fcntl.h limits.h stdlib.h string.h unistd.h sys/socket.h \
 107                   getopt.h])
 108
 109 dnl Checks for typedefs, structures, and compiler characteristics.
 110 AC_C_CONST
 111 AC_TYPE_SIZE_T
 112 AC_STRUCT_TM
 113 AC_TYPE_SSIZE_T
 114 AC_TYPE_PID_T
 115
 116 AX_CHECK_COMPILE_FLAG([-D_FORTIFY_SOURCE=2],
 117                       [CPPFLAGS="$CPPFLAGS -D_FORTIFY_SOURCE=2"])
 118 ACX_PTHREAD(, AC_MSG_ERROR([Missing or incomplete pthread installation]))
 119 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 120 LIBS="$PTHREAD_LIBS $LIBS"
 121 PKG_PROG_PKG_CONFIG
 122
 123 acx_pthread_cancel_ok=no
 124 AC_MSG_CHECKING([for pthread_cancel()])
 125 AC_TRY_LINK_FUNC(pthread_cancel, acx_pthread_cancel_ok=yes)
 126 AC_MSG_RESULT($acx_pthread_cancel_ok)
 127 if test x"$acx_pthread_cancel_ok" = "xyes"; then
 128     AC_DEFINE(HAVE_PTHREAD_CANCEL, 1, [Define if your OS has pthread_cancel().])
 129 fi
 130
 131 AC_ARG_ENABLE(interactive, AC_HELP_STRING([--disable-interactive], [Disable interactive mode in pwmc.]),
 132                 WITH_INTERACTIVE=no, WITH_INTERACTIVE=yes)
 133 AC_MSG_CHECKING([if interactive mode is wanted])
 134 AC_MSG_RESULT($WITH_INTERACTIVE)
 135 if test "x$WITH_INTERACTIVE" = "xyes"; then
 136     VL_LIB_READLINE
 137
 138     if test "x$vl_cv_lib_readline" != "xno"; then
 139         READLINE_LIBS="$vl_cv_lib_readline"
 140         AC_SUBST(READLINE_LIBS)
 141     else
 142         AC_MSG_ERROR([Missing or incomplete readline installation.])
 143         WITH_INTERACTIVE="no"
 144     fi
 145 fi
 146 AM_CONDITIONAL([WITH_READLINE], [test x"$vl_cv_lib_readline" != "x"])
 147
 148 AM_PATH_LIBASSUAN([2.1.0], have_libassuan_2_1_0=yes)
 149 if test x"$have_libassuan_2_1_0" != x"yes";then
 150    AM_PATH_LIBASSUAN([2.0.3],, AC_MSG_ERROR([libassuan 2.0.3 or later required.]))
 151 else
 152    AC_DEFINE(LIBASSUAN_2_1_0, 1, [Define if you have libassuan 2.1.0 or later.])
 153 fi
 154
 155 AM_PATH_GPG_ERROR(,, AC_MSG_ERROR([Missing or incomplete libgpg-error installation.]))
 156
 157 AC_ARG_ENABLE(ssh, AC_HELP_STRING([--enable-ssh], [Enable SSH support.]),
 158                 WITH_SSH=$enableval, WITH_SSH=no)
 159 AC_MSG_CHECKING([if ssh support is wanted])
 160 AC_MSG_RESULT($WITH_SSH)
 161 if test "x$WITH_SSH" = "xyes"; then
 162     AC_MSG_CHECKING([for libssh2 availability])
 163     PKG_CHECK_EXISTS([libssh2], have_libssh2=1)
 164     WITH_SSH=no
 165
 166     if test $have_libssh2; then
 167         PKG_CHECK_MODULES([libssh2], [libssh2 >= 1.2.9])
 168         AC_DEFINE(WITH_SSH, 1, [Define if you want SSH support.])
 169         WITH_SSH=yes
 170     else
 171         AC_MSG_ERROR([Missing or incomplete libssh2 installation.])
 172     fi
 173 fi
 174 AM_CONDITIONAL([WITH_SSH], [test "x$WITH_SSH" = "xyes"])
 175
 176 AC_ARG_ENABLE(gnutls, AC_HELP_STRING([--enable-gnutls],
 177               [Enable GnuTLS client support.]), WITH_GNUTLS=$enableval,
 178               WITH_GNUTLS=no)
 179 AC_MSG_CHECKING([if gnutls support is wanted])
 180 AC_MSG_RESULT($WITH_GNUTLS)
 181 if test "x$WITH_GNUTLS" = "xyes"; then
 182     AC_MSG_CHECKING([for libgnutls availability])
 183     PKG_CHECK_EXISTS(gnutls, have_libgnutls=1, AC_MSG_ERROR([gnutls pkg-config module not found]))
 184     WITH_GNUTLS=no
 185
 186     if test $have_libgnutls; then
 187         PKG_CHECK_MODULES([GNUTLS], [gnutls >= 3.3.0])
 188         AC_DEFINE(WITH_GNUTLS, 1, [Define if you want GnuTLS support.])
 189         WITH_GNUTLS=yes
 190     else
 191         AC_MSG_ERROR([Missing or incomplete gnutls installation.])
 192     fi
 193 fi
 194 AM_CONDITIONAL(WITH_GNUTLS, [test "x$WITH_GNUTLS" = "xyes"])
 195
 196 # Default pwmd socket.
 197 AC_ARG_WITH(pwmd_socket, AC_HELP_STRING([--with-pwmd-socket=PATH],
 198               [Default pwmd socket (~/.pwmd/socket)]),
 199               pwmd_socket="$withval", pwmd_socket=)
 200 if test x"$pwmd_socket" != "x"; then
 201    AC_DEFINE_UNQUOTED(DEFAULT_PWMD_SOCKET, ["$pwmd_socket"],
 202                       [Default pwmd socket (~/.pwmd/socket).])
 203 else
 204    pwmd_socket="~/.pwmd/socket"
 205 fi
 206 AC_SUBST(pwmd_socket)
 207
 208 dnl Checks for library functions.
 209 AC_FUNC_MALLOC
 210 AC_FUNC_REALLOC
 211 AC_FUNC_STRFTIME
 212 AC_FUNC_SELECT_ARGTYPES
 213 AC_CHECK_FUNCS([memmove select socket strdup strerror setlocale getcwd \
 214                 memset stpcpy strchr strrchr strtok_r getopt_long getpwuid_r])
 215 AM_CONDITIONAL([NEED_GETOPT_LONG], [test "$ac_cv_func_getopt_long" != "yes"])
 216
 217 AC_DEFUN([AC_MEM_DEBUG],
 218 [
 219     if test "$1"; then
 220         ac_cv_sys_mem_debug=$1
 221     fi
 222
 223     AC_CACHE_CHECK([if memory debugging is wanted], [ac_cv_sys_mem_debug],
 224         [ac_cv_sys_mem_debug=no])
 225     AM_CONDITIONAL([WITH_MEM_DEBUG], [test "$ac_cv_sys_mem_debug" = "yes"])
 226 ])
 227
 228 AC_ARG_ENABLE(mem_debug, AC_HELP_STRING([--enable-mem-debug],
 229               [Enable memory debugging.]), AC_MEM_DEBUG([$enableval]),
 230               AC_MEM_DEBUG)
 231
 232 AM_CONDITIONAL(MEM_DEBUG, test "x${ac_cv_sys_mem_debug}" != "xno")
 233
 234 AC_ARG_ENABLE(pinentry, AC_HELP_STRING([--disable-pinentry],
 235               [Disable pinentry(1) support (not pwmd).]), WITH_PINENTRY=no,
 236               WITH_PINENTRY=yes)
 237
 238 if test "x$WITH_PINENTRY" != "xno"; then
 239     AC_CHECK_HEADERS([locale.h])
 240     AC_DEFINE(WITH_PINENTRY, 1, [Define if you want local pinentry(1) support.])
 241 fi
 242
 243 AM_CONDITIONAL([WITH_PINENTRY], [test "x$WITH_PINENTRY" = "xyes"])
 244 pinentry="/usr/bin/pinentry"
 245
 246 AC_ARG_WITH(pinentry, AC_HELP_STRING([--with-pinentry=PATH],
 247               [Default location of the pinentry binary (/usr/bin/pinentry)]),
 248               pinentry="$withval")
 249
 250 AC_SUBST(pinentry)
 251 AC_DEFINE_UNQUOTED(PINENTRY_PATH, ["$pinentry"],
 252                    [Default location of the pinentry binary.])
 253
 254 # Cracklib support (requires pinentry support).
 255 AC_ARG_ENABLE(quality, AC_HELP_STRING([--enable-quality],
 256               [Enable password quality checking with cracklib.]),
 257               WITH_QUALITY=$enableval, WITH_QUALITY=no)
 258 if test "x$WITH_QUALITY" = "xyes"; then
 259     if test "x$WITH_PINENTRY" != "xyes"; then
 260         AC_MSG_ERROR([--enable-quality needs --enable-pinentry])
 261     fi
 262
 263     AC_CHECK_HEADER([crack.h],, AC_MSG_ERROR([Missing or invalid cracklib installation.]))
 264     AC_CHECK_LIB([crack], FascistCheck,, AC_MSG_ERROR([Missing or invalid cracklib installation.]))
 265     AC_DEFINE(WITH_QUALITY, 1, [Define if you want password quality checking.])
 266 fi
 267 AM_CONDITIONAL(WITH_QUALITY, [test "x$WITH_QUALITY" = "xyes"])
 268
 269 crackdict="/var/cache/cracklib/cracklib_dict"
 270 AC_ARG_WITH(crackdict, AC_HELP_STRING([--with-crack-dict=PATH],
 271               [Location of the cracklib dictionary (/var/cache/cracklib/cracklib_dict).]),
 272               crackdict="$withval")
 273 AC_SUBST(crackdict)
 274 AC_DEFINE_UNQUOTED(CRACKLIB_DICT, ["$crackdict"], [The location of the cracklib dictionary.])
 275
 276 AC_CONFIG_FILES([Makefile libpwmd-8.0.pc doc/Makefile doc/doxygen.conf.in \
 277                  doc/pwmc.1 src/Makefile src/libpwmd.h po/Makefile.in])
 278 AC_OUTPUT
 279 echo
 280 echo "Features:"
 281 echo "    Interactive pwmc: $WITH_INTERACTIVE"
 282 echo "    Ssh: $WITH_SSH"
 283 echo "    GnuTLS: $WITH_GNUTLS"
 284 echo "    Local pinentry: $WITH_PINENTRY"
 285 echo "    Pinentry location: $pinentry"
 286
 287 if test x"$pwmd_socket" != "x"; then
 288 echo "    Default pwmd socket: $pwmd_socket"
 289 else
 290 echo "    Default pwmd socket: ~/.pwmd/socket"
 291 fi
 292
 293 echo "    Local passphrase quality checking: $WITH_QUALITY"
 294 echo "    Crack dictionary: $crackdict"
 295 echo "    Memory debug: ${ac_cv_sys_mem_debug}"