io-multiplex/epoll.lisp

   1 ;; -*- Mode: Lisp; Syntax: ANSI-Common-Lisp -*-
   2
   3 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
   4 ;   Copyright (C) 2006,2007 by Stelian Ionescu                            ;
   5 ;                                                                         ;
   6 ;   This program is free software; you can redistribute it and/or modify  ;
   7 ;   it under the terms of the GNU General Public License as published by  ;
   8 ;   the Free Software Foundation; either version 2 of the License, or     ;
   9 ;   (at your option) any later version.                                   ;
  10 ;                                                                         ;
  11 ;   This program is distributed in the hope that it will be useful,       ;
  12 ;   but WITHOUT ANY WARRANTY; without even the implied warranty of        ;
  13 ;   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the         ;
  14 ;   GNU General Public License for more details.                          ;
  15 ;                                                                         ;
  16 ;   You should have received a copy of the GNU General Public License     ;
  17 ;   along with this program; if not, write to the                         ;
  18 ;   Free Software Foundation, Inc.,                                       ;
  19 ;   51 Franklin St, Fifth Floor, Boston, MA  02110-1301  USA              ;
  20 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  21
  22 (in-package :io.multiplex)
  23
  24 (defconstant +epoll-priority+ 1)
  25
  26
  27 (define-multiplexer epoll-multiplexer +epoll-priority+ (multiplexer)
  28   ())
  29
  30
  31 (defmethod print-object ((mux epoll-multiplexer) stream)
  32   (print-unreadable-object (mux stream :type nil :identity nil)
  33     (format stream "epoll(4) multiplexer")))
  34
  35
  36 (defconstant +epoll-default-size-hint+ 25)
  37 (defvar *epoll-max-events* 200)
  38
  39
  40 (defmethod initialize-instance :after ((mux epoll-multiplexer)
  41                                        &key (size +epoll-default-size-hint+))
  42   (let ((epoll-fd (et:epoll-create size)))
  43     (setf (slot-value mux 'fd) epoll-fd)
  44     (et:finalize-object-closing-fd mux epoll-fd)))
  45
  46
  47 (defun calc-epoll-flags (fd-entry)
  48   (logior (if (not (queue-empty-p (fd-entry-read-events fd-entry))) et:epollin 0)
  49           (if (not (queue-empty-p (fd-entry-write-events fd-entry))) et:epollout 0)
  50           et:epollpri))
  51
  52
  53 (defmethod monitor-fd ((mux epoll-multiplexer) fd-entry)
  54   (assert fd-entry)
  55   (let ((flags (calc-epoll-flags fd-entry))
  56         (fd (fd-entry-fd fd-entry)))
  57     (with-foreign-object (ev 'et:epoll-event)
  58       (et:memset ev 0 et:size-of-epoll-event)
  59       (setf (foreign-slot-value ev 'et:epoll-event 'et:events) flags)
  60       (setf (foreign-slot-value (foreign-slot-value ev 'et:epoll-event 'et:data)
  61                                 'et:epoll-data 'et:fd)
  62             fd)
  63       (handler-case
  64           (et:epoll-ctl (fd-of mux) et:epoll-ctl-add fd ev)
  65         (et:unix-error-badf (err)
  66           (declare (ignore err))
  67           (warn "FD ~A is invalid, cannot monitor it." fd))
  68         (et:unix-error-exist (err)
  69           (declare (ignore err))
  70           (warn "FD ~A is already monitored." fd))))))
  71
  72
  73 (defmethod update-fd ((mux epoll-multiplexer) fd-entry)
  74   (assert fd-entry)
  75   (let ((flags (calc-epoll-flags fd-entry))
  76         (fd (fd-entry-fd fd-entry)))
  77     (with-foreign-object (ev 'et:epoll-event)
  78       (et:memset ev 0 et:size-of-epoll-event)
  79       (setf (foreign-slot-value ev 'et:epoll-event 'et:events) flags)
  80       (setf (foreign-slot-value (foreign-slot-value ev 'et:epoll-event 'et:data)
  81                                 'et:epoll-data 'et:fd)
  82             fd)
  83       (handler-case
  84           (et:epoll-ctl (fd-of mux) et:epoll-ctl-mod fd ev)
  85         (et:unix-error-badf (err)
  86           (declare (ignore err))
  87           (warn "FD ~A is invalid, cannot update its status." fd))
  88         (et:unix-error-noent (err)
  89           (declare (ignore err))
  90           (warn "FD ~A was not monitored, cannot update its status." fd))))
  91     (values fd-entry)))
  92
  93
  94 (defmethod unmonitor-fd ((mux epoll-multiplexer) fd-entry)
  95   (handler-case
  96       (et:epoll-ctl (fd-of mux)
  97                     et:epoll-ctl-del
  98                     (fd-entry-fd fd-entry)
  99                     (null-pointer))
 100     (et:unix-error-badf (err)
 101       (declare (ignore err))
 102       (warn "FD ~A is invalid, cannot unmonitor it." (fd-entry-fd fd-entry)))
 103     (et:unix-error-noent (err)
 104       (declare (ignore err))
 105       (warn "FD ~A was not monitored, cannot unmonitor it." (fd-entry-fd fd-entry)))))
 106
 107
 108 (defmethod harvest-events ((mux epoll-multiplexer) timeout)
 109   (let ((milisec-timeout (timeout->milisec timeout)))
 110     (with-foreign-object (events 'et:epoll-event *epoll-max-events*)
 111       (et:memset events 0 (* *epoll-max-events* et:size-of-epoll-event))
 112       (let ((ready-fds
 113              (et:epoll-wait (fd-of mux) events
 114                             *epoll-max-events* milisec-timeout)))
 115         (macrolet ((epoll-slot (slot-name)
 116                      `(foreign-slot-value (mem-aref events 'et:epoll-event i)
 117                                           'et:epoll-event ',slot-name)))
 118           (return-from harvest-events
 119             (loop
 120                :for i :below ready-fds
 121                :for fd := (foreign-slot-value (epoll-slot et:data) 'et:epoll-data 'et:fd)
 122                :for event-mask := (epoll-slot et:events)
 123                :for epoll-event := (make-epoll-event fd event-mask)
 124                :when epoll-event :collect epoll-event)))))))
 125
 126
 127 (defun make-epoll-event (fd mask)
 128   (let ((event ()))
 129     (flags-case mask
 130       ((et:epollout et:epollhup)
 131        (push :write event))
 132       ((et:epollin et:epollpri et:epollhup)
 133        (push :read event))
 134       (et:epollerr
 135        (push :error event)))
 136     (when event
 137       (list fd event))))