auto.def

   1 # vim:se syn=tcl:
   2 #
   3
   4 define JIM_VERSION 76
   5
   6 # Note: modules which support options *must* be included before 'options'
   7 use cc cc-shared cc-db cc-lib
   8 use local
   9
  10 options {
  11     utf8            => "include support for utf8-encoded strings"
  12     lineedit=1      => "disable line editing"
  13     references=1    => "disable support for references"
  14     math            => "include support for math functions"
  15     ssl             => "include ssl/tls support in the aio extension"
  16     ipv6            => "include ipv6 support in the aio extension"
  17     maintainer      => {enable the [debug] command and JimPanic}
  18     full            => "Enable some optional features: ipv6, ssl, math, utf8, binary, oo, tree"
  19     with-jim-shared shared => "build a shared library instead of a static library"
  20     jim-regexp=1    => "prefer POSIX regex if over the the built-in (Tcl-compatible) regex"
  21     docs=1          => "don't build or install the documentation"
  22     docdir:path     => "path to install docs (if built)"
  23     random-hash     => "randomise hash tables. more secure but hash table results are not predicable"
  24     with-jim-ext: {with-ext:"ext1 ext2 ..."} => {
  25         Specify additional jim extensions to include.
  26         These are enabled by default:
  27
  28         aio       - ANSI I/O, including open and socket
  29         eventloop - after, vwait, update
  30         array     - Tcl-compatible array command
  31         clock     - Tcl-compatible clock command
  32         exec      - Tcl-compatible exec command
  33         file      - Tcl-compatible file command
  34         glob      - Tcl-compatible glob command
  35         history   - Tcl access to interactive history
  36         readdir   - Required for glob
  37         package   - Package management with the package command
  38         load      - Load binary extensions at runtime with load or package
  39         posix     - Posix APIs including os.fork, os.wait, pid
  40         regexp    - Tcl-compatible regexp, regsub commands
  41         signal    - Signal handling
  42         stdlib    - Built-in commands including lassign, lambda, alias
  43         syslog    - System logging with syslog
  44         tclcompat - Tcl compatible read, gets, puts, parray, case, ...
  45         namespace - Tcl compatible namespace support
  46
  47         These are disabled by default:
  48
  49         oo        - Jim OO extension
  50         tree      - OO tree structure, similar to tcllib ::struct::tree
  51         binary    - Tcl-compatible 'binary' command
  52         readline  - Interface to libreadline
  53         rlprompt  - Tcl wrapper around the readline extension
  54         mk        - Interface to Metakit
  55         tclprefix - Support for the tcl::prefix command
  56         sqlite3   - Interface to sqlite3
  57         zlib      - Interface to zlib
  58         win32     - Interface to win32
  59     }
  60     with-out-jim-ext: {without-ext:"default|ext1 ext2 ..."} => {
  61         Specify jim extensions to exclude.
  62         If 'default' is given, the default extensions will not be added.
  63     }
  64     with-jim-extmod: {with-mod:"ext1 ext2 ..."} => {
  65         Specify jim extensions to build as separate modules (either C or Tcl).
  66         Note that not all extensions can be built as loadable modules.
  67     }
  68     # To help out openocd with automake
  69     install-jim=1
  70 }
  71
  72 # Save the user-specified LIBS
  73 # We add detected libs to LDLIBS explicitly
  74 set LIBS [get-define LIBS]
  75
  76 cc-check-types "long long"
  77
  78 define CCOPTS ""
  79 define CXXOPTS ""
  80 if {[cctest -cflags -fno-unwind-tables]} {
  81     define-append CCOPTS -fno-unwind-tables
  82 }
  83 if {[cctest -cflags -fno-asynchronous-unwind-tables]} {
  84     define-append CCOPTS -fno-asynchronous-unwind-tables
  85 }
  86
  87 cc-check-includes sys/time.h sys/socket.h netinet/in.h arpa/inet.h netdb.h
  88 cc-check-includes sys/un.h dlfcn.h unistd.h dirent.h crt_externs.h
  89
  90 define LDLIBS ""
  91
  92 # Haiku needs -lnetwork, Solaris needs -lnsl
  93 if {[cc-check-function-in-lib inet_ntop {nsl network}]} {
  94     # This does nothing if no libs are needed
  95     cc-with [list -libs [get-define lib_inet_ntop]]
  96     define-append LDLIBS [get-define lib_inet_ntop]
  97 }
  98 # Solaris needs -lsocket, Windows needs -lwsock32
  99 if {[cc-check-function-in-lib socket socket]} {
 100     define-append LDLIBS [get-define lib_socket]
 101 }
 102
 103 cc-check-functions ualarm lstat fork vfork system select execvpe
 104 cc-check-functions backtrace geteuid mkstemp realpath strptime isatty
 105 cc-check-functions regcomp waitpid sigaction sys_signame sys_siglist isascii
 106 cc-check-functions syslog opendir readlink sleep usleep pipe getaddrinfo utimes
 107 cc-check-functions shutdown socketpair isinf isnan link symlink fsync dup
 108
 109 if {[cc-check-functions sysinfo]} {
 110     cc-with {-includes sys/sysinfo.h} {
 111         cc-check-members "struct sysinfo.uptime"
 112     }
 113 }
 114
 115 cc-check-lfs
 116 cc-check-functions fseeko ftello
 117
 118 define TCL_LIBRARY [get-define prefix]/lib/jim
 119
 120 lassign [split [get-define host] -] host_cpu host_vendor host_os
 121 # Scrub revision from the host_os
 122 regsub -all {[0-9.]} $host_os {} host_os
 123
 124 switch -glob -- $host_os {
 125     mingw* {
 126         # We provide our own implementation of dlopen for mingw32
 127         define-feature dlopen-compat
 128         define-feature winconsole
 129         define TCL_PLATFORM_OS $host_os
 130         define TCL_PLATFORM_PLATFORM windows
 131         define TCL_PLATFORM_PATH_SEPARATOR {;}
 132     }
 133     default {
 134         # Note that cygwin is considered a unix platform
 135         define TCL_PLATFORM_OS $host_os
 136         define TCL_PLATFORM_PLATFORM unix
 137         define TCL_PLATFORM_PATH_SEPARATOR :
 138     }
 139 }
 140
 141 # Find some tools
 142 cc-check-tools ar ranlib strip
 143 define tclsh [info nameofexecutable]
 144
 145 if {![cc-check-functions _NSGetEnviron]} {
 146     msg-checking "Checking environ declared in unistd.h..."
 147     if {[cctest -cflags -D_GNU_SOURCE -includes unistd.h -code {char **ep = environ;}]} {
 148         define NO_ENVIRON_EXTERN
 149         msg-result "yes"
 150     } else {
 151         msg-result "no"
 152     }
 153 }
 154
 155 # Windows has a mkdir with no permission arg
 156 cc-check-includes sys/types.h sys/stat.h
 157 msg-checking "Checking for mkdir with one arg..."
 158 if {[cctest -includes {sys/types.h sys/stat.h} -code {mkdir("/dummy");}]} {
 159     define HAVE_MKDIR_ONE_ARG
 160     msg-result yes
 161 } else {
 162     msg-result no
 163 }
 164
 165 set extra_objs {}
 166 set jimregexp 0
 167
 168 if {[opt-bool utf8 full]} {
 169     msg-result "Enabling UTF-8"
 170     define JIM_UTF8
 171     incr jimregexp
 172 } else {
 173     define JIM_UTF8 0
 174 }
 175 if {[opt-bool maintainer]} {
 176     msg-result "Enabling maintainer settings"
 177     define JIM_MAINTAINER
 178 }
 179 if {[opt-bool math full]} {
 180     msg-result "Enabling math functions"
 181     define JIM_MATH_FUNCTIONS
 182     cc-check-function-in-lib sin m
 183     define-append LDLIBS [get-define lib_sin]
 184 }
 185 if {[opt-bool ipv6 full]} {
 186     msg-result "Enabling IPv6"
 187     define JIM_IPV6
 188 }
 189 if {[opt-bool ssl full]} {
 190     if {[cc-check-includes openssl/ssl.h] && [cc-check-function-in-lib ERR_error_string crypto] && [cc-check-function-in-lib TLSv1_2_method ssl]} {
 191         msg-result "Enabling SSL"
 192         define JIM_SSL
 193         define-append LDLIBS [get-define lib_ERR_error_string] [get-define lib_TLSv1_2_method]
 194     } elseif {[opt-bool ssl]} {
 195         user-error "SSL support requires OpenSSL"
 196     }
 197 }
 198 if {[opt-bool lineedit full]} {
 199     if {([cc-check-includes termios.h] && [have-feature isatty]) || [have-feature winconsole]} {
 200         msg-result "Enabling line editing"
 201         define USE_LINENOISE
 202         lappend extra_objs linenoise.o
 203     }
 204 }
 205 if {[opt-bool references]} {
 206     msg-result "Enabling references"
 207     define JIM_REFERENCES
 208 }
 209 if {[opt-bool shared with-jim-shared]} {
 210     msg-result "Building shared library"
 211 } else {
 212     msg-result "Building static library"
 213     define JIM_STATICLIB
 214 }
 215 define LIBSOEXT [format [get-define SH_SOEXTVER] [format %.2f [expr {[get-define JIM_VERSION] / 100.0}]]]
 216 define JIM_INSTALL [opt-bool install-jim]
 217 define JIM_DOCS [opt-bool docs]
 218 define JIM_RANDOMISE_HASH [opt-bool random-hash]
 219 if {[opt-val docdir] ne ""} {
 220     define docdir [opt-val docdir]
 221 } else {
 222     define docdir {${prefix}/docs/jim}
 223 }
 224
 225 # Attributes of the extensions
 226 # tcl=Pure Tcl extension
 227 # static=Can't be built as a module
 228 # optional=Not selected by default
 229 # cpp=Is a C++ extension
 230 global extdb
 231 dict set extdb attrs {
 232     aio       { static }
 233     array     {}
 234     binary    { tcl }
 235     clock     {}
 236     eventloop { static }
 237     exec      { static }
 238     file      {}
 239     glob      { tcl }
 240     history   {}
 241     load      { static }
 242     mk        { cpp optional }
 243     namespace { static }
 244     nshelper  { tcl optional }
 245     oo        { tcl }
 246     pack      {}
 247     package   { static }
 248     posix     {}
 249     readdir   {}
 250     readline  { optional }
 251     regexp    {}
 252     rlprompt  { tcl optional }
 253     sdl       { optional }
 254     signal    { static }
 255     sqlite3   { optional }
 256     zlib      { optional }
 257     stdlib    { tcl static }
 258     syslog    {}
 259     tclcompat { tcl static }
 260     tclprefix {}
 261     tree      { tcl }
 262     win32     { optional }
 263 }
 264
 265 # Additional information about certain extensions
 266 # dep=list of extensions which are required for this extension
 267 # check=[expr] expression to evaluate to determine if the extension can be used
 268 # libdep=list of 'define' symbols for dependent libraries
 269 dict set extdb info {
 270     binary   { dep pack }
 271     exec     { check {([have-feature vfork] && [have-feature waitpid]) || [have-feature system]} }
 272     glob     { dep readdir }
 273     load     { check {[have-feature dlopen-compat] || [cc-check-function-in-lib dlopen dl]} libdep lib_dlopen }
 274     mk       { check {[check-metakit]} libdep lib_mk }
 275     namespace { dep nshelper }
 276     posix    { check {[have-feature waitpid]} }
 277     readdir  { check {[have-feature opendir]} }
 278     readline { check {[cc-check-function-in-lib readline readline]} libdep lib_readline}
 279     rlprompt { dep readline }
 280     tree     { dep oo }
 281     sdl      { check {[cc-check-function-in-lib SDL_SetVideoMode SDL] && [cc-check-function-in-lib rectangleRGBA SDL_gfx]}
 282                libdep {lib_SDL_SetVideoMode lib_rectangleRGBA}
 283              }
 284     signal   { check {[have-feature sigaction] && [have-feature vfork]} }
 285     sqlite3  { check {[cc-check-function-in-lib sqlite3_prepare_v2 sqlite3]} libdep lib_sqlite3_prepare_v2 }
 286     zlib     { check {[cc-check-function-in-lib deflate z]} libdep lib_deflate }
 287     syslog   { check {[have-feature syslog]} }
 288     tree     { dep oo }
 289     win32    { check {[have-feature windows]} }
 290 }
 291
 292 # autosetup cc-check-function-in-library can't handle C++ libraries
 293 proc check-metakit {} {
 294     set found 0
 295     msg-checking "Checking for Metakit..."
 296     cc-with {-lang c++} {
 297         if {[cctest -includes mk4.h -libs -lmk4 -code {c4_Storage dummy();}]} {
 298             msg-result ok
 299             define lib_mk -lmk4
 300             incr found
 301         } else {
 302             msg-result "not found"
 303         }
 304     }
 305     return $found
 306 }
 307
 308 # Set up the withinfo array based on what the user selected
 309 global withinfo
 310 set withinfo(without) [join [opt-val {without-ext with-out-jim-ext}]]
 311 set withinfo(ext) [join [opt-val {with-ext with-jim-ext}]]
 312 set withinfo(mod) [join [opt-val {with-mod with-jim-extmod}]]
 313 set withinfo(nodefault) 0
 314 if {$withinfo(without) eq "default"} {
 315     set withinfo(without) {}
 316     set withinfo(nodefault) 1
 317 }
 318
 319 # Now go check everything - see autosetup/local.tcl
 320 array set extinfo [check-extensions]
 321
 322 # Now special checks
 323 if {[have-feature windows]} {
 324     lappend extra_objs jim-win32compat.o
 325
 326     if {[llength $extinfo(module-c)] && [get-define JIM_STATICLIB]} {
 327         user-error "cygwin/mingw require --shared for dynamic modules"
 328     }
 329 }
 330
 331 if {[ext-get-status regexp] in {y m}} {
 332     if {![have-feature regcomp]} {
 333         # No regcomp means we need to use the built-in version
 334         incr jimregexp
 335     }
 336 }
 337
 338 if {$jimregexp || [opt-bool jim-regexp]} {
 339     msg-result "Using built-in regexp"
 340     define JIM_REGEXP
 341
 342     # If the built-in regexp overrides the system regcomp, etc.
 343     # jim must be built shared so that the correct symbols are found
 344     if {[ext-get-status regexp] eq "m" && [get-define JIM_STATICLIB] && [have-feature regcomp]} {
 345         user-error "Must use --shared with regexp module and built-in regexp"
 346     }
 347 }
 348
 349 if {[ext-get-status load] eq "n"} {
 350     # If we don't have load, no need to support shared objects
 351     define SH_LINKFLAGS ""
 352 }
 353
 354 msg-result "Jim static extensions: [lsort [concat $extinfo(static-tcl) $extinfo(static-c)]]"
 355 if {[llength $extinfo(module-tcl)]} {
 356     msg-result "Jim Tcl extensions: [lsort $extinfo(module-tcl)]"
 357 }
 358 if {[llength $extinfo(module-c)]} {
 359     msg-result "Jim dynamic extensions: [lsort $extinfo(module-c)]"
 360 }
 361
 362 define STATIC_EXTS [concat $extinfo(static-c) $extinfo(static-tcl)]
 363 define C_EXT_OBJS [prefix jim- [suffix .o $extinfo(static-c)]]
 364 define TCL_EXT_OBJS [suffix .o $extinfo(static-tcl)]
 365 define C_EXT_SHOBJS [suffix .so $extinfo(module-c)]
 366 define TCL_EXTS [suffix .tcl $extinfo(module-tcl)]
 367 define EXTRA_OBJS $extra_objs
 368
 369 # Restore the user-specified LIBS
 370 define LIBS $LIBS
 371
 372 make-config-header jim-config.h -auto {HAVE_LONG_LONG* JIM_UTF8} -bare JIM_VERSION -none *
 373 make-config-header jimautoconf.h -auto {jim_ext_* TCL_PLATFORM_* TCL_LIBRARY USE_* JIM_* _FILE_OFFSET*}
 374 make-template Makefile.in
 375 make-template build-jim-ext.in
 376
 377 catch {exec chmod +x build-jim-ext}