src/sockets/socket-methods.lisp

   1 ;;;; -*- Mode: Lisp; indent-tabs-mode: nil -*-
   2 ;;;
   3 ;;; --- Various socket methods.
   4 ;;;
   5
   6 (in-package :iolib.sockets)
   7
   8 ;;;-------------------------------------------------------------------------
   9 ;;; Shared Initialization
  10 ;;;-------------------------------------------------------------------------
  11
  12 (defun translate-make-socket-keywords-to-constants (address-family type protocol)
  13   (let ((sf (ecase address-family
  14               (:ipv4  af-inet)
  15               (:ipv6  af-inet6)
  16               (:local af-local)))
  17         (st (ecase type
  18               (:stream   sock-stream)
  19               (:datagram sock-dgram)
  20               (:raw      sock-raw)))
  21         (sp (etypecase protocol
  22               ((eql :default) 0)
  23               (integer        protocol))))
  24     (values sf st sp)))
  25
  26 (defmethod socket-os-fd ((socket socket))
  27   (fd-of socket))
  28
  29 (defmethod shared-initialize :after
  30     ((socket socket) slot-names
  31      &key file-descriptor (dup t) address-family type protocol)
  32   (declare (ignore slot-names))
  33   (with-accessors ((fd fd-of) (fam socket-address-family) (proto socket-protocol))
  34       socket
  35     (setf fd (or (and file-descriptor (if dup
  36                                           (isys:dup file-descriptor)
  37                                           file-descriptor))
  38                  (multiple-value-call #'%socket
  39                    (translate-make-socket-keywords-to-constants
  40                     address-family type protocol))))
  41     (setf fam address-family
  42           proto protocol)))
  43
  44 (defmethod (setf external-format-of) (external-format (socket passive-socket))
  45   (setf (slot-value socket 'external-format)
  46         (babel:ensure-external-format (or external-format :default))))
  47
  48 (defmethod shared-initialize :after ((socket passive-socket) slot-names
  49                                      &key external-format
  50                                      input-buffer-size output-buffer-size)
  51   ;; Makes CREATE-SOCKET simpler
  52   (declare (ignore slot-names input-buffer-size output-buffer-size))
  53   (setf (external-format-of socket) (or external-format :default)))
  54 \f
  55
  56 ;;;-------------------------------------------------------------------------
  57 ;;; Misc
  58 ;;;-------------------------------------------------------------------------
  59
  60 (defmethod socket-type ((socket stream-socket))
  61   :stream)
  62
  63 (defmethod socket-type ((socket datagram-socket))
  64   :datagram)
  65
  66 (defun socket-ipv6-p (socket)
  67   "Return T if SOCKET is an AF_INET6 socket."
  68   (eql :ipv6 (socket-address-family socket)))
  69
  70 (defun ipv6-socket-p (&rest args)
  71   (apply #'socket-ipv6-p args))
  72
  73 (defobsolete ipv6-socket-p socket-ipv6-p)
  74 \f
  75
  76 ;;;-------------------------------------------------------------------------
  77 ;;; PRINT-OBJECT
  78 ;;;-------------------------------------------------------------------------
  79
  80 (defun sock-fam (socket)
  81   (ecase (socket-address-family socket)
  82     (:ipv4 "IPv4")
  83     (:ipv6 "IPv6")))
  84
  85 (defmethod print-object ((socket socket-stream-internet-active) stream)
  86   (print-unreadable-object (socket stream :identity t)
  87     (format stream "active ~A stream socket" (sock-fam socket))
  88     (if (socket-connected-p socket)
  89         (multiple-value-bind (host port) (remote-name socket)
  90           (format stream " connected to ~A/~A"
  91                   (address-to-string host) port))
  92         (format stream ", ~:[closed~;unconnected~]" (fd-of socket)))))
  93
  94 (defmethod print-object ((socket socket-stream-internet-passive) stream)
  95   (print-unreadable-object (socket stream :identity t)
  96     (format stream "passive ~A stream socket" (sock-fam socket))
  97     (if (socket-bound-p socket)
  98         (multiple-value-bind (host port) (local-name socket)
  99           (format stream " ~:[bound to~;waiting @~] ~A/~A"
 100                   (socket-listening-p socket)
 101                   (address-to-string host) port))
 102         (format stream ", ~:[closed~;unbound~]" (fd-of socket)))))
 103
 104 (defmethod print-object ((socket socket-stream-local-active) stream)
 105   (print-unreadable-object (socket stream :identity t)
 106     (format stream "active local stream socket")
 107     (if (socket-connected-p socket)
 108         (format stream " connected to ~S"
 109                 (address-to-string (remote-filename socket)))
 110         (format stream ", ~:[closed~;unconnected~]" (fd-of socket)))))
 111
 112 (defmethod print-object ((socket socket-stream-local-passive) stream)
 113   (print-unreadable-object (socket stream :identity t)
 114     (format stream "passive local stream socket")
 115     (if (socket-bound-p socket)
 116         (format stream " ~:[bound to~;waiting @~] ~S"
 117                   (socket-listening-p socket)
 118                   (address-to-string (local-filename socket)))
 119         (format stream ", ~:[closed~;unbound~]" (fd-of socket)))))
 120
 121 (defmethod print-object ((socket socket-datagram-local) stream)
 122   (print-unreadable-object (socket stream :identity t)
 123     (format stream "local datagram socket")
 124     (if (socket-connected-p socket)
 125         (format stream " connected to ~S"
 126                 (address-to-string (remote-filename socket)))
 127         (if (fd-of socket)
 128             (format stream " waiting @ ~S" (address-to-string (local-filename socket)))
 129             (format stream ", closed" )))))
 130
 131 (defmethod print-object ((socket socket-datagram-internet) stream)
 132   (print-unreadable-object (socket stream :identity t)
 133     (format stream "~A datagram socket" (sock-fam socket))
 134     (if (socket-connected-p socket)
 135         (multiple-value-bind (host port) (remote-name socket)
 136           (format stream " connected to ~A/~A"
 137                   (address-to-string host) port))
 138         (if (fd-of socket)
 139             (multiple-value-bind (host port) (local-name socket)
 140               (format stream " waiting @ ~A/~A"
 141                       (address-to-string host) port))
 142             (format stream ", closed" )))))
 143 \f
 144
 145 ;;;-------------------------------------------------------------------------
 146 ;;; CLOSE
 147 ;;;-------------------------------------------------------------------------
 148
 149 (defmethod close :around ((socket socket) &key abort)
 150   (declare (ignore abort))
 151   (prog1 (socket-open-p socket)
 152     (call-next-method)
 153     (setf (slot-value socket 'bound) nil)))
 154
 155 (defmethod close ((socket passive-socket) &key abort)
 156   (declare (ignore abort))
 157   (when (next-method-p) (call-next-method))
 158   (setf (slot-value socket 'listening) nil))
 159
 160 (defmethod close ((socket datagram-socket) &key abort)
 161   (declare (ignore abort))
 162   (when (next-method-p) (call-next-method)))
 163
 164 (defmethod socket-open-p ((socket socket))
 165   (when (fd-of socket)
 166     (with-sockaddr-storage-and-socklen (ss size)
 167       (handler-case
 168           (%getsockname (fd-of socket) ss size)
 169         (isys:ebadf () nil)
 170         (socket-connection-reset-error () nil)
 171         (:no-error (_) (declare (ignore _)) t)))))
 172 \f
 173
 174 ;;;-------------------------------------------------------------------------
 175 ;;; GETSOCKNAME
 176 ;;;-------------------------------------------------------------------------
 177
 178 (defun %local-name (socket)
 179   (with-sockaddr-storage-and-socklen (ss size)
 180     (%getsockname (fd-of socket) ss size)
 181     (sockaddr-storage->sockaddr ss)))
 182
 183 (defmethod local-name ((socket socket))
 184   (%local-name socket))
 185
 186 (defmethod local-host ((socket internet-socket))
 187   (nth-value 0 (%local-name socket)))
 188
 189 (defmethod local-port ((socket internet-socket))
 190   (nth-value 1 (%local-name socket)))
 191
 192 (defmethod local-filename ((socket local-socket))
 193   (%local-name socket))
 194 \f
 195
 196 ;;;-------------------------------------------------------------------------
 197 ;;; GETPEERNAME
 198 ;;;-------------------------------------------------------------------------
 199
 200 (defun %remote-name (socket)
 201   (with-sockaddr-storage-and-socklen (ss size)
 202     (%getpeername (fd-of socket) ss size)
 203     (sockaddr-storage->sockaddr ss)))
 204
 205 (defmethod remote-name ((socket socket))
 206   (%remote-name socket))
 207
 208 (defmethod remote-host ((socket internet-socket))
 209   (nth-value 0 (%remote-name socket)))
 210
 211 (defmethod remote-port ((socket internet-socket))
 212   (nth-value 1 (%remote-name socket)))
 213
 214 (defmethod remote-filename ((socket local-socket))
 215   (%remote-name socket))
 216 \f
 217
 218 ;;;-------------------------------------------------------------------------
 219 ;;; BIND
 220 ;;;-------------------------------------------------------------------------
 221
 222 (defmethod bind-address :before ((socket internet-socket) address
 223                                  &key (reuse-address t))
 224   (declare (ignore address))
 225   (when reuse-address
 226     (setf (socket-option socket :reuse-address) t)))
 227
 228 (defun bind-ipv4-address (fd address port)
 229   (with-sockaddr-in (sin address port)
 230     (%bind fd sin (isys:sizeof 'sockaddr-in))))
 231
 232 (defun bind-ipv6-address (fd address port)
 233   (with-sockaddr-in6 (sin6 address port)
 234     (%bind fd sin6 (isys:sizeof 'sockaddr-in6))))
 235
 236 (defmethod bind-address ((socket internet-socket) (address ipv4-address)
 237                          &key (port 0))
 238   (let ((port (ensure-numerical-service port)))
 239     (if (socket-ipv6-p socket)
 240         (bind-ipv6-address (fd-of socket)
 241                            (map-ipv4-vector-to-ipv6 (address-name address))
 242                            port)
 243         (bind-ipv4-address (fd-of socket) (address-name address) port)))
 244   (values socket))
 245
 246 (defmethod bind-address ((socket internet-socket) (address ipv6-address)
 247                          &key (port 0))
 248   (bind-ipv6-address (fd-of socket)
 249                      (address-name address)
 250                      (ensure-numerical-service port))
 251   (values socket))
 252
 253 (defmethod bind-address ((socket local-socket) (address local-address) &key)
 254   (with-sockaddr-un (sun (address-name address) (abstract-address-p address))
 255     (%bind (fd-of socket) sun (actual-size-of-sockaddr-un sun)))
 256   (values socket))
 257
 258 (defmethod bind-address :after ((socket socket) (address address) &key)
 259   (setf (slot-value socket 'bound) t))
 260 \f
 261
 262 ;;;-------------------------------------------------------------------------
 263 ;;; LISTEN
 264 ;;;-------------------------------------------------------------------------
 265
 266 (defmethod listen-on ((socket socket) &key backlog)
 267   (unless backlog (setf backlog (min *default-backlog-size*
 268                                      +max-backlog-size+)))
 269   (check-type backlog unsigned-byte "a non-negative integer")
 270   (%listen (fd-of socket) backlog)
 271   (setf (slot-value socket 'listening) t)
 272   (values socket))
 273 \f
 274
 275 ;;;-------------------------------------------------------------------------
 276 ;;; ACCEPT
 277 ;;;-------------------------------------------------------------------------
 278
 279 (defmethod accept-connection ((socket passive-socket) &key external-format
 280                               input-buffer-size output-buffer-size (wait t))
 281   (check-type wait timeout-designator)
 282   (flet ((make-client-socket (fd)
 283            (make-instance (active-class socket)
 284                           :address-family (socket-address-family socket)
 285                           :file-descriptor fd :dup nil
 286                           :external-format (or external-format
 287                                                (external-format-of socket))
 288                           :input-buffer-size input-buffer-size
 289                           :output-buffer-size output-buffer-size)))
 290     (ignore-some-conditions (isys:ewouldblock iomux:poll-timeout)
 291       (iomux:wait-until-fd-ready (fd-of socket) :input (wait->timeout wait) t)
 292       (with-sockaddr-storage-and-socklen (ss size)
 293         (values (make-client-socket (%accept (fd-of socket) ss size))
 294                 (sockaddr-storage->sockaddr ss))))))
 295 \f
 296
 297 ;;;-------------------------------------------------------------------------
 298 ;;; CONNECT
 299 ;;;-------------------------------------------------------------------------
 300
 301 (defun ipv4-connect (fd address port)
 302   (with-sockaddr-in (sin address port)
 303     (%connect fd sin (isys:sizeof 'sockaddr-in))))
 304
 305 (defun ipv6-connect (fd address port)
 306   (with-sockaddr-in6 (sin6 address port)
 307     (%connect fd sin6 (isys:sizeof 'sockaddr-in6))))
 308
 309 (defun call-with-socket-to-wait-connect (socket thunk wait)
 310   (check-type wait timeout-designator)
 311   (let ((timeout (wait->timeout wait)))
 312     (flet
 313         ((wait-connect ()
 314            (when (or (null  timeout)
 315                      (plusp timeout))
 316              (handler-case
 317                  (iomux:wait-until-fd-ready (fd-of socket) :output timeout t)
 318                (iomux:poll-error ()
 319                  (let ((errcode (socket-option socket :error)))
 320                    (if (zerop errcode)
 321                        (bug "Polling socket signalled an error but SO_ERROR is 0")
 322                        (signal-socket-error errcode "connect" (fd-of socket)))))))))
 323       (ignore-some-conditions (iomux:poll-timeout)
 324         (handler-case
 325             (funcall thunk)
 326           ((or isys:ewouldblock
 327                isys:einprogress) ()
 328             (wait-connect)))))))
 329
 330 (defmacro with-socket-to-wait-connect ((socket wait) &body body)
 331   `(call-with-socket-to-wait-connect ,socket (lambda () ,@body) ,wait))
 332
 333 (defmethod connect ((socket internet-socket) (address inet-address)
 334                     &key (port 0) (wait t))
 335   (let ((name (address-name address))
 336         (port (ensure-numerical-service port)))
 337     (with-socket-to-wait-connect (socket wait)
 338       (cond
 339         ((socket-ipv6-p socket)
 340          (when (ipv4-address-p address)
 341            (setf name (map-ipv4-vector-to-ipv6 name)))
 342          (ipv6-connect (fd-of socket) name port))
 343         (t (ipv4-connect (fd-of socket) name port)))))
 344   (values socket))
 345
 346 (defmethod connect ((socket local-socket) (address local-address) &key (wait t))
 347   (with-socket-to-wait-connect (socket wait)
 348     (with-sockaddr-un (sun (address-name address) (abstract-address-p address))
 349         (%connect (fd-of socket) sun (actual-size-of-sockaddr-un sun))))
 350   (values socket))
 351
 352 (defmethod socket-connected-p ((socket socket))
 353   (if (fd-of socket)
 354       (with-sockaddr-storage-and-socklen (ss size)
 355         (handler-case
 356             (%getpeername (fd-of socket) ss size)
 357           ((or isys:enotconn isys:einval) ()  nil)
 358           (:no-error (_) (declare (ignore _)) t)))
 359       nil))
 360 \f
 361
 362 ;;;-------------------------------------------------------------------------
 363 ;;; DISCONNECT
 364 ;;;-------------------------------------------------------------------------
 365
 366 (defmethod disconnect ((socket datagram-socket))
 367   (with-foreign-object (sin 'sockaddr-in)
 368     (isys:bzero sin (isys:sizeof 'sockaddr-in))
 369     (setf (foreign-slot-value sin 'sockaddr-in 'addr) af-unspec)
 370     (%connect (fd-of socket) sin (isys:sizeof 'sockaddr-in))
 371     (values socket)))
 372 \f
 373
 374 ;;;-------------------------------------------------------------------------
 375 ;;; SHUTDOWN
 376 ;;;-------------------------------------------------------------------------
 377
 378 (defmethod shutdown ((socket socket) &key read write)
 379   (assert (or read write) (read write)
 380           "You must select at least one direction to shut down.")
 381   (%shutdown (fd-of socket)
 382              (multiple-value-case ((read write))
 383                ((*   nil) shut-rd)
 384                ((nil *)   shut-wr)
 385                (t         shut-rdwr)))
 386   (values socket))
 387 \f
 388
 389 ;;;-------------------------------------------------------------------------
 390 ;;; Socket flag definition
 391 ;;;-------------------------------------------------------------------------
 392
 393 (defmacro define-socket-flag (place name value platform)
 394   (let ((val (cond ((or (not platform)
 395                         (featurep platform)) value)
 396                    ((not (featurep platform)) 0))))
 397     `(pushnew (cons ,name ,val) ,place)))
 398
 399 (defmacro define-socket-flags (place &body definitions)
 400   (flet ((dflag (form)
 401            (destructuring-bind (name value &optional platform) form
 402              `(define-socket-flag ,place ,name ,value ,platform))))
 403     `(progn
 404        ,@(mapcar #'dflag definitions))))
 405 \f
 406
 407 ;;;-------------------------------------------------------------------------
 408 ;;; SENDTO
 409 ;;;-------------------------------------------------------------------------
 410
 411 (defvar *sendto-flags* ())
 412
 413 (define-socket-flags *sendto-flags*
 414   (:dont-route    msg-dontroute)
 415   (:dont-wait     msg-dontwait  (:not :windows))
 416   (:out-of-band   msg-oob)
 417   (:more          msg-more      :linux)
 418   (:confirm       msg-confirm   :linux))
 419
 420 (defun %%send-to (fd ss got-peer buff-sap start length flags)
 421   (incf-pointer buff-sap start)
 422   (loop
 423     (restart-case
 424         (return*
 425          (%sendto fd buff-sap length flags
 426                   (if got-peer ss (null-pointer))
 427                   (if got-peer (sockaddr-size ss) 0)))
 428       (ignore-syscall-error ()
 429         :report "Ignore this socket condition"
 430         :test isys:syscall-error-p
 431         (return* 0))
 432       (retry-syscall (&optional (timeout 15.0d0))
 433         :report "Try to send data again"
 434         :test isys:syscall-error-p
 435         (when (plusp timeout)
 436           (iomux:wait-until-fd-ready fd :output timeout nil))))))
 437
 438 (defun %send-to (fd ss got-peer buffer start end flags)
 439   (etypecase buffer
 440     (ub8-sarray
 441      (check-bounds buffer start end)
 442      (with-pointer-to-vector-data (buff-sap buffer)
 443        (%%send-to fd ss got-peer buff-sap start (- end start) flags)))
 444     ((or ub8-vector (vector t))
 445      (check-bounds buffer start end)
 446      (with-pointer-to-vector-data (buff-sap (coerce buffer 'ub8-sarray))
 447        (%%send-to fd ss got-peer buff-sap start (- end start) flags)))
 448     (foreign-pointer
 449      (check-type start unsigned-byte)
 450      (check-type end   unsigned-byte)
 451      (%%send-to fd ss got-peer buffer start (- end start) flags))))
 452
 453 (defmethod send-to ((socket internet-socket) buffer &rest args
 454                     &key (start 0) end remote-host (remote-port 0) flags (ipv6 *ipv6*))
 455   (let ((*ipv6* ipv6))
 456     (with-sockaddr-storage (ss)
 457       (when remote-host
 458         (sockaddr->sockaddr-storage ss (ensure-hostname remote-host)
 459                                     (ensure-numerical-service remote-port)))
 460       (%send-to (fd-of socket) ss (if remote-host t) buffer start end
 461                 (or flags (compute-flags *sendto-flags* args))))))
 462
 463 (defmethod send-to ((socket local-socket) buffer &rest args
 464                     &key (start 0) end remote-filename flags)
 465   (with-sockaddr-storage (ss)
 466     (when remote-filename
 467       (sockaddr->sockaddr-storage ss (ensure-address remote-filename :family :local) 0))
 468     (%send-to (fd-of socket) ss (if remote-filename t) buffer start end
 469               (or flags (compute-flags *sendto-flags* args)))))
 470
 471 (define-compiler-macro send-to (&whole form &environment env socket buffer &rest args
 472                                 &key (start 0) end (remote-host nil host-p) (remote-port 0 port-p)
 473                                 (remote-filename nil file-p) flags (ipv6 '*ipv6* ipv6-p) &allow-other-keys)
 474   (let ((flags-val (compute-flags *sendto-flags* args env)))
 475     (cond
 476       ((and (not flags) flags-val)
 477        (append
 478         `(send-to ,socket ,buffer :start ,start :end ,end :flags ,flags-val)
 479         (when host-p `(:remote-host ,remote-host))
 480         (when port-p `(:remote-port ,remote-port))
 481         (when ipv6-p `(:ipv6 ,ipv6))
 482         (when file-p `(:remote-filename ,remote-filename))))
 483       (t
 484        form))))
 485 \f
 486
 487 ;;;-------------------------------------------------------------------------
 488 ;;; RECVFROM
 489 ;;;-------------------------------------------------------------------------
 490
 491 (defvar *recvfrom-flags* ())
 492
 493 (define-socket-flags *recvfrom-flags*
 494   (:out-of-band msg-oob)
 495   (:peek        msg-peek)
 496   (:wait-all    msg-waitall  (:not :windows))
 497   (:dont-wait   msg-dontwait (:not :windows)))
 498
 499 (defun %%receive-from (fd ss size buffer start length flags)
 500   (with-pointer-to-vector-data (buff-sap buffer)
 501     (incf-pointer buff-sap start)
 502     (loop
 503        (restart-case
 504            (return* (%recvfrom fd buff-sap length flags ss size))
 505          (ignore-syscall-error ()
 506            :report "Ignore this socket condition"
 507            :test isys:syscall-error-p
 508            (return* 0))
 509          (retry-syscall (&optional (timeout 15.0d0))
 510            :report "Try to receive data again"
 511            :test isys:syscall-error-p
 512            (when (plusp timeout)
 513              (iomux:wait-until-fd-ready fd :input timeout nil)))))))
 514
 515 (defun %receive-from (fd ss size buffer start end flags)
 516   (check-bounds buffer start end)
 517   (flet ((%do-recvfrom (buff start length)
 518            (%%receive-from fd ss size buff start length flags)))
 519     (let (nbytes)
 520       (etypecase buffer
 521         (ub8-sarray
 522          (setf nbytes (%do-recvfrom buffer start (- end start))))
 523         ((or ub8-vector (vector t))
 524          (let ((tmpbuff (make-array (- end start) :element-type 'ub8)))
 525            (setf nbytes (%do-recvfrom tmpbuff 0 (- end start)))
 526            (replace buffer tmpbuff :start1 start :end1 end :start2 0 :end2 nbytes))))
 527       (values nbytes))))
 528
 529 (defmethod receive-from :around ((socket socket) &rest args
 530                                  &key buffer size (start 0) end flags &allow-other-keys)
 531   (let ((flags-val (or flags (compute-flags *recvfrom-flags* args))))
 532     (cond
 533       (buffer
 534        (call-next-method socket :buffer buffer :start start :end end :flags flags-val))
 535       (t
 536        (check-type size unsigned-byte "a non-negative integer")
 537        (call-next-method socket :buffer (make-array size :element-type 'ub8)
 538                          :start 0 :end size :flags flags-val)))))
 539
 540 (defmethod receive-from ((socket stream-socket) &key buffer start end flags)
 541   (with-sockaddr-storage-and-socklen (ss size)
 542     (let ((nbytes (%receive-from (fd-of socket) ss size buffer start end flags)))
 543       (values buffer nbytes))))
 544
 545 (defmethod receive-from ((socket datagram-socket) &key buffer start end flags)
 546   (with-sockaddr-storage-and-socklen (ss size)
 547     (let ((nbytes (%receive-from (fd-of socket) ss size buffer start end flags)))
 548       (multiple-value-call #'values buffer nbytes
 549                            (sockaddr-storage->sockaddr ss)))))
 550
 551 (define-compiler-macro receive-from (&whole form &environment env socket &rest args
 552                                      &key buffer size (start 0) end flags &allow-other-keys)
 553   (let ((flags-val (compute-flags *recvfrom-flags* args env)))
 554     (cond
 555       ((and (not flags) flags-val)
 556        `(receive-from ,socket :buffer ,buffer :start ,start :end ,end
 557                       :size ,size :flags ,flags-val))
 558       (t
 559        form))))