utils/themeeditor/themeeditor.pro

   1 # Setting the binary name
   2 TARGET = rbthemeeditor
   3 VERSION = 0.5
   4 CONFIG(debug) {
   5     REVISION = $$system(svnversion)
   6     VERSION = $$join(VERSION,,,r)
   7     VERSION = $$join(VERSION,,,$$REVISION)
   8 }
   9
  10 # Adding network support
  11 QT += network
  12
  13 # Enabling profiling
  14 QMAKE_CXXFLAGS_DEBUG += -pg
  15 QMAKE_LFLAGS_DEBUG += -pg
  16
  17 # Adding zlib dependency for QuaZip
  18 LIBS += -lz
  19 INCLUDEPATH += zlib
  20
  21 # build in a separate folder.
  22 MYBUILDDIR = $$OUT_PWD/build/
  23 OBJECTS_DIR = $$MYBUILDDIR/o
  24 UI_DIR = $$MYBUILDDIR/ui
  25 MOC_DIR = $$MYBUILDDIR/moc
  26 RCC_DIR = $$MYBUILDDIR/rcc
  27 RBBASE_DIR = $$_PRO_FILE_PWD_
  28 RBBASE_DIR = $$replace(RBBASE_DIR,/utils/themeeditor,)
  29
  30 # Include directories
  31 INCLUDEPATH += gui
  32 INCLUDEPATH += models
  33 INCLUDEPATH += graphics
  34 INCLUDEPATH += quazip
  35 INCLUDEPATH += qtfindreplacedialog
  36 DEFINES += FINDREPLACE_NOLIB
  37 cross {
  38     message("Crossbuilding for W32 binary")
  39
  40     # retrieve ar binary for w32 cross compile. This might be specific to
  41     # Fedora mingw32 packages of Qt. Using member() here is needed because at
  42     # least the F13 packages add ar options to the variable.
  43     CROSSOPTIONS += AR=$$member(QMAKE_LIB)
  44
  45     # make sure we use the correct subsystem to prevent a console window coming up.
  46     LIBS += -Wl,-subsystem,windows
  47 }
  48
  49 # Stuff for the parse lib
  50 libskin_parser.commands = @$(MAKE) \
  51     TARGET_DIR=$$MYBUILDDIR \
  52     CC=\"$$QMAKE_CC\" \
  53     $$CROSSOPTIONS \
  54     BUILDDIR=$$OBJECTS_DIR \
  55     -C \
  56     $$RBBASE_DIR/lib/skin_parser \
  57     libskin_parser.a
  58 QMAKE_EXTRA_TARGETS += libskin_parser
  59 PRE_TARGETDEPS += libskin_parser
  60 INCLUDEPATH += $$RBBASE_DIR/lib/skin_parser
  61 LIBS += -L$$MYBUILDDIR \
  62     -lskin_parser
  63 DEPENDPATH = $$INCLUDEPATH
  64 HEADERS += models/parsetreemodel.h \
  65     models/parsetreenode.h \
  66     gui/editorwindow.h \
  67     gui/skinhighlighter.h \
  68     gui/skindocument.h \
  69     gui/preferencesdialog.h \
  70     gui/codeeditor.h \
  71     models/projectmodel.h \
  72     gui/tabcontent.h \
  73     gui/configdocument.h \
  74     gui/skinviewer.h \
  75     graphics/rbscreen.h \
  76     graphics/rbviewport.h \
  77     graphics/rbrenderinfo.h \
  78     graphics/rbimage.h \
  79     graphics/rbfont.h \
  80     gui/devicestate.h \
  81     graphics/rbalbumart.h \
  82     graphics/rbprogressbar.h \
  83     graphics/rbtext.h \
  84     graphics/rbfontcache.h \
  85     graphics/rbtextcache.h \
  86     gui/skintimer.h \
  87     graphics/rbtoucharea.h \
  88     gui/newprojectdialog.h \
  89     models/targetdata.h \
  90     quazip/zip.h \
  91     quazip/unzip.h \
  92     quazip/quazipnewinfo.h \
  93     quazip/quazipfileinfo.h \
  94     quazip/quazipfile.h \
  95     quazip/quazip.h \
  96     quazip/ioapi.h \
  97     quazip/crypt.h \
  98     zlib/zlib.h \
  99     zlib/zconf.h \
 100     gui/fontdownloader.h \
 101     qtfindreplacedialog/varianteditor.h \
 102     qtfindreplacedialog/findreplace_global.h \
 103     qtfindreplacedialog/findreplaceform.h \
 104     qtfindreplacedialog/findreplacedialog.h \
 105     qtfindreplacedialog/findform.h \
 106     qtfindreplacedialog/finddialog.h \
 107     gui/projectexporter.h \
 108     gui/targetdownloader.h \
 109     gui/syntaxcompleter.h
 110 SOURCES += main.cpp \
 111     models/parsetreemodel.cpp \
 112     models/parsetreenode.cpp \
 113     gui/editorwindow.cpp \
 114     gui/skinhighlighter.cpp \
 115     gui/skindocument.cpp \
 116     gui/preferencesdialog.cpp \
 117     gui/codeeditor.cpp \
 118     models/projectmodel.cpp \
 119     gui/configdocument.cpp \
 120     gui/skinviewer.cpp \
 121     graphics/rbscreen.cpp \
 122     graphics/rbviewport.cpp \
 123     graphics/rbrenderinfo.cpp \
 124     graphics/rbimage.cpp \
 125     graphics/rbfont.cpp \
 126     gui/devicestate.cpp \
 127     graphics/rbalbumart.cpp \
 128     graphics/rbprogressbar.cpp \
 129     graphics/rbtext.cpp \
 130     graphics/rbfontcache.cpp \
 131     graphics/rbtextcache.cpp \
 132     gui/skintimer.cpp \
 133     graphics/rbtoucharea.cpp \
 134     gui/newprojectdialog.cpp \
 135     models/targetdata.cpp \
 136     quazip/zip.c \
 137     quazip/unzip.c \
 138     quazip/quazipnewinfo.cpp \
 139     quazip/quazipfile.cpp \
 140     quazip/quazip.cpp \
 141     quazip/ioapi.c \
 142     gui/fontdownloader.cpp \
 143     qtfindreplacedialog/varianteditor.cpp \
 144     qtfindreplacedialog/findreplaceform.cpp \
 145     qtfindreplacedialog/findreplacedialog.cpp \
 146     qtfindreplacedialog/findform.cpp \
 147     qtfindreplacedialog/finddialog.cpp \
 148     gui/projectexporter.cpp \
 149     gui/targetdownloader.cpp \
 150     gui/syntaxcompleter.cpp
 151 OTHER_FILES += README \
 152     resources/windowicon.png \
 153     resources/appicon.xcf \
 154     resources/COPYING \
 155     resources/document-save.png \
 156     resources/document-open.png \
 157     resources/document-new.png \
 158     resources/deviceoptions \
 159     resources/render/statusbar.png \
 160     resources/render/scenebg.png \
 161     resources/play.xcf \
 162     resources/play.png \
 163     resources/rwnd.png \
 164     resources/pause.xcf \
 165     resources/pause.png \
 166     resources/ffwd.xcf \
 167     resources/ffwd.png \
 168     resources/lines.xcf \
 169     resources/lines.png \
 170     resources/cursor.xcf \
 171     resources/cursor.png \
 172     resources/targetdb \
 173     quazip/README.ROCKBOX \
 174     quazip/LICENSE.GPL \
 175     qtfindreplacedialog/dialogs.pro \
 176     resources/tagdb
 177 FORMS += gui/editorwindow.ui \
 178     gui/preferencesdialog.ui \
 179     gui/configdocument.ui \
 180     gui/skinviewer.ui \
 181     gui/skintimer.ui \
 182     gui/newprojectdialog.ui \
 183     gui/fontdownloader.ui \
 184     qtfindreplacedialog/findreplaceform.ui \
 185     qtfindreplacedialog/findreplacedialog.ui \
 186     gui/projectexporter.ui \
 187     gui/targetdownloader.ui
 188 RESOURCES += resources.qrc
 189 win32:RC_FILE = themeeditor.rc
 190 macx {
 191     QMAKE_MAC_SDK = /Developer/SDKs/MacOSX10.4u.sdk
 192     QMAKE_LFLAGS_PPC = -mmacosx-version-min=10.4 \
 193         -arch \
 194         ppc
 195     QMAKE_LFLAGS_X86 = -mmacosx-version-min=10.4 \
 196         -arch \
 197         i386
 198     CONFIG += x86 \
 199         ppc
 200     QMAKE_INFO_PLIST = Info.plist
 201     RC_FILE = resources/windowicon.icns
 202 }