configure.ac

   1 AC_INIT
   2 AC_CONFIG_AUX_DIR([.])
   3 AC_CONFIG_MACRO_DIR([m4])
   4 AM_INIT_AUTOMAKE(isl, 0.01)
   5 AC_SUBST(versioninfo)
   6 versioninfo=1:0:0
   7
   8 AC_PROG_CC
   9
  10 AX_CC_MAXOPT
  11 AX_GCC_WARN_UNUSED_RESULT
  12
  13 AC_PROG_LIBTOOL
  14
  15 AC_CHECK_PROG(PERL, perl, perl, [])
  16 AC_CHECK_PROG(PDFLATEX, pdflatex, pdflatex, [])
  17 AC_CHECK_PROG(POD2HTML, pod2html, pod2html, [])
  18
  19 AM_CONDITIONAL(GENERATE_DOC, test -n "$PERL" -a -n "$PDFLATEX" -a -n "$POD2HTML")
  20
  21 AX_CREATE_STDINT_H(include/isl_stdint.h)
  22
  23 AX_SUBMODULE(gmp,system,system)
  24
  25 AC_SUBST(GMP_CPPFLAGS)
  26 AC_SUBST(GMP_LDFLAGS)
  27 if test "x$with_gmp_prefix" != "x"; then
  28         isl_configure_args="$isl_configure_args --with-gmp=$with_gmp_prefix"
  29         GMP_CPPFLAGS="-I$with_gmp_prefix/include"
  30         GMP_LDFLAGS="-L$with_gmp_prefix/lib"
  31 fi
  32 SAVE_CPPFLAGS="$CPPFLAGS"
  33 CPPFLAGS="$GMP_CPPFLAGS $CPPFLAGS"
  34 need_get_memory_functions=false
  35 AC_CHECK_DECLS(mp_get_memory_functions,[],[
  36         need_get_memory_functions=true
  37 ],[#include <gmp.h>])
  38 CPPFLAGS="$SAVE_CPPFLAGS"
  39 AM_CONDITIONAL(NEED_GET_MEMORY_FUNCTIONS, test x$need_get_memory_functions = xtrue)
  40
  41 AX_SUBMODULE(piplib,no|system|build|bundled,no)
  42
  43 have_piplib=false
  44 AC_SUBST(PIPLIB_CPPFLAGS)
  45 AC_SUBST(PIPLIB_LDFLAGS)
  46 AC_SUBST(PIPLIB_LIBS)
  47 case "$with_piplib" in
  48         bundled)
  49                 PIPLIB_CPPFLAGS="-I$srcdir/piplib/include"
  50                 isl_configure_args="$isl_configure_args --with-bits=gmp"
  51         ;;
  52         build)
  53                 PIPLIB_CPPFLAGS="-I$piplib_srcdir/include"
  54                 PIPLIB_LIBS="$with_piplib_builddir/libpiplibMP.la"
  55         ;;
  56         system)
  57                 PIPLIB_LIBS="-lpiplibMP"
  58                 if test "x$with_piplib_prefix" != "x"; then
  59                         PIPLIB_CPPFLAGS="-I$with_piplib_prefix/include"
  60                         PIPLIB_LDFLAGS="-L$with_piplib_prefix/lib"
  61                 fi
  62                 SAVE_CPPFLAGS="$CPPFLAGS"
  63                 SAVE_LDFLAGS="$LDFLAGS"
  64                 CPPFLAGS="$PIPLIB_CPPFLAGS $CPPFLAGS"
  65                 LDFLAGS="$PIPLIB_LDFLAGS $LDFLAGS"
  66                 AC_CHECK_LIB(piplibMP, pip_solve,[
  67                         AC_CHECK_MEMBER(PipOptions.Urs_parms, [], [
  68                                 AC_MSG_ERROR([Piplib too old; please install version 1.3.6 or newer])
  69                         ],[#include <piplib/piplibMP.h>])
  70                 ],[
  71                         AC_MSG_ERROR([Piplib not found])
  72                 ])
  73                 CPPFLAGS="$SAVE_CPPFLAGS"
  74                 LDFLAGS="$SAVE_LDFLAGS"
  75         ;;
  76         no)
  77         ;;
  78         *)
  79                 AC_MSG_ERROR(unsupported)
  80         ;;
  81 esac
  82 if test "$with_piplib" != "no"; then
  83         AC_DEFINE(ISL_PIPLIB,,piplib is available)
  84         have_piplib=true
  85 fi
  86 AM_CONDITIONAL(HAVE_PIPLIB, test x$have_piplib = xtrue)
  87 AM_CONDITIONAL(BUNDLED_PIPLIB, test $with_piplib = bundled)
  88
  89 PACKAGE_CFLAGS="-I$prefix/include/isl"
  90 AX_CREATE_PKGCONFIG_INFO
  91
  92 AC_CONFIG_HEADERS(config.h)
  93 AC_CONFIG_HEADERS(include/isl_config.h)
  94 AC_CONFIG_FILES(Makefile)
  95 AC_CONFIG_FILES(doc/Makefile)
  96 if test $with_piplib = bundled; then
  97         AC_CONFIG_SUBDIRS(piplib)
  98 fi
  99 AC_CONFIG_COMMANDS_POST([
 100         dnl pass on arguments to subdir configures, but don't
 101         dnl add them to config.status
 102         ac_configure_args="$ac_configure_args $isl_configure_args"
 103 ])
 104 AC_OUTPUT