ksplice-undo.in

   1 #!/usr/bin/perl
   2
   3 # Copyright (C) 2007-2009  Ksplice, Inc.
   4 # Authors: Jeff Arnold, Anders Kaseorg, Tim Abbott
   5 #
   6 # This program is free software; you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License, version 2.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software
  16 # Foundation, Inc., 51 Franklin Street - Fifth Floor, Boston, MA
  17 # 02110-1301, USA.
  18
  19 use strict;
  20 use warnings;
  21 use lib 'KSPLICE_DATA_DIR';
  22 use Ksplice;
  23 my $have_usleep = eval { require Time::HiRes };
  24
  25 my $debug;
  26 my $debugon = 0;
  27 GetOptions(@common_options,
  28         "debug" => \$debugon,
  29         "debugfile=s" => \$debug) or pod2usage(1);
  30
  31 pod2usage(1) if($help || scalar(@ARGV) != 1);
  32 $debugon = 1 if (defined($debug));
  33 $debug = abs_path($debug) if (defined $debug);
  34
  35 my $kid = $ARGV[0];
  36 $kid =~ s/^ksplice[-_]//;
  37 $kid =~ s/[-_].*$//;
  38 my $update = "ksplice_$kid";
  39 my $nounload = runstr("lsmod") =~ m/- $/m;
  40
  41 if (!update_loaded($kid)) {
  42         print "Ksplice id $kid is not present in the kernel\n";
  43         exit(1);
  44 }
  45
  46 chdir("/sys/module/");
  47 set_debug_level($kid, $debugon);
  48
  49 my $stage = get_stage($kid);
  50 if ($stage ne 'applied') {
  51         print "Ksplice id $kid is not applied\n";
  52 }
  53 else {
  54         set_stage($kid, "reversed");
  55 }
  56 $stage = get_stage($kid);
  57 ($stage eq 'reversed') or error_die();
  58
  59 foreach my $module (glob("${update}_*")) {
  60         if (!$nounload && runval_raw('rmmod', $module) != 0) {
  61                 child_error();
  62                 error_die();
  63         }
  64 }
  65
  66 set_stage($kid, "cleanup");
  67 if ($have_usleep) {
  68         my $count = 0;
  69         while (update_loaded($kid) && $count < 5) {
  70                 Time::HiRes::usleep(100000);
  71                 $count++;
  72         }
  73 } else {
  74         sleep(1) if (!update_loaded($kid));
  75 }
  76 if (-e "/sys/module/$update") {
  77         if (!$nounload && runval_raw('rmmod', $update) != 0) {
  78                 child_error();
  79                 error_die();
  80         }
  81 }
  82
  83 rmtree("/var/run/ksplice/updates/$kid");
  84
  85 exit(0);
  86
  87 sub error_die {
  88         my $debugfile = get_debug_output($kid, $debug);
  89         print STDERR "Error undoing Ksplice update $kid:\n";
  90         my $abort_cause = get_abort_cause($kid);
  91         my $conflicts = get_conflicts($kid);
  92         print_error($abort_cause);
  93         if ($abort_cause eq 'code_busy') {
  94                 print $conflicts;
  95         }
  96         if($debugon && defined $debugfile) {
  97                 print("Debugging output saved to $debugfile\n");
  98         }
  99         die;
 100 }
 101
 102 sub print_error {
 103         my ($error) = @_;
 104         my %errors = (
 105                 "code_busy" => <<'END',
 106 Ksplice has aborted the undo operation because it appears that the code that
 107 you are trying to change is continuously in use by the system.  More
 108 specifically, Ksplice has been unable to find a moment when one or more of the
 109 to-be-changed functions is not on a thread's kernel stack.
 110 END
 111                 "module_busy" => <<'END',
 112 Ksplice has aborted the undo operation because it appears that the Ksplice
 113 update that you are trying to unload is in use by another module.  You can find
 114 out what module is using the Ksplice update using the lsmod command.
 115 END
 116                 "unexpected_running_task" => <<'END',
 117 Ksplice has aborted the undo operation because of an unexpected failure during
 118 the kernel stack check.  Please consider reporting a bug to PACKAGE_BUGREPORT.
 119 END
 120                 "out_of_memory" => <<'END',
 121 Ksplice has aborted the undo operation because the kernel ran out of memory.
 122 END
 123                 "call_failed" => <<'END',
 124 Ksplice has aborted the undo operation at the request of a one of the
 125 pre-application hooks that were included as part of this Ksplice
 126 update.  This is likely the result of a bug in the patch used to
 127 generate this update.
 128 END
 129                 "cold_update_loaded" => <<'END',
 130 Ksplice has aborted the undo operation because the update was applied using the
 131 --partial option, and one of the modules that was changed by the update was loaded
 132 since the update was applied.  You must first unload that (cold patched) module
 133 before you can undo this update.
 134 END
 135                 "unexpected" => <<'END',
 136 Ksplice has aborted because of an unexpected error.
 137 Please consider reporting a bug to PACKAGE_BUGREPORT.
 138 END
 139                 "UNKNOWN" => <<'END',
 140 The Ksplice kernel component has returned an error code that this version of
 141 ksplice-undo does not understand.
 142 END
 143                 "ok" => <<'END',
 144 Ksplice has aborted the undo operation for unknown reasons.
 145 Please consider reporting a bug to PACKAGE_BUGREPORT.
 146 END
 147 );
 148         $error = "UNKNOWN" if (!exists $errors{$error});
 149         print STDERR "\n$errors{$error}\n";
 150 }
 151
 152 =head1 NAME
 153
 154 ksplice-undo - Undo a Ksplice update that has been applied to the running kernel
 155
 156 =head1 SYNOPSIS
 157
 158 B<ksplice-undo> [I<OPTIONS>] I<KSPLICE_ID>
 159
 160 =head1 DESCRIPTION
 161
 162 B<ksplice-undo> takes as input a Ksplice identification tag, as reported by
 163 L<ksplice-view(8)>, and it reverses that update within the running binary kernel.
 164
 165 =head1 OPTIONS
 166
 167 =over 8
 168
 169 =item B<--debug>
 170
 171 Reverses the update with debugging output enabled.  Recommended only for
 172 debugging.
 173
 174 =item B<--debugfile=>I<filename>
 175
 176 Sets the location where debugging output should be saved.  Implies --debug.
 177
 178 =back
 179
 180 =head1 SEE ALSO
 181
 182 L<ksplice-create(8)>, L<ksplice-apply(8)>, L<ksplice-view(8)>
 183
 184 =head1 BUGS
 185
 186 Please report bugs to <PACKAGE_BUGREPORT>.
 187
 188 =head1 AUTHORS
 189
 190 Jeff Arnold, Anders Kaseorg, and Tim Abbott
 191
 192 =head1 COPYRIGHT
 193
 194 Copyright (C) 2007-2009  Ksplice, Inc.
 195
 196 This is free software and documentation.  You can redistribute and/or modify it
 197 under the terms of the GNU General Public License, version 2.
 198
 199 =cut