C4/XSLT.pm

   1 package C4::XSLT;
   2
   3 # Copyright (C) 2006 LibLime
   4 # <jmf at liblime dot com>
   5 # Parts Copyright Katrin Fischer 2011
   6 # Parts Copyright ByWater Solutions 2011
   7 # Parts Copyright Biblibre 2012
   8 #
   9 # This file is part of Koha.
  10 #
  11 # Koha is free software; you can redistribute it and/or modify it under the
  12 # terms of the GNU General Public License as published by the Free Software
  13 # Foundation; either version 3 of the License, or (at your option) any later
  14 # version.
  15 #
  16 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  17 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  18 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU General Public License along
  21 # with Koha; if not, write to the Free Software Foundation, Inc.,
  22 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  23
  24 use strict;
  25 use warnings;
  26
  27 use C4::Context;
  28 use C4::Branch;
  29 use C4::Items;
  30 use C4::Koha;
  31 use C4::Biblio;
  32 use C4::Circulation;
  33 use C4::Reserves;
  34 use Koha::XSLT_Handler;
  35 use Koha::Libraries;
  36
  37 use Encode;
  38
  39 use vars qw(@ISA @EXPORT);
  40
  41 my $engine; #XSLT Handler object
  42 my %authval_per_framework;
  43     # Cache for tagfield-tagsubfield to decode per framework.
  44     # Should be preferably be placed in Koha-core...
  45
  46 BEGIN {
  47     require Exporter;
  48     @ISA = qw(Exporter);
  49     @EXPORT = qw(
  50         &XSLTParse4Display
  51     );
  52     $engine=Koha::XSLT_Handler->new( { do_not_return_source => 1 } );
  53 }
  54
  55 =head1 NAME
  56
  57 C4::XSLT - Functions for displaying XSLT-generated content
  58
  59 =head1 FUNCTIONS
  60
  61 =head2 transformMARCXML4XSLT
  62
  63 Replaces codes with authorized values in a MARC::Record object
  64 Is only used in this module currently.
  65
  66 =cut
  67
  68 sub transformMARCXML4XSLT {
  69     my ($biblionumber, $record) = @_;
  70     my $frameworkcode = GetFrameworkCode($biblionumber) || '';
  71     my $tagslib = &GetMarcStructure(1,$frameworkcode);
  72     my @fields;
  73     # FIXME: wish there was a better way to handle exceptions
  74     eval {
  75         @fields = $record->fields();
  76     };
  77     if ($@) { warn "PROBLEM WITH RECORD"; next; }
  78     my $marcflavour = C4::Context->preference('marcflavour');
  79     my $av = getAuthorisedValues4MARCSubfields($frameworkcode);
  80     foreach my $tag ( keys %$av ) {
  81         foreach my $field ( $record->field( $tag ) ) {
  82             if ( $av->{ $tag } ) {
  83                 my @new_subfields = ();
  84                 for my $subfield ( $field->subfields() ) {
  85                     my ( $letter, $value ) = @$subfield;
  86                     # Replace the field value with the authorised value *except* for MARC21/NORMARC field 942$n (suppression in opac)
  87                     if ( !( $tag eq '942' && $subfield eq 'n' ) || $marcflavour eq 'UNIMARC' ) {
  88                         $value = GetAuthorisedValueDesc( $tag, $letter, $value, '', $tagslib )
  89                             if $av->{ $tag }->{ $letter };
  90                     }
  91                     push( @new_subfields, $letter, $value );
  92                 }
  93                 $field ->replace_with( MARC::Field->new(
  94                     $tag,
  95                     $field->indicator(1),
  96                     $field->indicator(2),
  97                     @new_subfields
  98                 ) );
  99             }
 100         }
 101     }
 102     return $record;
 103 }
 104
 105 =head2 getAuthorisedValues4MARCSubfields
 106
 107 Returns a ref of hash of ref of hash for tag -> letter controlled by authorised values
 108 Is only used in this module currently.
 109
 110 =cut
 111
 112 sub getAuthorisedValues4MARCSubfields {
 113     my ($frameworkcode) = @_;
 114     unless ( $authval_per_framework{ $frameworkcode } ) {
 115         my $dbh = C4::Context->dbh;
 116         my $sth = $dbh->prepare("SELECT DISTINCT tagfield, tagsubfield
 117                                  FROM marc_subfield_structure
 118                                  WHERE authorised_value IS NOT NULL
 119                                    AND authorised_value!=''
 120                                    AND frameworkcode=?");
 121         $sth->execute( $frameworkcode );
 122         my $av = { };
 123         while ( my ( $tag, $letter ) = $sth->fetchrow() ) {
 124             $av->{ $tag }->{ $letter } = 1;
 125         }
 126         $authval_per_framework{ $frameworkcode } = $av;
 127     }
 128     return $authval_per_framework{ $frameworkcode };
 129 }
 130
 131 =head2 XSLTParse4Display
 132
 133 Returns xml for biblionumber and requested XSLT transformation.
 134 Returns undef if the transform fails.
 135
 136 Used in OPAC results and detail, intranet results and detail, list display.
 137 (Depending on the settings of your XSLT preferences.)
 138
 139 The helper function _get_best_default_xslt_filename is used in a unit test.
 140
 141 =cut
 142
 143 sub _get_best_default_xslt_filename {
 144     my ($htdocs, $theme, $lang, $base_xslfile) = @_;
 145
 146     my @candidates = (
 147         "$htdocs/$theme/$lang/xslt/${base_xslfile}", # exact match
 148         "$htdocs/$theme/en/xslt/${base_xslfile}",    # if not, preferred theme in English
 149         "$htdocs/prog/$lang/xslt/${base_xslfile}",   # if not, 'prog' theme in preferred language
 150         "$htdocs/prog/en/xslt/${base_xslfile}",      # otherwise, prog theme in English; should always
 151                                                      # exist
 152     );
 153     my $xslfilename;
 154     foreach my $filename (@candidates) {
 155         $xslfilename = $filename;
 156         if (-f $filename) {
 157             last; # we have a winner!
 158         }
 159     }
 160     return $xslfilename;
 161 }
 162
 163 sub get_xslt_sysprefs {
 164     my $sysxml = "<sysprefs>\n";
 165     foreach my $syspref ( qw/ hidelostitems OPACURLOpenInNewWindow
 166                               DisplayOPACiconsXSLT URLLinkText viewISBD
 167                               OPACBaseURL TraceCompleteSubfields UseICU
 168                               UseAuthoritiesForTracings TraceSubjectSubdivisions
 169                               Display856uAsImage OPACDisplay856uAsImage
 170                               UseControlNumber IntranetBiblioDefaultView BiblioDefaultView
 171                               OPACItemLocation DisplayIconsXSLT
 172                               AlternateHoldingsField AlternateHoldingsSeparator
 173                               TrackClicks opacthemes IdRef OpacSuppression / )
 174     {
 175         my $sp = C4::Context->preference( $syspref );
 176         next unless defined($sp);
 177         $sysxml .= "<syspref name=\"$syspref\">$sp</syspref>\n";
 178     }
 179
 180     # singleBranchMode was a system preference, but no longer is
 181     # we can retain it here for compatibility
 182     my $singleBranchMode = Koha::Libraries->search->count == 1;
 183     $sysxml .= "<syspref name=\"singleBranchMode\">$singleBranchMode</syspref>\n";
 184
 185     $sysxml .= "</sysprefs>\n";
 186     return $sysxml;
 187 }
 188
 189 sub XSLTParse4Display {
 190     my ( $biblionumber, $orig_record, $xslsyspref, $fixamps, $hidden_items, $sysxml, $xslfilename, $lang ) = @_;
 191
 192     $sysxml ||= C4::Context->preference($xslsyspref);
 193     $xslfilename ||= C4::Context->preference($xslsyspref);
 194     $lang ||= C4::Languages::getlanguage();
 195
 196     if ( $xslfilename =~ /^\s*"?default"?\s*$/i ) {
 197         my $htdocs;
 198         my $theme;
 199         my $xslfile;
 200         if ($xslsyspref eq "XSLTDetailsDisplay") {
 201             $htdocs  = C4::Context->config('intrahtdocs');
 202             $theme   = C4::Context->preference("template");
 203             $xslfile = C4::Context->preference('marcflavour') .
 204                        "slim2intranetDetail.xsl";
 205         } elsif ($xslsyspref eq "XSLTResultsDisplay") {
 206             $htdocs  = C4::Context->config('intrahtdocs');
 207             $theme   = C4::Context->preference("template");
 208             $xslfile = C4::Context->preference('marcflavour') .
 209                         "slim2intranetResults.xsl";
 210         } elsif ($xslsyspref eq "OPACXSLTDetailsDisplay") {
 211             $htdocs  = C4::Context->config('opachtdocs');
 212             $theme   = C4::Context->preference("opacthemes");
 213             $xslfile = C4::Context->preference('marcflavour') .
 214                        "slim2OPACDetail.xsl";
 215         } elsif ($xslsyspref eq "OPACXSLTResultsDisplay") {
 216             $htdocs  = C4::Context->config('opachtdocs');
 217             $theme   = C4::Context->preference("opacthemes");
 218             $xslfile = C4::Context->preference('marcflavour') .
 219                        "slim2OPACResults.xsl";
 220         }
 221         $xslfilename = _get_best_default_xslt_filename($htdocs, $theme, $lang, $xslfile);
 222     }
 223
 224     if ( $xslfilename =~ m/\{langcode\}/ ) {
 225         $xslfilename =~ s/\{langcode\}/$lang/;
 226     }
 227
 228     # grab the XML, run it through our stylesheet, push it out to the browser
 229     my $record = transformMARCXML4XSLT($biblionumber, $orig_record);
 230     my $itemsxml  = buildKohaItemsNamespace($biblionumber, $hidden_items);
 231     my $xmlrecord = $record->as_xml(C4::Context->preference('marcflavour'));
 232
 233     $xmlrecord =~ s/\<\/record\>/$itemsxml$sysxml\<\/record\>/;
 234     if ($fixamps) { # We need to correct the HTML entities that Zebra outputs
 235         $xmlrecord =~ s/\&amp;amp;/\&amp;/g;
 236         $xmlrecord =~ s/\&amp\;lt\;/\&lt\;/g;
 237         $xmlrecord =~ s/\&amp\;gt\;/\&gt\;/g;
 238     }
 239     $xmlrecord =~ s/\& /\&amp\; /;
 240     $xmlrecord =~ s/\&amp\;amp\; /\&amp\; /;
 241
 242     #If the xslt should fail, we will return undef (old behavior was
 243     #raw MARC)
 244     #Note that we did set do_not_return_source at object construction
 245     return $engine->transform($xmlrecord, $xslfilename ); #file or URL
 246 }
 247
 248 =head2 buildKohaItemsNamespace
 249
 250 Returns XML for items.
 251 Is only used in this module currently.
 252
 253 =cut
 254
 255 sub buildKohaItemsNamespace {
 256     my ($biblionumber, $hidden_items) = @_;
 257
 258     my @items = C4::Items::GetItemsInfo($biblionumber);
 259     if ($hidden_items && @$hidden_items) {
 260         my %hi = map {$_ => 1} @$hidden_items;
 261         @items = grep { !$hi{$_->{itemnumber}} } @items;
 262     }
 263
 264     my $shelflocations = GetKohaAuthorisedValues('items.location',GetFrameworkCode($biblionumber), 'opac');
 265     my $ccodes         = GetKohaAuthorisedValues('items.ccode',GetFrameworkCode($biblionumber), 'opac');
 266
 267     my $branches = GetBranches();
 268     my $itemtypes = GetItemTypes();
 269     my $location = "";
 270     my $ccode = "";
 271     my $xml = '';
 272     for my $item (@items) {
 273         my $status;
 274
 275         my ( $transfertwhen, $transfertfrom, $transfertto ) = C4::Circulation::GetTransfers($item->{itemnumber});
 276
 277         my $reservestatus = C4::Reserves::GetReserveStatus( $item->{itemnumber} );
 278
 279         if ( $itemtypes->{ $item->{itype} }->{notforloan} || $item->{notforloan} || $item->{onloan} || $item->{withdrawn} || $item->{itemlost} || $item->{damaged} ||
 280              (defined $transfertwhen && $transfertwhen ne '') || $item->{itemnotforloan} || (defined $reservestatus && $reservestatus eq "Waiting") ){
 281             if ( $item->{notforloan} < 0) {
 282                 $status = "On order";
 283             }
 284             if ( $item->{itemnotforloan} > 0 || $item->{notforloan} > 0 || $itemtypes->{ $item->{itype} }->{notforloan} == 1 ) {
 285                 $status = "reference";
 286             }
 287             if ($item->{onloan}) {
 288                 $status = "Checked out";
 289             }
 290             if ( $item->{withdrawn}) {
 291                 $status = "Withdrawn";
 292             }
 293             if ($item->{itemlost}) {
 294                 $status = "Lost";
 295             }
 296             if ($item->{damaged}) {
 297                 $status = "Damaged";
 298             }
 299             if (defined $transfertwhen && $transfertwhen ne '') {
 300                 $status = 'In transit';
 301             }
 302             if (defined $reservestatus && $reservestatus eq "Waiting") {
 303                 $status = 'Waiting';
 304             }
 305         } else {
 306             $status = "available";
 307         }
 308         my $homebranch = $item->{homebranch}? xml_escape($branches->{$item->{homebranch}}->{'branchname'}):'';
 309         my $holdingbranch = $item->{holdingbranch}? xml_escape($branches->{$item->{holdingbranch}}->{'branchname'}):'';
 310         $location = $item->{location}? xml_escape($shelflocations->{$item->{location}}||$item->{location}):'';
 311         $ccode = $item->{ccode}? xml_escape($ccodes->{$item->{ccode}}||$item->{ccode}):'';
 312         my $itemcallnumber = xml_escape($item->{itemcallnumber});
 313         $xml.= "<item><homebranch>$homebranch</homebranch>".
 314                 "<holdingbranch>$holdingbranch</holdingbranch>".
 315                 "<location>$location</location>".
 316                 "<ccode>$ccode</ccode>".
 317                 "<status>$status</status>".
 318                 "<itemcallnumber>".$itemcallnumber."</itemcallnumber>".
 319                 "</item>";
 320     }
 321     $xml = "<items xmlns=\"http://www.koha-community.org/items\">".$xml."</items>";
 322     return $xml;
 323 }
 324
 325 =head2 engine
 326
 327 Returns reference to XSLT handler object.
 328
 329 =cut
 330
 331 sub engine {
 332     return $engine;
 333 }
 334
 335 1;
 336
 337 __END__
 338
 339 =head1 AUTHOR
 340
 341 Joshua Ferraro <jmf@liblime.com>
 342
 343 Koha Development Team <http://koha-community.org/>
 344
 345 =cut