auto.def

   1 # vim:se syn=tcl:
   2 #
   3
   4 define JIM_VERSION 77
   5
   6 # Note: modules which support options *must* be included before 'options'
   7 use cc cc-shared cc-db cc-lib pkg-config
   8 use local
   9
  10 options {
  11     utf8            => "include support for utf8-encoded strings"
  12     lineedit=1      => "disable line editing"
  13     references=1    => "disable support for references"
  14     math            => "include support for math functions"
  15     ssl             => "include ssl/tls support in the aio extension"
  16     ipv6            => "include ipv6 support in the aio extension"
  17     maintainer      => {enable the [debug] command and JimPanic}
  18     full            => "Enable some optional features: ipv6, ssl, math, utf8, binary, oo, tree"
  19     with-jim-shared shared => "build a shared library instead of a static library"
  20     jim-regexp=1    => "prefer POSIX regex if over the the built-in (Tcl-compatible) regex"
  21     docs=1          => "don't build or install the documentation"
  22     docdir:path     => "path to install docs (if built)"
  23     random-hash     => "randomise hash tables. more secure but hash table results are not predicable"
  24     with-jim-ext: {with-ext:"ext1 ext2 ..."} => {
  25         Specify additional jim extensions to include.
  26         These are enabled by default:
  27
  28         aio       - ANSI I/O, including open and socket
  29         eventloop - after, vwait, update
  30         array     - Tcl-compatible array command
  31         clock     - Tcl-compatible clock command
  32         exec      - Tcl-compatible exec command
  33         file      - Tcl-compatible file command
  34         glob      - Tcl-compatible glob command
  35         history   - Tcl access to interactive history
  36         readdir   - Required for glob
  37         package   - Package management with the package command
  38         load      - Load binary extensions at runtime with load or package
  39         posix     - Posix APIs including os.fork, os.wait, pid
  40         regexp    - Tcl-compatible regexp, regsub commands
  41         signal    - Signal handling
  42         stdlib    - Built-in commands including lassign, lambda, alias
  43         syslog    - System logging with syslog
  44         tclcompat - Tcl compatible read, gets, puts, parray, case, ...
  45         namespace - Tcl compatible namespace support
  46
  47         These are disabled by default:
  48
  49         oo        - Jim OO extension
  50         tree      - OO tree structure, similar to tcllib ::struct::tree
  51         binary    - Tcl-compatible 'binary' command
  52         readline  - Interface to libreadline
  53         rlprompt  - Tcl wrapper around the readline extension
  54         mk        - Interface to Metakit
  55         tclprefix - Support for the tcl::prefix command
  56         sqlite3   - Interface to sqlite3
  57         zlib      - Interface to zlib
  58         win32     - Interface to win32
  59     }
  60     with-out-jim-ext: {without-ext:"default|ext1 ext2 ..."} => {
  61         Specify jim extensions to exclude.
  62         If 'default' is given, the default extensions will not be added.
  63     }
  64     with-jim-extmod: {with-mod:"ext1 ext2 ..."} => {
  65         Specify jim extensions to build as separate modules (either C or Tcl).
  66         Note that not all extensions can be built as loadable modules.
  67     }
  68     # To help out openocd with automake
  69     install-jim=1
  70 }
  71
  72 # Save the user-specified LIBS
  73 # We add detected libs to LDLIBS explicitly
  74 set LIBS [get-define LIBS]
  75
  76 cc-check-types "long long"
  77
  78 define CCOPTS ""
  79 define CXXOPTS ""
  80 if {[cctest -cflags -fno-unwind-tables]} {
  81     define-append CCOPTS -fno-unwind-tables
  82 }
  83 if {[cctest -cflags -fno-asynchronous-unwind-tables]} {
  84     define-append CCOPTS -fno-asynchronous-unwind-tables
  85 }
  86
  87 cc-check-includes sys/time.h sys/socket.h netinet/in.h arpa/inet.h netdb.h
  88 cc-check-includes sys/un.h dlfcn.h unistd.h dirent.h crt_externs.h
  89
  90 define LDLIBS ""
  91
  92 # Haiku needs -lnetwork, Solaris needs -lnsl
  93 if {[cc-check-function-in-lib inet_ntop {nsl network}]} {
  94     # This does nothing if no libs are needed
  95     cc-with [list -libs [get-define lib_inet_ntop]]
  96     define-append LDLIBS [get-define lib_inet_ntop]
  97 }
  98 # Solaris needs -lsocket, Windows needs -lwsock32
  99 if {[cc-check-function-in-lib socket socket]} {
 100     define-append LDLIBS [get-define lib_socket]
 101 }
 102
 103 cc-check-functions ualarm lstat fork vfork system select execvpe
 104 cc-check-functions backtrace geteuid mkstemp realpath strptime isatty
 105 cc-check-functions regcomp waitpid sigaction sys_signame sys_siglist isascii
 106 cc-check-functions syslog opendir readlink sleep usleep pipe getaddrinfo utimes
 107 cc-check-functions shutdown socketpair isinf isnan link symlink fsync dup umask
 108
 109 if {[cc-check-functions sysinfo]} {
 110     cc-with {-includes sys/sysinfo.h} {
 111         cc-check-members "struct sysinfo.uptime"
 112     }
 113 }
 114
 115 cc-with {-includes fcntl.h} {
 116     cc-check-types "struct flock"
 117 }
 118
 119 cc-check-lfs
 120 cc-check-functions fseeko ftello
 121
 122 define TCL_LIBRARY [get-define prefix]/lib/jim
 123
 124 lassign [split [get-define host] -] host_cpu host_vendor host_os
 125 # Scrub revision from the host_os
 126 regsub -all {[0-9.]} $host_os {} host_os
 127
 128 switch -glob -- $host_os {
 129     mingw* {
 130         # We provide our own implementation of dlopen for mingw32
 131         define-feature dlopen-compat
 132         define-feature winconsole
 133         define TCL_PLATFORM_OS $host_os
 134         define TCL_PLATFORM_PLATFORM windows
 135         define TCL_PLATFORM_PATH_SEPARATOR {;}
 136     }
 137     default {
 138         # Note that cygwin is considered a unix platform
 139         define TCL_PLATFORM_OS $host_os
 140         define TCL_PLATFORM_PLATFORM unix
 141         define TCL_PLATFORM_PATH_SEPARATOR :
 142     }
 143 }
 144
 145 # Find some tools
 146 cc-check-tools ar ranlib strip
 147 define tclsh [info nameofexecutable]
 148
 149 if {![cc-check-functions _NSGetEnviron]} {
 150     msg-checking "Checking environ declared in unistd.h..."
 151     if {[cctest -cflags {-D_GNU_SOURCE -D_POSIX_SOURCE} -includes unistd.h -code {char **ep = environ;}]} {
 152         define NO_ENVIRON_EXTERN
 153         msg-result "yes"
 154     } else {
 155         msg-result "no"
 156     }
 157 }
 158
 159 # Windows has a mkdir with no permission arg
 160 cc-check-includes sys/types.h sys/stat.h
 161 msg-checking "Checking for mkdir with one arg..."
 162 if {[cctest -includes {sys/types.h sys/stat.h} -code {mkdir("/dummy");}]} {
 163     define HAVE_MKDIR_ONE_ARG
 164     msg-result yes
 165 } else {
 166     msg-result no
 167 }
 168
 169 cc-with {-includes sys/stat.h} {
 170     foreach i {S_IXUSR S_IRWXG S_IRWXO} {
 171         if {![cc-check-decls $i]} {
 172             define $i 0
 173         }
 174     }
 175 }
 176
 177 set extra_objs {}
 178 set jimregexp 0
 179
 180 # Returns 1 if either the given option is enabled, or
 181 # --full is enabled and the option isn't explicitly disabled
 182 #
 183 proc opt-bool-or-full {opt} {
 184     if {[opt-bool $opt]} {
 185         return 1
 186     }
 187     if {[opt-bool full] && [opt-bool -nodefault $opt] != 0} {
 188         return 1
 189     }
 190     return 0
 191 }
 192
 193 if {[opt-bool-or-full utf8]} {
 194     msg-result "Enabling UTF-8"
 195     define JIM_UTF8
 196     define-append CCOPTS -DUSE_UTF8
 197     define PARSE_UNIDATA_FLAGS ""
 198     incr jimregexp
 199 } else {
 200     define JIM_UTF8 0
 201 }
 202 if {[opt-bool maintainer]} {
 203     msg-result "Enabling maintainer settings"
 204     define JIM_MAINTAINER
 205 }
 206 # If --math or --full and not --disable-math
 207 if {[opt-bool-or-full math]} {
 208     msg-result "Enabling math functions"
 209     define JIM_MATH_FUNCTIONS
 210     cc-check-function-in-lib sin m
 211     define-append LDLIBS [get-define lib_sin]
 212 }
 213 if {[opt-bool-or-full ipv6]} {
 214     msg-result "Enabling IPv6"
 215     define JIM_IPV6
 216 }
 217 if {[opt-bool-or-full ssl]} {
 218     if {[pkg-config-init 0]} {
 219         foreach pkg {openssl libssl} {
 220             if {[pkg-config $pkg]} {
 221                 define JIM_SSL
 222                 define-append LDLIBS [pkg-config-get $pkg LIBS]
 223                 define-append LDFLAGS [pkg-config-get $pkg LDFLAGS]
 224                 define-append CCOPTS [pkg-config-get $pkg CFLAGS]
 225                 msg-result "Enabling SSL ($pkg)"
 226                 break
 227             }
 228         }
 229     }
 230     if {![is-defined JIM_SSL]} {
 231         if {[cc-check-includes openssl/ssl.h] && [cc-check-function-in-lib ERR_error_string crypto] && [cc-check-function-in-lib TLSv1_2_method ssl]} {
 232             msg-result "Enabling SSL"
 233             define JIM_SSL
 234             define-append LDLIBS [get-define lib_ERR_error_string] [get-define lib_TLSv1_2_method]
 235         } elseif {[opt-bool ssl]} {
 236             user-error "SSL support requires OpenSSL"
 237         }
 238     }
 239 }
 240 if {[opt-bool-or-full lineedit]} {
 241     if {([cc-check-includes termios.h] && [have-feature isatty]) || [have-feature winconsole]} {
 242         msg-result "Enabling line editing"
 243         define USE_LINENOISE
 244         define-append PARSE_UNIDATA_FLAGS -width
 245         lappend extra_objs linenoise.o
 246     }
 247 }
 248 if {[opt-bool references]} {
 249     msg-result "Enabling references"
 250     define JIM_REFERENCES
 251 }
 252 if {[opt-bool shared with-jim-shared]} {
 253     msg-result "Building shared library"
 254 } else {
 255     msg-result "Building static library"
 256     define JIM_STATICLIB
 257 }
 258 define LIBSOEXT [format [get-define SH_SOEXTVER] [format %.2f [expr {[get-define JIM_VERSION] / 100.0}]]]
 259 define JIM_INSTALL [opt-bool install-jim]
 260 define JIM_DOCS [opt-bool docs]
 261 define JIM_RANDOMISE_HASH [opt-bool random-hash]
 262 if {[opt-val docdir] ne ""} {
 263     define docdir [opt-val docdir]
 264 } else {
 265     define docdir {${prefix}/docs/jim}
 266 }
 267
 268 # Attributes of the extensions
 269 # tcl=Pure Tcl extension
 270 # static=Can't be built as a module
 271 # optional=Not selected by default
 272 # cpp=Is a C++ extension
 273 global extdb
 274 dict set extdb attrs {
 275     aio       { static }
 276     array     {}
 277     binary    { tcl }
 278     clock     {}
 279     eventloop { static }
 280     exec      { static }
 281     file      {}
 282     glob      { tcl }
 283     history   {}
 284     interp    { }
 285     load      { static }
 286     mk        { cpp optional }
 287     namespace { static }
 288     nshelper  { tcl optional }
 289     oo        { tcl }
 290     pack      {}
 291     package   { static }
 292     posix     {}
 293     readdir   {}
 294     readline  { optional }
 295     regexp    {}
 296     rlprompt  { tcl optional }
 297     sdl       { optional }
 298     signal    { static }
 299     sqlite3   { optional }
 300     zlib      { optional }
 301     stdlib    { tcl static }
 302     syslog    {}
 303     tclcompat { tcl static }
 304     tclprefix {}
 305     tree      { tcl }
 306     win32     { optional }
 307 }
 308
 309 # Additional information about certain extensions
 310 # dep=list of extensions which are required for this extension
 311 # check=[expr] expression to evaluate to determine if the extension can be used
 312 # libdep=list of 'define' symbols for dependent libraries
 313 dict set extdb info {
 314     binary   { dep pack }
 315     exec     { check {([have-feature vfork] && [have-feature waitpid]) || [have-feature system]} }
 316     glob     { dep readdir }
 317     load     { check {[have-feature dlopen-compat] || [cc-check-function-in-lib dlopen dl]} libdep lib_dlopen }
 318     mk       { check {[check-metakit]} libdep lib_mk }
 319     namespace { dep nshelper }
 320     posix    { check {[have-feature waitpid]} }
 321     readdir  { check {[have-feature opendir]} }
 322     readline { pkg-config readline check {[cc-check-function-in-lib readline readline]} libdep lib_readline}
 323     rlprompt { dep readline }
 324     tree     { dep oo }
 325     sdl      { pkg-config SDL_gfx check {[cc-check-function-in-lib SDL_SetVideoMode SDL] && [cc-check-function-in-lib rectangleRGBA SDL_gfx]}
 326                libdep {lib_SDL_SetVideoMode lib_rectangleRGBA}
 327              }
 328     signal   { check {[have-feature sigaction] && [have-feature vfork]} }
 329     sqlite3  { pkg-config sqlite3 check {[cc-check-function-in-lib sqlite3_prepare_v2 sqlite3]} libdep lib_sqlite3_prepare_v2 }
 330     zlib     { pkg-config zlib check {[cc-check-function-in-lib deflate z]} libdep lib_deflate }
 331     syslog   { check {[have-feature syslog]} }
 332     tree     { dep oo }
 333     win32    { check {[have-feature windows]} }
 334 }
 335
 336 # autosetup cc-check-function-in-library can't handle C++ libraries
 337 proc check-metakit {} {
 338     set found 0
 339     msg-checking "Checking for Metakit..."
 340     cc-with {-lang c++} {
 341         if {[cctest -includes mk4.h -libs -lmk4 -code {c4_Storage dummy();}]} {
 342             msg-result ok
 343             define lib_mk -lmk4
 344             incr found
 345         } else {
 346             msg-result "not found"
 347         }
 348     }
 349     return $found
 350 }
 351
 352 # Set up the withinfo array based on what the user selected
 353 global withinfo
 354 set withinfo(without) [join [opt-val {without-ext with-out-jim-ext}]]
 355 set withinfo(ext) [join [opt-val {with-ext with-jim-ext}]]
 356 set withinfo(mod) [join [opt-val {with-mod with-jim-extmod}]]
 357 set withinfo(nodefault) 0
 358 if {$withinfo(without) eq "default"} {
 359     set withinfo(without) {}
 360     set withinfo(nodefault) 1
 361 }
 362
 363 # Now go check everything - see autosetup/local.tcl
 364 array set extinfo [check-extensions]
 365
 366 # Now special checks
 367 if {[have-feature windows]} {
 368     lappend extra_objs jim-win32compat.o
 369
 370     if {[llength $extinfo(module-c)] && [get-define JIM_STATICLIB]} {
 371         user-error "cygwin/mingw require --shared for dynamic modules"
 372     }
 373 }
 374 if {[have-feature termios.h]} {
 375     lappend extra_objs jim-tty.o
 376 }
 377
 378 if {[ext-get-status regexp] in {y m}} {
 379     if {![have-feature regcomp]} {
 380         # No regcomp means we need to use the built-in version
 381         incr jimregexp
 382     }
 383 }
 384
 385 if {$jimregexp || [opt-bool jim-regexp]} {
 386     msg-result "Using built-in regexp"
 387     define JIM_REGEXP
 388
 389     # If the built-in regexp overrides the system regcomp, etc.
 390     # jim must be built shared so that the correct symbols are found
 391     if {[ext-get-status regexp] eq "m" && [get-define JIM_STATICLIB] && [have-feature regcomp]} {
 392         user-error "Must use --shared with regexp module and built-in regexp"
 393     }
 394 }
 395
 396 if {[ext-get-status load] eq "n"} {
 397     # If we don't have load, no need to support shared objects
 398     define SH_LINKFLAGS ""
 399 }
 400
 401 msg-result "Jim static extensions: [lsort [concat $extinfo(static-tcl) $extinfo(static-c)]]"
 402 if {[llength $extinfo(module-tcl)]} {
 403     msg-result "Jim Tcl extensions: [lsort $extinfo(module-tcl)]"
 404 }
 405 if {[llength $extinfo(module-c)]} {
 406     msg-result "Jim dynamic extensions: [lsort $extinfo(module-c)]"
 407 }
 408
 409 define STATIC_EXTS [concat $extinfo(static-c) $extinfo(static-tcl)]
 410 define C_EXT_OBJS [prefix jim- [suffix .o $extinfo(static-c)]]
 411 define TCL_EXT_OBJS [suffix .o $extinfo(static-tcl)]
 412 define C_EXT_SHOBJS [suffix .so $extinfo(module-c)]
 413 define TCL_EXTS [suffix .tcl $extinfo(module-tcl)]
 414 define EXTRA_OBJS $extra_objs
 415
 416 # Restore the user-specified LIBS
 417 define LIBS $LIBS
 418
 419 make-config-header jim-config.h -auto {HAVE_LONG_LONG* JIM_UTF8} -bare JIM_VERSION -none *
 420 make-config-header jimautoconf.h -auto {jim_ext_* TCL_PLATFORM_* TCL_LIBRARY USE_* JIM_* _FILE_OFFSET*} -bare {S_I*}
 421 make-template Makefile.in
 422 make-template build-jim-ext.in
 423
 424 catch {exec chmod +x build-jim-ext}