ksplice-apply.in

   1 #!/usr/bin/perl
   2
   3 # Copyright (C) 2007-2009  Ksplice, Inc.
   4 # Authors: Jeff Arnold, Anders Kaseorg, Tim Abbott
   5 #
   6 # This program is free software; you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License, version 2.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software
  16 # Foundation, Inc., 51 Franklin Street - Fifth Floor, Boston, MA
  17 # 02110-1301, USA.
  18
  19 use strict;
  20 use warnings;
  21 use sigtrap 'handler', \&handler, qw(normal-signals error-signals);
  22 use lib 'KSPLICE_DATA_DIR';
  23 use Ksplice;
  24
  25 our %apply_errors;
  26 initialize_abort_code_table();
  27
  28 my $debug;
  29 my $debugon = 0;
  30 my $partial = 0;
  31 GetOptions(@common_options,
  32         "partial" => \$partial,
  33         "debug" => \$debugon,
  34         "debugfile=s" => \$debug) or pod2usage(1);
  35
  36 pod2usage(1) if($help || scalar(@ARGV) != 1);
  37
  38 my $file = abs_path($ARGV[0]);
  39 $debugon = 1 if(defined $debug);
  40 $debug = abs_path($debug) if (defined $debug);
  41
  42 my $tmpdir = tempdir('ksplice-tmp-XXXXXX', TMPDIR => 1, CLEANUP => 1);
  43 chdir($tmpdir);
  44 my $ksplice = unpack_update($file);
  45 chdir($ksplice);
  46
  47 die "No contents file in $file\n" if (!-e "contents");
  48 open(CONTENTS, '<', "contents");
  49 my $core;
  50 my @changes;
  51 while (<CONTENTS>) {
  52         my ($type, @args) = split(' ', $_);
  53         if ($type eq 'core') {
  54                 die "Multiple core modules in $file!" if (defined $core);
  55                 $core = {};
  56                 @$core{qw(module file)} = @args;
  57         } elsif ($type eq 'change') {
  58                 my $change = {};
  59                 @$change{qw(target new_code new_code_file old_code old_code_file)} = @args;
  60                 push @changes, $change;
  61         }
  62 }
  63 close(CONTENTS);
  64
  65 die "Update was built using an old version of Ksplice" if (@changes == 0);
  66
  67 my $nounload = runstr("lsmod") =~ m/- $/m;
  68
  69 (my $kid = $ksplice) =~s|ksplice[-_]([^-_]+)|$1|;
  70 my $update = "ksplice_$kid";
  71 if(update_loaded($kid)) {
  72         my $stage = get_stage($kid);
  73         if ($stage eq "applied") {
  74                 print STDERR "Ksplice update $kid already applied.\n" unless $raw_errors;
  75                 exit(0);
  76         }
  77         die "Reversed Ksplice module $update already loaded!" if ($stage eq "reversed");
  78 }
  79
  80 runstr_err(qw(modprobe -q ksplice)) eq "" or die("Error loading Ksplice module.\n");
  81 if (defined $core) {
  82         die "Could not find Ksplice core module $core->{file}\n" if (!-e $core->{file});
  83         if (runstr("lsmod") =~ m/^\Q$core->{module}\E\s+/) {
  84                 die "Ksplice core module $core already loaded.";
  85         }
  86         if (!load_module($core->{file}, "debug=$debugon")) {
  87                 die "Error loading Ksplice core module $core->{module} for update $kid";
  88         }
  89 }
  90
  91 foreach my $change (@changes) {
  92         die unless (-e $change->{old_code_file} && -e $change->{new_code_file});
  93         if ($change->{'target'} ne 'vmlinux' &&
  94             runstr("lsmod") !~ m/^\Q$change->{target}\E\s+/m) {
  95                 if (!$partial) {
  96                         cleanup_modules();
  97                         print_abort_code("target_not_loaded", %apply_errors);
  98                         die "Module $change->{target} to be patched not loaded";
  99                 }
 100         }
 101 }
 102
 103 foreach my $change (@changes) {
 104         if(!load_module($change->{new_code_file})) {
 105                 die "Error loading new code module $change->{new_code}";
 106         }
 107         if(!load_module($change->{old_code_file})) {
 108                 if($debugon) {
 109                         my $debugfile = get_debug_output("init_$kid", $debug);
 110                         print("Debugging output saved to $debugfile\n") if $debugfile;
 111                 }
 112                 cleanup_modules();
 113                 die("Error loading old code module $change->{old_code}\n");
 114         }
 115 }
 116
 117 mkpath("/var/run/ksplice/updates/$kid");
 118 copy("patch", "/var/run/ksplice/updates/$kid/patch") if (-e "patch");
 119 copy("description", "/var/run/ksplice/updates/$kid/description") if (-e "description");
 120
 121 set_debug_level($kid, $debugon);
 122 set_partial($kid, $partial);
 123 set_stage($kid, "applied");
 124 my $stage = get_stage($kid);
 125 if($stage ne 'applied') {
 126         print STDERR "Error applying Ksplice update $kid:\n" unless $raw_errors;
 127         print_error($kid);
 128
 129         if ($debugon) {
 130                 my $debugfile = get_debug_output($kid, $debug);
 131                 print("Debugging output saved to $debugfile\n") if $debugfile;
 132         }
 133
 134         rmtree("/var/run/ksplice/updates/$kid") if (-e "/var/run/ksplice/updates/$kid");
 135         cleanup_modules();
 136
 137         exit(-1);
 138 }
 139
 140 if (!$nounload) {
 141         foreach my $change (@changes) {
 142                 runval('rmmod', $change->{old_code});
 143                 runval('rmmod', $change->{new_code}) if ($partial && refcount($change->{new_code}) == 0);
 144         }
 145 }
 146
 147 print "Done!\n";
 148 exit(0);
 149
 150 my @modules_loaded = qw();
 151
 152 sub handler {
 153         my ($sig) = @_;
 154         die "caught SIG$sig, abort\n" if (!defined($kid));
 155         die "caught SIG$sig after finished\n"
 156             if (update_loaded($kid) && (get_stage($kid) eq 'applied'));
 157         print STDERR "caught SIG$sig, aborting\n";
 158         rmtree("/var/run/ksplice/updates/$kid") if (-e "/var/run/ksplice/updates/$kid");
 159         cleanup_modules();
 160         exit(1);
 161 }
 162
 163 sub load_module {
 164         my ($module, @params) = @_;
 165         push @modules_loaded, ($module =~ m/^(.*)\.ko$/);
 166         if (runval_raw("insmod", $module, @params) != 0) {
 167                 pop @modules_loaded;
 168                 child_error();
 169                 return 0;
 170         }
 171         return 1;
 172 }
 173
 174 sub refcount {
 175         my ($module) = @_;
 176         $module =~ s/-/_/g;
 177         foreach(split(/\n/, runstr("lsmod"))) {
 178                 if (m/^(\S+)\s+[0-9]+\s+([0-9])+\s/) {
 179                         return $2 if ($1 eq $module);
 180                 }
 181         }
 182         return -1;
 183 }
 184
 185 sub cleanup_modules {
 186         foreach my $module (reverse(@modules_loaded)) {
 187                 runval_raw("rmmod", $module) if(!$nounload);
 188         }
 189 }
 190
 191 sub initialize_abort_code_table {
 192         %apply_errors = (
 193                 "no_match" => <<'END',
 194 Ksplice has aborted the upgrade because Ksplice has been unable to match the
 195 object code produced by your current compiler and assembler against the running
 196 kernel's object code.  If you provided the exact kernel source to the running
 197 kernel, then it appears that your current compiler and/or assembler are
 198 behaving differently from the compiler and assembler used to build the running
 199 kernel.  If possible, please use the exact compiler and assembler that were
 200 used to build the running kernel.  If you are using exactly the same compiler
 201 and assembler, consider reporting a bug to PACKAGE_BUGREPORT.
 202 END
 203                 "code_busy" => <<'END',
 204 Ksplice has aborted the upgrade because it appears that the code that you are
 205 trying to patch is continuously in use by the system.  More specifically,
 206 Ksplice has been unable to find a moment when one or more of the to-be-patched
 207 functions is not on a thread's kernel stack.
 208 END
 209                 "bad_system_map" => <<'END',
 210 Ksplice has aborted the upgrade because it appears that the System.map file
 211 provided to ksplice-create does not match the running kernel.
 212 END
 213                 "failed_to_find" => <<'END',
 214 Ksplice has aborted the upgrade because it was unable to resolve some of the
 215 symbols used in the update.
 216 END
 217                 "already_reversed" => <<'END',
 218 The Ksplice update that you are attempting to apply has already been applied
 219 and reversed.  You need to unload the Ksplice modules associated with this
 220 update before you can apply this update again.
 221 END
 222                 "missing_export" => <<'END',
 223 Ksplice has aborted the upgrade because the symbols exported by the kernel
 224 did not match Ksplice's expectations.
 225 END
 226                 "unexpected_running_task" => <<'END',
 227 Ksplice has aborted the upgrade because of an unexpected failure during the
 228 kernel stack check.  Please consider reporting a bug to PACKAGE_BUGREPORT.
 229 END
 230                 "target_not_loaded" => <<'END',
 231 Ksplice has aborted the upgrade because one of the modules to be
 232 patched by the update was not loaded.  If you want to apply this
 233 update only to those modules that are loaded, then you should use the
 234 --partial option.
 235 END
 236                 "out_of_memory" => <<'END',
 237 Ksplice has aborted the upgrade because the kernel ran out of memory.
 238 END
 239                 "call_failed" => <<'END',
 240 Ksplice has aborted the upgrade at the request of a one of the
 241 pre-application hooks that were included as part of this Ksplice
 242 update.  This is likely the result of a bug in the patch used to
 243 generate this update.
 244 END
 245                 "unexpected" => <<'END',
 246 Ksplice has aborted because of an unexpected error.
 247 Please consider reporting a bug to PACKAGE_BUGREPORT.
 248 END
 249                 "UNKNOWN" => <<'END',
 250 The Ksplice kernel component has returned an error code that this version of
 251 ksplice-apply does not understand.
 252 END
 253                 "ok" => <<'END',
 254 Ksplice has aborted the upgrade for unknown reasons.
 255 Please consider reporting a bug to PACKAGE_BUGREPORT.
 256 END
 257         );
 258 }
 259
 260 sub print_error {
 261         my ($kid) = @_;
 262         print_abort_error($kid, %apply_errors);
 263 }
 264
 265 =head1 NAME
 266
 267 ksplice-apply - Apply an on-disk Ksplice update to the running kernel
 268
 269 =head1 SYNOPSIS
 270
 271 B<ksplice-apply> [I<OPTIONS>] I<UPDATE_TARBALL>
 272
 273 =head1 DESCRIPTION
 274
 275 B<ksplice-apply> takes as input a Ksplice update tarball, as generated by
 276 L<ksplice-create(8)>, and it applies the update to the running binary kernel.
 277
 278 The update tarball used with B<ksplice-apply> must have been generated for the
 279 running kernel's version.
 280
 281 =head1 OPTIONS
 282
 283 =over 8
 284
 285 =item B<--debug>
 286
 287 Applies the update with debugging output enabled.  Recommended only for
 288 debugging.
 289
 290 =item B<--debugfile=>I<filename>
 291
 292 Sets the location where debugging output should be saved.  Implies --debug.
 293
 294 =item B<--partial>
 295
 296 Applies the update only to those modules which are loaded.  Any
 297 modules patched by the update that are not loaded are ignored (without
 298 this option, Ksplice aborts if any modules patched by the update are
 299 not loaded).
 300
 301 =item B<--raw-errors>
 302
 303 Print only raw error information designed to be machine-readable on
 304 standard error (standard output is still intended to be
 305 human-readable).  If B<ksplice-apply> fails due to an error from the
 306 Ksplice kernel modules, the first line on standard error will be a
 307 Ksplice B<abort code> (see the Ksplice source code for documentation
 308 on these codes).  Further lines will vary depending on the abort code.
 309 If B<ksplice-apply> fails for any other reason, it will output the
 310 line C<"OTHER\n">, followed by a human-readable failure message, to
 311 standard error.
 312
 313 =back
 314
 315 =head1 SEE ALSO
 316
 317 L<ksplice-create(8)>, L<ksplice-view(8)>, L<ksplice-undo(8)>
 318
 319 =head1 BUGS
 320
 321 Please report bugs to <PACKAGE_BUGREPORT>.
 322
 323 =head1 AUTHORS
 324
 325 Jeff Arnold, Anders Kaseorg, and Tim Abbott
 326
 327 =head1 COPYRIGHT
 328
 329 Copyright (C) 2007-2009  Ksplice, Inc.
 330
 331 This is free software and documentation.  You can redistribute and/or modify it
 332 under the terms of the GNU General Public License, version 2.
 333
 334 =cut