C4/Auth_with_ldap.pm

   1 package C4::Auth_with_ldap;
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use strict;
  21 #use warnings; FIXME - Bug 2505
  22 use Carp;
  23
  24 use C4::Debug;
  25 use C4::Context;
  26 use C4::Members qw(AddMember);
  27 use C4::Members::Attributes;
  28 use C4::Members::AttributeTypes;
  29 use C4::Members::Messaging;
  30 use C4::Auth qw(checkpw_internal);
  31 use Koha::Patrons;
  32 use Koha::AuthUtils qw(hash_password);
  33 use List::MoreUtils qw( any );
  34 use Net::LDAP;
  35 use Net::LDAP::Filter;
  36
  37 use vars qw(@ISA @EXPORT @EXPORT_OK %EXPORT_TAGS $debug);
  38
  39 BEGIN {
  40         require Exporter;
  41         @ISA    = qw(Exporter);
  42         @EXPORT = qw( checkpw_ldap );
  43 }
  44
  45 # Redefine checkpw_ldap:
  46 # connect to LDAP (named or anonymous)
  47 # ~ retrieves $userid from KOHA_CONF mapping
  48 # ~ then compares $password with userPassword
  49 # ~ then gets the LDAP entry
  50 # ~ and calls the memberadd if necessary
  51
  52 sub ldapserver_error {
  53         return sprintf('No ldapserver "%s" defined in KOHA_CONF: ' . $ENV{KOHA_CONF}, shift);
  54 }
  55
  56 use vars qw($mapping @ldaphosts $base $ldapname $ldappassword);
  57 my $context = C4::Context->new()        or die 'C4::Context->new failed';
  58 my $ldap = C4::Context->config("ldapserver") or die 'No "ldapserver" in server hash from KOHA_CONF: ' . $ENV{KOHA_CONF};
  59 my $prefhost  = $ldap->{hostname}       or die ldapserver_error('hostname');
  60 my $base      = $ldap->{base}           or die ldapserver_error('base');
  61 $ldapname     = $ldap->{user}           ;
  62 $ldappassword = $ldap->{pass}           ;
  63 our %mapping  = %{$ldap->{mapping}}; # FIXME dpavlin -- don't die because of || (); from 6eaf8511c70eb82d797c941ef528f4310a15e9f9
  64 my @mapkeys = keys %mapping;
  65 $debug and print STDERR "Got ", scalar(@mapkeys), " ldap mapkeys (  total  ): ", join ' ', @mapkeys, "\n";
  66 @mapkeys = grep {defined $mapping{$_}->{is}} @mapkeys;
  67 $debug and print STDERR "Got ", scalar(@mapkeys), " ldap mapkeys (populated): ", join ' ', @mapkeys, "\n";
  68
  69 my %categorycode_conversions;
  70 my $default_categorycode;
  71 if(defined $ldap->{categorycode_mapping}) {
  72     $default_categorycode = $ldap->{categorycode_mapping}->{default};
  73     foreach my $cat (@{$ldap->{categorycode_mapping}->{categorycode}}) {
  74         $categorycode_conversions{$cat->{value}} = $cat->{content};
  75     }
  76 }
  77
  78 my %config = (
  79         anonymous => ($ldapname and $ldappassword) ? 0 : 1,
  80     replicate => defined($ldap->{replicate}) ? $ldap->{replicate} : 1,  #    add from LDAP to Koha database for new user
  81        update => defined($ldap->{update}   ) ? $ldap->{update}    : 1,  # update from LDAP to Koha database for existing user
  82 );
  83
  84 sub description {
  85         my $result = shift or return;
  86         return "LDAP error #" . $result->code
  87                         . ": " . $result->error_name . "\n"
  88                         . "# " . $result->error_text . "\n";
  89 }
  90
  91 sub search_method {
  92     my $db     = shift or return;
  93     my $userid = shift or return;
  94         my $uid_field = $mapping{userid}->{is} or die ldapserver_error("mapping for 'userid'");
  95         my $filter = Net::LDAP::Filter->new("$uid_field=$userid") or die "Failed to create new Net::LDAP::Filter";
  96         my $search = $db->search(
  97                   base => $base,
  98                 filter => $filter,
  99                 # attrs => ['*'],
 100     );
 101     die "LDAP search failed to return object : " . $search->error if $search->code;
 102
 103         my $count = $search->count;
 104         if ($search->code > 0) {
 105                 warn sprintf("LDAP Auth rejected : %s gets %d hits\n", $filter->as_string, $count) . description($search);
 106                 return 0;
 107         }
 108         if ($count != 1) {
 109                 warn sprintf("LDAP Auth rejected : %s gets %d hits\n", $filter->as_string, $count);
 110                 return 0;
 111         }
 112     return $search;
 113 }
 114
 115 sub checkpw_ldap {
 116     my ($dbh, $userid, $password) = @_;
 117     my @hosts = split(',', $prefhost);
 118     my $db = Net::LDAP->new(\@hosts);
 119     unless ( $db ) {
 120         warn "LDAP connexion failed";
 121         return 0;
 122     }
 123
 124         #$debug and $db->debug(5);
 125     my $userldapentry;
 126
 127     if ( $ldap->{auth_by_bind} ) {
 128         my $principal_name;
 129         if ( $ldap->{anonymous_bind} ) {
 130
 131             # Perform an anonymous bind
 132             my $res = $db->bind;
 133             if ( $res->code ) {
 134                 warn "Anonymous LDAP bind failed: " . description($res);
 135                 return 0;
 136             }
 137
 138             # Perform a LDAP search for the given username
 139             my $search = search_method( $db, $userid )
 140               or return 0;    # warnings are in the sub
 141             $userldapentry = $search->shift_entry;
 142             $principal_name = $userldapentry->dn;
 143         }
 144         else {
 145             $principal_name = $ldap->{principal_name};
 146             if ( $principal_name and $principal_name =~ /\%/ ) {
 147                 $principal_name = sprintf( $principal_name, $userid );
 148             }
 149             else {
 150                 $principal_name = $userid;
 151             }
 152         }
 153
 154         # Perform a LDAP bind for the given username using the matched DN
 155         my $res = $db->bind( $principal_name, password => $password );
 156         if ( $res->code ) {
 157             if ( $ldap->{anonymous_bind} ) {
 158                 # With anonymous_bind approach we can be sure we have found the correct user
 159                 # and that any 'code' response indicates a 'bad' user (be that blocked, banned
 160                 # or password changed). We should not fall back to local accounts in this case.
 161                 warn "LDAP bind failed as kohauser $userid: " . description($res);
 162                 return -1;
 163             } else {
 164                 # Without a anonymous_bind, we cannot be sure we are looking at a valid ldap user
 165                 # at all, and thus we should fall back to local logins to restore previous behaviour
 166                 # see bug 12831
 167                 warn "LDAP bind failed as kohauser $userid: " . description($res);
 168                 return 0;
 169             }
 170         }
 171         if ( !defined($userldapentry)
 172             && ( $config{update} or $config{replicate} ) )
 173         {
 174             my $search = search_method( $db, $userid ) or return 0;
 175             $userldapentry = $search->shift_entry;
 176         }
 177     } else {
 178                 my $res = ($config{anonymous}) ? $db->bind : $db->bind($ldapname, password=>$ldappassword);
 179                 if ($res->code) {               # connection refused
 180                         warn "LDAP bind failed as ldapuser " . ($ldapname || '[ANONYMOUS]') . ": " . description($res);
 181                         return 0;
 182                 }
 183         my $search = search_method($db, $userid) or return 0;   # warnings are in the sub
 184         $userldapentry = $search->shift_entry;
 185                 my $cmpmesg = $db->compare( $userldapentry, attr=>'userpassword', value => $password );
 186                 if ($cmpmesg->code != 6) {
 187                         warn "LDAP Auth rejected : invalid password for user '$userid'. " . description($cmpmesg);
 188                         return -1;
 189                 }
 190         }
 191
 192     # To get here, LDAP has accepted our user's login attempt.
 193     # But we still have work to do.  See perldoc below for detailed breakdown.
 194
 195     my (%borrower);
 196         my ($borrowernumber,$cardnumber,$local_userid,$savedpw) = exists_local($userid);
 197
 198     if (( $borrowernumber and $config{update}   ) or
 199         (!$borrowernumber and $config{replicate})   ) {
 200         %borrower = ldap_entry_2_hash($userldapentry,$userid);
 201         $debug and print STDERR "checkpw_ldap received \%borrower w/ " . keys(%borrower), " keys: ", join(' ', keys %borrower), "\n";
 202     }
 203
 204     if ($borrowernumber) {
 205         if ($config{update}) { # A1, B1
 206             my $c2 = &update_local($local_userid,$password,$borrowernumber,\%borrower) || '';
 207             ($cardnumber eq $c2) or warn "update_local returned cardnumber '$c2' instead of '$cardnumber'";
 208         } else { # C1, D1
 209             # maybe update just the password?
 210                 return(1, $cardnumber, $local_userid);
 211         }
 212     } elsif ($config{replicate}) { # A2, C2
 213         $borrowernumber = AddMember(%borrower) or die "AddMember failed";
 214         C4::Members::Messaging::SetMessagingPreferencesFromDefaults( { borrowernumber => $borrowernumber, categorycode => $borrower{'categorycode'} } );
 215    } else {
 216         return 0;   # B2, D2
 217     }
 218     if (C4::Context->preference('ExtendedPatronAttributes') && $borrowernumber && ($config{update} ||$config{replicate})) {
 219         foreach my $attribute_type ( C4::Members::AttributeTypes::GetAttributeTypes() ) {
 220             my $code = $attribute_type->{code};
 221             unless (exists($borrower{$code}) && $borrower{$code} !~ m/^\s*$/ ) {
 222                 next;
 223             }
 224             if (C4::Members::Attributes::CheckUniqueness($code, $borrower{$code}, $borrowernumber)) {
 225                 C4::Members::Attributes::UpdateBorrowerAttribute($borrowernumber, {code => $code, value => $borrower{$code}});
 226             } else {
 227                 warn "ERROR_extended_unique_id_failed $code $borrower{$code}";
 228             }
 229         }
 230     }
 231     return(1, $cardnumber, $userid);
 232 }
 233
 234 # Pass LDAP entry object and local cardnumber (userid).
 235 # Returns borrower hash.
 236 # Edit KOHA_CONF so $memberhash{'xxx'} fits your ldap structure.
 237 # Ensure that mandatory fields are correctly filled!
 238 #
 239 sub ldap_entry_2_hash {
 240         my $userldapentry = shift;
 241         my %borrower = ( cardnumber => shift );
 242         my %memberhash;
 243         $userldapentry->exists('uid');  # This is bad, but required!  By side-effect, this initializes the attrs hash.
 244         if ($debug) {
 245                 foreach (keys %$userldapentry) {
 246                         print STDERR "\n\nLDAP key: $_\t", sprintf('(%s)', ref $userldapentry->{$_}), "\n";
 247                 }
 248         }
 249         my $x = $userldapentry->{attrs} or return;
 250         foreach (keys %$x) {
 251                 $memberhash{$_} = join ' ', @{$x->{$_}};
 252                 $debug and print STDERR sprintf("building \$memberhash{%s} = ", $_, join(' ', @{$x->{$_}})), "\n";
 253         }
 254         $debug and print STDERR "Finsihed \%memberhash has ", scalar(keys %memberhash), " keys\n",
 255                                         "Referencing \%mapping with ", scalar(keys %mapping), " keys\n";
 256         foreach my $key (keys %mapping) {
 257                 my  $data = $memberhash{ lc($mapping{$key}->{is}) }; # Net::LDAP returns all names in lowercase
 258                 $debug and printf STDERR "mapping %20s ==> %-20s (%s)\n", $key, $mapping{$key}->{is}, $data;
 259                 unless (defined $data) {
 260                         $data = $mapping{$key}->{content} || '';        # default or failsafe ''
 261                 }
 262                 $borrower{$key} = ($data ne '') ? $data : ' ' ;
 263         }
 264         $borrower{initials} = $memberhash{initials} ||
 265                 ( substr($borrower{'firstname'},0,1)
 266                 . substr($borrower{ 'surname' },0,1)
 267                 . " ");
 268
 269     # categorycode conversions
 270     if(defined $categorycode_conversions{$borrower{categorycode}}) {
 271         $borrower{categorycode} = $categorycode_conversions{$borrower{categorycode}};
 272     }
 273     elsif($default_categorycode) {
 274         $borrower{categorycode} = $default_categorycode;
 275     }
 276
 277         # check if categorycode exists, if not, fallback to default from koha-conf.xml
 278         my $dbh = C4::Context->dbh;
 279         my $sth = $dbh->prepare("SELECT categorycode FROM categories WHERE categorycode = ?");
 280         $sth->execute( uc($borrower{'categorycode'}) );
 281         unless ( my $row = $sth->fetchrow_hashref ) {
 282                 my $default = $mapping{'categorycode'}->{content};
 283                 $debug && warn "Can't find ", $borrower{'categorycode'}, " default to: $default for ", $borrower{userid};
 284                 $borrower{'categorycode'} = $default
 285         }
 286
 287         return %borrower;
 288 }
 289
 290 sub exists_local {
 291         my $arg = shift;
 292         my $dbh = C4::Context->dbh;
 293         my $select = "SELECT borrowernumber,cardnumber,userid,password FROM borrowers ";
 294
 295         my $sth = $dbh->prepare("$select WHERE userid=?");      # was cardnumber=?
 296         $sth->execute($arg);
 297         $debug and printf STDERR "Userid '$arg' exists_local? %s\n", $sth->rows;
 298         ($sth->rows == 1) and return $sth->fetchrow;
 299
 300         $sth = $dbh->prepare("$select WHERE cardnumber=?");
 301         $sth->execute($arg);
 302         $debug and printf STDERR "Cardnumber '$arg' exists_local? %s\n", $sth->rows;
 303         ($sth->rows == 1) and return $sth->fetchrow;
 304         return 0;
 305 }
 306
 307 # This function performs a password update, given the userid, borrowerid,
 308 # and digested password. It will verify that things are correct and return the
 309 # borrowers cardnumber. The idea is that it is used to keep the local
 310 # passwords in sync with the LDAP passwords.
 311 #
 312 #   $cardnum = _do_changepassword($userid, $borrowerid, $digest)
 313 #
 314 # Note: if the LDAP config has the update_password tag set to a false value,
 315 # then this will not update the password, it will simply return the cardnumber.
 316 sub _do_changepassword {
 317     my ($userid, $borrowerid, $password) = @_;
 318
 319     if ( exists( $ldap->{update_password} ) && !$ldap->{update_password} ) {
 320
 321         # We don't store the password in the database
 322         my $sth = C4::Context->dbh->prepare(
 323             'SELECT cardnumber FROM borrowers WHERE borrowernumber=?');
 324         $sth->execute($borrowerid);
 325         die "Unable to access borrowernumber "
 326             . "with userid=$userid, "
 327             . "borrowernumber=$borrowerid"
 328           if !$sth->rows;
 329         my ($cardnum) = $sth->fetchrow;
 330         $sth = C4::Context->dbh->prepare(
 331             'UPDATE borrowers SET password = null WHERE borrowernumber=?');
 332         $sth->execute($borrowerid);
 333         return $cardnum;
 334     }
 335     my $digest = hash_password($password);
 336
 337     $debug and print STDERR "changing local password for borrowernumber=$borrowerid to '$digest'\n";
 338     Koha::Patrons->find($borrowerid)->update_password( $userid, $digest );
 339
 340     my ($ok, $cardnum) = checkpw_internal(C4::Context->dbh, $userid, $password);
 341     return $cardnum if $ok;
 342
 343     warn "Password mismatch after update to borrowernumber=$borrowerid";
 344     return;
 345 }
 346
 347 sub update_local {
 348     my $userid     = shift or croak "No userid";
 349     my $password   = shift or croak "No password";
 350     my $borrowerid = shift or croak "No borrowerid";
 351     my $borrower   = shift or croak "No borrower record";
 352
 353     my @keys = keys %$borrower;
 354     my $dbh = C4::Context->dbh;
 355     my $query = "UPDATE  borrowers\nSET     " .
 356         join(',', map {"$_=?"} @keys) .
 357         "\nWHERE   borrowernumber=? ";
 358     my $sth = $dbh->prepare($query);
 359     if ($debug) {
 360         print STDERR $query, "\n",
 361             join "\n", map {"$_ = '" . $borrower->{$_} . "'"} @keys;
 362         print STDERR "\nuserid = $userid\n";
 363     }
 364     $sth->execute(
 365         ((map {$borrower->{$_}} @keys), $borrowerid)
 366     );
 367
 368     # MODIFY PASSWORD/LOGIN if password was mapped
 369     _do_changepassword($userid, $borrowerid, $password) if $borrower->{'password'};
 370 }
 371
 372 1;
 373 __END__
 374
 375 =head1 NAME
 376
 377 C4::Auth - Authenticates Koha users
 378
 379 =head1 SYNOPSIS
 380
 381   use C4::Auth_with_ldap;
 382
 383 =head1 LDAP Configuration
 384
 385     This module is specific to LDAP authentification. It requires Net::LDAP package and one or more
 386         working LDAP servers.
 387         To use it :
 388            * Modify ldapserver element in KOHA_CONF
 389            * Establish field mapping in <mapping> element.
 390
 391         For example, if your user records are stored according to the inetOrgPerson schema, RFC#2798,
 392         the username would match the "uid" field, and the password should match the "userpassword" field.
 393
 394         Make sure that ALL required fields are populated by your LDAP database (and mapped in KOHA_CONF).
 395         What are the required fields?  Well, in mysql you can check the database table "borrowers" like this:
 396
 397         mysql> show COLUMNS from borrowers;
 398                 +---------------------+--------------+------+-----+---------+----------------+
 399                 | Field               | Type         | Null | Key | Default | Extra          |
 400                 +---------------------+--------------+------+-----+---------+----------------+
 401                 | borrowernumber      | int(11)      | NO   | PRI | NULL    | auto_increment |
 402                 | cardnumber          | varchar(16)  | YES  | UNI | NULL    |                |
 403                 | surname             | mediumtext   | NO   |     | NULL    |                |
 404                 | firstname           | text         | YES  |     | NULL    |                |
 405                 | title               | mediumtext   | YES  |     | NULL    |                |
 406                 | othernames          | mediumtext   | YES  |     | NULL    |                |
 407                 | initials            | text         | YES  |     | NULL    |                |
 408                 | streetnumber        | varchar(10)  | YES  |     | NULL    |                |
 409                 | streettype          | varchar(50)  | YES  |     | NULL    |                |
 410                 | address             | mediumtext   | NO   |     | NULL    |                |
 411                 | address2            | text         | YES  |     | NULL    |                |
 412                 | city                | mediumtext   | NO   |     | NULL    |                |
 413                 | state               | mediumtext   | YES  |     | NULL    |                |
 414                 | zipcode             | varchar(25)  | YES  |     | NULL    |                |
 415                 | country             | text         | YES  |     | NULL    |                |
 416                 | email               | mediumtext   | YES  |     | NULL    |                |
 417                 | phone               | text         | YES  |     | NULL    |                |
 418                 | mobile              | varchar(50)  | YES  |     | NULL    |                |
 419                 | fax                 | mediumtext   | YES  |     | NULL    |                |
 420                 | emailpro            | text         | YES  |     | NULL    |                |
 421                 | phonepro            | text         | YES  |     | NULL    |                |
 422                 | B_streetnumber      | varchar(10)  | YES  |     | NULL    |                |
 423                 | B_streettype        | varchar(50)  | YES  |     | NULL    |                |
 424                 | B_address           | varchar(100) | YES  |     | NULL    |                |
 425                 | B_address2          | text         | YES  |     | NULL    |                |
 426                 | B_city              | mediumtext   | YES  |     | NULL    |                |
 427                 | B_state             | mediumtext   | YES  |     | NULL    |                |
 428                 | B_zipcode           | varchar(25)  | YES  |     | NULL    |                |
 429                 | B_country           | text         | YES  |     | NULL    |                |
 430                 | B_email             | text         | YES  |     | NULL    |                |
 431                 | B_phone             | mediumtext   | YES  |     | NULL    |                |
 432                 | dateofbirth         | date         | YES  |     | NULL    |                |
 433                 | branchcode          | varchar(10)  | NO   | MUL |         |                |
 434                 | categorycode        | varchar(10)  | NO   | MUL |         |                |
 435                 | dateenrolled        | date         | YES  |     | NULL    |                |
 436                 | dateexpiry          | date         | YES  |     | NULL    |                |
 437                 | gonenoaddress       | tinyint(1)   | YES  |     | NULL    |                |
 438                 | lost                | tinyint(1)   | YES  |     | NULL    |                |
 439                 | debarred            | date         | YES  |     | NULL    |                |
 440                 | debarredcomment     | varchar(255) | YES  |     | NULL    |                |
 441                 | contactname         | mediumtext   | YES  |     | NULL    |                |
 442                 | contactfirstname    | text         | YES  |     | NULL    |                |
 443                 | contacttitle        | text         | YES  |     | NULL    |                |
 444                 | guarantorid         | int(11)      | YES  | MUL | NULL    |                |
 445                 | borrowernotes       | mediumtext   | YES  |     | NULL    |                |
 446                 | relationship        | varchar(100) | YES  |     | NULL    |                |
 447                 | ethnicity           | varchar(50)  | YES  |     | NULL    |                |
 448                 | ethnotes            | varchar(255) | YES  |     | NULL    |                |
 449                 | sex                 | varchar(1)   | YES  |     | NULL    |                |
 450                 | password            | varchar(30)  | YES  |     | NULL    |                |
 451                 | flags               | int(11)      | YES  |     | NULL    |                |
 452                 | userid              | varchar(30)  | YES  | MUL | NULL    |                |
 453                 | opacnote            | mediumtext   | YES  |     | NULL    |                |
 454                 | contactnote         | varchar(255) | YES  |     | NULL    |                |
 455                 | sort1               | varchar(80)  | YES  |     | NULL    |                |
 456                 | sort2               | varchar(80)  | YES  |     | NULL    |                |
 457                 | altcontactfirstname | varchar(255) | YES  |     | NULL    |                |
 458                 | altcontactsurname   | varchar(255) | YES  |     | NULL    |                |
 459                 | altcontactaddress1  | varchar(255) | YES  |     | NULL    |                |
 460                 | altcontactaddress2  | varchar(255) | YES  |     | NULL    |                |
 461                 | altcontactaddress3  | varchar(255) | YES  |     | NULL    |                |
 462                 | altcontactstate     | mediumtext   | YES  |     | NULL    |                |
 463                 | altcontactzipcode   | varchar(50)  | YES  |     | NULL    |                |
 464                 | altcontactcountry   | text         | YES  |     | NULL    |                |
 465                 | altcontactphone     | varchar(50)  | YES  |     | NULL    |                |
 466                 | smsalertnumber      | varchar(50)  | YES  |     | NULL    |                |
 467                 | privacy             | int(11)      | NO   |     | 1       |                |
 468                 +---------------------+--------------+------+-----+---------+----------------+
 469                 66 rows in set (0.00 sec)
 470                 Where Null="NO", the field is required.
 471
 472 =head1 KOHA_CONF and field mapping
 473
 474 Example XML stanza for LDAP configuration in KOHA_CONF.
 475
 476  <config>
 477   ...
 478   <useldapserver>1</useldapserver>
 479   <!-- LDAP SERVER (optional) -->
 480   <ldapserver id="ldapserver">
 481     <hostname>localhost</hostname>
 482     <base>dc=metavore,dc=com</base>
 483     <user>cn=Manager,dc=metavore,dc=com</user>             <!-- DN, if not anonymous -->
 484     <pass>metavore</pass>          <!-- password, if not anonymous -->
 485     <replicate>1</replicate>       <!-- add new users from LDAP to Koha database -->
 486     <update>1</update>             <!-- update existing users in Koha database -->
 487     <auth_by_bind>0</auth_by_bind> <!-- set to 1 to authenticate by binding instead of
 488                                         password comparison, e.g., to use Active Directory -->
 489     <anonymous_bind>0</anonymous_bind> <!-- set to 1 if users should be searched using
 490                                             an anonymous bind, even when auth_by_bind is on -->
 491     <principal_name>%s@my_domain.com</principal_name>
 492                                    <!-- optional, for auth_by_bind: a printf format to make userPrincipalName from koha userid.
 493                                         Not used with anonymous_bind. -->
 494     <update_password>1</update_password> <!-- set to 0 if you don't want LDAP passwords
 495                                               synced to the local database -->
 496     <mapping>                  <!-- match koha SQL field names to your LDAP record field names -->
 497       <firstname    is="givenname"      ></firstname>
 498       <surname      is="sn"             ></surname>
 499       <address      is="postaladdress"  ></address>
 500       <city         is="l"              >Athens, OH</city>
 501       <zipcode      is="postalcode"     ></zipcode>
 502       <branchcode   is="branch"         >MAIN</branchcode>
 503       <userid       is="uid"            ></userid>
 504       <password     is="userpassword"   ></password>
 505       <email        is="mail"           ></email>
 506       <categorycode is="employeetype"   >PT</categorycode>
 507       <phone        is="telephonenumber"></phone>
 508     </mapping>
 509   </ldapserver>
 510  </config>
 511
 512 The <mapping> subelements establish the relationship between mysql fields and LDAP attributes. The element name
 513 is the column in mysql, with the "is" characteristic set to the LDAP attribute name.  Optionally, any content
 514 between the element tags is taken as the default value.  In this example, the default categorycode is "PT" (for
 515 patron).
 516
 517 =head1 CONFIGURATION
 518
 519 Once a user has been accepted by the LDAP server, there are several possibilities for how Koha will behave, depending on
 520 your configuration and the presence of a matching Koha user in your local DB:
 521
 522                          LOCAL_USER
 523  OPTION UPDATE REPLICATE  EXISTS?  RESULT
 524    A1      1       1        1      OK : We're updating them anyway.
 525    A2      1       1        0      OK : We're adding them anyway.
 526    B1      1       0        1      OK : We update them.
 527    B2      1       0        0     FAIL: We cannot add new user.
 528    C1      0       1        1      OK : We do nothing.  (maybe should update password?)
 529    C2      0       1        0      OK : We add the new user.
 530    D1      0       0        1      OK : We do nothing.  (maybe should update password?)
 531    D2      0       0        0     FAIL: We cannot add new user.
 532
 533 Note: failure here just means that Koha will fallback to checking the local DB.  That is, a given user could login with
 534 their LDAP password OR their local one.  If this is a problem, then you should enable update and supply a mapping for
 535 password.  Then the local value will be updated at successful LDAP login and the passwords will be synced.
 536
 537 If you choose NOT to update local users, the borrowers table will not be affected at all.
 538 Note that this means that patron passwords may appear to change if LDAP is ever disabled, because
 539 the local table never contained the LDAP values.
 540
 541 =head2 auth_by_bind
 542
 543 Binds as the user instead of retrieving their record.  Recommended if update disabled.
 544
 545 =head2 principal_name
 546
 547 Provides an optional sprintf-style format for manipulating the userid before the bind.
 548 Even though the userPrincipalName is one intended target, any uniquely identifying
 549 attribute that the server allows to be used for binding could be used.
 550
 551 Currently, principal_name only operates when auth_by_bind is enabled.
 552
 553 =head2 update_password
 554
 555 If this tag is left out or set to a true value, then the user's LDAP password
 556 will be stored (hashed) in the local Koha database. If you don't want this
 557 to happen, then set the value of this to '0'. Note that if passwords are not
 558 stored locally, and the connection to the LDAP system fails, then the users
 559 will not be able to log in at all.
 560
 561 =head2 Active Directory
 562
 563 The auth_by_bind and principal_name settings are recommended for Active Directory.
 564
 565 Under default Active Directory rules, we cannot determine the distinguishedName attribute from the Koha userid as reliably as
 566 we would typically under openldap.  Instead of:
 567
 568     distinguishedName: CN=barnes.7,DC=my_company,DC=com
 569
 570 We might get:
 571
 572     distinguishedName: CN=Barnes\, Jim,OU=Test Accounts,OU=User Accounts,DC=my_company,DC=com
 573
 574 Matching that would require us to know more info about the account (firstname, surname) and to include punctuation and whitespace
 575 in Koha userids.  But the userPrincipalName should be consistent, something like:
 576
 577     userPrincipalName: barnes.7@my_company.com
 578
 579 Therefore it is often easier to bind to Active Directory with userPrincipalName, effectively the
 580 canonical email address for that user, or what it would be if email were enabled for them.  If Koha userid values
 581 will match the username portion of the userPrincipalName, and the domain suffix is the same for all users, then use principal_name
 582 like this:
 583     <principal_name>%s@core.my_company.com</principal_name>
 584
 585 The user of the previous example, barnes.7, would then attempt to bind as:
 586     barnes.7@core.my_company.com
 587
 588 =head1 SEE ALSO
 589
 590 CGI(3)
 591
 592 Net::LDAP()
 593
 594 XML::Simple()
 595
 596 Digest::MD5(3)
 597
 598 sprintf()
 599
 600 =cut
 601
 602 # For reference, here's an important difference in the data structure we rely on.
 603 # ========================================
 604 # Using attrs instead of {asn}->attributes
 605 # ========================================
 606 #
 607 #       LDAP key: ->{             cn} = ARRAY w/ 3 members.
 608 #       LDAP key: ->{             cn}->{           sss} = sss
 609 #       LDAP key: ->{             cn}->{   Steve Smith} = Steve Smith
 610 #       LDAP key: ->{             cn}->{Steve S. Smith} = Steve S. Smith
 611 #
 612 #       LDAP key: ->{      givenname} = ARRAY w/ 1 members.
 613 #       LDAP key: ->{      givenname}->{Steve} = Steve
 614 #