rbutil/rbutilqt/rbutilqt.pro

   1 #
   2 #             __________               __   ___.
   3 #   Open      \______   \ ____   ____ |  | _\_ |__   _______  ___
   4 #   Source     |       _//  _ \_/ ___\|  |/ /| __ \ /  _ \  \/  /
   5 #   Jukebox    |    |   (  <_> )  \___|    < | \_\ (  <_> > <  <
   6 #   Firmware   |____|_  /\____/ \___  >__|_ \|___  /\____/__/\_ \
   7 #                     \/            \/     \/    \/            \/
   8 # $Id$
   9 #
  10 # All files in this archive are subject to the GNU General Public License.
  11 # See the file COPYING in the source tree root for full license agreement.
  12 #
  13 # This software is distributed on an "AS IS" basis, WITHOUT WARRANTY OF ANY
  14 # KIND, either express or implied.
  15 #
  16
  17 # ccache
  18 unix:!mac:!noccache {
  19     CCACHE = $$system(which ccache)
  20     !isEmpty(CCACHE) {
  21         message("using ccache")
  22         QMAKE_CXX = ccache g++
  23         QMAKE_CC = ccache gcc
  24     }
  25 }
  26
  27 MYBUILDDIR = $$OUT_PWD/build/
  28 OBJECTS_DIR = $$MYBUILDDIR/o
  29 UI_DIR = $$MYBUILDDIR/ui
  30 MOC_DIR = $$MYBUILDDIR/moc
  31 RCC_DIR = $$MYBUILDDIR/rcc
  32
  33
  34 # check version of Qt installation
  35 VER = $$find(QT_VERSION, ^4\.[5-9]+.*)
  36 isEmpty(VER) {
  37     !isEmpty(QT_VERSION) error("Qt found:" $$[QT_VERSION])
  38     error("Qt >= 4.3 required!")
  39 }
  40 message("Qt version used:" $$VER)
  41
  42 RBBASE_DIR = $$_PRO_FILE_PWD_
  43 RBBASE_DIR = $$replace(RBBASE_DIR,/rbutil/rbutilqt,)
  44
  45 message("Rockbox Base dir: "$$RBBASE_DIR)
  46
  47 # custom rules for rockbox-specific libs
  48 !mac {
  49     RBLIBPOSTFIX = .a
  50 }
  51 mac {
  52     RBLIBPOSTFIX = -universal
  53 }
  54 rbspeex.commands = @$(MAKE) \
  55         TARGET_DIR=$$MYBUILDDIR -C $$RBBASE_DIR/tools/rbspeex \
  56         librbspeex$$RBLIBPOSTFIX CC=\"$$QMAKE_CC\"
  57 libucl.commands = @$(MAKE) \
  58         TARGET_DIR=$$MYBUILDDIR -C $$RBBASE_DIR/tools/ucl/src \
  59         libucl$$RBLIBPOSTFIX CC=\"$$QMAKE_CC\"
  60 libmkamsboot.commands = @$(MAKE) \
  61         TARGET_DIR=$$MYBUILDDIR -C $$RBBASE_DIR/rbutil/mkamsboot \
  62         libmkamsboot$$RBLIBPOSTFIX CC=\"$$QMAKE_CC\"
  63 libmktccboot.commands = @$(MAKE) \
  64         TARGET_DIR=$$MYBUILDDIR -C $$RBBASE_DIR/rbutil/mktccboot \
  65         libmktccboot$$RBLIBPOSTFIX CC=\"$$QMAKE_CC\"
  66 libmkmpioboot.commands = @$(MAKE) \
  67         TARGET_DIR=$$MYBUILDDIR -C $$RBBASE_DIR/rbutil/mkmpioboot \
  68         libmkmpioboot$$RBLIBPOSTFIX CC=\"$$QMAKE_CC\"
  69 QMAKE_EXTRA_TARGETS += rbspeex libucl libmkamsboot libmktccboot libmkmpioboot
  70 PRE_TARGETDEPS += rbspeex libucl libmkamsboot libmktccboot libmkmpioboot
  71
  72 # rule for creating ctags file
  73 tags.commands = ctags -R --c++-kinds=+p --fields=+iaS --extra=+q $(SOURCES)
  74 tags.depends = $(SOURCES)
  75 QMAKE_EXTRA_TARGETS += tags
  76
  77 # add a custom rule for making the translations
  78 lrelease.commands = $$[QT_INSTALL_BINS]/lrelease -silent $$_PRO_FILE_
  79 QMAKE_EXTRA_TARGETS += lrelease
  80 !dbg {
  81     PRE_TARGETDEPS += lrelease
  82 }
  83
  84 # Needed by QT on Win
  85 INCLUDEPATH = $$_PRO_FILE_PWD_ $$_PRO_FILE_PWD_/irivertools \
  86             $$_PRO_FILE_PWD_/zip $$_PRO_FILE_PWD_/zlib $$_PRO_FILE_PWD_/base
  87 INCLUDEPATH += $$RBBASE_DIR/rbutil/ipodpatcher $$RBBASE_DIR/rbutil/sansapatcher \
  88             $$RBBASE_DIR/tools/rbspeex $$RBBASE_DIR/tools
  89
  90 DEPENDPATH = $$INCLUDEPATH
  91
  92 LIBS += -L$$OUT_PWD -L$$MYBUILDDIR -lrbspeex -lmkamsboot -lmktccboot -lmkmpioboot -lucl
  93
  94 # check for system speex. Add a custom rule for pre-building librbspeex if not
  95 # found. Newer versions of speex are split up into libspeex and libspeexdsp,
  96 # and some distributions package them separately. Check for both and fall back
  97 # to librbspeex if not found.
  98 # NOTE: keep this after -lrbspeex, otherwise linker errors occur if the linker
  99 # defaults to --as-needed (see http://www.gentoo.org/proj/en/qa/asneeded.xml)
 100 LIBSPEEX = $$system(pkg-config --silence-errors --libs speex speexdsp)
 101 !static:!isEmpty(LIBSPEEX) {
 102     LIBS += $$LIBSPEEX
 103 }
 104
 105 TEMPLATE = app
 106 TARGET = RockboxUtility
 107 QT += network
 108 dbg {
 109     CONFIG += debug thread qt warn_on
 110     DEFINES -= QT_NO_DEBUG_OUTPUT
 111     message("debug")
 112 }
 113 !dbg {
 114     CONFIG += release thread qt
 115     DEFINES -= QT_NO_DEBUG_OUTPUT
 116     DEFINES += NODEBUG
 117     message("release")
 118 }
 119
 120 DEFINES += RBUTIL _LARGEFILE64_SOURCE
 121
 122 # platform specific
 123 win32 {
 124     LIBS += -lsetupapi -lnetapi32
 125 }
 126 unix:!static:!libusb1 {
 127     LIBS += -lusb
 128 }
 129 unix:!static:libusb1 {
 130     DEFINES += LIBUSB1
 131     LIBS += -lusb-1.0
 132 }
 133
 134 unix:static {
 135     # force statically linking of libusb. Libraries that are appended
 136     # later will get linked dynamically again.
 137     LIBS += -Wl,-Bstatic -lusb -Wl,-Bdynamic
 138 }
 139
 140 macx {
 141     QMAKE_MAC_SDK=/Developer/SDKs/MacOSX10.4u.sdk
 142     QMAKE_LFLAGS_PPC=-mmacosx-version-min=10.4 -arch ppc
 143     QMAKE_LFLAGS_X86=-mmacosx-version-min=10.4 -arch i386
 144     CONFIG+=x86 ppc
 145     LIBS += -L/usr/local/lib -lz \
 146             -framework IOKit -framework CoreFoundation -framework Carbon \
 147             -framework SystemConfiguration -framework CoreServices
 148     INCLUDEPATH += /usr/local/include
 149
 150     # rule for creating a dmg file
 151     dmg.commands = hdiutil create -ov -srcfolder rbutilqt.app/ rbutil.dmg
 152     QMAKE_EXTRA_TARGETS += dmg
 153 }
 154
 155 static {
 156     QTPLUGIN += qtaccessiblewidgets
 157     LIBS += -L$$(QT_BUILD_TREE)/plugins/accessible -lqtaccessiblewidgets
 158     LIBS += -L.
 159     DEFINES += STATIC
 160     message("using static plugin")
 161 }
 162
 163 unix {
 164     target.path = /usr/local/bin
 165     INSTALLS += target
 166 }
 167
 168 # source files are separate.
 169 include(rbutilqt.pri)
 170