configure.ac

   1 define([_XTABLES_VERSION_MAJOR], 1)
   2 define([_XTABLES_VERSION_MINOR], 4)
   3 define([_XTABLES_VERSION_PATCH], 3)
   4 define([_XTABLES_VERSION_EXTRA], -rc1)
   5
   6 define([_XTABLES_VERSION],_XTABLES_VERSION_MAJOR._XTABLES_VERSION_MINOR._XTABLES_VERSION_PATCH[]_XTABLES_VERSION_EXTRA)
   7
   8 AC_INIT([iptables], _XTABLES_VERSION)
   9 AC_CONFIG_HEADERS([config.h])
  10 AC_PROG_INSTALL
  11 AM_INIT_AUTOMAKE
  12 AC_PROG_CC
  13 AM_PROG_CC_C_O
  14 AC_DISABLE_STATIC
  15 AC_PROG_LIBTOOL
  16
  17 AC_ARG_WITH([kernel],
  18         AS_HELP_STRING([--with-kernel=PATH],
  19         [Path to kernel source/build directory]),
  20         [kbuilddir="$withval"; ksourcedir="$withval";])
  21 AC_ARG_WITH([kbuild],
  22         AS_HELP_STRING([--with-kbuild=PATH],
  23         [Path to kernel build directory [[/lib/modules/CURRENT/build]]]),
  24         [kbuilddir="$withval"])
  25 AC_ARG_WITH([ksource],
  26         AS_HELP_STRING([--with-ksource=PATH],
  27         [Path to kernel source directory [[/lib/modules/CURRENT/source]]]),
  28         [ksourcedir="$withval"])
  29 AC_ARG_WITH([xtlibdir],
  30         AS_HELP_STRING([--with-xtlibdir=PATH],
  31         [Path where to install Xtables extensions [[LIBEXECDIR/xtables]]]),
  32         [xtlibdir="$withval"],
  33         [xtlibdir="${libexecdir}/xtables"])
  34 AC_ARG_ENABLE([devel],
  35         AS_HELP_STRING([--enable-devel],
  36         [Install Xtables development headers]),
  37         [enable_devel="$enableval"], [enable_devel="yes"])
  38 AC_ARG_ENABLE([libipq],
  39         AS_HELP_STRING([--enable-libipq], [Build and install libipq]))
  40 AC_ARG_WITH([pkgconfigdir], AS_HELP_STRING([--with-pkgconfigdir=PATH],
  41         [Path to the pkgconfig directory [[LIBDIR/pkgconfig]]]),
  42         [pkgconfigdir="$withval"], [pkgconfigdir='${libdir}/pkgconfig'])
  43
  44 AC_CHECK_HEADER([linux/dccp.h])
  45
  46 blacklist_modules="";
  47 if test "$ac_cv_header_linux_dccp_h" != "yes"; then
  48         blacklist_modules="$blacklist_modules dccp";
  49 fi;
  50 AC_SUBST([blacklist_modules])
  51
  52 AM_CONDITIONAL([ENABLE_STATIC], [test "$enable_static" = "yes"])
  53 AM_CONDITIONAL([ENABLE_SHARED], [test "$enable_shared" = "yes"])
  54 AM_CONDITIONAL([ENABLE_DEVEL], [test "$enable_devel" = "yes"])
  55 AM_CONDITIONAL([ENABLE_LIBIPQ], [test "$enable_libipq" = "yes"])
  56
  57 regular_CFLAGS="-D_LARGEFILE_SOURCE=1 -D_LARGE_FILES -D_FILE_OFFSET_BITS=64 \
  58         -D_REENTRANT -Wall -Waggregate-return -Wmissing-declarations \
  59         -Wmissing-prototypes -Wredundant-decls -Wshadow -Wstrict-prototypes \
  60         -Winline -pipe \
  61         -DXTABLES_LIBDIR=\\\"\${xtlibdir}\\\" -DXTABLES_INTERNAL";
  62 kinclude_CFLAGS="";
  63 if [[ -n "$kbuilddir" ]]; then
  64         kinclude_CFLAGS="$kinclude_CFLAGS -I $kbuilddir/include";
  65 fi;
  66 if [[ -n "$ksourcedir" ]]; then
  67         kinclude_CFLAGS="$kinclude_CFLAGS -I $ksourcedir/include";
  68 fi;
  69
  70 AC_SUBST([regular_CFLAGS])
  71 AC_SUBST([kinclude_CFLAGS])
  72 AC_SUBST([kbuilddir])
  73 AC_SUBST([ksourcedir])
  74 AC_SUBST([xtlibdir])
  75 AC_SUBST([pkgconfigdir])
  76
  77 XTABLES_VERSION_MAJOR=_XTABLES_VERSION_MAJOR
  78 XTABLES_VERSION_MINOR=_XTABLES_VERSION_MINOR
  79 XTABLES_VERSION_PATCH=_XTABLES_VERSION_PATCH
  80 XTABLES_VERSION_EXTRA=_XTABLES_VERSION_EXTRA
  81 AC_SUBST([XTABLES_VERSION_MAJOR])
  82 AC_SUBST([XTABLES_VERSION_MINOR])
  83 AC_SUBST([XTABLES_VERSION_PATCH])
  84 AC_SUBST([XTABLES_VERSION_EXTRA])
  85
  86 AC_OUTPUT([Makefile extensions/GNUmakefile libipq/Makefile include/xtables.h
  87         xtables.pc])