configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION($Revision$)
   3 AC_PREREQ(2.62)
   4 test -z "$CFLAGS" && CFLAGS="-g"
   5 AC_INIT([Heimdal],[1.3.3],[heimdal-bugs@h5l.org])
   6 AC_CONFIG_SRCDIR([kuser/kinit.c])
   7 AC_CONFIG_HEADERS(include/config.h)
   8 AC_CONFIG_MACRO_DIR([cf])
   9
  10 AM_INIT_AUTOMAKE([foreign 1.10.3])
  11 AM_MAINTAINER_MODE
  12
  13 dnl Checks for programs.
  14 AC_PROG_CC
  15 AM_PROG_CC_C_O
  16 AC_PROG_CPP
  17 AC_PROG_LIBTOOL
  18
  19 AC_PREFIX_DEFAULT(/usr/heimdal)
  20
  21 test "$sysconfdir" = '${prefix}/etc' && sysconfdir='/etc'
  22 test "$localstatedir" = '${prefix}/var' && localstatedir='/var/heimdal'
  23
  24 AC_CANONICAL_HOST
  25 CANONICAL_HOST=$host
  26 AC_SUBST(CANONICAL_HOST)
  27
  28 dnl Hints for autobuild
  29 AB_INIT
  30
  31 rk_SYS_LARGEFILE
  32
  33 rk_AIX
  34 rk_IRIX
  35 rk_SUNOS
  36
  37 dnl
  38 dnl this is needed to run the configure tests against glibc
  39 dnl
  40 AC_DEFINE([_GNU_SOURCE], 1,
  41         [Define to enable extensions on glibc-based systems such as Linux.])
  42
  43 AC_OBJEXT
  44 AC_EXEEXT
  45
  46 dnl AC_KRB_PROG_YACC
  47 AC_PROG_YACC
  48 AM_PROG_LEX
  49 dnl AC_PROG_RANLIB
  50 AC_PROG_AWK
  51 AC_KRB_PROG_LN_S
  52
  53 AC_MIPS_ABI
  54 CC="$CC $abi"
  55 libdir="$libdir$abilibdirext"
  56
  57 AC_C___ATTRIBUTE__
  58
  59 LT_PREREQ([2.2])
  60 LT_INIT([shared static win32-dll])
  61
  62 AM_CONDITIONAL(ENABLE_SHARED, test "$enable_shared" = "yes")
  63 rk_VERSIONSCRIPT
  64
  65 dnl
  66 dnl Helper bits for cross compiling
  67 dnl
  68
  69
  70
  71 AM_CONDITIONAL(CROSS_COMPILE, test "${cross_compiling}" = yes)
  72
  73 AC_ARG_WITH(cross-tools,
  74         AS_HELP_STRING([--with-cross-tools=dir], [use cross tools in dir]),
  75         [if test "$withval" = "yes"; then
  76                 AC_MSG_ERROR([Need path to cross tools])
  77         fi
  78         with_cross_tools="${with_cross_tools}/"
  79         ])
  80
  81 if test "${cross_compiling}" != yes ; then
  82
  83    ASN1_COMPILE="\$(top_builddir)/lib/asn1/asn1_compile\$(EXEEXT)"
  84    SLC="\$(top_builddir)/lib/sl/slc"
  85
  86    ASN1_COMPILE_DEP="\$(ASN1_COMPILE)"
  87    SLC_DEP="\$(SLC)"
  88 else
  89    ASN1_COMPILE="${with_cross_tools}asn1_compile"
  90    SLC="${with_cross_tools}slc"
  91
  92    ASN1_COMPILE_DEP=
  93    SLC_DEP=
  94 fi
  95
  96 AC_SUBST([ASN1_COMPILE])
  97 AC_SUBST([ASN1_COMPILE_DEP])
  98 AC_SUBST([SLC])
  99 AC_SUBST([SLC_DEP])
 100
 101
 102 dnl ---
 103
 104 AC_DEFINE(HEIM_WEAK_CRYPTO, 1, [Define if you want support for weak crypto])
 105
 106 rk_TEST_PACKAGE(openldap,
 107 [#include <lber.h>
 108 #include <ldap.h>],
 109 [-lldap -llber],,,OPENLDAP)
 110
 111 AC_ARG_ENABLE(hdb-openldap-module,
 112         AS_HELP_STRING([--enable-hdb-openldap-module],
 113                 [if you want support to build openldap hdb as shared object]))
 114 if test "$enable_hdb_openldap_module" = yes -a "$with_openldap" = yes; then
 115     AC_DEFINE(OPENLDAP_MODULE, 1, [Define if you want support for hdb ldap module])
 116 fi
 117 AM_CONDITIONAL(OPENLDAP_MODULE, test "$enable_hdb_openldap_module" = yes -a "$with_openldap" = yes)
 118
 119 dnl
 120 dnl Optional modules, pk-init, digest, kx509
 121 dnl
 122
 123 AC_ARG_ENABLE(pk-init,
 124         AS_HELP_STRING([--disable-pk-init],
 125                 [if you want disable to PK-INIT support]))
 126 if test "$enable_pk_init" != no ;then
 127         AC_DEFINE([PKINIT], 1, [Define to enable PKINIT.])
 128 fi
 129 AM_CONDITIONAL(PKINIT, test "$enable_pk_init" != no)
 130
 131 AC_ARG_ENABLE(digest,
 132         AS_HELP_STRING([--disable-digest],
 133                 [if you want disable to DIGEST support]))
 134 if test "$enable_digest" != no ;then
 135         AC_DEFINE([DIGEST], 1, [Define to enable DIGEST.])
 136 fi
 137
 138 AC_ARG_ENABLE(kx509,
 139         AS_HELP_STRING([--disable-kx509],
 140                 [if you want disable to kx509 support]))
 141 if test "$enable_kx509" != no ;then
 142         AC_DEFINE([KX509], 1, [Define to enable kx509.])
 143 fi
 144
 145 AC_ARG_ENABLE(krb4,
 146         AS_HELP_STRING([--disable-krb4],
 147                 [if you want disable to krb4 support]))
 148 if test "$enable_krb4" != no ;then
 149         AC_DEFINE([KRB4], 1, [Define to enable Kerberos 4.])
 150 fi
 151
 152
 153 dnl Check for sqlite
 154 rk_TEST_PACKAGE(sqlite3,
 155 [#include <sqlite3.h>
 156 #ifndef SQLITE_OPEN_CREATE
 157 #error "old version"
 158 #endif],
 159 [-lsqlite3],,,SQLITE3)
 160
 161 if test "X$with_sqlite3" != Xyes ; then
 162    INCLUDE_sqlite3="-I\$(top_srcdir)/lib/sqlite"
 163    LIB_sqlite3="\$(top_builddir)/lib/sqlite/libheimsqlite.la"
 164 fi
 165 AM_CONDITIONAL(SQLITE3,  test "X$with_sqlite3" = Xyes)
 166
 167 dnl check for libintl
 168 rk_TEST_PACKAGE(libintl,
 169 [#include <libintl.h>],
 170 [-lintl],,,LIBINTL)
 171
 172 dnl path where the hdb directory is stored
 173 AC_ARG_WITH([hdbdir],
 174         [AS_HELP_STRING([--with-hdbdir],[Default location for KDC database @<:@default=/var/heimdal@:>@])],
 175         [],
 176         [with_hdbdir=/var/heimdal])
 177 DIR_hdbdir="$with_hdbdir"
 178 AC_SUBST([DIR_hdbdir])
 179
 180
 181 dnl no kerberos4 any more
 182 with_krb4=no
 183 AC_SUBST(INCLUDE_krb4)
 184 AC_SUBST(LIB_krb4)
 185 AM_CONDITIONAL(KRB4, false)
 186
 187 AM_CONDITIONAL(KRB5, true)
 188 AM_CONDITIONAL(do_roken_rename, true)
 189
 190 AC_DEFINE(KRB5, 1, [Enable Kerberos 5 support in applications.])dnl
 191 AC_SUBST(LIB_kdb)dnl
 192
 193 KRB_CRYPTO
 194
 195 KRB_PTHREADS
 196
 197 AC_ARG_ENABLE(dce,
 198         AS_HELP_STRING([--enable-dce],[if you want support for DCE/DFS PAG's]))
 199 if test "$enable_dce" = yes; then
 200     AC_DEFINE(DCE, 1, [Define if you want support for DCE/DFS PAG's.])
 201 fi
 202 AM_CONDITIONAL(DCE, test "$enable_dce" = yes)
 203
 204 ## XXX quite horrible:
 205 if test -f /etc/ibmcxx.cfg; then
 206         dpagaix_ldadd=`sed -n '/^xlc_r4/,/^$/p' /etc/ibmcxx.cfg | sed -n -e '/libraries/{;s/^[[^=]]*=\(.*\)/\1/;s/,/ /gp;}'`
 207         dpagaix_cflags=`sed -n '/^xlc_r4/,/^$/p' /etc/ibmcxx.cfg | sed -n -e '/options/{;s/^[[^=]]*=\(.*\)/\1/;s/-q[^,]*//;s/,/ /gp;}'`
 208         dpagaix_ldflags=
 209 else
 210         dpagaix_cflags="-D_THREAD_SAFE -D_AIX_PTHREADS_D7 -D_AIX32_THREADS=1 -D_AES_SOURCE -D_AIX41 -I/usr/include/dce"
 211         dpagaix_ldadd="-L/usr/lib/threads -ldcelibc_r -ldcepthreads -lpthreads_compat lpthreads -lc_r"
 212         dpagaix_ldflags="-Wl,-bI:dfspag.exp"
 213 fi
 214 AC_SUBST(dpagaix_cflags)
 215 AC_SUBST(dpagaix_ldadd)
 216 AC_SUBST(dpagaix_ldflags)
 217
 218 AC_ARG_ENABLE([afs-support],
 219         AS_HELP_STRING([--disable-afs-support],[if you don't want support for AFS]))
 220 if test "$enable_afs_support" = no; then
 221         AC_DEFINE(NO_AFS, 1, [Define if you don't wan't support for AFS.])
 222 fi
 223 AC_SUBST(NO_AFS)dnl
 224
 225 rk_DB
 226
 227 dnl AC_ROKEN(10,[/usr/heimdal /usr/athena],[lib/roken],[$(top_builddir)/lib/roken/libroken.la],[-I$(top_builddir)/lib/roken -I$(top_srcdir)/lib/roken])
 228
 229 rk_ROKEN(lib/roken)
 230 LIBADD_roken="$LIB_roken"
 231 AC_SUBST(LIBADD_roken)dnl
 232 LIB_roken="\$(top_builddir)/lib/vers/libvers.la $LIB_roken"
 233
 234 rk_OTP
 235
 236 AC_CHECK_OSFC2
 237
 238 AC_ARG_ENABLE(mmap,
 239         AS_HELP_STRING([--disable-mmap],[disable use of mmap]))
 240 if test "$enable_mmap" = "no"; then
 241         AC_DEFINE(NO_MMAP, 1, [Define if you don't want to use mmap.])
 242 fi
 243
 244 AC_ARG_ENABLE(afs-string-to-key,
 245         AS_HELP_STRING([--disable-afs-string-to-key],
 246         [disable use of weak AFS string-to-key functions]),
 247         [], [enable_afs_string_to_key=yes])
 248
 249 if test "$enable_afs_string_to_key" = "yes"; then
 250         AC_DEFINE(ENABLE_AFS_STRING_TO_KEY, 1, [Define if want to use the weak AFS string to key functions.])
 251 fi
 252
 253
 254 rk_CHECK_MAN
 255
 256 rk_TEST_PACKAGE(readline,
 257 [#include <stdio.h>
 258  #include <readline.h>],-lreadline,,, READLINE)
 259
 260 rk_TEST_PACKAGE(hesiod,[#include <hesiod.h>],-lhesiod,,, HESIOD)
 261
 262 KRB_C_BIGENDIAN
 263 AC_C_INLINE
 264
 265 KRB_CHECK_X
 266
 267 AM_CONDITIONAL(HAVE_X, test "$no_x" != yes)
 268
 269 AC_CHECK_XAU
 270
 271 dnl AM_C_PROTOTYPES
 272
 273 dnl Checks for typedefs, structures, and compiler characteristics.
 274 AC_C_CONST
 275 AC_TYPE_OFF_T
 276 AC_CHECK_TYPE_EXTRA(mode_t, unsigned short, [])
 277 AC_CHECK_TYPE_EXTRA(sig_atomic_t, int, [#include <signal.h>])
 278 AC_HAVE_TYPE([long long])
 279 AC_HEADER_TIME
 280 AC_STRUCT_TM
 281
 282 dnl Checks for header files.
 283 AC_HEADER_STDC
 284
 285 AC_CHECK_HEADERS([\
 286         CommonCrypto/CommonDigest.h             \
 287         arpa/ftp.h                              \
 288         arpa/telnet.h                           \
 289         bind/bitypes.h                          \
 290         bsdsetjmp.h                             \
 291         curses.h                                \
 292         dlfcn.h                                 \
 293         fnmatch.h                               \
 294         inttypes.h                              \
 295         io.h                                    \
 296         libutil.h                               \
 297         limits.h                                \
 298         maillock.h                              \
 299         netgroup.h                              \
 300         netinet/in6_machtypes.h                 \
 301         pthread.h                               \
 302         pty.h                                   \
 303         sac.h                                   \
 304         sgtty.h                                 \
 305         siad.h                                  \
 306         signal.h                                \
 307         strings.h                               \
 308         stropts.h                               \
 309         sys/bitypes.h                           \
 310         sys/category.h                          \
 311         sys/file.h                              \
 312         sys/filio.h                             \
 313         sys/ioccom.h                            \
 314         sys/mman.h                              \
 315         sys/param.h                             \
 316         sys/pty.h                               \
 317         sys/ptyio.h                             \
 318         sys/select.h                            \
 319         sys/socket.h                            \
 320         sys/str_tty.h                           \
 321         sys/stream.h                            \
 322         sys/stropts.h                           \
 323         sys/syscall.h                           \
 324         sys/termio.h                            \
 325         sys/timeb.h                             \
 326         sys/times.h                             \
 327         sys/types.h                             \
 328         sys/un.h                                \
 329         locale.h                                \
 330         termcap.h                               \
 331         termio.h                                \
 332         termios.h                               \
 333         time.h                                  \
 334         tmpdir.h                                \
 335         udb.h                                   \
 336         util.h                                  \
 337         utmp.h                                  \
 338         utmpx.h                                 \
 339 ])
 340
 341 dnl On Solaris 8 there's a compilation warning for term.h because
 342 dnl it doesn't define `bool'.
 343 AC_CHECK_HEADERS(term.h, , , -)
 344
 345 dnl aix have asl.h (A/IX screen library) that we don't want
 346 AC_CHECK_HEADERS(asl.h, , , [
 347 #include <asl.h>
 348 #ifndef ASL_STRING_EMERG
 349 #error ASL_STRING_EMERG missing
 350 #endif])
 351
 352 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
 353 #if HAVE_SYS_SOCKET_H
 354 #include <sys/socket.h>
 355 #endif])
 356
 357 AC_CHECK_HEADERS(sys/ptyvar.h, , , [AC_INCLUDES_DEFAULT
 358 #if HAVE_SYS_TTY_H
 359 #include <sys/tty.h>
 360 #endif])
 361
 362 AC_CHECK_HEADERS(sys/strtty.h, , , [AC_INCLUDES_DEFAULT
 363 #if HAVE_TERMIOS_H
 364 #include <termios.h>
 365 #endif
 366 #if HAVE_SYS_STREAM_H
 367 #include <sys/stream.h>
 368 #endif])
 369
 370 AC_CHECK_HEADERS(sys/ucred.h, , , [AC_INCLUDES_DEFAULT
 371 #if HAVE_SYS_TYPES_H
 372 #include <sys/types.h>
 373 #endif
 374 #if HAVE_SYS_PARAM_H
 375 #include <sys/param.h>
 376 #endif])
 377
 378 AC_CHECK_HEADERS(security/pam_modules.h, , , [AC_INCLUDES_DEFAULT
 379 #include <security/pam_appl.h>
 380 ])
 381
 382 dnl export symbols
 383 rk_WIN32_EXPORT(BUILD_KRB5_LIB, KRB5_LIB)
 384 rk_WIN32_EXPORT(BUILD_ROKEN_LIB, ROKEN_LIB)
 385 rk_WIN32_EXPORT(BUILD_GSSAPI_LIB, GSSAPI_LIB)
 386
 387 dnl Checks for libraries.
 388
 389 AC_FIND_FUNC_NO_LIBS(logwtmp, util,[
 390 #ifdef HAVE_UTIL_H
 391 #include <util.h>
 392 #endif
 393 ],[0,0,0])
 394 AC_FIND_FUNC_NO_LIBS(logout, util,[
 395 #ifdef HAVE_UTIL_H
 396 #include <util.h>
 397 #endif
 398 ],[0])
 399 AC_FIND_FUNC_NO_LIBS(openpty, util,[
 400 #ifdef HAVE_UTIL_H
 401 #include <util.h>
 402 #endif
 403 ],[0,0,0,0,0])
 404
 405 AC_FIND_FUNC_NO_LIBS(tgetent, termcap ncurses curses,[
 406 #ifdef HAVE_TERMCAP_H
 407 #include <termcap.h>
 408 #endif
 409 #ifdef HAVE_CURSES_H
 410 #include <curses.h>
 411 #endif
 412 ],[0,0])
 413
 414 dnl Checks for library functions.
 415
 416 AC_CHECK_FUNCS([                                \
 417         _getpty                                 \
 418         _scrsize                                \
 419         arc4random                              \
 420         fcntl                                   \
 421         getpeereid                              \
 422         getpeerucred                            \
 423         grantpt                                 \
 424         mktime                                  \
 425         ptsname                                 \
 426         rand                                    \
 427         revoke                                  \
 428         select                                  \
 429         setitimer                               \
 430         setpcred                                \
 431         setpgid                                 \
 432         setproctitle                            \
 433         setregid                                \
 434         setresgid                               \
 435         setresuid                               \
 436         setreuid                                \
 437         setsid                                  \
 438         setutent                                \
 439         sigaction                               \
 440         strstr                                  \
 441         ttyname                                 \
 442         ttyslot                                 \
 443         umask                                   \
 444         unlockpt                                \
 445         vhangup                                 \
 446         yp_get_default_domain                   \
 447 ])
 448
 449 AC_FUNC_MMAP
 450
 451 KRB_CAPABILITIES
 452
 453 AC_CHECK_GETPWNAM_R_POSIX
 454
 455 dnl detect doors on solaris
 456 if test "$enable_pthread_support" != no; then
 457    saved_LIBS="$LIBS"
 458    LIBS="$LIBS $PTHREADS_LIBS"
 459    AC_FIND_FUNC_NO_LIBS(door_create, door)
 460    LIBS="$saved_LIBS"
 461 fi
 462
 463 AC_ARG_ENABLE(kcm,
 464         AS_HELP_STRING([--enable-kcm],[enable Kerberos Credentials Manager]),
 465 ,[enable_kcm=yes])
 466
 467 if test "$enable_kcm" = yes ; then
 468    if test  "$ac_cv_header_sys_un_h" != yes -a "$ac_cv_funclib_door_create" != yes ; then
 469         enable_kcm=no
 470    fi
 471 fi
 472 if test "$enable_kcm" = yes; then
 473        AC_DEFINE(HAVE_KCM, 1,
 474                [Define if you want to use the Kerberos Credentials Manager.])
 475 fi
 476 AM_CONDITIONAL(KCM, test "$enable_kcm" = yes)
 477
 478
 479
 480 dnl Cray stuff
 481 AC_CHECK_FUNCS(getudbnam setlim)
 482
 483 dnl AC_KRB_FUNC_GETCWD_BROKEN
 484
 485 dnl
 486 dnl Check for fields in struct utmp
 487 dnl
 488
 489 AC_HAVE_STRUCT_FIELD(struct utmp, ut_addr, [#include <utmp.h>])
 490 AC_HAVE_STRUCT_FIELD(struct utmp, ut_host, [#include <utmp.h>])
 491 AC_HAVE_STRUCT_FIELD(struct utmp, ut_id, [#include <utmp.h>])
 492 AC_HAVE_STRUCT_FIELD(struct utmp, ut_pid, [#include <utmp.h>])
 493 AC_HAVE_STRUCT_FIELD(struct utmp, ut_type, [#include <utmp.h>])
 494 AC_HAVE_STRUCT_FIELD(struct utmp, ut_user, [#include <utmp.h>])
 495 AC_HAVE_STRUCT_FIELD(struct utmpx, ut_exit, [#include <utmpx.h>])
 496 AC_HAVE_STRUCT_FIELD(struct utmpx, ut_syslen, [#include <utmpx.h>])
 497
 498 AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t,
 499         u_int8_t, u_int16_t, u_int32_t, u_int64_t,
 500         uint8_t, uint16_t, uint32_t, uint64_t],,,[
 501 #ifdef HAVE_INTTYPES_H
 502 #include <inttypes.h>
 503 #endif
 504 #ifdef HAVE_SYS_TYPES_H
 505 #include <sys/types.h>
 506 #endif
 507 #ifdef HAVE_SYS_BITYPES_H
 508 #include <sys/bitypes.h>
 509 #endif
 510 #ifdef HAVE_BIND_BITYPES_H
 511 #include <bind/bitypes.h>
 512 #endif
 513 #ifdef HAVE_NETINET_IN6_MACHTYPES_H
 514 #include <netinet/in6_machtypes.h>
 515 #endif
 516 ])
 517
 518 rk_FRAMEWORK_SECURITY
 519
 520 KRB_READLINE
 521
 522 rk_TELNET
 523
 524 dnl Some operating systems already have com_err and compile_et
 525 CHECK_COMPILE_ET
 526
 527 rk_AUTH_MODULES([sia afskauthlib])
 528
 529 rk_DESTDIRS
 530
 531 rk_WFLAGS([-Wall -Wmissing-prototypes -Wpointer-arith -Wbad-function-cast -Wmissing-declarations -Wnested-externs])
 532
 533
 534 AH_BOTTOM([#ifdef ROKEN_RENAME
 535 #include "roken_rename.h"
 536 #endif])
 537
 538 AC_CONFIG_FILES(Makefile                \
 539         etc/Makefile                    \
 540         include/Makefile                \
 541         include/gssapi/Makefile         \
 542         include/hcrypto/Makefile        \
 543         include/kadm5/Makefile          \
 544         lib/Makefile                    \
 545         lib/auth/Makefile               \
 546         lib/auth/afskauthlib/Makefile   \
 547         lib/auth/pam/Makefile           \
 548         lib/auth/sia/Makefile           \
 549         lib/asn1/Makefile               \
 550         lib/com_err/Makefile            \
 551         lib/hcrypto/Makefile            \
 552         lib/editline/Makefile           \
 553         lib/hx509/Makefile              \
 554         lib/gssapi/Makefile             \
 555         lib/ntlm/Makefile               \
 556         lib/hdb/Makefile                \
 557         lib/kadm5/Makefile              \
 558         lib/kafs/Makefile               \
 559         lib/kdfs/Makefile               \
 560         lib/krb5/Makefile               \
 561         lib/otp/Makefile                \
 562         lib/roken/Makefile              \
 563         lib/sl/Makefile                 \
 564         lib/sqlite/Makefile             \
 565         lib/vers/Makefile               \
 566         lib/wind/Makefile               \
 567         po/Makefile                     \
 568         kuser/Makefile                  \
 569         kpasswd/Makefile                \
 570         kadmin/Makefile                 \
 571         admin/Makefile                  \
 572         kcm/Makefile                    \
 573         kdc/Makefile                    \
 574         appl/Makefile                   \
 575         appl/afsutil/Makefile           \
 576         appl/ftp/Makefile               \
 577         appl/ftp/common/Makefile        \
 578         appl/ftp/ftp/Makefile           \
 579         appl/ftp/ftpd/Makefile          \
 580         appl/gssmask/Makefile           \
 581         appl/kx/Makefile                \
 582         appl/login/Makefile             \
 583         appl/otp/Makefile               \
 584         appl/popper/Makefile            \
 585         appl/push/Makefile              \
 586         appl/rsh/Makefile               \
 587         appl/rcp/Makefile               \
 588         appl/su/Makefile                \
 589         appl/xnlock/Makefile            \
 590         appl/telnet/Makefile            \
 591         appl/telnet/libtelnet/Makefile  \
 592         appl/telnet/telnet/Makefile     \
 593         appl/telnet/telnetd/Makefile    \
 594         appl/test/Makefile              \
 595         appl/kf/Makefile                \
 596         appl/dceutils/Makefile          \
 597         tests/Makefile                  \
 598         tests/bin/Makefile              \
 599         tests/can/Makefile              \
 600         tests/db/Makefile               \
 601         tests/kdc/Makefile              \
 602         tests/ldap/Makefile             \
 603         tests/gss/Makefile              \
 604         tests/java/Makefile             \
 605         tests/plugin/Makefile           \
 606         packages/Makefile               \
 607         packages/mac/Makefile           \
 608         doc/Makefile                    \
 609         tools/Makefile                  \
 610 )
 611
 612 AC_OUTPUT
 613
 614 dnl
 615 dnl This is the release version name-number[beta]
 616 dnl
 617
 618 cat > include/newversion.h.in <<EOF
 619 #ifndef VERSION_HIDDEN
 620 #define VERSION_HIDDEN
 621 #endif
 622 VERSION_HIDDEN const char *heimdal_long_version = "@([#])\$Version: $PACKAGE_STRING by @USER@ on @HOST@ ($host) @DATE@ \$";
 623 VERSION_HIDDEN const char *heimdal_version = "AC_PACKAGE_STRING";
 624 EOF
 625
 626 if test -f include/version.h && cmp -s include/newversion.h.in include/version.h.in; then
 627         echo "include/version.h is unchanged"
 628         rm -f include/newversion.h.in
 629 else
 630         echo "creating include/version.h"
 631         User=${USER-${LOGNAME}}
 632         Host=`(hostname || uname -n || echo unknown) 2>/dev/null | sed 1q`
 633         Date=`date`
 634         mv -f include/newversion.h.in include/version.h.in
 635         sed -e "s/@USER@/$User/" -e "s/@HOST@/$Host/" -e "s/@DATE@/$Date/" include/version.h.in > include/version.h
 636 fi