configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION($Revision$)
   3 AC_PREREQ(2.62)
   4 test -z "$CFLAGS" && CFLAGS="-g"
   5 AC_INIT([Heimdal],[1.3.0pre5],[heimdal-bugs@h5l.org])
   6 AC_CONFIG_SRCDIR([kuser/kinit.c])
   7 AC_CONFIG_HEADERS(include/config.h)
   8 AC_CONFIG_MACRO_DIR([cf])
   9
  10 AM_INIT_AUTOMAKE([foreign 1.10])
  11 AM_MAINTAINER_MODE
  12
  13 dnl Checks for programs.
  14 AC_PROG_CC
  15 AM_PROG_CC_C_O
  16 AC_PROG_CPP
  17
  18 AC_PREFIX_DEFAULT(/usr/heimdal)
  19
  20 test "$sysconfdir" = '${prefix}/etc' && sysconfdir='/etc'
  21 test "$localstatedir" = '${prefix}/var' && localstatedir='/var/heimdal'
  22
  23 AC_CANONICAL_HOST
  24 CANONICAL_HOST=$host
  25 AC_SUBST(CANONICAL_HOST)
  26
  27 dnl Hints for autobuild
  28 AB_INIT
  29
  30 rk_SYS_LARGEFILE
  31
  32 rk_AIX
  33 rk_IRIX
  34 rk_SUNOS
  35
  36 dnl
  37 dnl this is needed to run the configure tests against glibc
  38 dnl
  39 AC_DEFINE([_GNU_SOURCE], 1,
  40         [Define to enable extensions on glibc-based systems such as Linux.])
  41
  42 AC_OBJEXT
  43 AC_EXEEXT
  44
  45 dnl AC_KRB_PROG_YACC
  46 AC_PROG_YACC
  47 AM_PROG_LEX
  48 dnl AC_PROG_RANLIB
  49 AC_PROG_AWK
  50 AC_KRB_PROG_LN_S
  51
  52 AC_MIPS_ABI
  53 CC="$CC $abi"
  54 libdir="$libdir$abilibdirext"
  55
  56 AC_C___ATTRIBUTE__
  57
  58 LT_PREREQ([2.2])
  59 LT_INIT([shared static win32-dll])
  60
  61 AM_CONDITIONAL(ENABLE_SHARED, test "$enable_shared" = "yes")
  62 rk_VERSIONSCRIPT
  63
  64 AC_DEFINE(HEIM_WEAK_CRYPTO, 1, [Define if you want support for weak crypto])
  65
  66 rk_TEST_PACKAGE(openldap,
  67 [#include <lber.h>
  68 #include <ldap.h>],
  69 [-lldap -llber],,,OPENLDAP)
  70
  71 AC_ARG_ENABLE(hdb-openldap-module,
  72         AS_HELP_STRING([--enable-hdb-openldap-module],
  73                 [if you want support to build openldap hdb as shared object]))
  74 if test "$enable_hdb_openldap_module" = yes -a "$with_openldap" = yes; then
  75     AC_DEFINE(OPENLDAP_MODULE, 1, [Define if you want support for hdb ldap module])
  76 fi
  77 AM_CONDITIONAL(OPENLDAP_MODULE, test "$enable_hdb_openldap_module" = yes -a "$with_openldap" = yes)
  78
  79 dnl
  80 dnl Optional modules, pk-init, digest, kx509
  81 dnl
  82
  83 AC_ARG_ENABLE(pk-init,
  84         AS_HELP_STRING([--disable-pk-init],
  85                 [if you want disable to PK-INIT support]))
  86 if test "$enable_pk_init" != no ;then
  87         AC_DEFINE([PKINIT], 1, [Define to enable PKINIT.])
  88 fi
  89 AM_CONDITIONAL(PKINIT, test "$enable_pk_init" != no)
  90
  91 AC_ARG_ENABLE(digest,
  92         AS_HELP_STRING([--disable-digest],
  93                 [if you want disable to DIGEST support]))
  94 if test "$enable_digest" != no ;then
  95         AC_DEFINE([DIGEST], 1, [Define to enable DIGEST.])
  96 fi
  97
  98 AC_ARG_ENABLE(kx509,
  99         AS_HELP_STRING([--disable-kx509],
 100                 [if you want disable to kx509 support]))
 101 if test "$enable_kx509" != no ;then
 102         AC_DEFINE([KX509], 1, [Define to enable kx509.])
 103 fi
 104
 105 AC_ARG_ENABLE(krb4,
 106         AS_HELP_STRING([--disable-krb4],
 107                 [if you want disable to krb4 support]))
 108 if test "$enable_krb4" != no ;then
 109         AC_DEFINE([KRB4], 1, [Define to enable Kerberos 4.])
 110 fi
 111
 112
 113 dnl Check for sqlite
 114 rk_TEST_PACKAGE(sqlite3,
 115 [#include <sqlite3.h>
 116 #ifndef SQLITE_OPEN_CREATE
 117 #error "old version"
 118 #endif],
 119 [-lsqlite3],,,SQLITE3)
 120
 121 if test "X$with_sqlite3" != Xyes ; then
 122    INCLUDE_sqlite3="-I\$(top_srcdir)/lib/sqlite"
 123    LIB_sqlite3="\$(top_builddir)/lib/sqlite/libheimsqlite.la"
 124 fi
 125 AM_CONDITIONAL(SQLITE3,  test "X$with_sqlite3" = Xyes)
 126
 127 dnl check for libintl
 128 rk_TEST_PACKAGE(libintl,
 129 [#include <libintl.h>],
 130 [-lintl],,,LIBINTL)
 131
 132 dnl path where the hdb directory is stored
 133 AC_ARG_WITH([hdbdir],
 134         [AS_HELP_STRING([--with-hdbdir],[Default location for KDC database @<:@default=/var/heimdal@:>@])],
 135         [],
 136         [with_hdbdir=/var/heimdal])
 137 DIR_hdbdir="$with_hdbdir"
 138 AC_SUBST([DIR_hdbdir])
 139
 140
 141 dnl no kerberos4 any more
 142 with_krb4=no
 143 AC_SUBST(INCLUDE_krb4)
 144 AC_SUBST(LIB_krb4)
 145 AM_CONDITIONAL(KRB4, false)
 146
 147 AM_CONDITIONAL(KRB5, true)
 148 AM_CONDITIONAL(do_roken_rename, true)
 149
 150 AC_DEFINE(KRB5, 1, [Enable Kerberos 5 support in applications.])dnl
 151 AC_SUBST(LIB_kdb)dnl
 152
 153 KRB_CRYPTO
 154
 155 KRB_PTHREADS
 156
 157 AC_ARG_ENABLE(dce,
 158         AS_HELP_STRING([--enable-dce],[if you want support for DCE/DFS PAG's]))
 159 if test "$enable_dce" = yes; then
 160     AC_DEFINE(DCE, 1, [Define if you want support for DCE/DFS PAG's.])
 161 fi
 162 AM_CONDITIONAL(DCE, test "$enable_dce" = yes)
 163
 164 ## XXX quite horrible:
 165 if test -f /etc/ibmcxx.cfg; then
 166         dpagaix_ldadd=`sed -n '/^xlc_r4/,/^$/p' /etc/ibmcxx.cfg | sed -n -e '/libraries/{;s/^[[^=]]*=\(.*\)/\1/;s/,/ /gp;}'`
 167         dpagaix_cflags=`sed -n '/^xlc_r4/,/^$/p' /etc/ibmcxx.cfg | sed -n -e '/options/{;s/^[[^=]]*=\(.*\)/\1/;s/-q[^,]*//;s/,/ /gp;}'`
 168         dpagaix_ldflags=
 169 else
 170         dpagaix_cflags="-D_THREAD_SAFE -D_AIX_PTHREADS_D7 -D_AIX32_THREADS=1 -D_AES_SOURCE -D_AIX41 -I/usr/include/dce"
 171         dpagaix_ldadd="-L/usr/lib/threads -ldcelibc_r -ldcepthreads -lpthreads_compat lpthreads -lc_r"
 172         dpagaix_ldflags="-Wl,-bI:dfspag.exp"
 173 fi
 174 AC_SUBST(dpagaix_cflags)
 175 AC_SUBST(dpagaix_ldadd)
 176 AC_SUBST(dpagaix_ldflags)
 177
 178 AC_ARG_ENABLE([afs-support],
 179         AS_HELP_STRING([--disable-afs-support],[if you don't want support for AFS]))
 180 if test "$enable_afs_support" = no; then
 181         AC_DEFINE(NO_AFS, 1, [Define if you don't wan't support for AFS.])
 182 fi
 183
 184 rk_DB
 185
 186 dnl AC_ROKEN(10,[/usr/heimdal /usr/athena],[lib/roken],[$(top_builddir)/lib/roken/libroken.la],[-I$(top_builddir)/lib/roken -I$(top_srcdir)/lib/roken])
 187
 188 rk_ROKEN(lib/roken)
 189 LIBADD_roken="$LIB_roken"
 190 AC_SUBST(LIBADD_roken)dnl
 191 LIB_roken="\$(top_builddir)/lib/vers/libvers.la $LIB_roken"
 192
 193 rk_OTP
 194
 195 AC_CHECK_OSFC2
 196
 197 AC_ARG_ENABLE(mmap,
 198         AS_HELP_STRING([--disable-mmap],[disable use of mmap]))
 199 if test "$enable_mmap" = "no"; then
 200         AC_DEFINE(NO_MMAP, 1, [Define if you don't want to use mmap.])
 201 fi
 202
 203 AC_ARG_ENABLE(afs-string-to-key,
 204         AS_HELP_STRING([--disable-afs-string-to-key],
 205         [disable use of weak AFS string-to-key functions]),
 206         [], [enable_afs_string_to_key=yes])
 207
 208 if test "$enable_afs_string_to_key" = "yes"; then
 209         AC_DEFINE(ENABLE_AFS_STRING_TO_KEY, 1, [Define if want to use the weak AFS string to key functions.])
 210 fi
 211
 212
 213 rk_CHECK_MAN
 214
 215 rk_TEST_PACKAGE(readline,
 216 [#include <stdio.h>
 217  #include <readline.h>],-lreadline,,, READLINE)
 218
 219 rk_TEST_PACKAGE(hesiod,[#include <hesiod.h>],-lhesiod,,, HESIOD)
 220
 221 KRB_C_BIGENDIAN
 222 AC_C_INLINE
 223
 224 KRB_CHECK_X
 225
 226 AM_CONDITIONAL(HAVE_X, test "$no_x" != yes)
 227
 228 AC_CHECK_XAU
 229
 230 dnl AM_C_PROTOTYPES
 231
 232 dnl Checks for typedefs, structures, and compiler characteristics.
 233 AC_C_CONST
 234 AC_TYPE_OFF_T
 235 AC_CHECK_TYPE_EXTRA(mode_t, unsigned short, [])
 236 AC_CHECK_TYPE_EXTRA(sig_atomic_t, int, [#include <signal.h>])
 237 AC_HAVE_TYPE([long long])
 238 AC_HEADER_TIME
 239 AC_STRUCT_TM
 240
 241 dnl Checks for header files.
 242 AC_HEADER_STDC
 243
 244 AC_CHECK_HEADERS([\
 245         arpa/ftp.h                              \
 246         arpa/telnet.h                           \
 247         bind/bitypes.h                          \
 248         bsdsetjmp.h                             \
 249         curses.h                                \
 250         dlfcn.h                                 \
 251         fnmatch.h                               \
 252         inttypes.h                              \
 253         io.h                                    \
 254         libutil.h                               \
 255         limits.h                                \
 256         maillock.h                              \
 257         netgroup.h                              \
 258         netinet/in6_machtypes.h                 \
 259         pthread.h                               \
 260         pty.h                                   \
 261         sac.h                                   \
 262         sgtty.h                                 \
 263         siad.h                                  \
 264         signal.h                                \
 265         strings.h                               \
 266         stropts.h                               \
 267         sys/bitypes.h                           \
 268         sys/category.h                          \
 269         sys/file.h                              \
 270         sys/filio.h                             \
 271         sys/ioccom.h                            \
 272         sys/mman.h                              \
 273         sys/param.h                             \
 274         sys/pty.h                               \
 275         sys/ptyio.h                             \
 276         sys/select.h                            \
 277         sys/socket.h                            \
 278         sys/str_tty.h                           \
 279         sys/stream.h                            \
 280         sys/stropts.h                           \
 281         sys/syscall.h                           \
 282         sys/termio.h                            \
 283         sys/timeb.h                             \
 284         sys/times.h                             \
 285         sys/types.h                             \
 286         sys/un.h                                \
 287         locale.h                                \
 288         termcap.h                               \
 289         termio.h                                \
 290         termios.h                               \
 291         time.h                                  \
 292         tmpdir.h                                \
 293         udb.h                                   \
 294         util.h                                  \
 295         utmp.h                                  \
 296         utmpx.h                                 \
 297 ])
 298
 299 dnl On Solaris 8 there's a compilation warning for term.h because
 300 dnl it doesn't define `bool'.
 301 AC_CHECK_HEADERS(term.h, , , -)
 302
 303 dnl aix have asl.h (A/IX screen library) that we don't want
 304 AC_CHECK_HEADERS(asl.h, , , [
 305 #include <asl.h>
 306 #ifndef ASL_STRING_EMERG
 307 #error ASL_STRING_EMERG missing
 308 #endif])
 309
 310 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
 311 #if HAVE_SYS_SOCKET_H
 312 #include <sys/socket.h>
 313 #endif])
 314
 315 AC_CHECK_HEADERS(sys/ptyvar.h, , , [AC_INCLUDES_DEFAULT
 316 #if HAVE_SYS_TTY_H
 317 #include <sys/tty.h>
 318 #endif])
 319
 320 AC_CHECK_HEADERS(sys/strtty.h, , , [AC_INCLUDES_DEFAULT
 321 #if HAVE_TERMIOS_H
 322 #include <termios.h>
 323 #endif
 324 #if HAVE_SYS_STREAM_H
 325 #include <sys/stream.h>
 326 #endif])
 327
 328 AC_CHECK_HEADERS(sys/ucred.h, , , [AC_INCLUDES_DEFAULT
 329 #if HAVE_SYS_TYPES_H
 330 #include <sys/types.h>
 331 #endif
 332 #if HAVE_SYS_PARAM_H
 333 #include <sys/param.h>
 334 #endif])
 335
 336 AC_CHECK_HEADERS(security/pam_modules.h, , , [AC_INCLUDES_DEFAULT
 337 #include <security/pam_appl.h>
 338 ])
 339
 340 dnl export symbols
 341 rk_WIN32_EXPORT(BUILD_KRB5_LIB, KRB5_LIB)
 342 rk_WIN32_EXPORT(BUILD_ROKEN_LIB, ROKEN_LIB)
 343 rk_WIN32_EXPORT(BUILD_GSSAPI_LIB, GSSAPI_LIB)
 344
 345 dnl Checks for libraries.
 346
 347 AC_FIND_FUNC_NO_LIBS(logwtmp, util,[
 348 #ifdef HAVE_UTIL_H
 349 #include <util.h>
 350 #endif
 351 ],[0,0,0])
 352 AC_FIND_FUNC_NO_LIBS(logout, util,[
 353 #ifdef HAVE_UTIL_H
 354 #include <util.h>
 355 #endif
 356 ],[0])
 357 AC_FIND_FUNC_NO_LIBS(openpty, util,[
 358 #ifdef HAVE_UTIL_H
 359 #include <util.h>
 360 #endif
 361 ],[0,0,0,0,0])
 362
 363 AC_FIND_FUNC_NO_LIBS(tgetent, termcap ncurses curses,[
 364 #ifdef HAVE_TERMCAP_H
 365 #include <termcap.h>
 366 #endif
 367 #ifdef HAVE_CURSES_H
 368 #include <curses.h>
 369 #endif
 370 ],[0,0])
 371
 372 dnl Checks for library functions.
 373
 374 AC_CHECK_FUNCS([                                \
 375         _getpty                                 \
 376         _scrsize                                \
 377         arc4random                              \
 378         fcntl                                   \
 379         getpeereid                              \
 380         getpeerucred                            \
 381         grantpt                                 \
 382         mktime                                  \
 383         ptsname                                 \
 384         rand                                    \
 385         revoke                                  \
 386         select                                  \
 387         setitimer                               \
 388         setpcred                                \
 389         setpgid                                 \
 390         setproctitle                            \
 391         setregid                                \
 392         setresgid                               \
 393         setresuid                               \
 394         setreuid                                \
 395         setsid                                  \
 396         setutent                                \
 397         sigaction                               \
 398         strstr                                  \
 399         ttyname                                 \
 400         ttyslot                                 \
 401         umask                                   \
 402         unlockpt                                \
 403         vhangup                                 \
 404         yp_get_default_domain                   \
 405 ])
 406
 407 AC_FUNC_MMAP
 408
 409 KRB_CAPABILITIES
 410
 411 AC_CHECK_GETPWNAM_R_POSIX
 412
 413 dnl detect doors on solaris
 414 if test "$enable_pthread_support" != no; then
 415    saved_LIBS="$LIBS"
 416    LIBS="$LIBS $PTHREADS_LIBS"
 417    AC_FIND_FUNC_NO_LIBS(door_create, door)
 418    LIBS="$saved_LIBS"
 419 fi
 420
 421 AC_ARG_ENABLE(kcm,
 422         AS_HELP_STRING([--enable-kcm],[enable Kerberos Credentials Manager]),
 423 ,[enable_kcm=yes])
 424
 425 if test "$enable_kcm" = yes ; then
 426    if test  "$ac_cv_header_sys_un_h" != yes -a "$ac_cv_funclib_door_create" != yes ; then
 427         enable_kcm=no
 428    fi
 429 fi
 430 if test "$enable_kcm" = yes; then
 431        AC_DEFINE(HAVE_KCM, 1,
 432                [Define if you want to use the Kerberos Credentials Manager.])
 433 fi
 434 AM_CONDITIONAL(KCM, test "$enable_kcm" = yes)
 435
 436
 437
 438 dnl Cray stuff
 439 AC_CHECK_FUNCS(getudbnam setlim)
 440
 441 dnl AC_KRB_FUNC_GETCWD_BROKEN
 442
 443 dnl
 444 dnl Check for fields in struct utmp
 445 dnl
 446
 447 AC_HAVE_STRUCT_FIELD(struct utmp, ut_addr, [#include <utmp.h>])
 448 AC_HAVE_STRUCT_FIELD(struct utmp, ut_host, [#include <utmp.h>])
 449 AC_HAVE_STRUCT_FIELD(struct utmp, ut_id, [#include <utmp.h>])
 450 AC_HAVE_STRUCT_FIELD(struct utmp, ut_pid, [#include <utmp.h>])
 451 AC_HAVE_STRUCT_FIELD(struct utmp, ut_type, [#include <utmp.h>])
 452 AC_HAVE_STRUCT_FIELD(struct utmp, ut_user, [#include <utmp.h>])
 453 AC_HAVE_STRUCT_FIELD(struct utmpx, ut_exit, [#include <utmpx.h>])
 454 AC_HAVE_STRUCT_FIELD(struct utmpx, ut_syslen, [#include <utmpx.h>])
 455
 456 AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t,
 457         u_int8_t, u_int16_t, u_int32_t, u_int64_t,
 458         uint8_t, uint16_t, uint32_t, uint64_t],,,[
 459 #ifdef HAVE_INTTYPES_H
 460 #include <inttypes.h>
 461 #endif
 462 #ifdef HAVE_SYS_TYPES_H
 463 #include <sys/types.h>
 464 #endif
 465 #ifdef HAVE_SYS_BITYPES_H
 466 #include <sys/bitypes.h>
 467 #endif
 468 #ifdef HAVE_BIND_BITYPES_H
 469 #include <bind/bitypes.h>
 470 #endif
 471 #ifdef HAVE_NETINET_IN6_MACHTYPES_H
 472 #include <netinet/in6_machtypes.h>
 473 #endif
 474 ])
 475
 476 rk_FRAMEWORK_SECURITY
 477
 478 KRB_READLINE
 479
 480 rk_TELNET
 481
 482 dnl Some operating systems already have com_err and compile_et
 483 CHECK_COMPILE_ET
 484
 485 rk_AUTH_MODULES([sia afskauthlib])
 486
 487 rk_DESTDIRS
 488
 489 rk_WFLAGS([-Wall -Wmissing-prototypes -Wpointer-arith -Wbad-function-cast -Wmissing-declarations -Wnested-externs])
 490
 491
 492 AH_BOTTOM([#ifdef ROKEN_RENAME
 493 #include "roken_rename.h"
 494 #endif])
 495
 496 AC_CONFIG_FILES(Makefile                \
 497         etc/Makefile                    \
 498         include/Makefile                \
 499         include/gssapi/Makefile         \
 500         include/hcrypto/Makefile        \
 501         include/kadm5/Makefile          \
 502         lib/Makefile                    \
 503         lib/45/Makefile                 \
 504         lib/auth/Makefile               \
 505         lib/auth/afskauthlib/Makefile   \
 506         lib/auth/pam/Makefile           \
 507         lib/auth/sia/Makefile           \
 508         lib/asn1/Makefile               \
 509         lib/com_err/Makefile            \
 510         lib/hcrypto/Makefile            \
 511         lib/editline/Makefile           \
 512         lib/hx509/Makefile              \
 513         lib/gssapi/Makefile             \
 514         lib/ntlm/Makefile               \
 515         lib/hdb/Makefile                \
 516         lib/kadm5/Makefile              \
 517         lib/kafs/Makefile               \
 518         lib/kdfs/Makefile               \
 519         lib/krb5/Makefile               \
 520         lib/otp/Makefile                \
 521         lib/roken/Makefile              \
 522         lib/sl/Makefile                 \
 523         lib/sqlite/Makefile             \
 524         lib/vers/Makefile               \
 525         lib/wind/Makefile               \
 526         po/Makefile                     \
 527         kuser/Makefile                  \
 528         kpasswd/Makefile                \
 529         kadmin/Makefile                 \
 530         admin/Makefile                  \
 531         kcm/Makefile                    \
 532         kdc/Makefile                    \
 533         appl/Makefile                   \
 534         appl/afsutil/Makefile           \
 535         appl/ftp/Makefile               \
 536         appl/ftp/common/Makefile        \
 537         appl/ftp/ftp/Makefile           \
 538         appl/ftp/ftpd/Makefile          \
 539         appl/gssmask/Makefile           \
 540         appl/kx/Makefile                \
 541         appl/login/Makefile             \
 542         appl/otp/Makefile               \
 543         appl/popper/Makefile            \
 544         appl/push/Makefile              \
 545         appl/rsh/Makefile               \
 546         appl/rcp/Makefile               \
 547         appl/su/Makefile                \
 548         appl/xnlock/Makefile            \
 549         appl/telnet/Makefile            \
 550         appl/telnet/libtelnet/Makefile  \
 551         appl/telnet/telnet/Makefile     \
 552         appl/telnet/telnetd/Makefile    \
 553         appl/test/Makefile              \
 554         appl/kf/Makefile                \
 555         appl/dceutils/Makefile          \
 556         tests/Makefile                  \
 557         tests/can/Makefile              \
 558         tests/db/Makefile               \
 559         tests/kdc/Makefile              \
 560         tests/ldap/Makefile             \
 561         tests/gss/Makefile              \
 562         tests/java/Makefile             \
 563         tests/plugin/Makefile           \
 564         packages/Makefile               \
 565         packages/mac/Makefile           \
 566         doc/Makefile                    \
 567         tools/Makefile                  \
 568 )
 569
 570 AC_OUTPUT
 571
 572 dnl
 573 dnl This is the release version name-number[beta]
 574 dnl
 575
 576 cat > include/newversion.h.in <<EOF
 577 const char *heimdal_long_version = "@([#])\$Version: $PACKAGE_STRING by @USER@ on @HOST@ ($host) @DATE@ \$";
 578 const char *heimdal_version = "AC_PACKAGE_STRING";
 579 EOF
 580
 581 if test -f include/version.h && cmp -s include/newversion.h.in include/version.h.in; then
 582         echo "include/version.h is unchanged"
 583         rm -f include/newversion.h.in
 584 else
 585         echo "creating include/version.h"
 586         User=${USER-${LOGNAME}}
 587         Host=`(hostname || uname -n || echo unknown) 2>/dev/null | sed 1q`
 588         Date=`date`
 589         mv -f include/newversion.h.in include/version.h.in
 590         sed -e "s/@USER@/$User/" -e "s/@HOST@/$Host/" -e "s/@DATE@/$Date/" include/version.h.in > include/version.h
 591 fi