C4/ClassSource.pm

   1 package C4::ClassSource;
   2
   3 # Copyright (C) 2007 LibLime
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use strict;
  21 use warnings;
  22
  23 require Exporter;
  24 use C4::Context;
  25 use C4::ClassSortRoutine;
  26
  27 use vars qw(@ISA @EXPORT @EXPORT_OK %EXPORT_TAGS);
  28
  29
  30 =head1 NAME
  31
  32 C4::ClassSources - handle classification sources in Koha
  33
  34 =head1 SYNOPSIS
  35
  36 use C4::ClassSource;
  37
  38 =head1 DESCRIPTION
  39
  40 This module deals with manipulating classification
  41 sources and sorting rules.
  42
  43 =head1 FUNCTIONS
  44
  45 =cut
  46
  47
  48 @ISA    = qw(Exporter);
  49 @EXPORT = qw(
  50     &GetClassSources
  51     &AddClassSource
  52     &GetClassSource
  53     &ModClassSource
  54     &DelClassSource
  55     &GetClassSortRules
  56     &AddClassSortRule
  57     &GetClassSortRule
  58     &ModClassSortRule
  59     &DelClassSortRule
  60
  61     &GetSourcesForSortRule
  62     &GetClassSort
  63
  64 );
  65
  66 =head2 GetClassSources
  67
  68   my $sources = GetClassSources();
  69
  70   Returns reference to hash of references to
  71   the class sources, keyed on cn_source.
  72
  73 =head3 Example
  74
  75 my $sources = GetClassSources();
  76 my @sources = ();
  77 foreach my $cn_source (sort keys %$sources) {
  78     my $source = $sources->{$cn_source};
  79     push @sources,
  80       {
  81         code        => $source->{'cn_source'},
  82         description => $source->{'description'},
  83         used => $source->{'used'},
  84         sortrule    => $source->{'class_sort_rule'}
  85       }
  86 }
  87
  88 =cut
  89
  90 sub GetClassSources {
  91
  92     my %class_sources = ();
  93     my $dbh = C4::Context->dbh;
  94     my $sth = $dbh->prepare("SELECT * FROM `class_sources`");
  95     $sth->execute();
  96     while (my $source = $sth->fetchrow_hashref) {
  97         $class_sources{ $source->{'cn_source'} } = $source;
  98     }
  99
 100     return \%class_sources;
 101
 102 }
 103
 104 =head2 AddClassSource
 105
 106   AddClassSource($cn_source, $description, $used, $class_sort_rule);
 107
 108   Adds a class_sources row.
 109
 110 =cut
 111
 112 sub AddClassSource {
 113
 114     my ($cn_source, $description, $used, $class_sort_rule) = @_;
 115     my $dbh = C4::Context->dbh;
 116     my $sth = $dbh->prepare("INSERT INTO `class_sources`
 117                                            (`cn_source`, `description`, `used`, `class_sort_rule`)
 118                                            VALUES (?, ?, ?, ?)");
 119     $sth->execute($cn_source, $description, $used, $class_sort_rule);
 120
 121 }
 122
 123 =head2 GetClassSource
 124
 125   my $hashref = GetClassSource($cn_source);
 126
 127   Retrieves a class_sources row by cn_source.
 128
 129 =cut
 130
 131 sub GetClassSource {
 132
 133     my ($cn_source) = (@_);
 134     my $dbh = C4::Context->dbh;
 135     my $sth = $dbh->prepare("SELECT * FROM `class_sources` WHERE cn_source = ?");
 136     $sth->execute($cn_source);
 137     my $row = $sth->fetchrow_hashref();
 138     return $row;
 139 }
 140
 141 =head2 ModClassSource
 142
 143   ModClassSource($cn_source, $description, $used, $class_sort_rule);
 144
 145   Updates a class_sources row.
 146
 147 =cut
 148
 149 sub ModClassSource {
 150
 151     my ($cn_source, $description, $used, $class_sort_rule) = @_;
 152     my $dbh = C4::Context->dbh;
 153     my $sth = $dbh->prepare("UPDATE `class_sources`
 154                                     SET  `description` = ?,
 155                                          `used` = ?,
 156                                          `class_sort_rule` = ?
 157                                     WHERE `cn_source` = ?");
 158     $sth->execute($description, $used, $class_sort_rule, $cn_source);
 159
 160 }
 161
 162 =head2 DelClassSource
 163
 164   DelClassSource($cn_source);
 165
 166   Deletes class_sources row.
 167
 168 =cut
 169
 170 sub DelClassSource {
 171
 172     my ($cn_source) = @_;
 173     my $dbh = C4::Context->dbh;
 174     my $sth = $dbh->prepare("DELETE FROM `class_sources` WHERE `cn_source` = ?");
 175     $sth->execute($cn_source);
 176
 177 }
 178
 179 =head2 GetClassSortRules
 180
 181   my $sort_rules = GetClassSortRules();
 182
 183 Returns reference to hash of references to
 184 the class sorting rules, keyed on class_sort_rule
 185
 186 =head3 Example
 187
 188   my $sort_rules = GetClassSortRules();
 189   my @sort_rules = ();
 190   foreach my $sort_rule (sort keys %$sort_rules) {
 191       my $sort_rule = $sort_rules->{$sort_rule};
 192       push @sort_rules,
 193           {
 194           rule        => $sort_rule->{'class_sort_rule'},
 195           description => $sort_rule->{'description'},
 196           sort_routine    => $sort_rule->{'sort_routine'}
 197       }
 198    }
 199
 200 =cut
 201
 202 sub GetClassSortRules {
 203
 204     my %class_sort_rules = ();
 205     my $dbh = C4::Context->dbh;
 206     my $sth = $dbh->prepare("SELECT * FROM `class_sort_rules`");
 207     $sth->execute();
 208     while (my $sort_rule = $sth->fetchrow_hashref) {
 209         $class_sort_rules{ $sort_rule->{'class_sort_rule'} } = $sort_rule;
 210     }
 211
 212     return \%class_sort_rules;
 213
 214 }
 215
 216 =head2 AddClassSortRule
 217
 218   AddClassSortRule($class_sort_rule, $description, $sort_routine);
 219
 220   Adds a class_sort_rules row.
 221
 222 =cut
 223
 224 sub AddClassSortRule {
 225
 226     my ($class_sort_rule, $description, $sort_routine) = @_;
 227     my $dbh = C4::Context->dbh;
 228     my $sth = $dbh->prepare("INSERT INTO `class_sort_rules`
 229                                            (`class_sort_rule`, `description`, `sort_routine`)
 230                                            VALUES (?, ?, ?)");
 231     $sth->execute($class_sort_rule, $description, $sort_routine);
 232
 233 }
 234
 235 =head2 GetClassSortRule
 236
 237   my $hashref = GetClassSortRule($class_sort_rule);
 238
 239   Retrieves a class_sort_rules row by class_sort_rule.
 240
 241 =cut
 242
 243 sub GetClassSortRule {
 244
 245     my ($class_sort_rule) = (@_);
 246     my $dbh = C4::Context->dbh;
 247     my $sth = $dbh->prepare("SELECT * FROM `class_sort_rules` WHERE `class_sort_rule` = ?");
 248     $sth->execute($class_sort_rule);
 249     my $row = $sth->fetchrow_hashref();
 250     return $row;
 251 }
 252
 253 =head2 ModClassSortRule
 254
 255   ModClassSortRule($class_sort_rule, $description, $sort_routine);
 256
 257   Updates a class_sort_rules row.
 258
 259 =cut
 260
 261 sub ModClassSortRule {
 262
 263     my ($class_sort_rule, $description, $sort_routine) = @_;
 264     my $dbh = C4::Context->dbh;
 265     my $sth = $dbh->prepare("UPDATE `class_sort_rules`
 266                                     SET  `description` = ?,
 267                                          `sort_routine` = ?
 268                                     WHERE `class_sort_rule` = ?");
 269     $sth->execute($description, $sort_routine, $class_sort_rule);
 270
 271 }
 272
 273 =head2 DelClassSortRule
 274
 275   DelClassSortRule($class_sort_rule);
 276
 277   Deletes class_sort_rules row.
 278
 279 =cut
 280
 281 sub DelClassSortRule {
 282
 283     my ($class_sort_rule) = @_;
 284     my $dbh = C4::Context->dbh;
 285     my $sth = $dbh->prepare("DELETE FROM `class_sort_rules` WHERE `class_sort_rule` = ?");
 286     $sth->execute($class_sort_rule);
 287
 288 }
 289
 290 =head2 GetSourcesForSortRule
 291
 292   my @source = GetSourcesForSortRule($class_sort_rule);
 293
 294   Retrieves an array class_source.cn_rule for each source
 295   that uses the supplied $class_sort_rule.
 296
 297 =cut
 298
 299 sub GetSourcesForSortRule {
 300
 301     my ($class_sort_rule) = @_;
 302
 303     my $dbh = C4::Context->dbh;
 304     my $sth = $dbh->prepare("SELECT cn_source FROM class_sources WHERE class_sort_rule = ?");
 305     $sth->execute($class_sort_rule);
 306     my @sources = ();
 307     while (my ($source) = $sth->fetchrow_array()) {
 308         push @sources, $source;
 309     }
 310     return @sources;
 311
 312 }
 313
 314 =head2 GetClassSort
 315
 316   my $cn_sort = GetClassSort($cn_source, $cn_class, $cn_item);
 317
 318 Get the sort key corresponding to the classification part and item part
 319 and the defined call number source.
 320
 321 =cut
 322
 323 sub GetClassSort {
 324
 325     my ($cn_source, $cn_class, $cn_item) = @_;
 326
 327     my $source_ref = GetClassSource($cn_source);
 328     unless (defined $source_ref) {
 329         $source_ref = GetClassSource(C4::Context->preference("DefaultClassificationSource"));
 330     }
 331     my $routine = "";
 332     if (defined $source_ref) {
 333         my $rule_ref = GetClassSortRule($source_ref->{'class_sort_rule'});
 334         if (defined $rule_ref) {
 335             $routine = $rule_ref->{'sort_routine'};
 336         }
 337     }
 338
 339     return GetClassSortKey($routine, $cn_class, $cn_item);
 340
 341 }
 342
 343 1;
 344
 345 =head1 AUTHOR
 346
 347 Koha Development Team <http://koha-community.org/>
 348
 349 =cut