configure.ac

   1 AC_INIT([isl], [0.13], [isl-development@googlegroups.com])
   2 AC_CONFIG_AUX_DIR([.])
   3 AC_CONFIG_MACRO_DIR([m4])
   4 AM_INIT_AUTOMAKE([foreign])
   5 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
   6 AC_SUBST(versioninfo)
   7 versioninfo=13:0:0
   8
   9 if test "x$prefix" != "xNONE"; then
  10         prefix_wd=`cd $prefix && pwd`
  11         srcdir_wd=`cd $srcdir && pwd`
  12         wd=`pwd`
  13         if test "x$prefix_wd" = "x$srcdir_wd"; then
  14                 AC_MSG_ERROR(Installation in source directory not supported)
  15         fi
  16         if test "x$prefix_wd" = "x$wd"; then
  17                 AC_MSG_ERROR(Installation in build directory not supported)
  18         fi
  19 fi
  20
  21 AC_PROG_CC
  22 AC_PROG_CXX
  23
  24 AX_CC_MAXOPT
  25 AX_GCC_WARN_UNUSED_RESULT
  26 AX_C___ATTRIBUTE__
  27
  28 AC_PROG_LIBTOOL
  29
  30 AC_CHECK_PROG(PERL, perl, perl, [])
  31 AC_CHECK_PROG(PDFLATEX, pdflatex, pdflatex, [])
  32 AC_CHECK_PROG(POD2HTML, pod2html, pod2html, [])
  33
  34 AM_CONDITIONAL(GENERATE_DOC, test -n "$PERL" -a -n "$PDFLATEX" -a -n "$POD2HTML")
  35
  36 AX_CREATE_STDINT_H(include/isl/stdint.h)
  37
  38 AX_SUBMODULE(gmp,system|build,system)
  39
  40 AC_SUBST(GMP_CPPFLAGS)
  41 AC_SUBST(GMP_LDFLAGS)
  42 AC_SUBST(GMP_LIBS)
  43 case "$with_gmp" in
  44 system)
  45         if test "x$with_gmp_prefix" != "x"; then
  46                 isl_configure_args="$isl_configure_args --with-gmp=$with_gmp_prefix"
  47                 GMP_CPPFLAGS="-I$with_gmp_prefix/include"
  48                 GMP_LDFLAGS="-L$with_gmp_prefix/lib"
  49         fi
  50         GMP_LIBS=-lgmp
  51         SAVE_CPPFLAGS="$CPPFLAGS"
  52         SAVE_LDFLAGS="$LDFLAGS"
  53         SAVE_LIBS="$LIBS"
  54         CPPFLAGS="$GMP_CPPFLAGS $CPPFLAGS"
  55         LDFLAGS="$GMP_LDFLAGS $LDFLAGS"
  56         LIBS="$GMP_LIBS $LIBS"
  57         AC_CHECK_HEADER([gmp.h], [], [AC_ERROR([gmp.h header not found])])
  58         AC_CHECK_LIB([gmp], [main], [], [AC_ERROR([gmp library not found])])
  59         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <gmp.h>]], [[
  60                 mpz_t n, d;
  61                 if (mpz_divisible_p(n, d))
  62                         mpz_divexact_ui(n, n, 4);
  63         ]])], [], [AC_ERROR([gmp library too old])])
  64         CPPFLAGS="$SAVE_CPPFLAGS"
  65         LDFLAGS="$SAVE_LDFLAGS"
  66         LIBS="$SAVE_LIBS"
  67         ;;
  68 build)
  69         GMP_CPPFLAGS="-I$gmp_srcdir -I$with_gmp_builddir"
  70         GMP_LIBS="$with_gmp_builddir/libgmp.la"
  71         ;;
  72 esac
  73 SAVE_CPPFLAGS="$CPPFLAGS"
  74 SAVE_LDFLAGS="$LDFLAGS"
  75 SAVE_LIBS="$LIBS"
  76 CPPFLAGS="$GMP_CPPFLAGS $CPPFLAGS"
  77 LDFLAGS="$GMP_LDFLAGS $LDFLAGS"
  78 LIBS="$GMP_LIBS $LIBS"
  79 need_get_memory_functions=false
  80 AC_CHECK_DECLS(mp_get_memory_functions,[],[
  81         need_get_memory_functions=true
  82 ],[#include <gmp.h>])
  83 CPPFLAGS="$SAVE_CPPFLAGS"
  84 LDFLAGS="$SAVE_LDFLAGS"
  85 LIBS="$SAVE_LIBS"
  86 AM_CONDITIONAL(NEED_GET_MEMORY_FUNCTIONS, test x$need_get_memory_functions = xtrue)
  87 AC_CHECK_DECLS(ffs,[],[],[#include <strings.h>])
  88 AC_CHECK_DECLS(__builtin_ffs,[],[],[])
  89
  90 AC_SUBST(CLANG_CXXFLAGS)
  91 AC_SUBST(CLANG_LDFLAGS)
  92 AC_SUBST(CLANG_LIBS)
  93 AX_SUBMODULE(clang,system|no,no)
  94 case "$with_clang" in
  95 system)
  96         AC_PROG_GREP
  97         llvm_config="llvm-config"
  98         AC_CHECK_PROG([llvm_config_found], ["$llvm_config"], [yes])
  99         if test "x$with_clang_prefix" != "x"; then
 100                 llvm_config="$with_clang_prefix/bin/llvm-config"
 101                 if test -x "$llvm_config"; then
 102                         llvm_config_found=yes
 103                 fi
 104         fi
 105         if test "$llvm_config_found" != yes; then
 106                 AC_MSG_ERROR([llvm-config not found])
 107         fi
 108         CLANG_CXXFLAGS=`$llvm_config --cxxflags`
 109         CLANG_LDFLAGS=`$llvm_config --ldflags`
 110         targets=`$llvm_config --targets-built`
 111         components="$targets asmparser bitreader support mc"
 112         $llvm_config --components | $GREP option > /dev/null 2> /dev/null
 113         if test $? -eq 0; then
 114                 components="$components option"
 115         fi
 116         CLANG_LIBS=`$llvm_config --libs $components`
 117         systemlibs=`$llvm_config --system-libs 2> /dev/null | tail -1`
 118         if test $? -eq 0; then
 119                 CLANG_LIBS="$CLANG_LIBS $systemlibs"
 120         fi
 121         CLANG_PREFIX=`$llvm_config --prefix`
 122         AC_DEFINE_UNQUOTED(CLANG_PREFIX, ["$CLANG_PREFIX"],
 123                                 [Clang installation prefix])
 124
 125         SAVE_CPPFLAGS="$CPPFLAGS"
 126         CPPFLAGS="$CLANG_CXXFLAGS $CPPFLAGS"
 127         AC_LANG_PUSH(C++)
 128         AC_CHECK_HEADER([clang/Basic/SourceLocation.h], [],
 129                 [AC_ERROR([clang header file not found])])
 130         AC_EGREP_HEADER([getDefaultTargetTriple], [llvm/Support/Host.h], [],
 131                 [AC_DEFINE([getDefaultTargetTriple], [getHostTriple],
 132                 [Define to getHostTriple for older versions of clang])])
 133         AC_EGREP_HEADER([getExpansionLineNumber],
 134                 [clang/Basic/SourceLocation.h], [],
 135                 [AC_DEFINE([getExpansionLineNumber],
 136                         [getInstantiationLineNumber],
 137             [Define to getInstantiationLineNumber for older versions of clang])])
 138         AC_EGREP_HEADER([DiagnosticsEngine],
 139                 [clang/Basic/Diagnostic.h], [],
 140                 [AC_DEFINE([DiagnosticsEngine],
 141                         [Diagnostic],
 142             [Define to Diagnostic for older versions of clang])])
 143         AC_EGREP_HEADER([ArrayRef], [clang/Driver/Driver.h],
 144                 [AC_DEFINE([USE_ARRAYREF], [],
 145                         [Define if Driver::BuildCompilation takes ArrayRef])])
 146         AC_EGREP_HEADER([CXXIsProduction], [clang/Driver/Driver.h],
 147                 [AC_DEFINE([HAVE_CXXISPRODUCTION], [],
 148                 [Define if Driver constructor takes CXXIsProduction argument])])
 149         AC_EGREP_HEADER([ IsProduction], [clang/Driver/Driver.h],
 150                 [AC_DEFINE([HAVE_ISPRODUCTION], [],
 151                 [Define if Driver constructor takes IsProduction argument])])
 152         AC_EGREP_HEADER([void HandleTopLevelDecl\(], [clang/AST/ASTConsumer.h],
 153                 [AC_DEFINE([HandleTopLevelDeclReturn], [void],
 154                            [Return type of HandleTopLevelDeclReturn])
 155                  AC_DEFINE([HandleTopLevelDeclContinue], [],
 156                            [Return type of HandleTopLevelDeclReturn])],
 157                 [AC_DEFINE([HandleTopLevelDeclReturn], [bool],
 158                            [Return type of HandleTopLevelDeclReturn])
 159                  AC_DEFINE([HandleTopLevelDeclContinue], [true],
 160                            [Return type of HandleTopLevelDeclReturn])])
 161         AC_CHECK_HEADER([clang/Basic/DiagnosticOptions.h],
 162                 [AC_DEFINE([HAVE_BASIC_DIAGNOSTICOPTIONS_H], [],
 163                            [Define if clang/Basic/DiagnosticOptions.h exists])])
 164         AC_TRY_COMPILE([#include <clang/Basic/TargetInfo.h>], [
 165                 using namespace clang;
 166                 TargetOptions *TO;
 167                 DiagnosticsEngine *Diags;
 168                 TargetInfo::CreateTargetInfo(*Diags, TO);
 169         ], [AC_DEFINE([CREATETARGETINFO_TAKES_POINTER], [],
 170                       [Define if TargetInfo::CreateTargetInfo takes pointer])])
 171         AC_TRY_COMPILE([#include <clang/Frontend/CompilerInstance.h>], [
 172                 using namespace clang;
 173                 DiagnosticConsumer *client;
 174                 CompilerInstance *Clang;
 175                 Clang->createDiagnostics(client);
 176         ], [], [AC_DEFINE([CREATEDIAGNOSTICS_TAKES_ARG], [],
 177         [Define if CompilerInstance::createDiagnostics takes argc and argv])])
 178         AC_TRY_COMPILE([#include <clang/Lex/HeaderSearchOptions.h>], [
 179                 using namespace clang;
 180                 HeaderSearchOptions HSO;
 181                 HSO.AddPath("", frontend::Angled, false, false);
 182         ], [AC_DEFINE([ADDPATH_TAKES_4_ARGUMENTS], [],
 183                 [Define if HeaderSearchOptions::AddPath takes 4 arguments])])
 184         AC_EGREP_HEADER([getNumParams],
 185                 [clang/AST/CanonicalType.h],
 186                 [AC_DEFINE([getNumArgs], [getNumParams],
 187                     [Define to getNumParams for newer versions of clang])
 188                  AC_DEFINE([getArgType], [getParamType],
 189                     [Define to getParamType for newer versions of clang])])
 190         AC_EGREP_HEADER([getReturnType],
 191                 [clang/AST/CanonicalType.h], [],
 192                 [AC_DEFINE([getReturnType], [getResultType],
 193                     [Define to getResultType for older versions of clang])])
 194         AC_TRY_COMPILE([#include <clang/Frontend/CompilerInstance.h>], [
 195                 using namespace clang;
 196                 CompilerInstance *Clang;
 197                 Clang->createPreprocessor(TU_Complete);
 198         ], [AC_DEFINE([CREATEPREPROCESSOR_TAKES_TUKIND], [],
 199         [Define if CompilerInstance::createPreprocessor takes
 200          TranslationUnitKind])])
 201         AC_LANG_POP
 202         CPPFLAGS="$SAVE_CPPFLAGS"
 203
 204         SAVE_LDFLAGS="$LDFLAGS"
 205         LDFLAGS="$CLANG_LDFLAGS $LDFLAGS"
 206         AC_SUBST(LIB_CLANG_EDIT)
 207         AC_CHECK_LIB([clangEdit], [main], [LIB_CLANG_EDIT=-lclangEdit], [])
 208         LDFLAGS="$SAVE_LDFLAGS"
 209         ;;
 210 esac
 211 AM_CONDITIONAL(HAVE_CLANG, test $with_clang = system)
 212
 213 AX_SET_WARNING_FLAGS
 214
 215 AC_SUBST(WARNING_FLAGS)
 216
 217 PACKAGE_CFLAGS="$GMP_CPPFLAGS"
 218 PACKAGE_LDFLAGS="$GMP_LDFLAGS"
 219 PACKAGE_LIBS="-lisl -lgmp"
 220 AX_CREATE_PKGCONFIG_INFO
 221
 222 AX_DETECT_GIT_HEAD
 223 echo '#define GIT_HEAD_ID "'$GIT_HEAD_ID'"' > gitversion.h
 224
 225 AH_BOTTOM([#include <isl_config_post.h>])
 226 AC_CONFIG_HEADERS(isl_config.h)
 227 AC_CONFIG_FILES(Makefile)
 228 AC_CONFIG_FILES(doc/Makefile)
 229 if test $with_clang = system; then
 230         AC_CONFIG_FILES(interface/Makefile)
 231 fi
 232 AC_CONFIG_FILES([bound_test.sh], [chmod +x bound_test.sh])
 233 AC_CONFIG_FILES([codegen_test.sh], [chmod +x codegen_test.sh])
 234 AC_CONFIG_FILES([pip_test.sh], [chmod +x pip_test.sh])
 235 AC_CONFIG_COMMANDS_POST([
 236         dnl pass on arguments to subdir configures, but don't
 237         dnl add them to config.status
 238         ac_configure_args="$ac_configure_args $isl_configure_args"
 239 ])
 240 AC_OUTPUT