ksplice-undo.in

   1 #!/usr/bin/perl
   2
   3 # Copyright (C) 2007-2009  Ksplice, Inc.
   4 # Authors: Jeff Arnold, Anders Kaseorg, Tim Abbott
   5 #
   6 # This program is free software; you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License, version 2.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software
  16 # Foundation, Inc., 51 Franklin Street - Fifth Floor, Boston, MA
  17 # 02110-1301, USA.
  18
  19 use strict;
  20 use warnings;
  21 use lib 'KSPLICE_DATA_DIR';
  22 use Ksplice;
  23 my $have_usleep = eval { require Time::HiRes };
  24
  25 my $debug;
  26 my $debugon = 0;
  27 GetOptions(@common_options,
  28         "debug" => \$debugon,
  29         "debugfile=s" => \$debug) or pod2usage(1);
  30
  31 pod2usage(1) if($help || scalar(@ARGV) != 1);
  32 $debugon = 1 if (defined($debug));
  33 $debug = abs_path($debug) if (defined $debug);
  34
  35 my $kid = $ARGV[0];
  36 $kid =~ s/^ksplice[-_]//;
  37 $kid =~ s/[-_].*$//;
  38 my $update = "ksplice_$kid";
  39 my $nounload = runstr("lsmod") =~ m/- $/m;
  40
  41 if (!update_loaded($kid)) {
  42         print "Ksplice id $kid is not present in the kernel\n";
  43         exit(1);
  44 }
  45
  46 chdir("/sys/module/");
  47 set_debug_level($kid, $debugon);
  48 my $stage = get_stage($kid);
  49 if ($stage ne 'applied') {
  50         print "Ksplice id $kid is not applied\n";
  51 }
  52 else {
  53         set_stage($kid, "reversed");
  54 }
  55
  56 $stage = get_stage($kid);
  57 my $failed = 0;
  58 $failed = 1 if ($stage ne 'reversed');
  59 foreach my $module (glob("${update}_*")) {
  60         if (!$nounload && runval_raw('rmmod', $module) != 0) {
  61                 child_error();
  62                 $failed = 1;
  63         }
  64 }
  65 if ($failed == 0) {
  66         set_stage($kid, "cleanup");
  67         if ($have_usleep) {
  68                 my $count = 0;
  69                 while (update_loaded($kid) && $count < 5) {
  70                         Time::HiRes::usleep(100000);
  71                         $count++;
  72                 }
  73         } else {
  74                 sleep(1) if (!update_loaded($kid));
  75         }
  76 }
  77 if ($failed == 0 && -e "/sys/module/$update") {
  78         if (!$nounload && runval_raw('rmmod', $update) != 0) {
  79                 child_error();
  80                 $failed = 1;
  81         }
  82 }
  83 unless($failed == 0) {
  84         my $debugfile = get_debug_output($kid, $debug);
  85         print STDERR "Error undoing Ksplice update $kid:\n";
  86         my $abort_cause = get_abort_cause($kid);
  87         my $conflicts = get_conflicts($kid);
  88         print_error($abort_cause);
  89         if ($abort_cause eq 'code_busy') {
  90                 print $conflicts;
  91         }
  92         if($debugon && defined $debugfile) {
  93                 print("Debugging output saved to $debugfile\n");
  94         }
  95         die;
  96 }
  97 rmtree("/var/run/ksplice/updates/$kid");
  98 exit(0);
  99
 100 sub print_error {
 101         my ($error) = @_;
 102         my %errors = (
 103                 "code_busy" => <<'END',
 104 Ksplice has aborted the undo operation because it appears that the code that
 105 you are trying to change is continuously in use by the system.  More
 106 specifically, Ksplice has been unable to find a moment when one or more of the
 107 to-be-changed functions is not on a thread's kernel stack.
 108 END
 109                 "module_busy" => <<'END',
 110 Ksplice has aborted the undo operation because it appears that the Ksplice
 111 update that you are trying to unload is in use by another module.  You can find
 112 out what module is using the Ksplice update using the lsmod command.
 113 END
 114                 "unexpected_running_task" => <<'END',
 115 Ksplice has aborted the undo operation because of an unexpected failure during
 116 the kernel stack check.  Please consider reporting a bug to PACKAGE_BUGREPORT.
 117 END
 118                 "out_of_memory" => <<'END',
 119 Ksplice has aborted the undo operation because the kernel ran out of memory.
 120 END
 121                 "call_failed" => <<'END',
 122 Ksplice has aborted the undo operation at the request of a one of the
 123 pre-application hooks that were included as part of this Ksplice
 124 update.  This is likely the result of a bug in the patch used to
 125 generate this update.
 126 END
 127                 "cold_update_loaded" => <<'END',
 128 Ksplice has aborted the undo operation because the update was applied using the
 129 --partial option, and one of the modules that was changed by the update was loaded
 130 since the update was applied.  You must first unload that (cold patched) module
 131 before you can undo this update.
 132 END
 133                 "unexpected" => <<'END',
 134 Ksplice has aborted because of an unexpected error.
 135 Please consider reporting a bug to PACKAGE_BUGREPORT.
 136 END
 137                 "UNKNOWN" => <<'END',
 138 The Ksplice kernel component has returned an error code that this version of
 139 ksplice-undo does not understand.
 140 END
 141                 "ok" => <<'END',
 142 Ksplice has aborted the undo operation for unknown reasons.
 143 Please consider reporting a bug to PACKAGE_BUGREPORT.
 144 END
 145 );
 146         $error = "UNKNOWN" if (!exists $errors{$error});
 147         print STDERR "\n$errors{$error}\n";
 148 }
 149
 150 =head1 NAME
 151
 152 ksplice-undo - Undo a Ksplice update that has been applied to the running kernel
 153
 154 =head1 SYNOPSIS
 155
 156 B<ksplice-undo> [I<OPTIONS>] I<KSPLICE_ID>
 157
 158 =head1 DESCRIPTION
 159
 160 B<ksplice-undo> takes as input a Ksplice identification tag, as reported by
 161 L<ksplice-view(8)>, and it reverses that update within the running binary kernel.
 162
 163 =head1 OPTIONS
 164
 165 =over 8
 166
 167 =item B<--debug>
 168
 169 Reverses the update with debugging output enabled.  Recommended only for
 170 debugging.
 171
 172 =item B<--debugfile=>I<filename>
 173
 174 Sets the location where debugging output should be saved.  Implies --debug.
 175
 176 =back
 177
 178 =head1 SEE ALSO
 179
 180 L<ksplice-create(8)>, L<ksplice-apply(8)>, L<ksplice-view(8)>
 181
 182 =head1 BUGS
 183
 184 Please report bugs to <PACKAGE_BUGREPORT>.
 185
 186 =head1 AUTHORS
 187
 188 Jeff Arnold, Anders Kaseorg, and Tim Abbott
 189
 190 =head1 COPYRIGHT
 191
 192 Copyright (C) 2007-2009  Ksplice, Inc.
 193
 194 This is free software and documentation.  You can redistribute and/or modify it
 195 under the terms of the GNU General Public License, version 2.
 196
 197 =cut