configure.ac

   1 AC_INIT
   2 AC_CONFIG_AUX_DIR([.])
   3 AC_CONFIG_MACRO_DIR([m4])
   4 AM_INIT_AUTOMAKE(isl-polylib, 0.01)
   5 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
   6 AC_SUBST(versioninfo)
   7 versioninfo=1:0:0
   8
   9 AC_PROG_CC
  10 AC_PROG_LIBTOOL
  11
  12 AX_SUBMODULE(gmp,system,system)
  13
  14 AC_SUBST(GMP_CPPFLAGS)
  15 AC_SUBST(GMP_LDFLAGS)
  16 if test "x$with_gmp_prefix" != "x"; then
  17         GMP_CPPFLAGS="-I$with_gmp_prefix/include"
  18 fi
  19 if test "x$with_gmp_exec_prefix" != "x"; then
  20         GMP_LDFLAGS="-L$with_gmp_exec_prefix/lib"
  21 fi
  22
  23 AX_SUBMODULE(isl,system|build|bundled,bundled)
  24
  25 AX_SUBMODULE(polylib,system|build|bundled,bundled)
  26 AC_SUBST(POLYLIB_CPPFLAGS)
  27 AC_SUBST(POLYLIB_LDFLAGS)
  28 AC_SUBST(POLYLIB_LIBS)
  29 case "$with_polylib" in
  30         bundled)
  31                 POLYLIB_CPPFLAGS="-I$srcdir/polylib/include"
  32                 if test "x$with_gmp_prefix" != "x"; then
  33                         isl_polylib_configure_args="$isl_polylib_configure_args --with-libgmp=$with_gmp_prefix"
  34                 else
  35                         isl_polylib_configure_args="$isl_polylib_configure_args --with-libgmp"
  36                 fi
  37         ;;
  38         build)
  39                 polylibs=`echo @polylibs@ | $with_polylib_builddir/config.status --file=-`
  40                 AC_MSG_NOTICE(Configured polylibs: $polylibs)
  41                 isl_cv_polylib=missing
  42                 for bits in $polylibs; do
  43                         if test "$bits" = "libpolylibgmp.la"; then
  44                                 isl_cv_polylib=ok
  45                         fi
  46                 done
  47                 if test "$isl_cv_polylib" = "missing"; then
  48                         AC_MSG_ERROR(no gmp polylib configured)
  49                 fi
  50                 POLYLIB_CPPFLAGS="-I$with_polylib_builddir/include -I$polylib_srcdir/include"
  51                 POLYLIB_LIBS="$with_polylib_builddir/libpolylibgmp.la"
  52         ;;
  53         system)
  54                 POLYLIB_LIBS="-lpolylibgmp"
  55                 if test "x$with_polylib_prefix" != "x"; then
  56                         POLYLIB_CPPFLAGS="-I$with_polylib_prefix/include"
  57                         POLYLIB_LDFLAGS="-L$with_polylib_prefix/lib"
  58                 fi
  59                 SAVE_CPPFLAGS="$CPPFLAGS"
  60                 SAVE_LDFLAGS="$LDFLAGS"
  61                 CPPFLAGS="$POLYLIB_CPPFLAGS $CPPFLAGS"
  62                 LDFLAGS="$POLYLIB_LDFLAGS $LDFLAGS"
  63                 AC_CHECK_LIB(polylibgmp, PolyhedronTSort,[ true ],[
  64                         AC_MSG_ERROR(Need polylib)
  65                 ])
  66                 CPPFLAGS="$SAVE_CPPFLAGS"
  67                 LDFLAGS="$SAVE_LDFLAGS"
  68         ;;
  69         *)
  70                 AC_MSG_ERROR(unsupported)
  71         ;;
  72 esac
  73 AM_CONDITIONAL(BUNDLED_POLYLIB, test $with_polylib = bundled)
  74
  75 AC_SUBST(ISL_CFLAGS)
  76 AC_SUBST(ISL_LIBS)
  77 case "$with_isl" in
  78 bundled)
  79         ISL_CFLAGS="-I$srcdir/isl/include -Iisl/include"
  80         ;;
  81 build)
  82         ISL_CFLAGS="-I$isl_srcdir/include -I$with_isl_builddir/include"
  83         ISL_LIBS="$with_isl_builddir/libisl.la"
  84         ;;
  85 system)
  86         if test "x$with_isl_exec_prefix" != "x"; then
  87                 export PKG_CONFIG_PATH=$with_isl_exec_prefix/lib/pkgconfig:$PKG_CONFIG_PATH
  88         fi
  89         PKG_CHECK_MODULES([ISL], [isl])
  90 esac
  91 AM_CONDITIONAL(BUNDLED_ISL, test $with_isl = bundled)
  92
  93 PACKAGE_CFLAGS="-I\${prefix}/include/isl-polylib -I\${prefix}/include"
  94 AX_CREATE_PKGCONFIG_INFO
  95
  96 AC_CONFIG_FILES(Makefile)
  97 if test $with_isl = bundled; then
  98     AC_CONFIG_SUBDIRS(isl)
  99 fi
 100 if test $with_polylib = bundled; then
 101     AC_CONFIG_SUBDIRS(polylib)
 102 fi
 103 AC_CONFIG_COMMANDS_POST([
 104         dnl pass on arguments to subdir configures, but don't
 105         dnl add them to config.status
 106         ac_configure_args="$ac_configure_args $isl_polylib_configure_args --with-bits=gmp"
 107 ])
 108 AC_OUTPUT