t/db_dependent/Acquisition.t

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17
  18 use Modern::Perl;
  19
  20 use POSIX qw(strftime);
  21
  22 use Test::More tests => 68;
  23 use t::lib::Mocks;
  24 use Koha::Database;
  25
  26 use MARC::File::XML ( BinaryEncoding => 'utf8', RecordFormat => 'MARC21' );
  27
  28 BEGIN {
  29     use_ok('C4::Acquisition');
  30     use_ok('C4::Biblio');
  31     use_ok('C4::Budgets');
  32     use_ok('Koha::Acquisition::Orders');
  33     use_ok('Koha::Acquisition::Booksellers');
  34 }
  35
  36 # Sub used for testing C4::Acquisition subs returning order(s):
  37 #    GetOrdersByStatus, GetOrders, GetDeletedOrders, GetOrder etc.
  38 # (\@test_missing_fields,\@test_extra_fields,\@test_different_fields,$test_nbr_fields) =
  39 #  _check_fields_of_order ($exp_fields, $original_order_content, $order_to_check);
  40 # params :
  41 # $exp_fields             : arrayref whose elements are the keys we expect to find
  42 # $original_order_content : hashref whose 2 keys str and num contains hashrefs
  43 #                           containing content fields of the order created with Koha::Acquisition::Order
  44 # $order_to_check         : hashref whose keys/values are the content of an order
  45 #                           returned by the C4::Acquisition sub we are testing
  46 # returns :
  47 # \@test_missing_fields   : arrayref void if ok ; otherwise contains the list of
  48 #                           fields missing in $order_to_check
  49 # \@test_extra_fields     : arrayref void if ok ; otherwise contains the list of
  50 #                           fields unexpected in $order_to_check
  51 # \@test_different_fields : arrayref void if ok ; otherwise contains the list of
  52 #                           fields which value is not the same in between $order_to_check and
  53 # $test_nbr_fields        : contains the number of fields of $order_to_check
  54
  55 sub _check_fields_of_order {
  56     my ( $exp_fields, $original_order_content, $order_to_check ) = @_;
  57     my @test_missing_fields   = ();
  58     my @test_extra_fields     = ();
  59     my @test_different_fields = ();
  60     my $test_nbr_fields       = scalar( keys %$order_to_check );
  61     foreach my $field (@$exp_fields) {
  62         push @test_missing_fields, $field
  63           unless exists( $order_to_check->{$field} );
  64     }
  65     foreach my $field ( keys %$order_to_check ) {
  66         push @test_extra_fields, $field
  67           unless grep ( /^$field$/, @$exp_fields );
  68     }
  69     foreach my $field ( keys %{ $original_order_content->{str} } ) {
  70         push @test_different_fields, $field
  71           unless ( !exists $order_to_check->{$field} )
  72           or ( $original_order_content->{str}->{$field} eq
  73             $order_to_check->{$field} );
  74     }
  75     foreach my $field ( keys %{ $original_order_content->{num} } ) {
  76         push @test_different_fields, $field
  77           unless ( !exists $order_to_check->{$field} )
  78           or ( $original_order_content->{num}->{$field} ==
  79             $order_to_check->{$field} );
  80     }
  81     return (
  82         \@test_missing_fields,   \@test_extra_fields,
  83         \@test_different_fields, $test_nbr_fields
  84     );
  85 }
  86
  87 # Sub used for testing C4::Acquisition subs returning several orders
  88 # (\@test_missing_fields,\@test_extra_fields,\@test_different_fields,\@test_nbr_fields) =
  89 #   _check_fields_of_orders ($exp_fields, $original_orders_content, $orders_to_check)
  90 sub _check_fields_of_orders {
  91     my ( $exp_fields, $original_orders_content, $orders_to_check ) = @_;
  92     my @test_missing_fields   = ();
  93     my @test_extra_fields     = ();
  94     my @test_different_fields = ();
  95     my @test_nbr_fields       = ();
  96     foreach my $order_to_check (@$orders_to_check) {
  97         my $original_order_content =
  98           ( grep { $_->{str}->{ordernumber} eq $order_to_check->{ordernumber} }
  99               @$original_orders_content )[0];
 100         my (
 101             $t_missing_fields,   $t_extra_fields,
 102             $t_different_fields, $t_nbr_fields
 103           )
 104           = _check_fields_of_order( $exp_fields, $original_order_content,
 105             $order_to_check );
 106         push @test_missing_fields,   @$t_missing_fields;
 107         push @test_extra_fields,     @$t_extra_fields;
 108         push @test_different_fields, @$t_different_fields;
 109         push @test_nbr_fields,       $t_nbr_fields;
 110     }
 111     @test_missing_fields = keys %{ { map { $_ => 1 } @test_missing_fields } };
 112     @test_extra_fields   = keys %{ { map { $_ => 1 } @test_extra_fields } };
 113     @test_different_fields =
 114       keys %{ { map { $_ => 1 } @test_different_fields } };
 115     return (
 116         \@test_missing_fields,   \@test_extra_fields,
 117         \@test_different_fields, \@test_nbr_fields
 118     );
 119 }
 120
 121
 122 my $schema = Koha::Database->new()->schema();
 123 $schema->storage->txn_begin();
 124
 125 my $dbh = C4::Context->dbh;
 126 $dbh->{RaiseError} = 1;
 127
 128 # Creating some orders
 129 my $bookseller = Koha::Acquisition::Bookseller->new(
 130     {
 131         name         => "my vendor",
 132         address1     => "bookseller's address",
 133         phone        => "0123456",
 134         active       => 1,
 135         deliverytime => 5,
 136     }
 137 )->store;
 138 my $booksellerid = $bookseller->id;
 139
 140 my $booksellerinfo = Koha::Acquisition::Booksellers->find( $booksellerid );
 141 is( $booksellerinfo->deliverytime,
 142     5, 'set deliverytime when creating vendor (Bug 10556)' );
 143
 144 my ( $basket, $basketno );
 145 ok(
 146     $basketno = NewBasket( $booksellerid, 1 ),
 147     "NewBasket(  $booksellerid , 1  ) returns $basketno"
 148 );
 149 ok( $basket = GetBasket($basketno), "GetBasket($basketno) returns $basket" );
 150
 151 my $bpid=AddBudgetPeriod({
 152         budget_period_startdate => '2008-01-01'
 153         , budget_period_enddate => '2008-12-31'
 154         , budget_period_active  => 1
 155         , budget_period_description    => "MAPERI"
 156 });
 157
 158 my $budgetid = C4::Budgets::AddBudget(
 159     {
 160         budget_code => "budget_code_test_1",
 161         budget_name => "budget_name_test_1",
 162         budget_period_id => $bpid,
 163     }
 164 );
 165 my $budget = C4::Budgets::GetBudget($budgetid);
 166
 167 my @ordernumbers;
 168 my ( $biblionumber1, $biblioitemnumber1 ) = AddBiblio( MARC::Record->new, '' );
 169 my ( $biblionumber2, $biblioitemnumber2 ) = AddBiblio( MARC::Record->new, '' );
 170 my ( $biblionumber3, $biblioitemnumber3 ) = AddBiblio( MARC::Record->new, '' );
 171 my ( $biblionumber4, $biblioitemnumber4 ) = AddBiblio( MARC::Record->new, '' );
 172 my ( $biblionumber5, $biblioitemnumber5 ) = AddBiblio( MARC::Record->new, '' );
 173
 174
 175
 176 # Prepare 5 orders, and make distinction beween fields to be tested with eq and with ==
 177 # Ex : a price of 50.1 will be stored internally as 5.100000
 178
 179 my @order_content = (
 180     {
 181         str => {
 182             basketno       => $basketno,
 183             biblionumber   => $biblionumber1,
 184             budget_id      => $budget->{budget_id},
 185             uncertainprice => 0,
 186             order_internalnote => "internal note",
 187             order_vendornote   => "vendor note",
 188             ordernumber => '',
 189         },
 190         num => {
 191             quantity  => 24,
 192             listprice => 50.121111,
 193             ecost     => 38.15,
 194             rrp       => 40.15,
 195             discount  => 5.1111,
 196         }
 197     },
 198     {
 199         str => {
 200             basketno     => $basketno,
 201             biblionumber => $biblionumber2,
 202             budget_id    => $budget->{budget_id}
 203         },
 204         num => { quantity => 42 }
 205     },
 206     {
 207         str => {
 208             basketno       => $basketno,
 209             biblionumber   => $biblionumber2,
 210             budget_id      => $budget->{budget_id},
 211             uncertainprice => 0,
 212             order_internalnote => "internal note",
 213             order_vendornote   => "vendor note"
 214         },
 215         num => {
 216             quantity  => 4,
 217             ecost     => 42.1,
 218             rrp       => 42.1,
 219             listprice => 10.1,
 220             ecost     => 38.1,
 221             rrp       => 11.0,
 222             discount  => 5.1,
 223         }
 224     },
 225     {
 226         str => {
 227             basketno     => $basketno,
 228             biblionumber => $biblionumber3,
 229             budget_id    => $budget->{budget_id},
 230             order_internalnote => "internal note",
 231             order_vendornote   => "vendor note"
 232         },
 233         num => {
 234             quantity       => 4,
 235             ecost          => 40,
 236             rrp            => 42,
 237             listprice      => 10,
 238             ecost          => 38.15,
 239             rrp            => 11.00,
 240             discount       => 0,
 241             uncertainprice => 0,
 242         }
 243     },
 244     {
 245         str => {
 246             basketno     => $basketno,
 247             biblionumber => $biblionumber4,
 248             budget_id    => $budget->{budget_id},
 249             order_internalnote => "internal note",
 250             order_vendornote   => "vendor note"
 251         },
 252         num => {
 253             quantity       => 1,
 254             ecost          => 10,
 255             rrp            => 10,
 256             listprice      => 10,
 257             ecost          => 10,
 258             rrp            => 10,
 259             discount       => 0,
 260             uncertainprice => 0,
 261         }
 262     },
 263     {
 264         str => {
 265             basketno     => $basketno,
 266             biblionumber => $biblionumber5,
 267             budget_id    => $budget->{budget_id},
 268             order_internalnote => "internal note",
 269             order_vendornote   => "vendor note"
 270         },
 271         num => {
 272             quantity       => 1,
 273             ecost          => 10,
 274             rrp            => 10,
 275             listprice      => 10,
 276             ecost          => 10,
 277             rrp            => 10,
 278             discount       => 0,
 279             uncertainprice => 0,
 280         }
 281     }
 282 );
 283
 284 # Create 5 orders in database
 285 for ( 0 .. 5 ) {
 286     my %ocontent;
 287     @ocontent{ keys %{ $order_content[$_]->{num} } } =
 288       values %{ $order_content[$_]->{num} };
 289     @ocontent{ keys %{ $order_content[$_]->{str} } } =
 290       values %{ $order_content[$_]->{str} };
 291     $ordernumbers[$_] = Koha::Acquisition::Order->new( \%ocontent )->store->ordernumber;
 292     $order_content[$_]->{str}->{ordernumber} = $ordernumbers[$_];
 293 }
 294
 295 DelOrder( $order_content[3]->{str}->{biblionumber}, $ordernumbers[3] );
 296
 297 my $invoiceid = AddInvoice(
 298     invoicenumber => 'invoice',
 299     booksellerid  => $booksellerid,
 300     unknown       => "unknown"
 301 );
 302
 303 my $invoice = GetInvoice( $invoiceid );
 304
 305 my ($datereceived, $new_ordernumber) = ModReceiveOrder(
 306     {
 307         biblionumber      => $biblionumber4,
 308         order             => Koha::Acquisition::Orders->find( $ordernumbers[4] )->unblessed,
 309         quantityreceived  => 1,
 310         invoice           => $invoice,
 311         budget_id          => $order_content[4]->{str}->{budget_id},
 312     }
 313 );
 314
 315 my $search_orders = SearchOrders({
 316     booksellerid => $booksellerid,
 317     basketno     => $basketno
 318 });
 319 isa_ok( $search_orders, 'ARRAY' );
 320 ok(
 321     (
 322         ( scalar @$search_orders == 5 )
 323           and !grep ( $_->{ordernumber} eq $ordernumbers[3], @$search_orders )
 324     ),
 325     "SearchOrders only gets non-cancelled orders"
 326 );
 327
 328 $search_orders = SearchOrders({
 329     booksellerid => $booksellerid,
 330     basketno     => $basketno,
 331     pending      => 1
 332 });
 333 ok(
 334     (
 335         ( scalar @$search_orders == 4 ) and !grep ( (
 336                      ( $_->{ordernumber} eq $ordernumbers[3] )
 337                   or ( $_->{ordernumber} eq $ordernumbers[4] )
 338             ),
 339             @$search_orders )
 340     ),
 341     "SearchOrders with pending params gets only pending orders (bug 10723)"
 342 );
 343
 344 $search_orders = SearchOrders({
 345     booksellerid => $booksellerid,
 346     basketno     => $basketno,
 347     pending      => 1,
 348     ordered      => 1,
 349 });
 350 is( scalar (@$search_orders), 0, "SearchOrders with pending and ordered params gets only pending ordered orders (bug 11170)" );
 351
 352 $search_orders = SearchOrders({
 353     ordernumber => $ordernumbers[4]
 354 });
 355 is( scalar (@$search_orders), 1, "SearchOrders takes into account the ordernumber filter" );
 356
 357 $search_orders = SearchOrders({
 358     biblionumber => $biblionumber4
 359 });
 360 is( scalar (@$search_orders), 1, "SearchOrders takes into account the biblionumber filter" );
 361
 362 $search_orders = SearchOrders({
 363     biblionumber => $biblionumber4,
 364     pending      => 1
 365 });
 366 is( scalar (@$search_orders), 0, "SearchOrders takes into account the biblionumber and pending filters" );
 367
 368 #
 369 # Test GetBudgetByOrderNumber
 370 #
 371 ok( GetBudgetByOrderNumber( $ordernumbers[0] )->{'budget_id'} eq $budgetid,
 372     "GetBudgetByOrderNumber returns expected budget" );
 373
 374 my @lateorders = GetLateOrders(0);
 375 is( scalar grep ( $_->{basketno} eq $basketno, @lateorders ),
 376     0, "GetLateOrders does not get orders from opened baskets" );
 377 C4::Acquisition::CloseBasket($basketno);
 378 @lateorders = GetLateOrders(0);
 379 isnt( scalar grep ( $_->{basketno} eq $basketno, @lateorders ),
 380     0, "GetLateOrders gets orders from closed baskets" );
 381 ok( !grep ( $_->{ordernumber} eq $ordernumbers[3], @lateorders ),
 382     "GetLateOrders does not get cancelled orders" );
 383 ok( !grep ( $_->{ordernumber} eq $ordernumbers[4], @lateorders ),
 384     "GetLateOrders does not get received orders" );
 385
 386 $search_orders = SearchOrders({
 387     booksellerid => $booksellerid,
 388     basketno     => $basketno,
 389     pending      => 1,
 390     ordered      => 1,
 391 });
 392 is( scalar (@$search_orders), 4, "SearchOrders with pending and ordered params gets only pending ordered orders. After closing the basket, orders are marked as 'ordered' (bug 11170)" );
 393
 394 #
 395 # Test AddClaim
 396 #
 397
 398 my $order = $lateorders[0];
 399 AddClaim( $order->{ordernumber} );
 400 my $neworder = GetOrder( $order->{ordernumber} );
 401 is(
 402     $neworder->{claimed_date},
 403     strftime( "%Y-%m-%d", localtime(time) ),
 404     "AddClaim : Check claimed_date"
 405 );
 406
 407 my $order2 = Koha::Acquisition::Orders->find( $ordernumbers[1] )->unblessed;
 408 $order2->{order_internalnote} = "my notes";
 409 ( $datereceived, $new_ordernumber ) = ModReceiveOrder(
 410     {
 411         biblionumber     => $biblionumber2,
 412         order            => $order2,
 413         quantityreceived => 2,
 414         invoice          => $invoice,
 415     }
 416 )
 417 ;
 418 $order2 = GetOrder( $ordernumbers[1] );
 419 is( $order2->{'quantityreceived'},
 420     0, 'Splitting up order did not receive any on original order' );
 421 is( $order2->{'quantity'}, 40, '40 items on original order' );
 422 is( $order2->{'budget_id'}, $budgetid,
 423     'Budget on original order is unchanged' );
 424 is( $order2->{order_internalnote}, "my notes",
 425     'ModReceiveOrder and GetOrder deal with internal notes' );
 426
 427 $neworder = GetOrder($new_ordernumber);
 428 is( $neworder->{'quantity'}, 2, '2 items on new order' );
 429 is( $neworder->{'quantityreceived'},
 430     2, 'Splitting up order received items on new order' );
 431 is( $neworder->{'budget_id'}, $budgetid, 'Budget on new order is unchanged' );
 432
 433 is( $neworder->{ordernumber}, $new_ordernumber, 'Split: test ordernumber' );
 434 is( $neworder->{parent_ordernumber}, $ordernumbers[1], 'Split: test parent_ordernumber' );
 435
 436 my $orders = GetHistory( ordernumber => $ordernumbers[1] );
 437 is( scalar( @$orders ), 1, 'GetHistory with a given ordernumber returns 1 order' );
 438 $orders = GetHistory( ordernumber => $ordernumbers[1], search_children_too => 1 );
 439 is( scalar( @$orders ), 2, 'GetHistory with a given ordernumber and search_children_too set returns 2 orders' );
 440
 441 # Test GetHistory() with and without SearchWithISBNVariations
 442 # The ISBN passed as a param is the ISBN-10 version of the 13-digit ISBN in the sample record declared in $marcxml
 443
 444 my $budgetid2 = C4::Budgets::AddBudget(
 445     {
 446         budget_code => "budget_code_test_modrecv",
 447         budget_name => "budget_name_test_modrecv",
 448     }
 449 );
 450
 451 my $order3 = Koha::Acquisition::Orders->find( $ordernumbers[2] )->unblessed;
 452 $order3->{order_internalnote} = "my other notes";
 453 ( $datereceived, $new_ordernumber ) = ModReceiveOrder(
 454     {
 455         biblionumber     => $biblionumber2,
 456         order            => $order3,
 457         quantityreceived => 2,
 458         invoice          => $invoice,
 459         budget_id        => $budgetid2,
 460     }
 461 );
 462
 463 $order3 = GetOrder( $ordernumbers[2] );
 464 is( $order3->{'quantityreceived'},
 465     0, 'Splitting up order did not receive any on original order' );
 466 is( $order3->{'quantity'}, 2, '2 items on original order' );
 467 is( $order3->{'budget_id'}, $budgetid,
 468     'Budget on original order is unchanged' );
 469 is( $order3->{order_internalnote}, "my other notes",
 470     'ModReceiveOrder and GetOrder deal with notes' );
 471
 472 $neworder = GetOrder($new_ordernumber);
 473 is( $neworder->{'quantity'}, 2, '2 items on new order' );
 474 is( $neworder->{'quantityreceived'},
 475     2, 'Splitting up order received items on new order' );
 476 is( $neworder->{'budget_id'}, $budgetid2, 'Budget on new order is changed' );
 477
 478 $order3 = Koha::Acquisition::Orders->find( $ordernumbers[2] )->unblessed;
 479 $order3->{order_internalnote} = "my third notes";
 480 ( $datereceived, $new_ordernumber ) = ModReceiveOrder(
 481     {
 482         biblionumber     => $biblionumber2,
 483         order            => $order3,
 484         quantityreceived => 2,
 485         invoice          => $invoice,
 486         budget_id        => $budgetid2,
 487     }
 488 );
 489
 490 $order3 = GetOrder( $ordernumbers[2] );
 491 is( $order3->{'quantityreceived'}, 2,          'Order not split up' );
 492 is( $order3->{'quantity'},         2,          '2 items on order' );
 493 is( $order3->{'budget_id'},        $budgetid2, 'Budget has changed' );
 494 is( $order3->{order_internalnote}, "my third notes", 'ModReceiveOrder and GetOrder deal with notes' );
 495
 496 my $nonexistent_order = GetOrder();
 497 is( $nonexistent_order, undef, 'GetOrder returns undef if no ordernumber is given' );
 498 $nonexistent_order = GetOrder( 424242424242 );
 499 is( $nonexistent_order, undef, 'GetOrder returns undef if a nonexistent ordernumber is given' );
 500
 501 # Tests for DelOrder
 502 my $order1 = GetOrder($ordernumbers[0]);
 503 my $error = DelOrder($order1->{biblionumber}, $order1->{ordernumber});
 504 ok((not defined $error), "DelOrder does not fail");
 505 $order1 = GetOrder($order1->{ordernumber});
 506 ok((defined $order1->{datecancellationprinted}), "order is cancelled");
 507 ok((not defined $order1->{cancellationreason}), "order has no cancellation reason");
 508 ok((defined Koha::Biblios->find( $order1->{biblionumber} )), "biblio still exists");
 509
 510 $order2 = GetOrder($ordernumbers[1]);
 511 $error = DelOrder($order2->{biblionumber}, $order2->{ordernumber}, 1);
 512 ok((not defined $error), "DelOrder does not fail");
 513 $order2 = GetOrder($order2->{ordernumber});
 514 ok((defined $order2->{datecancellationprinted}), "order is cancelled");
 515 ok((not defined $order2->{cancellationreason}), "order has no cancellation reason");
 516 ok((not defined Koha::Biblios->find( $order2->{biblionumber} )), "biblio does not exist anymore");
 517
 518 my $order4 = GetOrder($ordernumbers[3]);
 519 $error = DelOrder($order4->{biblionumber}, $order4->{ordernumber}, 1, "foobar");
 520 ok((not defined $error), "DelOrder does not fail");
 521 $order4 = GetOrder($order4->{ordernumber});
 522 ok((defined $order4->{datecancellationprinted}), "order is cancelled");
 523 ok(($order4->{cancellationreason} eq "foobar"), "order has cancellation reason \"foobar\"");
 524 ok((not defined Koha::Biblios->find( $order4->{biblionumber} )), "biblio does not exist anymore");
 525
 526 my $order5 = GetOrder($ordernumbers[4]);
 527 C4::Items::AddItem( { barcode => '0102030405' }, $order5->{biblionumber} );
 528 $error = DelOrder($order5->{biblionumber}, $order5->{ordernumber}, 1);
 529 $order5 = GetOrder($order5->{ordernumber});
 530 ok((defined $order5->{datecancellationprinted}), "order is cancelled");
 531 ok((defined Koha::Biblios->find( $order5->{biblionumber} )), "biblio still exists");
 532
 533 # End of tests for DelOrder
 534
 535 subtest 'ModOrder' => sub {
 536     plan tests => 1;
 537     ModOrder( { ordernumber => $order1->{ordernumber}, unitprice => 42 } );
 538     my $order = GetOrder( $order1->{ordernumber} );
 539     is( int($order->{unitprice}), 42, 'ModOrder should work even if biblionumber if not passed');
 540 };
 541
 542 # Budget reports
 543 my $all_count = scalar GetBudgetsReport();
 544 ok($all_count >= 1, "GetBudgetReport OK");
 545
 546 my $active_count = scalar GetBudgetsReport(1);
 547 ok($active_count >= 1 , "GetBudgetsReport(1) OK");
 548
 549 is($all_count, scalar GetBudgetsReport(), "GetBudgetReport returns inactive budget period acquisitions.");
 550 ok($active_count >= scalar GetBudgetsReport(1), "GetBudgetReport doesn't return inactive budget period acquisitions.");
 551
 552 # "Flavoured" tests (tests that required a run for each marc flavour)
 553 # Tests should be added to the run_flavoured_tests sub below
 554 my $biblio_module = new Test::MockModule('C4::Biblio');
 555 $biblio_module->mock(
 556     'GetMarcSubfieldStructure',
 557     sub {
 558         my ($self) = shift;
 559
 560         my ( $title_field,            $title_subfield )            = get_title_field();
 561         my ( $isbn_field,             $isbn_subfield )             = get_isbn_field();
 562         my ( $issn_field,             $issn_subfield )             = get_issn_field();
 563         my ( $biblionumber_field,     $biblionumber_subfield )     = ( '999', 'c' );
 564         my ( $biblioitemnumber_field, $biblioitemnumber_subfield ) = ( '999', '9' );
 565         my ( $itemnumber_field,       $itemnumber_subfield )       = get_itemnumber_field();
 566
 567         return {
 568             'biblio.title'                 => [ { tagfield => $title_field,            tagsubfield => $title_subfield } ],
 569             'biblio.biblionumber'          => [ { tagfield => $biblionumber_field,     tagsubfield => $biblionumber_subfield } ],
 570             'biblioitems.isbn'             => [ { tagfield => $isbn_field,             tagsubfield => $isbn_subfield } ],
 571             'biblioitems.issn'             => [ { tagfield => $issn_field,             tagsubfield => $issn_subfield } ],
 572             'biblioitems.biblioitemnumber' => [ { tagfield => $biblioitemnumber_field, tagsubfield => $biblioitemnumber_subfield } ],
 573             'items.itemnumber'             => [ { tagfield => $itemnumber_subfield,    tagsubfield => $itemnumber_subfield } ],
 574         };
 575       }
 576 );
 577
 578 sub run_flavoured_tests {
 579     my $marcflavour = shift;
 580     t::lib::Mocks::mock_preference('marcflavour', $marcflavour);
 581
 582     #
 583     # Test SearchWithISBNVariations syspref
 584     #
 585     my $marc_record = MARC::Record->new;
 586     $marc_record->append_fields( create_isbn_field( '9780136019701', $marcflavour ) );
 587     my ( $biblionumber6, $biblioitemnumber6 ) = AddBiblio( $marc_record, '' );
 588
 589     # Create order
 590     my $ordernumber = Koha::Acquisition::Order->new( {
 591             basketno     => $basketno,
 592             biblionumber => $biblionumber6,
 593             budget_id    => $budget->{budget_id},
 594             order_internalnote => "internal note",
 595             order_vendornote   => "vendor note",
 596             quantity       => 1,
 597             ecost          => 10,
 598             rrp            => 10,
 599             listprice      => 10,
 600             ecost          => 10,
 601             rrp            => 10,
 602             discount       => 0,
 603             uncertainprice => 0,
 604     } )->store->ordernumber;
 605
 606     t::lib::Mocks::mock_preference('SearchWithISBNVariations', 0);
 607     $orders = GetHistory( isbn => '0136019706' );
 608     is( scalar(@$orders), 0, "GetHistory searches correctly by ISBN" );
 609
 610     t::lib::Mocks::mock_preference('SearchWithISBNVariations', 1);
 611     $orders = GetHistory( isbn => '0136019706' );
 612     is( scalar(@$orders), 1, "GetHistory searches correctly by ISBN" );
 613
 614     my $order = GetOrder($ordernumber);
 615     DelOrder($order->{biblionumber}, $order->{ordernumber}, 1);
 616 }
 617
 618 # Do "flavoured" tests
 619 subtest 'MARC21' => sub {
 620     plan tests => 2;
 621     run_flavoured_tests('MARC21');
 622 };
 623
 624 subtest 'UNIMARC' => sub {
 625     plan tests => 2;
 626     run_flavoured_tests('UNIMARC');
 627 };
 628
 629 subtest 'NORMARC' => sub {
 630     plan tests => 2;
 631     run_flavoured_tests('NORMARC');
 632 };
 633
 634 ### Functions required for "flavoured" tests
 635 sub get_title_field {
 636     my $marc_flavour = C4::Context->preference('marcflavour');
 637     return ( $marc_flavour eq 'UNIMARC' ) ? ( '200', 'a' ) : ( '245', 'a' );
 638 }
 639
 640 sub get_isbn_field {
 641     my $marc_flavour = C4::Context->preference('marcflavour');
 642     return ( $marc_flavour eq 'UNIMARC' ) ? ( '010', 'a' ) : ( '020', 'a' );
 643 }
 644
 645 sub get_issn_field {
 646     my $marc_flavour = C4::Context->preference('marcflavour');
 647     return ( $marc_flavour eq 'UNIMARC' ) ? ( '011', 'a' ) : ( '022', 'a' );
 648 }
 649
 650 sub get_itemnumber_field {
 651     my $marc_flavour = C4::Context->preference('marcflavour');
 652     return ( $marc_flavour eq 'UNIMARC' ) ? ( '995', '9' ) : ( '952', '9' );
 653 }
 654
 655 sub create_isbn_field {
 656     my ( $isbn, $marcflavour ) = @_;
 657
 658     my ( $isbn_field, $isbn_subfield ) = get_isbn_field();
 659     my $field = MARC::Field->new( $isbn_field, '', '', $isbn_subfield => $isbn );
 660
 661     # Add the price subfield
 662     my $price_subfield = ( $marcflavour eq 'UNIMARC' ) ? 'd' : 'c';
 663     $field->add_subfields( $price_subfield => '$100' );
 664
 665     return $field;
 666 }
 667
 668 $schema->storage->txn_rollback();