net.sockets/socket-methods.lisp

   1 ;;;; -*- Mode: Lisp; Syntax: ANSI-Common-Lisp; indent-tabs-mode: nil -*-
   2 ;;;
   3 ;;; --- Various socket methods.
   4 ;;;
   5
   6 (in-package :net.sockets)
   7
   8 (defvar *socket-type-map*
   9   '(((:ipv4  :stream   :active  :default) . socket-stream-internet-active)
  10     ((:ipv6  :stream   :active  :default) . socket-stream-internet-active)
  11     ((:ipv4  :stream   :passive :default) . socket-stream-internet-passive)
  12     ((:ipv6  :stream   :passive :default) . socket-stream-internet-passive)
  13     ((:local :stream   :active  :default) . socket-stream-local-active)
  14     ((:local :stream   :passive :default) . socket-stream-local-passive)
  15     ((:local :datagram :active  :default) . socket-datagram-local-active)
  16     ((:ipv4  :datagram :active  :default) . socket-datagram-internet-active)
  17     ((:ipv6  :datagram :active  :default) . socket-datagram-internet-active)))
  18
  19 ;;; FIXME: should match :default to whatever protocol is the default.
  20 (defun select-socket-class (family type connect protocol)
  21   (or (cdr (assoc (list family type connect protocol) *socket-type-map*
  22                   :test #'equal))
  23       (error "No socket class found !!")))
  24
  25 ;;;; Shared Initialization
  26
  27 (defun translate-make-socket-keywords-to-constants (family type protocol)
  28   (let ((sf (ecase family
  29               (:ipv4  af-inet)
  30               (:ipv6  af-inet6)
  31               (:local af-local)))
  32         (st (ecase type
  33               (:stream   sock-stream)
  34               (:datagram sock-dgram)))
  35         (sp (cond
  36               ((integerp protocol) protocol)
  37               ((eq :default protocol) 0)
  38               (t (lookup-protocol protocol)))))
  39     (values sf st sp)))
  40
  41 (defmethod socket-os-fd ((socket socket))
  42   (fd-of socket))
  43
  44 (defmethod initialize-instance :after ((socket socket) &key
  45                                        file-descriptor family type
  46                                        (protocol :default))
  47   (with-accessors ((fd fd-of) (fam socket-family) (proto socket-protocol))
  48       socket
  49     (setf fd (or file-descriptor
  50                  (multiple-value-call #'%socket
  51                    (translate-make-socket-keywords-to-constants
  52                     family type protocol))))
  53     (setf fam family
  54           proto protocol)))
  55
  56 (defmethod (setf external-format-of) (external-format (socket passive-socket))
  57   (setf (slot-value socket 'external-format)
  58         (babel:ensure-external-format external-format)))
  59
  60 (defmethod initialize-instance :after ((socket passive-socket) &key external-format
  61                                        input-buffer-size output-buffer-size)
  62   ;; Makes CREATE-SOCKET simpler
  63   (declare (ignore input-buffer-size output-buffer-size))
  64   (setf (external-format-of socket) external-format))
  65
  66 (defmethod socket-type ((socket stream-socket))
  67   :stream)
  68
  69 (defmethod socket-type ((socket datagram-socket))
  70   :datagram)
  71
  72 (defun ipv6-socket-p (socket)
  73   "Return T if SOCKET is an AF_INET6 socket."
  74   (eq :ipv6 (socket-family socket)))
  75
  76 ;;;; Printing
  77
  78 (defun sock-fam (socket)
  79   (ecase (socket-family socket)
  80     (:ipv4 "IPv4")
  81     (:ipv6 "IPv6")))
  82
  83 (defmethod print-object ((socket socket-stream-internet-active) stream)
  84   (print-unreadable-object (socket stream :identity t)
  85     (format stream "active ~A stream socket" (sock-fam socket))
  86     (if (socket-connected-p socket)
  87         (multiple-value-bind (host port) (remote-name socket)
  88           (format stream " connected to ~A/~A"
  89                   (address-to-string host) port))
  90         (format stream ", ~:[closed~;unconnected~]" (fd-of socket)))))
  91
  92 (defmethod print-object ((socket socket-stream-internet-passive) stream)
  93   (print-unreadable-object (socket stream :identity t)
  94     (format stream "passive ~A stream socket" (sock-fam socket))
  95     (if (socket-bound-p socket)
  96         (multiple-value-bind (host port) (local-name socket)
  97           (format stream " ~:[bound to~;waiting @~] ~A/~A"
  98                   (socket-listening-p socket)
  99                   (address-to-string host) port))
 100         (format stream ", ~:[closed~;unbound~]" (fd-of socket)))))
 101
 102 (defmethod print-object ((socket socket-stream-local-active) stream)
 103   (print-unreadable-object (socket stream :identity t)
 104     (format stream "active local stream socket")
 105     (if (socket-connected-p socket)
 106         (format stream " connected to ~S"
 107                 (address-to-string (remote-filename socket)))
 108         (format stream ", ~:[closed~;unconnected~]" (fd-of socket)))))
 109
 110 (defmethod print-object ((socket socket-stream-local-passive) stream)
 111   (print-unreadable-object (socket stream :identity t)
 112     (format stream "passive local stream socket")
 113     (if (socket-bound-p socket)
 114         (format stream " ~:[bound to~;waiting @~] ~S"
 115                   (socket-listening-p socket)
 116                   (address-to-string (local-filename socket)))
 117         (format stream ", ~:[closed~;unbound~]" (fd-of socket)))))
 118
 119 (defmethod print-object ((socket socket-datagram-local-active) stream)
 120   (print-unreadable-object (socket stream :identity t)
 121     (format stream "local datagram socket")
 122     (if (socket-connected-p socket)
 123         (format stream " connected to ~S"
 124                 (address-to-string (remote-filename socket)))
 125         (if (fd-of socket)
 126             (format stream " waiting @ ~S" (address-to-string (local-filename socket)))
 127             (format stream ", closed" )))))
 128
 129 (defmethod print-object ((socket socket-datagram-internet-active) stream)
 130   (print-unreadable-object (socket stream :identity t)
 131     (format stream "~A datagram socket" (sock-fam socket))
 132     (if (socket-connected-p socket)
 133         (multiple-value-bind (host port) (remote-name socket)
 134           (format stream " connected to ~A/~A"
 135                   (address-to-string host) port))
 136         (if (fd-of socket)
 137             (multiple-value-bind (host port) (local-name socket)
 138               (format stream " waiting @ ~A/~A"
 139                       (address-to-string host) port))
 140             (format stream ", closed" )))))
 141
 142 ;;;; CLOSE
 143
 144 (defmethod close :around ((socket socket) &key abort)
 145   (declare (ignore abort))
 146   (call-next-method)
 147   (when (fd-of socket)
 148     (nix:close (fd-of socket)))
 149   (setf (fd-of socket) nil
 150         (slot-value socket 'bound) nil)
 151   (values socket))
 152
 153 (defmethod close :around ((socket passive-socket) &key abort)
 154   (declare (ignore abort))
 155   (call-next-method)
 156   (setf (slot-value socket 'listening) nil)
 157   (values socket))
 158
 159 (defmethod close ((socket socket) &key abort)
 160   (declare (ignore socket abort)))
 161
 162 (defmethod socket-open-p ((socket socket))
 163   (when (fd-of socket)
 164     (with-sockaddr-storage-and-socklen (ss size)
 165       (handler-case
 166           (%getsockname (fd-of socket) ss size)
 167         (nix:ebadf () nil)
 168         (socket-connection-reset-error () nil)
 169         (:no-error (_) (declare (ignore _)) t)))))
 170
 171 ;;;; GETSOCKNAME
 172
 173 (defun %local-name (socket)
 174   (with-sockaddr-storage-and-socklen (ss size)
 175     (%getsockname (fd-of socket) ss size)
 176     (sockaddr-storage->sockaddr ss)))
 177
 178 (defmethod local-name ((socket socket))
 179   (%local-name socket))
 180
 181 (defmethod local-host ((socket internet-socket))
 182   (nth-value 0 (%local-name socket)))
 183
 184 (defmethod local-port ((socket internet-socket))
 185   (nth-value 1 (%local-name socket)))
 186
 187 (defmethod local-filename ((socket local-socket))
 188   (%local-name socket))
 189
 190 ;;;; GETPEERNAME
 191
 192 (defun %remote-name (socket)
 193   (with-sockaddr-storage-and-socklen (ss size)
 194     (%getpeername (fd-of socket) ss size)
 195     (sockaddr-storage->sockaddr ss)))
 196
 197 (defmethod remote-name ((socket socket))
 198   (%remote-name socket))
 199
 200 (defmethod remote-host ((socket internet-socket))
 201   (nth-value 0 (%remote-name socket)))
 202
 203 (defmethod remote-port ((socket internet-socket))
 204   (nth-value 1 (%remote-name socket)))
 205
 206 (defmethod remote-filename ((socket local-socket))
 207   (%remote-name socket))
 208
 209 ;;;; BIND
 210
 211 (defmethod bind-address :before ((socket internet-socket) address
 212                                  &key (reuse-address t))
 213   (declare (ignore address))
 214   (when reuse-address
 215     (setf (socket-option socket :reuse-address) t)))
 216
 217 (defun bind-ipv4-address (fd address port)
 218   (with-sockaddr-in (sin address port)
 219     (%bind fd sin size-of-sockaddr-in)))
 220
 221 (defun bind-ipv6-address (fd address port)
 222   (with-sockaddr-in6 (sin6 address port)
 223     (%bind fd sin6 size-of-sockaddr-in6)))
 224
 225 (defmethod bind-address ((socket internet-socket) (address ipv4-address)
 226                          &key (port 0))
 227   (if (ipv6-socket-p socket)
 228       (bind-ipv6-address (fd-of socket)
 229                          (map-ipv4-vector-to-ipv6 (address-name address))
 230                          port)
 231       (bind-ipv4-address (fd-of socket) (address-name address) port))
 232   (values socket))
 233
 234 (defmethod bind-address ((socket internet-socket) (address ipv6-address)
 235                          &key (port 0))
 236   (bind-ipv6-address (fd-of socket) (address-name address) port)
 237   (values socket))
 238
 239 (defmethod bind-address ((socket local-socket) (address local-address) &key)
 240   (with-sockaddr-un (sun (address-name address))
 241     (%bind (fd-of socket) sun size-of-sockaddr-un))
 242   (values socket))
 243
 244 (defmethod bind-address :after ((socket socket) (address address) &key)
 245   (setf (slot-value socket 'bound) t))
 246
 247 ;;;; LISTEN
 248
 249 (defmethod listen-on ((socket passive-socket) &key backlog)
 250   (unless backlog (setf backlog (min *default-backlog-size*
 251                                      +max-backlog-size+)))
 252   (check-type backlog unsigned-byte "a non-negative integer")
 253   (%listen (fd-of socket) backlog)
 254   (setf (slot-value socket 'listening) t)
 255   (values socket))
 256
 257 (defmethod listen-on ((socket active-socket) &key)
 258   (error "You can't listen on active sockets."))
 259
 260 ;;;; ACCEPT
 261
 262 (defmethod accept-connection ((socket active-socket) &key)
 263   (error "You can't accept connections on active sockets."))
 264
 265 (defmethod accept-connection ((socket passive-socket) &key external-format
 266                               input-buffer-size output-buffer-size)
 267   (flet ((make-client-socket (fd)
 268            (make-instance (active-class socket)
 269                           :file-descriptor fd
 270                           :external-format (or external-format
 271                                                (external-format-of socket))
 272                           :input-buffer-size input-buffer-size
 273                           :output-buffer-size output-buffer-size)))
 274     (with-sockaddr-storage-and-socklen (ss size)
 275       (handler-case
 276           (make-client-socket (%accept (fd-of socket) ss size))
 277         (nix:ewouldblock ())))))
 278
 279 ;;;; CONNECT
 280
 281 (defmethod connect :before ((socket active-socket) address &key)
 282   (declare (ignore address))
 283 #+freebsd
 284   (setf (socket-option socket :no-sigpipe) t))
 285
 286 (defun ipv4-connect (fd address port)
 287   (with-sockaddr-in (sin address port)
 288     (%connect fd sin size-of-sockaddr-in)))
 289
 290 (defun ipv6-connect (fd address port)
 291   (with-sockaddr-in6 (sin6 address port)
 292     (%connect fd sin6 size-of-sockaddr-in6)))
 293
 294 (defmethod connect ((socket internet-socket) (address ipv4-address)
 295                     &key (port 0))
 296   (if (ipv6-socket-p socket)
 297       (ipv6-connect (fd-of socket)
 298                     (map-ipv4-vector-to-ipv6 (address-name address))
 299                     port)
 300       (ipv4-connect (fd-of socket) (address-name address) port))
 301   (values socket))
 302
 303 (defmethod connect ((socket internet-socket) (address ipv6-address)
 304                     &key (port 0))
 305   (ipv6-connect (fd-of socket) (address-name address) port)
 306   (values socket))
 307
 308 (defmethod connect ((socket local-socket) (address local-address) &key)
 309   (with-sockaddr-un (sun (address-name address))
 310     (%connect (fd-of socket) sun size-of-sockaddr-un))
 311   (values socket))
 312
 313 (defmethod connect ((socket passive-socket) address &key)
 314   (declare (ignore address))
 315   (error "You cannot connect passive sockets."))
 316
 317 (defmethod socket-connected-p ((socket socket))
 318   (when (fd-of socket)
 319     (with-sockaddr-storage-and-socklen (ss size)
 320       (handler-case
 321           (%getpeername (fd-of socket) ss size)
 322         (socket-not-connected-error () nil)
 323         (:no-error (_) (declare (ignore _)) t)))))
 324
 325 ;;;; DISCONNECT
 326
 327 (defmethod disconnect :before ((socket socket))
 328   (unless (typep socket 'datagram-socket)
 329     (error "You can only disconnect active datagram sockets.")))
 330
 331 (defmethod disconnect ((socket datagram-socket))
 332   (with-foreign-object (sin 'sockaddr-in)
 333     (bzero sin size-of-sockaddr-in)
 334     (setf (foreign-slot-value sin 'sockaddr-in 'addr) af-unspec)
 335     (%connect (fd-of socket) sin size-of-sockaddr-in)))
 336
 337 ;;;; SHUTDOWN
 338
 339 (defmethod shutdown ((socket socket) &key read write)
 340   (assert (or read write) (read write)
 341           "You must select at least one direction to shut down.")
 342   (%shutdown (fd-of socket)
 343              (multiple-value-case ((read write))
 344                ((_   nil) shut-rd)
 345                ((nil _)   shut-wr)
 346                (t         shut-rdwr)))
 347   (values socket))
 348
 349 ;;;; Socket flag definition
 350
 351 (defmacro define-socket-flag (place name value platform)
 352   (let ((val (cond ((or (not platform)
 353                         (featurep platform)) value)
 354                    ((not (featurep platform)) 0))))
 355     `(pushnew (cons ,name ,val) ,place)))
 356
 357 (defmacro define-socket-flags (place &body definitions)
 358   (flet ((dflag (form)
 359            (destructuring-bind (name value &optional platform) form
 360              `(define-socket-flag ,place ,name ,value ,platform))))
 361     `(progn
 362        ,@(mapcar #'dflag definitions))))
 363
 364 ;;;; SENDTO
 365
 366 (defvar *sendto-flags* ())
 367
 368 (define-socket-flags *sendto-flags*
 369   (:dont-route    msg-dontroute)
 370   (:dont-wait     msg-dontwait  (:not :windows))
 371   (:out-of-band   msg-oob)
 372   (:more          msg-more      :linux)
 373   (:confirm       msg-confirm   :linux))
 374
 375 (defun %normalize-send-buffer (buff start end ef)
 376   (check-bounds buff start end)
 377   (etypecase buff
 378     (ub8-sarray (values buff start (- end start)))
 379     (string     (let ((vector (%to-octets buff ef start end)))
 380                   (values vector 0 (length vector))))
 381     (vector     (values (coerce buff 'ub8-sarray)
 382                         start (- end start)))))
 383
 384 (defun %%send-to (fd ss got-peer buffer start end flags ef)
 385   (multiple-value-bind (buff start-offset bufflen)
 386       (%normalize-send-buffer buffer start end ef)
 387     (with-pointer-to-vector-data (buff-sap buff)
 388       (incf-pointer buff-sap start-offset)
 389       (loop
 390          (restart-case
 391              (return-from %%send-to
 392                (%sendto fd buff-sap bufflen flags
 393                         (if got-peer ss (null-pointer))
 394                         (if got-peer (sockaddr-size ss) 0)))
 395            (ignore ()
 396              :report "Ignore this socket condition"
 397              (return-from %%send-to 0))
 398            (continue (&optional (wait 0))
 399              :report "Try to send data again"
 400              (when (plusp wait) (sleep wait))))))))
 401
 402 (defun %inet-send-to (socket buffer start end remote-host remote-port flags)
 403   (with-sockaddr-storage (ss)
 404     (when remote-host
 405       (sockaddr->sockaddr-storage ss (ensure-hostname remote-host)
 406                                   (ensure-numerical-service remote-port)))
 407     (%%send-to (fd-of socket) ss (if remote-host t) buffer start end flags
 408                (external-format-of socket))))
 409
 410 (defun %local-send-to (socket buffer start end remote-filename flags)
 411   (with-sockaddr-storage (ss)
 412     (when remote-filename
 413       (sockaddr->sockaddr-storage ss (ensure-address remote-filename :family :local) 0))
 414     (%%send-to (fd-of socket) ss (if remote-filename t) buffer start end flags
 415                (external-format-of socket))))
 416
 417 (defmethod send-to ((socket internet-socket) buffer &rest args
 418                     &key (start 0) end remote-host (remote-port 0) (ipv6 *ipv6*))
 419   (let ((*ipv6* ipv6))
 420     (%inet-send-to socket buffer start end remote-host remote-port
 421                    (compute-flags *sendto-flags* args))))
 422
 423 (defmethod send-to ((socket local-socket) buffer &rest args
 424                     &key (start 0) end remote-filename)
 425   (%local-send-to socket buffer start end remote-filename
 426                   (compute-flags *sendto-flags* args)))
 427
 428 (define-compiler-macro send-to (&whole form socket buffer &rest args
 429                                 &key (start 0) end remote-host (remote-port 0)
 430                                 remote-filename (ipv6 '*ipv6*) &allow-other-keys)
 431   (let ((flags (compute-flags *sendto-flags* args)))
 432     (cond (flags
 433            (once-only (socket buffer start end remote-host
 434                        remote-port remote-filename flags)
 435              `(etypecase ,socket
 436                 (internet-socket
 437                  (let ((*ipv6* ,ipv6))
 438                    (%inet-send-to ,socket ,buffer ,start ,end
 439                                   ,remote-host ,remote-port ,flags)))
 440                 (local-socket
 441                  (%local-send-to ,socket ,buffer ,start ,end
 442                                  ,remote-filename ,flags)))))
 443           (t form))))
 444
 445 ;;;; RECVFROM
 446
 447 (defvar *recvfrom-flags* ())
 448
 449 (define-socket-flags *recvfrom-flags*
 450   (:out-of-band msg-oob)
 451   (:peek        msg-peek)
 452   (:wait-all    msg-waitall  (:not :windows))
 453   (:dont-wait   msg-dontwait (:not :windows)))
 454
 455 (defun allocate-ub8-buffer-for-string (length ef)
 456   (let* ((units-per-char (babel-encodings:enc-max-units-per-char
 457                           (babel:external-format-encoding ef)))
 458          (length (* units-per-char length)))
 459     (values (make-array length :element-type 'ub8)
 460             0 length)))
 461
 462 (defun %normalize-receive-buffer (buff start end ef)
 463   (etypecase buff
 464     (ub8-sarray (values buff start (- end start)))
 465     (string     (allocate-ub8-buffer-for-string (- end start) ef))))
 466
 467 (defun %%receive-from (fd ss size buffer start end flags ef)
 468   (check-bounds buffer start end)
 469   (multiple-value-bind (buff start-offset bufflen)
 470       (%normalize-receive-buffer buffer start end ef)
 471     (with-pointer-to-vector-data (buff-sap buff)
 472       (incf-pointer buff-sap start-offset)
 473       (loop
 474          (restart-case
 475              (let ((nbytes (%recvfrom fd buff-sap bufflen flags ss size)))
 476                (return-from %%receive-from
 477                  (if (stringp buffer)
 478                      ;; FIXME: convert the octets directly into the buffer
 479                      (let ((str (babel:octets-to-string buff :start 0 :end nbytes
 480                                                         :encoding (babel:external-format-encoding ef)
 481                                                         :errorp nil)))
 482                        (replace buffer str :start1 start :end1 end)
 483                        (- end start))
 484                      nbytes)))
 485            (ignore ()
 486              :report "Ignore this socket condition"
 487              (return-from %%receive-from 0))
 488            (continue (&optional (wait 0))
 489              :report "Try to receive data again"
 490              (when (plusp wait) (sleep wait))))))))
 491
 492 (declaim (inline %receive-from-stream-socket))
 493 (defun %receive-from-stream-socket (socket buffer start end flags)
 494   (with-sockaddr-storage-and-socklen (ss size)
 495     (let ((nelements (%%receive-from (fd-of socket) ss size buffer start end
 496                                      flags (external-format-of socket))))
 497       (values buffer nelements))))
 498
 499 (declaim (inline %receive-from-datagram-socket))
 500 (defun %receive-from-datagram-socket (socket buffer start end flags)
 501   (with-sockaddr-storage-and-socklen (ss size)
 502     (let ((nelements (%%receive-from (fd-of socket) ss size buffer start end
 503                                      flags (external-format-of socket))))
 504       (multiple-value-call #'values buffer nelements
 505                            (sockaddr-storage->sockaddr ss)))))
 506
 507 (defun %receive-from (socket buffer start end size flags)
 508   (unless buffer
 509     (check-type size unsigned-byte "a non-negative integer")
 510     (setf buffer (make-array size :element-type 'ub8)
 511           start 0 end size))
 512   (etypecase socket
 513     (stream-socket (%receive-from-stream-socket socket buffer start end flags))
 514     (datagram-socket (%receive-from-datagram-socket socket buffer start end flags))))
 515
 516 (defmethod receive-from ((socket active-socket) &rest args
 517                          &key buffer size (start 0) end)
 518   (%receive-from socket buffer start end size
 519                  (compute-flags *recvfrom-flags* args)))
 520
 521 (define-compiler-macro receive-from (&whole form socket &rest args
 522                                      &key buffer size (start 0) end &allow-other-keys)
 523   (let ((flags (compute-flags *recvfrom-flags* args)))
 524     (cond (flags `(%receive-from ,socket ,buffer ,start ,end ,size ,flags))
 525           (t form))))