tools/letter.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 =head1 tools/letter.pl
  21
  22  ALGO :
  23  this script use an $op to know what to do.
  24  if $op is empty or none of the values listed below,
  25         - the default screen is built (with all or filtered (if search string is set) records).
  26         - the   user can click on add, modify or delete record.
  27     - filtering is done on the code field
  28  if $op=add_form
  29         - if primary key (module + code) exists, this is a modification,so we read the required record
  30         - builds the add/modify form
  31  if $op=add_validate
  32         - the user has just send data, so we create/modify the record
  33  if $op=delete_form
  34         - we show the record selected and ask for confirmation
  35  if $op=delete_confirm
  36         - we delete the designated record
  37
  38 =cut
  39
  40 # TODO This script drives the CRUD operations on the letter table
  41 # The DB interaction should be handled by calls to C4/Letters.pm
  42
  43 use strict;
  44 use warnings;
  45 use CGI qw ( -utf8 );
  46 use C4::Auth;
  47 use C4::Context;
  48 use C4::Output;
  49 use C4::Letters;
  50 use C4::Members::Attributes;
  51
  52 # $protected_letters = protected_letters()
  53 # - return a hashref of letter_codes representing letters that should never be deleted
  54 sub protected_letters {
  55     my $dbh = C4::Context->dbh;
  56     my $codes = $dbh->selectall_arrayref(q{SELECT DISTINCT letter_code FROM message_transports});
  57     return { map { $_->[0] => 1 } @{$codes} };
  58 }
  59
  60 our $input       = new CGI;
  61 my $searchfield = $input->param('searchfield');
  62 my $script_name = '/cgi-bin/koha/tools/letter.pl';
  63 our $branchcode  = $input->param('branchcode');
  64 $branchcode = '' if defined $branchcode and $branchcode eq '*';
  65 my $code        = $input->param('code');
  66 my $module      = $input->param('module') || '';
  67 my $content     = $input->param('content');
  68 my $op          = $input->param('op') || '';
  69 my $dbh = C4::Context->dbh;
  70
  71 our ( $template, $borrowernumber, $cookie, $staffflags ) = get_template_and_user(
  72     {
  73         template_name   => 'tools/letter.tt',
  74         query           => $input,
  75         type            => 'intranet',
  76         authnotrequired => 0,
  77         flagsrequired   => { tools => 'edit_notices' },
  78         debug           => 1,
  79     }
  80 );
  81
  82 our $my_branch = C4::Context->preference("IndependentBranches") && !$staffflags->{'superlibrarian'}
  83   ?  C4::Context->userenv()->{'branch'}
  84   : undef;
  85 # we show only the TMPL_VAR names $op
  86
  87 $template->param(
  88     independant_branch => $my_branch,
  89         script_name => $script_name,
  90   searchfield => $searchfield,
  91     branchcode => $branchcode,
  92         action => $script_name
  93 );
  94
  95 if ( $op eq 'add_validate' or $op eq 'copy_validate' ) {
  96     add_validate();
  97     $op = q{}; # we return to the default screen for the next operation
  98 }
  99 if ($op eq 'copy_form') {
 100     my $oldbranchcode = $input->param('oldbranchcode') || q||;
 101     my $branchcode = $input->param('branchcode');
 102     add_form($oldbranchcode, $module, $code);
 103     $template->param(
 104         oldbranchcode => $oldbranchcode,
 105         branchcode => $branchcode,
 106         copying => 1,
 107         modify => 0,
 108     );
 109 }
 110 elsif ( $op eq 'add_form' ) {
 111     add_form($branchcode, $module, $code);
 112 }
 113 elsif ( $op eq 'delete_confirm' ) {
 114     delete_confirm($branchcode, $module, $code);
 115 }
 116 elsif ( $op eq 'delete_confirmed' ) {
 117     delete_confirmed($branchcode, $module, $code);
 118     $op = q{}; # next operation is to return to default screen
 119 }
 120 else {
 121     default_display($branchcode,$searchfield);
 122 }
 123
 124 # Do this last as delete_confirmed resets
 125 if ($op) {
 126     $template->param($op  => 1);
 127 } else {
 128     $template->param(no_op_set => 1);
 129 }
 130
 131 output_html_with_http_headers $input, $cookie, $template->output;
 132
 133 sub add_form {
 134     my ( $branchcode,$module, $code ) = @_;
 135
 136     my $letters;
 137     # if code has been passed we can identify letter and its an update action
 138     if ($code) {
 139         $letters = C4::Letters::GetLetterTemplates(
 140             {
 141                 branchcode => $branchcode,
 142                 module     => $module,
 143                 code       => $code,
 144             }
 145         );
 146     }
 147
 148     my $message_transport_types = GetMessageTransportTypes();
 149     my @letter_loop;
 150     if ($letters) {
 151         $template->param(
 152             modify     => 1,
 153             code       => $code,
 154             branchcode => $branchcode,
 155         );
 156         my $first_flag = 1;
 157         # The letter name is contained into each mtt row.
 158         # So we can only sent the first one to the template.
 159         for my $mtt ( @$message_transport_types ) {
 160             # The letter_name
 161             if ( $first_flag and $letters->{$mtt}{name} ) {
 162                 $template->param(
 163                     letter_name=> $letters->{$mtt}{name},
 164                 );
 165                 $first_flag = 0;
 166             }
 167
 168             push @letter_loop, {
 169                 message_transport_type => $mtt,
 170                 is_html    => $letters->{$mtt}{is_html},
 171                 title      => $letters->{$mtt}{title},
 172                 content    => $letters->{$mtt}{content}//'',
 173             };
 174         }
 175     }
 176     else { # initialize the new fields
 177         for my $mtt ( @$message_transport_types ) {
 178             push @letter_loop, {
 179                 message_transport_type => $mtt,
 180             }
 181         }
 182         $template->param(
 183             branchcode => $branchcode,
 184             module     => $module,
 185         );
 186         $template->param( adding => 1 );
 187     }
 188
 189     $template->param(
 190         letters => \@letter_loop,
 191     );
 192
 193     my $field_selection;
 194     push @{$field_selection}, add_fields('branches');
 195     if ($module eq 'reserves') {
 196         push @{$field_selection}, add_fields('borrowers', 'reserves', 'biblio', 'biblioitems', 'items');
 197     }
 198     elsif ( $module eq 'acquisition' ) {
 199         push @{$field_selection}, add_fields('aqbooksellers', 'aqorders', 'biblio', 'items');
 200     }
 201     elsif ($module eq 'claimacquisition') {
 202         push @{$field_selection}, add_fields('aqbooksellers', 'aqorders', 'biblio', 'biblioitems');
 203     }
 204     elsif ($module eq 'claimissues') {
 205         push @{$field_selection}, add_fields('aqbooksellers', 'serial', 'subscription');
 206         push @{$field_selection},
 207         {
 208             value => q{},
 209             text => '---BIBLIO---'
 210         };
 211         foreach(qw(title author serial)) {
 212             push @{$field_selection}, {value => "biblio.$_", text => ucfirst $_ };
 213         }
 214     }
 215     elsif ($module eq 'serial') {
 216         push @{$field_selection}, add_fields('branches', 'biblio', 'biblioitems', 'borrowers', 'subscription', 'serial');
 217     }
 218     elsif ($module eq 'suggestions') {
 219         push @{$field_selection}, add_fields('suggestions', 'borrowers', 'biblio');
 220     }
 221     else {
 222         push @{$field_selection}, add_fields('biblio','biblioitems'),
 223             add_fields('items'),
 224             {value => 'items.content', text => 'items.content'},
 225             {value => 'items.fine',    text => 'items.fine'},
 226             add_fields('borrowers');
 227         if ($module eq 'circulation') {
 228             push @{$field_selection}, add_fields('opac_news');
 229
 230         }
 231
 232         if ( $module eq 'circulation' and $code and $code eq "CHECKIN" ) {
 233             push @{$field_selection}, add_fields('old_issues');
 234         } else {
 235             push @{$field_selection}, add_fields('issues');
 236         }
 237     }
 238
 239     $template->param(
 240         module     => $module,
 241         SQLfieldnames => $field_selection,
 242         branchcode => $branchcode,
 243     );
 244     return;
 245 }
 246
 247 sub add_validate {
 248     my $dbh        = C4::Context->dbh;
 249     my $branchcode    = $input->param('branchcode');
 250     my $module        = $input->param('module');
 251     my $oldmodule     = $input->param('oldmodule');
 252     my $code          = $input->param('code');
 253     my $name          = $input->param('name');
 254     my @mtt           = $input->multi_param('message_transport_type');
 255     my @title         = $input->multi_param('title');
 256     my @content       = $input->multi_param('content');
 257     for my $mtt ( @mtt ) {
 258         my $is_html = $input->param("is_html_$mtt");
 259         my $title   = shift @title;
 260         my $content = shift @content;
 261         my $letter = C4::Letters::getletter( $oldmodule, $code, $branchcode, $mtt);
 262
 263         # getletter can return the default letter even if we pass a branchcode
 264         # If we got the default one and we needed the specific one, we didn't get the one we needed!
 265         if ( $letter and $branchcode and $branchcode ne $letter->{branchcode} ) {
 266             $letter = undef;
 267         }
 268         unless ( $title and $content ) {
 269             # Delete this mtt if no title or content given
 270             delete_confirmed( $branchcode, $oldmodule, $code, $mtt );
 271             next;
 272         }
 273         elsif ( $letter and $letter->{message_transport_type} eq $mtt ) {
 274             $dbh->do(
 275                 q{
 276                     UPDATE letter
 277                     SET branchcode = ?, module = ?, name = ?, is_html = ?, title = ?, content = ?
 278                     WHERE branchcode = ? AND module = ? AND code = ? AND message_transport_type = ?
 279                 },
 280                 undef,
 281                 $branchcode || '', $module, $name, $is_html || 0, $title, $content,
 282                 $branchcode, $oldmodule, $code, $mtt
 283             );
 284         } else {
 285             $dbh->do(
 286                 q{INSERT INTO letter (branchcode,module,code,name,is_html,title,content,message_transport_type) VALUES (?,?,?,?,?,?,?,?)},
 287                 undef,
 288                 $branchcode || '', $module, $code, $name, $is_html || 0, $title, $content, $mtt
 289             );
 290         }
 291     }
 292     # set up default display
 293     default_display($branchcode);
 294     return 1;
 295 }
 296
 297 sub delete_confirm {
 298     my ($branchcode, $module, $code) = @_;
 299     my $dbh = C4::Context->dbh;
 300     my $letter = C4::Letters::getletter($module, $code, $branchcode);
 301     my @values = values %$letter;
 302     $template->param(
 303         letter => $letter,
 304     );
 305     return;
 306 }
 307
 308 sub delete_confirmed {
 309     my ($branchcode, $module, $code, $mtt) = @_;
 310     C4::Letters::DelLetter(
 311         {
 312             branchcode => $branchcode || '',
 313             module     => $module,
 314             code       => $code,
 315             mtt        => $mtt
 316         }
 317     );
 318     # setup default display for screen
 319     default_display($branchcode);
 320     return;
 321 }
 322
 323 sub retrieve_letters {
 324     my ($branchcode, $searchstring) = @_;
 325
 326     $branchcode = $my_branch if $branchcode && $my_branch;
 327
 328     my $dbh = C4::Context->dbh;
 329     my ($sql, @where, @args);
 330     $sql = "SELECT branchcode, module, code, name, branchname
 331             FROM letter
 332             LEFT OUTER JOIN branches USING (branchcode)
 333     ";
 334     if ($searchstring && $searchstring=~m/(\S+)/) {
 335         $searchstring = $1 . q{%};
 336         push @where, 'code LIKE ?';
 337         push @args, $searchstring;
 338     }
 339     elsif ($branchcode) {
 340         push @where, 'branchcode = ?';
 341         push @args, $branchcode || '';
 342     }
 343     elsif ($my_branch) {
 344         push @where, "(branchcode = ? OR branchcode = '')";
 345         push @args, $my_branch;
 346     }
 347
 348     $sql .= " WHERE ".join(" AND ", @where) if @where;
 349     $sql .= " GROUP BY branchcode,module,code";
 350     $sql .= " ORDER BY module, code, branchcode";
 351
 352     return $dbh->selectall_arrayref($sql, { Slice => {} }, @args);
 353 }
 354
 355 sub default_display {
 356     my ($branchcode, $searchfield) = @_;
 357
 358     unless ( defined $branchcode ) {
 359         if ( C4::Context->preference('DefaultToLoggedInLibraryNoticesSlips') ) {
 360             $branchcode = C4::Context::mybranch();
 361         }
 362     }
 363
 364     if ( $searchfield  ) {
 365         $template->param( search      => 1 );
 366     }
 367     my $results = retrieve_letters($branchcode,$searchfield);
 368
 369     my $loop_data = [];
 370     my $protected_letters = protected_letters();
 371     foreach my $row (@{$results}) {
 372         $row->{protected} = !$row->{branchcode} && $protected_letters->{ $row->{code} };
 373         push @{$loop_data}, $row;
 374
 375     }
 376
 377     $template->param(
 378         letter => $loop_data,
 379         branchcode => $branchcode,
 380     );
 381 }
 382
 383 sub add_fields {
 384     my @tables = @_;
 385     my @fields = ();
 386
 387     for my $table (@tables) {
 388         push @fields, get_columns_for($table);
 389
 390     }
 391     return @fields;
 392 }
 393
 394 sub get_columns_for {
 395     my $table = shift;
 396 # FIXME untranslatable
 397     my %column_map = (
 398         aqbooksellers => '---BOOKSELLERS---',
 399         aqorders      => '---ORDERS---',
 400         serial        => '---SERIALS---',
 401         reserves      => '---HOLDS---',
 402         suggestions   => '---SUGGESTIONS---',
 403     );
 404     my @fields = ();
 405     if (exists $column_map{$table} ) {
 406         push @fields, {
 407             value => q{},
 408             text  => $column_map{$table} ,
 409         };
 410     }
 411     else {
 412         my $tlabel = '---' . uc $table;
 413         $tlabel.= '---';
 414         push @fields, {
 415             value => q{},
 416             text  => $tlabel,
 417         };
 418     }
 419
 420     my $sql = "SHOW COLUMNS FROM $table";# TODO not db agnostic
 421     my $table_prefix = $table . q|.|;
 422     my $rows = C4::Context->dbh->selectall_arrayref($sql, { Slice => {} });
 423     for my $row (@{$rows}) {
 424         next if $row->{'Field'} eq 'timestamp'; # this is really an irrelevant field and there may be other common fields that should be excluded from the list
 425         push @fields, {
 426             value => $table_prefix . $row->{Field},
 427             text  => $table_prefix . $row->{Field},
 428         }
 429     }
 430     if ($table eq 'borrowers') {
 431         if ( my $attributes = C4::Members::Attributes::GetAttributes() ) {
 432             foreach (@$attributes) {
 433                 push @fields, {
 434                     value => "borrower-attribute:$_",
 435                     text  => "attribute:$_",
 436                 }
 437             }
 438         }
 439     }
 440     return @fields;
 441 }