acqui/booksellers.pl

   1 #!/usr/bin/perl
   2
   3 #script to show suppliers and orders
   4
   5 # Copyright 2000-2002 Katipo Communications
   6 # Copyright 2008-2009 BibLibre SARL
   7 # Copyright 2010 PTFS Europe
   8 #
   9 # This file is part of Koha.
  10 #
  11 # Koha is free software; you can redistribute it and/or modify it
  12 # under the terms of the GNU General Public License as published by
  13 # the Free Software Foundation; either version 3 of the License, or
  14 # (at your option) any later version.
  15 #
  16 # Koha is distributed in the hope that it will be useful, but
  17 # WITHOUT ANY WARRANTY; without even the implied warranty of
  18 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  19 # GNU General Public License for more details.
  20 #
  21 # You should have received a copy of the GNU General Public License
  22 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  23
  24 =head1 NAME
  25
  26 booksellers.pl
  27
  28 =head1 DESCRIPTION
  29
  30 this script displays the list of suppliers & baskets like C<$supplier> given on input arg.
  31 thus, this page brings differents features like to display supplier's details,
  32 to add an order for a specific supplier or to just add a new supplier.
  33
  34 =head1 CGI PARAMETERS
  35
  36 =over 4
  37
  38 =item supplier
  39
  40 C<$supplier> is the string with which we search for a supplier
  41
  42 =back
  43
  44 =over 4
  45
  46 =item id or booksellerid
  47
  48 The id of the supplier whose baskets we will display
  49
  50 =back
  51
  52 =cut
  53
  54 use Modern::Perl;
  55 use C4::Auth;
  56 use C4::Biblio;
  57 use C4::Budgets;
  58 use C4::Output;
  59 use CGI qw ( -utf8 );
  60
  61 use C4::Acquisition qw/ GetBasketsInfosByBookseller CanUserManageBasket /;
  62 use C4::Context;
  63
  64 use Koha::Acquisition::Booksellers;
  65 use Koha::Patrons;
  66
  67 my $query = CGI->new;
  68 my ( $template, $loggedinuser, $cookie, $userflags ) = get_template_and_user(
  69     {   template_name   => 'acqui/booksellers.tt',
  70         query           => $query,
  71         type            => 'intranet',
  72         authnotrequired => 0,
  73         flagsrequired   => { acquisition => '*' },
  74         debug           => 1,
  75     }
  76 );
  77
  78 #parameters
  79 my $supplier = $query->param('supplier');
  80 my $booksellerid = $query->param('booksellerid');
  81 my $allbaskets= $query->param('allbaskets')||0;
  82 my @suppliers;
  83
  84 if ($booksellerid) {
  85     push @suppliers, Koha::Acquisition::Booksellers->find( $booksellerid );
  86 } else {
  87     @suppliers = Koha::Acquisition::Booksellers->search(
  88                         { name => { -like => "%$supplier%" } },
  89                         { order_by => { -asc => 'name' } } );
  90 }
  91
  92 my $supplier_count = @suppliers;
  93 if ( $supplier_count == 1 ) {
  94     $template->param(
  95         supplier_name => $suppliers[0]->name,
  96         booksellerid  => $suppliers[0]->id,
  97         basketcount   => $suppliers[0]->baskets->count,
  98         active        => $suppliers[0]->active,
  99     );
 100 }
 101
 102 my $uid;
 103 # FIXME This script should only be accessed by a valid logged in patron
 104 if ($loggedinuser) {
 105     # FIXME Should not be needed, logged in patron should be cached
 106     $uid = Koha::Patrons->find( $loggedinuser )->userid;
 107 }
 108
 109 my $userenv = C4::Context::userenv;
 110 my $viewbaskets = C4::Context->preference('AcqViewBaskets');
 111
 112 my $userbranch = $userenv->{branch};
 113
 114 my $budgets = GetBudgetHierarchy;
 115 my $has_budgets = 0;
 116 foreach my $r (@{$budgets}) {
 117     next unless (CanUserUseBudget($loggedinuser, $r, $userflags));
 118
 119     $has_budgets = 1;
 120     last;
 121 }
 122
 123 #build result page
 124 my $loop_suppliers = [];
 125
 126 for my $vendor (@suppliers) {
 127     my $baskets = GetBasketsInfosByBookseller( $vendor->id, $allbaskets );
 128
 129     my $loop_basket = [];
 130
 131     for my $basket ( @{$baskets} ) {
 132         if (CanUserManageBasket($loggedinuser, $basket, $userflags)) {
 133             my $patron = Koha::Patrons->find( $basket->{authorisedby} );
 134             foreach (qw(total_items total_biblios expected_items)) {
 135                 $basket->{$_} ||= 0;
 136             }
 137             if ( $patron ) {
 138                 $basket->{authorisedby} = $patron;
 139             }
 140             if ($basket->{basketgroupid}) {
 141                 my $basketgroup = C4::Acquisition::GetBasketgroup($basket->{basketgroupid});
 142                 if ($basketgroup) {
 143                     $basket->{basketgroup} = $basketgroup;
 144                 }
 145             }
 146             push @{$loop_basket}, $basket;
 147         }
 148     }
 149
 150     push @{$loop_suppliers},
 151       { loop_basket => $loop_basket,
 152         booksellerid  => $vendor->id,
 153         name        => $vendor->name,
 154         active      => $vendor->active,
 155       };
 156
 157 }
 158 $template->param(
 159     loop_suppliers => $loop_suppliers,
 160     supplier       => ( $booksellerid || $supplier ),
 161     count          => $supplier_count,
 162     has_budgets          => $has_budgets,
 163 );
 164 $template->{VARS}->{'allbaskets'} = $allbaskets;
 165
 166 output_html_with_http_headers $query, $cookie, $template->output;