cf/crypto.m4

   1 dnl $Id$
   2 dnl
   3 dnl test for crypto libraries:
   4 dnl - libcrypto (from openssl)
   5 dnl - libdes (from krb4)
   6 dnl - own-built libdes
   7
   8 m4_define([test_headers], [
   9                 #undef KRB5 /* makes md4.h et al unhappy */
  10                 #ifdef HAVE_OPENSSL
  11                 #ifdef HAVE_SYS_TYPES_H
  12                 #include <sys/types.h>
  13                 #endif
  14                 #include <openssl/md4.h>
  15                 #include <openssl/md5.h>
  16                 #include <openssl/sha.h>
  17                 #include <openssl/des.h>
  18                 #include <openssl/rc4.h>
  19                 #include <openssl/aes.h>
  20                 #include <openssl/ui.h>
  21                 #include <openssl/rand.h>
  22                 #else
  23                 #include <md4.h>
  24                 #include <md5.h>
  25                 #include <sha.h>
  26                 #include <des.h>
  27                 #include <rc4.h>
  28                 #include <aes.h>
  29                 #endif
  30                 #ifdef OLD_HASH_NAMES
  31                 typedef struct md4 MD4_CTX;
  32                 #define MD4_Init(C) md4_init((C))
  33                 #define MD4_Update(C, D, L) md4_update((C), (D), (L))
  34                 #define MD4_Final(D, C) md4_finito((C), (D))
  35                 typedef struct md5 MD5_CTX;
  36                 #define MD5_Init(C) md5_init((C))
  37                 #define MD5_Update(C, D, L) md5_update((C), (D), (L))
  38                 #define MD5_Final(D, C) md5_finito((C), (D))
  39                 typedef struct sha SHA_CTX;
  40                 #define SHA1_Init(C) sha_init((C))
  41                 #define SHA1_Update(C, D, L) sha_update((C), (D), (L))
  42                 #define SHA1_Final(D, C) sha_finito((C), (D))
  43                 #endif
  44                 ])
  45 m4_define([test_body], [
  46                 void *schedule = 0;
  47                 MD4_CTX md4;
  48                 MD5_CTX md5;
  49                 SHA_CTX sha1;
  50
  51                 MD4_Init(&md4);
  52                 MD5_Init(&md5);
  53                 SHA1_Init(&sha1);
  54                 #ifdef HAVE_OPENSSL
  55                 RAND_status();
  56                 UI_UTIL_read_pw_string(0,0,0,0);
  57                 #endif
  58
  59                 AES_encrypt(0,0,0);
  60                 DES_cbc_encrypt(0, 0, 0, schedule, 0, 0);
  61                 RC4(0, 0, 0, 0);])
  62
  63
  64 AC_DEFUN([KRB_CRYPTO],[
  65 crypto_lib=unknown
  66 AC_WITH_ALL([openssl])
  67
  68 DIR_des=
  69
  70 AC_MSG_CHECKING([for crypto library])
  71
  72 openssl=no
  73 old_hash=no
  74
  75 if test "$crypto_lib" = "unknown" -a "$with_krb4" != "no"; then
  76         save_CPPFLAGS="$CPPFLAGS"
  77         save_LIBS="$LIBS"
  78
  79         cdirs= clibs=
  80         for i in $LIB_krb4; do
  81                 case "$i" in
  82                 -L*) cdirs="$cdirs $i";;
  83                 -l*) clibs="$clibs $i";;
  84                 esac
  85         done
  86
  87         ires=
  88         for i in $INCLUDE_krb4; do
  89                 CFLAGS="-DHAVE_OPENSSL $i $save_CFLAGS"
  90                 for j in $cdirs; do
  91                         for k in $clibs; do
  92                                 LIBS="$j $k $save_LIBS"
  93                                 AC_LINK_IFELSE([AC_LANG_PROGRAM([test_headers],
  94                                                 [test_body])],
  95                                         [openssl=yes ires="$i" lres="$j $k"; break 3])
  96                         done
  97                 done
  98                 CFLAGS="$i $save_CFLAGS"
  99                 for j in $cdirs; do
 100                         for k in $clibs; do
 101                                 LIBS="$j $k $save_LIBS"
 102                                 AC_LINK_IFELSE([AC_LANG_PROGRAM([test_headers],[test_body])],
 103                                         [openssl=no ires="$i" lres="$j $k"; break 3])
 104                         done
 105                 done
 106                 CFLAGS="-DHAVE_OLD_HASH_NAMES $i $save_CFLAGS"
 107                 for j in $cdirs; do
 108                         for k in $clibs; do
 109                                 LIBS="$j $k $save_LIBS"
 110                                 AC_LINK_IFELSE([AC_LANG_PROGRAM([test_headers],[test_body])],
 111                                         [openssl=no ires="$i" lres="$j $k"; break 3])
 112                         done
 113                 done
 114         done
 115
 116         CFLAGS="$save_CFLAGS"
 117         LIBS="$save_LIBS"
 118         if test "$ires" -a "$lres"; then
 119                 INCLUDE_des="$ires"
 120                 LIB_des="$lres"
 121                 crypto_lib=krb4
 122                 AC_MSG_RESULT([same as krb4])
 123                 LIB_des_a='$(LIB_des)'
 124                 LIB_des_so='$(LIB_des)'
 125                 LIB_des_appl='$(LIB_des)'
 126         fi
 127 fi
 128
 129 if test "$crypto_lib" = "unknown" -a "$with_openssl" != "no"; then
 130         save_CFLAGS="$CFLAGS"
 131         save_LIBS="$LIBS"
 132         INCLUDE_des=
 133         LIB_des=
 134         if test "$with_openssl_include" != ""; then
 135                 INCLUDE_des="-I${with_openssl_include}"
 136         fi
 137         if test "$with_openssl_lib" != ""; then
 138                 LIB_des="-L${with_openssl_lib}"
 139         fi
 140         CFLAGS="-DHAVE_OPENSSL ${INCLUDE_des} ${CFLAGS}"
 141         saved_LIB_des="$LIB_des"
 142         for lres in "" "-lnsl -lsocket"; do
 143                 LIB_des="${saved_LIB_des} -lcrypto $lres"
 144                 LIB_des_a="$LIB_des"
 145                 LIB_des_so="$LIB_des"
 146                 LIB_des_appl="$LIB_des"
 147                 LIBS="${LIBS} ${LIB_des}"
 148                 AC_LINK_IFELSE([AC_LANG_PROGRAM([test_headers],[test_body])], [
 149                         crypto_lib=libcrypto openssl=yes
 150                         AC_MSG_RESULT([libcrypto])
 151                 ])
 152                 if test "$crypto_lib" = libcrypto ; then
 153                         break;
 154                 fi
 155         done
 156         CFLAGS="$save_CFLAGS"
 157         LIBS="$save_LIBS"
 158 fi
 159
 160 if test "$crypto_lib" = "unknown"; then
 161
 162   DIR_des='des'
 163   LIB_des='$(top_builddir)/lib/des/libdes.la'
 164   LIB_des_a='$(top_builddir)/lib/des/.libs/libdes.a'
 165   LIB_des_so='$(top_builddir)/lib/des/.libs/libdes.so'
 166   LIB_des_appl="-ldes"
 167
 168   AC_MSG_RESULT([included libdes])
 169
 170 fi
 171
 172 if test "$with_krb4" != no -a "$crypto_lib" != krb4; then
 173         AC_MSG_ERROR([the crypto library used by krb4 lacks features
 174 required by Kerberos 5; to continue, you need to install a newer
 175 Kerberos 4 or configure --without-krb4])
 176 fi
 177
 178 if test "$openssl" = "yes"; then
 179   AC_DEFINE([HAVE_OPENSSL], 1, [define to use openssl's libcrypto])
 180 fi
 181 if test "$old_hash" = yes; then
 182   AC_DEFINE([HAVE_OLD_HASH_NAMES], 1,
 183                 [define if you have hash functions like md4_finito()])
 184 fi
 185 AM_CONDITIONAL(HAVE_OPENSSL, test "$openssl" = yes)dnl
 186
 187 AC_SUBST(DIR_des)
 188 AC_SUBST(INCLUDE_des)
 189 AC_SUBST(LIB_des)
 190 AC_SUBST(LIB_des_a)
 191 AC_SUBST(LIB_des_so)
 192 AC_SUBST(LIB_des_appl)
 193 ])