configure.ac

   1 AC_INIT
   2 AC_CONFIG_AUX_DIR([.])
   3 AC_CONFIG_MACRO_DIR([m4])
   4 AM_INIT_AUTOMAKE(isl, 0.00)
   5
   6 AC_PROG_CC
   7
   8 AC_PROG_LIBTOOL
   9
  10 AX_CREATE_STDINT_H(include/isl_stdint.h)
  11
  12 AC_ARG_WITH(gmp_prefix,
  13         [AS_HELP_STRING([--with-gmp-prefix=DIR],
  14                         [Location of GMP installation])])
  15
  16 AC_SUBST(GMP_CPPFLAGS)
  17 AC_SUBST(GMP_LDFLAGS)
  18 if test "x$with_gmp_prefix" != "x"; then
  19         isl_configure_args="$isl_configure_args --with-gmp=$with_gmp_prefix"
  20         GMP_CPPFLAGS="-I$with_gmp_prefix/include"
  21         GMP_LDFLAGS="-L$with_gmp_prefix/lib"
  22 fi
  23 SAVE_CPPFLAGS="$CPPFLAGS"
  24 CPPFLAGS="$GMP_CPPFLAGS $CPPFLAGS"
  25 need_get_memory_functions=false
  26 AC_CHECK_DECLS(mp_get_memory_functions,[],[
  27         need_get_memory_functions=true
  28 ],[#include <gmp.h>])
  29 CPPFLAGS="$SAVE_CPPFLAGS"
  30 AM_CONDITIONAL(NEED_GET_MEMORY_FUNCTIONS, test x$need_get_memory_functions = xtrue)
  31
  32 AC_DEFUN([ISL_SUBMODULE],[
  33         AC_ARG_WITH($1_prefix,
  34                 [AS_HELP_STRING([--with-$1-prefix=DIR],
  35                                 [Location of system $1])])
  36         AC_ARG_WITH($1_builddir,
  37                     [AS_HELP_STRING([--with-$1-builddir=DIR],
  38                                     [Location of $1 builddir])])
  39         if test "x$with_$1_prefix" != "x"; then
  40                 if test "x$with_$1" != "x" -a "x$with_$1" != "xsystem"; then
  41                         AC_MSG_ERROR([Setting $with_$1_prefix implies use of system $1])
  42                 fi
  43                 with_$1="system"
  44         fi
  45         if test "x$with_$1_builddir" != "x"; then
  46                 if test "x$with_$1" != "x" -a "x$with_$1" != "xbuild"; then
  47                         AC_MSG_ERROR([Setting $with_$1_builddir implies use of build $1])
  48                 fi
  49                 with_$1="build"
  50                 $1_srcdir=`echo @abs_srcdir@ | $with_$1_builddir/config.status --file=-`
  51                 AC_MSG_NOTICE($1 sources in $$1_srcdir)
  52         fi
  53         case "$with_$1" in
  54         no|bundled|system|build)
  55                 ;;
  56         *)
  57                 if test -d $srcdir/.git -a \
  58                         -d $srcdir/$1 -a \
  59                         ! -d $srcdir/$1/.git; then
  60                         AC_MSG_WARN(
  61 [git repo detected, but submodule $1 not initialized])
  62                         AC_MSG_WARN([You may want to run])
  63                         AC_MSG_WARN([   git submodule init])
  64                         AC_MSG_WARN([   git submodule update])
  65                         AC_MSG_WARN([   sh autogen.sh])
  66                 fi
  67                 if test -f $srcdir/$1/configure; then
  68                         with_$1="bundled"
  69                 fi
  70                 ;;
  71         esac
  72 ])
  73
  74 AC_ARG_WITH(polylib,
  75         [AS_HELP_STRING([--with-polylib=build|system|no],
  76                         [Which PolyLib to use])])
  77 ISL_SUBMODULE(polylib)
  78 if test "x$with_polylib" = "x"; then
  79         with_polylib="no"
  80 fi
  81 AC_MSG_CHECKING([which polylib to use])
  82 AC_MSG_RESULT($with_polylib)
  83
  84 have_polylib=false
  85 AC_SUBST(POLYLIB_CPPFLAGS)
  86 AC_SUBST(POLYLIB_LDFLAGS)
  87 AC_SUBST(POLYLIB_LIBS)
  88 case "$with_polylib" in
  89         build)
  90                 polylibs=`echo @polylibs@ | $with_polylib_builddir/config.status --file=-`
  91                 AC_MSG_NOTICE(Configured polylibs: $polylibs)
  92                 isl_cv_polylib=missing
  93                 for bits in $polylibs; do
  94                         if test "$bits" = "libpolylibgmp.la"; then
  95                                 isl_cv_polylib=ok
  96                         fi
  97                 done
  98                 if test "$isl_cv_polylib" = "missing"; then
  99                         AC_MSG_ERROR(no gmp polylib configured)
 100                 fi
 101                 POLYLIB_CPPFLAGS="-I$with_polylib_builddir/include -I$polylib_srcdir/include"
 102                 POLYLIB_LIBS="$with_polylib_builddir/libpolylibgmp.la"
 103         ;;
 104         system)
 105                 POLYLIB_LIBS="-lpolylibgmp"
 106                 if test "x$with_polylib_prefix" != "x"; then
 107                         POLYLIB_CPPFLAGS="-I$with_polylib_prefix/include"
 108                         POLYLIB_LDFLAGS="-L$with_polylib_prefix/lib"
 109                 fi
 110                 SAVE_CPPFLAGS="$CPPFLAGS"
 111                 SAVE_LDFLAGS="$LDFLAGS"
 112                 CPPFLAGS="$POLYLIB_CPPFLAGS $CPPFLAGS"
 113                 LDFLAGS="$POLYLIB_LDFLAGS $LDFLAGS"
 114                 AC_CHECK_LIB(polylibgmp, PolyhedronTSort,[ true ],[
 115                         AC_MSG_ERROR(Need polylib)
 116                 ])
 117                 CPPFLAGS="$SAVE_CPPFLAGS"
 118                 LDFLAGS="$SAVE_LDFLAGS"
 119         ;;
 120         no)
 121         ;;
 122         *)
 123                 AC_MSG_ERROR(unsupported)
 124         ;;
 125 esac
 126 if test "$with_polylib" != "no"; then
 127         AC_DEFINE(ISL_POLYLIB,,polylib is available)
 128         have_polylib=true
 129 fi
 130 AM_CONDITIONAL(HAVE_POLYLIB, test x$have_polylib = xtrue)
 131
 132 AC_ARG_WITH(piplib,
 133         [AS_HELP_STRING([--with-piplib=build|bundled|system|no],
 134                         [Which piplib to use])])
 135 ISL_SUBMODULE(piplib)
 136 if test "x$with_piplib" = "x"; then
 137         with_piplib="system"
 138 fi
 139 AC_MSG_CHECKING([which piplib to use])
 140 AC_MSG_RESULT($with_piplib)
 141
 142 have_piplib=false
 143 AC_SUBST(PIPLIB_CPPFLAGS)
 144 AC_SUBST(PIPLIB_LDFLAGS)
 145 AC_SUBST(PIPLIB_LIBS)
 146 case "$with_piplib" in
 147         bundled)
 148                 PIPLIB_CPPFLAGS="-I$srcdir/piplib/include"
 149                 isl_configure_args="$isl_configure_args --with-bits=gmp"
 150         ;;
 151         build)
 152                 PIPLIB_CPPFLAGS="-I$piplib_srcdir/include"
 153                 PIPLIB_LIBS="$with_piplib_builddir/libpiplibMP.la"
 154         ;;
 155         system)
 156                 PIPLIB_LIBS="-lpiplibMP"
 157                 if test "x$with_piplib_prefix" != "x"; then
 158                         PIPLIB_CPPFLAGS="-I$with_piplib_prefix/include"
 159                         PIPLIB_LDFLAGS="-L$with_piplib_prefix/lib"
 160                 fi
 161                 SAVE_CPPFLAGS="$CPPFLAGS"
 162                 SAVE_LDFLAGS="$LDFLAGS"
 163                 CPPFLAGS="$PIPLIB_CPPFLAGS $CPPFLAGS"
 164                 LDFLAGS="$PIPLIB_LDFLAGS $LDFLAGS"
 165                 AC_CHECK_LIB(piplibMP, pip_solve,[
 166                         AC_CHECK_MEMBER(PipOptions.Urs_parms, [], [
 167                                 AC_MSG_ERROR([Piplib too old; please install version 1.3.6 or newer])
 168                         ],[#include <piplib/piplibMP.h>])
 169                 ],[
 170                         AC_MSG_ERROR([Piplib not found])
 171                 ])
 172                 CPPFLAGS="$SAVE_CPPFLAGS"
 173                 LDFLAGS="$SAVE_LDFLAGS"
 174         ;;
 175         no)
 176         ;;
 177         *)
 178                 AC_MSG_ERROR(unsupported)
 179         ;;
 180 esac
 181 if test "$with_piplib" != "no"; then
 182         AC_DEFINE(ISL_PIPLIB,,piplib is available)
 183         have_piplib=true
 184 fi
 185 AM_CONDITIONAL(HAVE_PIPLIB, test x$have_piplib = xtrue)
 186 AM_CONDITIONAL(BUNDLED_PIPLIB, test $with_piplib = bundled)
 187
 188 AC_CONFIG_HEADERS(config.h)
 189 AC_CONFIG_HEADERS(include/isl_ctx.h)
 190 AC_CONFIG_FILES(Makefile)
 191 if test $with_piplib = bundled; then
 192         AC_CONFIG_SUBDIRS(piplib)
 193 fi
 194 AC_CONFIG_COMMANDS_POST([
 195         dnl pass on arguments to subdir configures, but don't
 196         ac_configure_args="$ac_configure_args $isl_configure_args"
 197         ac_configure_args="$ac_configure_args $isl_configure_args"
 198 ])
 199 AC_OUTPUT