tools/letter.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 =head1 tools/letter.pl
  21
  22  ALGO :
  23  this script use an $op to know what to do.
  24  if $op is empty or none of the values listed below,
  25         - the default screen is built (with all or filtered (if search string is set) records).
  26         - the   user can click on add, modify or delete record.
  27     - filtering is done on the code field
  28  if $op=add_form
  29         - if primary key (module + code) exists, this is a modification,so we read the required record
  30         - builds the add/modify form
  31  if $op=add_validate
  32         - the user has just send data, so we create/modify the record
  33  if $op=delete_form
  34         - we show the record selected and ask for confirmation
  35  if $op=delete_confirm
  36         - we delete the designated record
  37
  38 =cut
  39
  40 # TODO This script drives the CRUD operations on the letter table
  41 # The DB interaction should be handled by calls to C4/Letters.pm
  42
  43 use Modern::Perl;
  44 use CGI qw ( -utf8 );
  45 use C4::Auth;
  46 use C4::Context;
  47 use C4::Output;
  48 use C4::Letters;
  49
  50 use Koha::Patron::Attribute::Types;
  51
  52 # $protected_letters = protected_letters()
  53 # - return a hashref of letter_codes representing letters that should never be deleted
  54 sub protected_letters {
  55     my $dbh = C4::Context->dbh;
  56     my $codes = $dbh->selectall_arrayref(q{SELECT DISTINCT letter_code FROM message_transports});
  57     return { map { $_->[0] => 1 } @{$codes} };
  58 }
  59
  60 our $input       = new CGI;
  61 my $searchfield = $input->param('searchfield');
  62 my $script_name = '/cgi-bin/koha/tools/letter.pl';
  63 our $branchcode  = $input->param('branchcode');
  64 $branchcode = '' if defined $branchcode and $branchcode eq '*';
  65 my $code        = $input->param('code');
  66 my $module      = $input->param('module') || '';
  67 my $content     = $input->param('content');
  68 my $op          = $input->param('op') || '';
  69 my $redirect      = $input->param('redirect');
  70 my $dbh = C4::Context->dbh;
  71
  72 our ( $template, $borrowernumber, $cookie, $staffflags ) = get_template_and_user(
  73     {
  74         template_name   => 'tools/letter.tt',
  75         query           => $input,
  76         type            => 'intranet',
  77         authnotrequired => 0,
  78         flagsrequired   => { tools => 'edit_notices' },
  79         debug           => 1,
  80     }
  81 );
  82
  83 our $my_branch = C4::Context->preference("IndependentBranches") && !$staffflags->{'superlibrarian'}
  84   ?  C4::Context->userenv()->{'branch'}
  85   : undef;
  86 # we show only the TMPL_VAR names $op
  87
  88 $template->param(
  89     independant_branch => $my_branch,
  90         script_name => $script_name,
  91   searchfield => $searchfield,
  92     branchcode => $branchcode,
  93         action => $script_name
  94 );
  95
  96 if ( $op eq 'add_validate' or $op eq 'copy_validate' ) {
  97     add_validate();
  98     if( $redirect eq "just_save" ){
  99         print $input->redirect("/cgi-bin/koha/tools/letter.pl?op=add_form&branchcode=$branchcode&module=$module&code=$code&redirect=done");
 100         exit;
 101     } else {
 102         $op = q{}; # we return to the default screen for the next operation
 103     }
 104 }
 105 if ($op eq 'copy_form') {
 106     my $oldbranchcode = $input->param('oldbranchcode') || q||;
 107     my $branchcode = $input->param('branchcode');
 108     add_form($oldbranchcode, $module, $code);
 109     $template->param(
 110         oldbranchcode => $oldbranchcode,
 111         branchcode => $branchcode,
 112         copying => 1,
 113         modify => 0,
 114     );
 115 }
 116 elsif ( $op eq 'add_form' ) {
 117     add_form($branchcode, $module, $code);
 118 }
 119 elsif ( $op eq 'delete_confirm' ) {
 120     delete_confirm($branchcode, $module, $code);
 121 }
 122 elsif ( $op eq 'delete_confirmed' ) {
 123     delete_confirmed($branchcode, $module, $code);
 124     $op = q{}; # next operation is to return to default screen
 125 }
 126 else {
 127     default_display($branchcode,$searchfield);
 128 }
 129
 130 # Do this last as delete_confirmed resets
 131 if ($op) {
 132     $template->param($op  => 1);
 133 } else {
 134     $template->param(no_op_set => 1);
 135 }
 136
 137 output_html_with_http_headers $input, $cookie, $template->output;
 138
 139 sub add_form {
 140     my ( $branchcode,$module, $code ) = @_;
 141
 142     my $letters;
 143     # if code has been passed we can identify letter and its an update action
 144     if ($code) {
 145         $letters = C4::Letters::GetLetterTemplates(
 146             {
 147                 branchcode => $branchcode,
 148                 module     => $module,
 149                 code       => $code,
 150             }
 151         );
 152     }
 153
 154     my $message_transport_types = GetMessageTransportTypes();
 155     my $templates = { map { $_ => { message_transport_type => $_ } } sort @$message_transport_types };
 156     my %letters = ( default => { templates => $templates } );
 157
 158     if ( C4::Context->preference('TranslateNotices') ) {
 159         my $translated_languages =
 160           C4::Languages::getTranslatedLanguages( 'opac',
 161             C4::Context->preference('template') );
 162         for my $language (@$translated_languages) {
 163             for my $sublanguage( @{ $language->{sublanguages_loop} } ) {
 164                 if ( $language->{plural} ) {
 165                     $letters{ $sublanguage->{rfc4646_subtag} } = {
 166                         description => $sublanguage->{native_description}
 167                           . ' '
 168                           . $sublanguage->{region_description} . ' ('
 169                           . $sublanguage->{rfc4646_subtag} . ')',
 170                         templates => { %$templates },
 171                     };
 172                 }
 173                 else {
 174                     $letters{ $sublanguage->{rfc4646_subtag} } = {
 175                         description => $sublanguage->{native_description}
 176                           . ' ('
 177                           . $sublanguage->{rfc4646_subtag} . ')',
 178                         templates => { %$templates },
 179                     };
 180                 }
 181             }
 182         }
 183         $template->param( languages => $translated_languages );
 184     }
 185     if ($letters) {
 186         $template->param(
 187             modify     => 1,
 188             code       => $code,
 189         );
 190         my $first_flag_name = 1;
 191         my ( $lang, @templates );
 192         # The letter name is contained into each mtt row.
 193         # So we can only sent the first one to the template.
 194         for my $letter ( @$letters ) {
 195             # The letter_name
 196             if ( $first_flag_name and $letter->{name} ) {
 197                 $template->param(
 198                     letter_name=> $letter->{name},
 199                 );
 200                 $first_flag_name = 0;
 201             }
 202
 203             my $lang = $letter->{lang};
 204             my $mtt = $letter->{message_transport_type};
 205             $letters{ $lang }{templates}{$mtt} = {
 206                 message_transport_type => $letter->{message_transport_type},
 207                 is_html    => $letter->{is_html},
 208                 title      => $letter->{title},
 209                 content    => $letter->{content} // '',
 210             };
 211         }
 212     }
 213     else {
 214         $template->param( adding => 1 );
 215     }
 216
 217     $template->param(
 218         letters => \%letters,
 219     );
 220
 221     my $field_selection;
 222     push @{$field_selection}, add_fields('branches');
 223     if ($module eq 'reserves') {
 224         push @{$field_selection}, add_fields('borrowers', 'reserves', 'biblio', 'biblioitems', 'items');
 225     }
 226     elsif ( $module eq 'acquisition' ) {
 227         push @{$field_selection}, add_fields('aqbooksellers', 'aqorders', 'biblio', 'items');
 228     }
 229     elsif ($module eq 'claimacquisition' || $module eq 'orderacquisition') {
 230         push @{$field_selection}, add_fields('aqbooksellers', 'aqbasket', 'aqorders', 'biblio', 'biblioitems');
 231     }
 232     elsif ($module eq 'claimissues') {
 233         push @{$field_selection}, add_fields('aqbooksellers', 'serial', 'subscription');
 234         push @{$field_selection},
 235         {
 236             value => q{},
 237             text => '---BIBLIO---'
 238         };
 239         foreach(qw(title author serial)) {
 240             push @{$field_selection}, {value => "biblio.$_", text => ucfirst $_ };
 241         }
 242     }
 243     elsif ($module eq 'serial') {
 244         push @{$field_selection}, add_fields('branches', 'biblio', 'biblioitems', 'borrowers', 'subscription', 'serial');
 245     }
 246     elsif ($module eq 'suggestions') {
 247         push @{$field_selection}, add_fields('suggestions', 'borrowers', 'biblio');
 248     }
 249     else {
 250         push @{$field_selection}, add_fields('biblio','biblioitems'),
 251             add_fields('items'),
 252             {value => 'items.content', text => 'items.content'},
 253             {value => 'items.fine',    text => 'items.fine'},
 254             add_fields('borrowers');
 255         if ($module eq 'circulation') {
 256             push @{$field_selection}, add_fields('opac_news');
 257
 258         }
 259
 260         if ( $module eq 'circulation' and $code and $code eq "CHECKIN" ) {
 261             push @{$field_selection}, add_fields('old_issues');
 262         } else {
 263             push @{$field_selection}, add_fields('issues');
 264         }
 265
 266         if ( $module eq 'circulation' and $code =~ /^AR_/  ) {
 267             push @{$field_selection}, add_fields('article_requests');
 268         }
 269     }
 270
 271     my $preview_is_available = grep {/^$code$/} qw(
 272         CHECKIN CHECKOUT HOLD_SLIP
 273     );
 274     $template->param(
 275         module     => $module,
 276         SQLfieldnames => $field_selection,
 277         branchcode => $branchcode,
 278         preview_is_available => $preview_is_available,
 279     );
 280     return;
 281 }
 282
 283 sub add_validate {
 284     my $dbh        = C4::Context->dbh;
 285     my $branchcode    = $input->param('branchcode');
 286     my $module        = $input->param('module');
 287     my $oldmodule     = $input->param('oldmodule');
 288     my $code          = $input->param('code');
 289     my $name          = $input->param('name');
 290     my @mtt           = $input->multi_param('message_transport_type');
 291     my @title         = $input->multi_param('title');
 292     my @content       = $input->multi_param('content');
 293     my @lang          = $input->multi_param('lang');
 294     for my $mtt ( @mtt ) {
 295         my $is_html = $input->param("is_html_$mtt");
 296         my $title   = shift @title;
 297         my $content = shift @content;
 298         my $lang = shift @lang;
 299         my $letter = C4::Letters::getletter( $oldmodule, $code, $branchcode, $mtt, $lang );
 300
 301         # getletter can return the default letter even if we pass a branchcode
 302         # If we got the default one and we needed the specific one, we didn't get the one we needed!
 303         if ( $letter and $branchcode and $branchcode ne $letter->{branchcode} ) {
 304             $letter = undef;
 305         }
 306         unless ( $title and $content ) {
 307             # Delete this mtt if no title or content given
 308             delete_confirmed( $branchcode, $oldmodule, $code, $mtt, $lang );
 309             next;
 310         }
 311         elsif ( $letter and $letter->{message_transport_type} eq $mtt and $letter->{lang} eq $lang ) {
 312             $dbh->do(
 313                 q{
 314                     UPDATE letter
 315                     SET branchcode = ?, module = ?, name = ?, is_html = ?, title = ?, content = ?, lang = ?
 316                     WHERE branchcode = ? AND module = ? AND code = ? AND message_transport_type = ? AND lang = ?
 317                 },
 318                 undef,
 319                 $branchcode || '', $module, $name, $is_html || 0, $title, $content, $lang,
 320                 $branchcode, $oldmodule, $code, $mtt, $lang
 321             );
 322         } else {
 323             $dbh->do(
 324                 q{INSERT INTO letter (branchcode,module,code,name,is_html,title,content,message_transport_type, lang) VALUES (?,?,?,?,?,?,?,?,?)},
 325                 undef,
 326                 $branchcode || '', $module, $code, $name, $is_html || 0, $title, $content, $mtt, $lang
 327             );
 328         }
 329     }
 330     # set up default display
 331     default_display($branchcode);
 332     return 1;
 333 }
 334
 335 sub delete_confirm {
 336     my ($branchcode, $module, $code) = @_;
 337     my $dbh = C4::Context->dbh;
 338     my $letter = C4::Letters::getletter($module, $code, $branchcode);
 339     my @values = values %$letter;
 340     $template->param(
 341         letter => $letter,
 342     );
 343     return;
 344 }
 345
 346 sub delete_confirmed {
 347     my ($branchcode, $module, $code, $mtt, $lang) = @_;
 348     C4::Letters::DelLetter(
 349         {
 350             branchcode => $branchcode || '',
 351             module     => $module,
 352             code       => $code,
 353             mtt        => $mtt,
 354             lang       => $lang,
 355         }
 356     );
 357     # setup default display for screen
 358     default_display($branchcode);
 359     return;
 360 }
 361
 362 sub retrieve_letters {
 363     my ($branchcode, $searchstring) = @_;
 364
 365     $branchcode = $my_branch if $branchcode && $my_branch;
 366
 367     my $dbh = C4::Context->dbh;
 368     my ($sql, @where, @args);
 369     $sql = "SELECT branchcode, module, code, name, branchname
 370             FROM letter
 371             LEFT OUTER JOIN branches USING (branchcode)
 372     ";
 373     if ($searchstring && $searchstring=~m/(\S+)/) {
 374         $searchstring = $1 . q{%};
 375         push @where, 'code LIKE ?';
 376         push @args, $searchstring;
 377     }
 378     elsif ($branchcode) {
 379         push @where, 'branchcode = ?';
 380         push @args, $branchcode || '';
 381     }
 382     elsif ($my_branch) {
 383         push @where, "(branchcode = ? OR branchcode = '')";
 384         push @args, $my_branch;
 385     }
 386
 387     $sql .= " WHERE ".join(" AND ", @where) if @where;
 388     $sql .= " GROUP BY branchcode,module,code";
 389     $sql .= " ORDER BY module, code, branchcode";
 390
 391     return $dbh->selectall_arrayref($sql, { Slice => {} }, @args);
 392 }
 393
 394 sub default_display {
 395     my ($branchcode, $searchfield) = @_;
 396
 397     unless ( defined $branchcode ) {
 398         if ( C4::Context->preference('DefaultToLoggedInLibraryNoticesSlips') ) {
 399             $branchcode = C4::Context::mybranch();
 400         }
 401     }
 402
 403     if ( $searchfield  ) {
 404         $template->param( search      => 1 );
 405     }
 406     my $results = retrieve_letters($branchcode,$searchfield);
 407
 408     my $loop_data = [];
 409     my $protected_letters = protected_letters();
 410     foreach my $row (@{$results}) {
 411         $row->{protected} = !$row->{branchcode} && $protected_letters->{ $row->{code} };
 412         push @{$loop_data}, $row;
 413
 414     }
 415
 416     $template->param(
 417         letter => $loop_data,
 418         branchcode => $branchcode,
 419     );
 420 }
 421
 422 sub add_fields {
 423     my @tables = @_;
 424     my @fields = ();
 425
 426     for my $table (@tables) {
 427         push @fields, get_columns_for($table);
 428
 429     }
 430     return @fields;
 431 }
 432
 433 sub get_columns_for {
 434     my $table = shift;
 435 # FIXME untranslatable
 436     my %column_map = (
 437         aqbooksellers => '---BOOKSELLERS---',
 438         aqorders      => '---ORDERS---',
 439         serial        => '---SERIALS---',
 440         reserves      => '---HOLDS---',
 441         suggestions   => '---SUGGESTIONS---',
 442     );
 443     my @fields = ();
 444     if (exists $column_map{$table} ) {
 445         push @fields, {
 446             value => q{},
 447             text  => $column_map{$table} ,
 448         };
 449     }
 450     else {
 451         my $tlabel = '---' . uc $table;
 452         $tlabel.= '---';
 453         push @fields, {
 454             value => q{},
 455             text  => $tlabel,
 456         };
 457     }
 458
 459     my $sql = "SHOW COLUMNS FROM $table";# TODO not db agnostic
 460     my $table_prefix = $table . q|.|;
 461     my $rows = C4::Context->dbh->selectall_arrayref($sql, { Slice => {} });
 462     for my $row (@{$rows}) {
 463         next if $row->{'Field'} eq 'timestamp'; # this is really an irrelevant field and there may be other common fields that should be excluded from the list
 464         push @fields, {
 465             value => $table_prefix . $row->{Field},
 466             text  => $table_prefix . $row->{Field},
 467         }
 468     }
 469     if ($table eq 'borrowers') {
 470         my $attribute_types = Koha::Patron::Attribute::Types->search(
 471             {},
 472             { order_by => 'code' },
 473         );
 474         while ( my $at = $attribute_types->next ) {
 475             push @fields, {
 476                 value => "borrower-attribute:" . $at->code,
 477                 text  => "attribute:" . $at->code,
 478             }
 479         }
 480     }
 481     return @fields;
 482 }