configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION($Revision$)
   3 AC_PREREQ(2.62)
   4 test -z "$CFLAGS" && CFLAGS="-g"
   5 AC_INIT([Heimdal],[1.5rc1],[heimdal-bugs@h5l.org])
   6 AC_CONFIG_SRCDIR([kuser/kinit.c])
   7 AC_CONFIG_HEADERS(include/config.h)
   8 AC_CONFIG_MACRO_DIR([cf])
   9
  10 AM_INIT_AUTOMAKE([foreign 1.10.3])
  11 AM_MAINTAINER_MODE
  12
  13 dnl Checks for programs.
  14 AC_PROG_CC
  15 AM_PROG_CC_C_O
  16 AC_PROG_CPP
  17 AC_PROG_LIBTOOL
  18
  19 AC_PREFIX_DEFAULT(/usr/heimdal)
  20
  21 test "$sysconfdir" = '${prefix}/etc' && sysconfdir='/etc'
  22 test "$localstatedir" = '${prefix}/var' && localstatedir='/var/heimdal'
  23
  24 AC_CANONICAL_HOST
  25 CANONICAL_HOST=$host
  26 AC_SUBST(CANONICAL_HOST)
  27
  28 rk_SYS_LARGEFILE
  29
  30 rk_AIX
  31 rk_IRIX
  32 rk_SUNOS
  33
  34 dnl
  35 dnl this is needed to run the configure tests against glibc
  36 dnl
  37 AC_DEFINE([_GNU_SOURCE], 1,
  38         [Define to enable extensions on glibc-based systems such as Linux.])
  39
  40 AC_OBJEXT
  41 AC_EXEEXT
  42
  43 dnl AC_KRB_PROG_YACC
  44 AC_PROG_YACC
  45 AM_PROG_LEX
  46 dnl AC_PROG_RANLIB
  47 AC_PROG_AWK
  48 AC_KRB_PROG_LN_S
  49
  50 AC_MIPS_ABI
  51 CC="$CC $abi"
  52 libdir="$libdir$abilibdirext"
  53
  54 AC_C___ATTRIBUTE__
  55
  56 LT_PREREQ([2.2])
  57 LT_INIT([shared static win32-dll])
  58
  59 AM_CONDITIONAL(ENABLE_SHARED, test "$enable_shared" = "yes")
  60 rk_VERSIONSCRIPT
  61
  62 dnl
  63 dnl Helper bits for cross compiling
  64 dnl
  65
  66
  67
  68 AM_CONDITIONAL(CROSS_COMPILE, test "${cross_compiling}" = yes)
  69
  70 AC_ARG_WITH(cross-tools,
  71         AS_HELP_STRING([--with-cross-tools=dir], [use cross tools in dir]),
  72         [if test "$withval" = "yes"; then
  73                 AC_MSG_ERROR([Need path to cross tools])
  74         fi
  75         with_cross_tools="${with_cross_tools}/"
  76         ])
  77
  78 if test "${cross_compiling}" != yes ; then
  79
  80    ASN1_COMPILE="\$(top_builddir)/lib/asn1/asn1_compile\$(EXEEXT)"
  81    SLC="\$(top_builddir)/lib/sl/slc"
  82
  83    ASN1_COMPILE_DEP="\$(ASN1_COMPILE)"
  84    SLC_DEP="\$(SLC)"
  85 else
  86    ASN1_COMPILE="${with_cross_tools}asn1_compile"
  87    SLC="${with_cross_tools}slc"
  88
  89    ASN1_COMPILE_DEP=
  90    SLC_DEP=
  91 fi
  92
  93 AC_SUBST([ASN1_COMPILE])
  94 AC_SUBST([ASN1_COMPILE_DEP])
  95 AC_SUBST([SLC])
  96 AC_SUBST([SLC_DEP])
  97
  98
  99 dnl ---
 100
 101 AC_DEFINE(HEIM_WEAK_CRYPTO, 1, [Define if you want support for weak crypto])
 102
 103 rk_TEST_PACKAGE(openldap,
 104 [#include <lber.h>
 105 #include <ldap.h>],
 106 [-lldap -llber],,,OPENLDAP)
 107
 108 AC_ARG_ENABLE(hdb-openldap-module,
 109         AS_HELP_STRING([--enable-hdb-openldap-module],
 110                 [if you want support to build openldap hdb as shared object]))
 111 if test "$enable_hdb_openldap_module" = yes -a "$with_openldap" = yes; then
 112     AC_DEFINE(OPENLDAP_MODULE, 1, [Define if you want support for hdb ldap module])
 113 fi
 114 AM_CONDITIONAL(OPENLDAP_MODULE, test "$enable_hdb_openldap_module" = yes -a "$with_openldap" = yes)
 115
 116 dnl
 117 dnl Optional modules, pk-init, digest, kx509
 118 dnl
 119
 120 AC_ARG_ENABLE(pk-init,
 121         AS_HELP_STRING([--disable-pk-init],
 122                 [if you want disable to PK-INIT support]))
 123 if test "$enable_pk_init" != no ;then
 124         AC_DEFINE([PKINIT], 1, [Define to enable PKINIT.])
 125 fi
 126 AM_CONDITIONAL(PKINIT, test "$enable_pk_init" != no)
 127
 128 AC_ARG_ENABLE(digest,
 129         AS_HELP_STRING([--disable-digest],
 130                 [if you want disable to DIGEST support]))
 131 if test "$enable_digest" != no ;then
 132         AC_DEFINE([DIGEST], 1, [Define to enable DIGEST.])
 133 fi
 134
 135 AC_ARG_ENABLE(kx509,
 136         AS_HELP_STRING([--disable-kx509],
 137                 [if you want disable to kx509 support]))
 138 if test "$enable_kx509" != no ;then
 139         AC_DEFINE([KX509], 1, [Define to enable kx509.])
 140 fi
 141
 142 dnl Need to test if pkg-config exists
 143 PKG_PROG_PKG_CONFIG
 144
 145 dnl libcap-ng
 146 AC_ARG_WITH([capng],
 147   AC_HELP_STRING([--with-capng], [use libcap-ng to drop KDC privileges @<:@default=check@:>@]),
 148   [],
 149   [with_capng=check])
 150 if test "$with_capng" != "no"; then
 151   PKG_CHECK_MODULES([CAPNG], [libcap-ng >= 0.4.0],
 152                     [with_capng=yes],[with_capng=no])
 153 fi
 154 if test "$with_capng" = "yes"; then
 155   AC_DEFINE_UNQUOTED([HAVE_CAPNG], 1, [whether capng is available for privilege reduction])
 156 fi
 157 AM_CONDITIONAL([HAVE_CAPNG], [test "$with_capng" != "no"])
 158 AC_SUBST([CAPNG_CFLAGS])
 159 AC_SUBST([CAPNG_LIBS])
 160
 161 dnl Check for sqlite
 162 rk_TEST_PACKAGE(sqlite3,
 163 [#include <sqlite3.h>
 164 #ifndef SQLITE_OPEN_CREATE
 165 #error "old version"
 166 #endif],
 167 [-lsqlite3],,,SQLITE3)
 168
 169 if test "X$with_sqlite3" != Xyes ; then
 170    INCLUDE_sqlite3="-I\$(top_srcdir)/lib/sqlite"
 171    LIB_sqlite3="\$(top_builddir)/lib/sqlite/libheimsqlite.la"
 172 fi
 173 AM_CONDITIONAL(SQLITE3,  test "X$with_sqlite3" = Xyes)
 174
 175 AC_DEFINE(HAVE_SQLITE3, 1, [Define if you want support for sqlite in Heimdal.])
 176
 177 AC_ARG_ENABLE(sqlite-cache,
 178         AS_HELP_STRING([--disable-sqlite-cache],[if you want support for cache in sqlite]))
 179 if test "$enable_sqlite_cache" != no; then
 180     AC_DEFINE(HAVE_SCC, 1, [Define if you want support for cache in sqlite.])
 181 fi
 182 AM_CONDITIONAL(have_scc, test "$enable_sqlite_cache" != no)
 183
 184
 185 dnl check for libintl
 186 rk_TEST_PACKAGE(libintl,
 187 [#include <libintl.h>],
 188 [-lintl],,,LIBINTL)
 189
 190 dnl path where the hdb directory is stored
 191 AC_ARG_WITH([hdbdir],
 192         [AS_HELP_STRING([--with-hdbdir],[Default location for KDC database @<:@default=/var/heimdal@:>@])],
 193         [],
 194         [with_hdbdir=/var/heimdal])
 195 DIR_hdbdir="$with_hdbdir"
 196 AC_SUBST([DIR_hdbdir])
 197
 198
 199 dnl no kerberos4 any more
 200 with_krb4=no
 201 AC_SUBST(INCLUDE_krb4)
 202 AC_SUBST(LIB_krb4)
 203 AM_CONDITIONAL(KRB4, false)
 204
 205 AM_CONDITIONAL(KRB5, true)
 206 AM_CONDITIONAL(do_roken_rename, true)
 207
 208 AC_DEFINE(SUPPORT_INETD, 1, [Enable use of inetd style startup.])dnl
 209
 210
 211 AC_DEFINE(KRB5, 1, [Enable Kerberos 5 support in applications.])dnl
 212 AC_SUBST(LIB_kdb)dnl
 213
 214 KRB_CRYPTO
 215
 216 KRB_PTHREADS
 217
 218 AC_ARG_ENABLE(dce,
 219         AS_HELP_STRING([--enable-dce],[if you want support for DCE/DFS PAG's]))
 220 if test "$enable_dce" = yes; then
 221     AC_DEFINE(DCE, 1, [Define if you want support for DCE/DFS PAG's.])
 222 fi
 223 AM_CONDITIONAL(DCE, test "$enable_dce" = yes)
 224
 225 ## XXX quite horrible:
 226 if test -f /etc/ibmcxx.cfg; then
 227         dpagaix_ldadd=`sed -n '/^xlc_r4/,/^$/p' /etc/ibmcxx.cfg | sed -n -e '/libraries/{;s/^[[^=]]*=\(.*\)/\1/;s/,/ /gp;}'`
 228         dpagaix_cflags=`sed -n '/^xlc_r4/,/^$/p' /etc/ibmcxx.cfg | sed -n -e '/options/{;s/^[[^=]]*=\(.*\)/\1/;s/-q[^,]*//;s/,/ /gp;}'`
 229         dpagaix_ldflags=
 230 else
 231         dpagaix_cflags="-D_THREAD_SAFE -D_AIX_PTHREADS_D7 -D_AIX32_THREADS=1 -D_AES_SOURCE -D_AIX41 -I/usr/include/dce"
 232         dpagaix_ldadd="-L/usr/lib/threads -ldcelibc_r -ldcepthreads -lpthreads_compat lpthreads -lc_r"
 233         dpagaix_ldflags="-Wl,-bI:dfspag.exp"
 234 fi
 235 AC_SUBST(dpagaix_cflags)
 236 AC_SUBST(dpagaix_ldadd)
 237 AC_SUBST(dpagaix_ldflags)
 238
 239 AC_ARG_ENABLE([afs-support],
 240         AS_HELP_STRING([--disable-afs-support],[if you don't want support for AFS]))
 241 if test "$enable_afs_support" = no; then
 242         AC_DEFINE(NO_AFS, 1, [Define if you don't wan't support for AFS.])
 243         NO_AFS="1"
 244 fi
 245 AC_SUBST(NO_AFS)dnl
 246
 247 rk_DB
 248
 249 dnl AC_ROKEN(10,[/usr/heimdal /usr/athena],[lib/roken],[$(top_builddir)/lib/roken/libroken.la],[-I$(top_builddir)/lib/roken -I$(top_srcdir)/lib/roken])
 250
 251 rk_ROKEN(lib/roken)
 252 LIBADD_roken="$LIB_roken"
 253 AC_SUBST(LIBADD_roken)dnl
 254 LIB_roken="\$(top_builddir)/lib/vers/libvers.la $LIB_roken"
 255
 256 rk_OTP
 257
 258 rk_LIBDISPATCH
 259
 260 AC_CHECK_OSFC2
 261
 262 AC_ARG_ENABLE(mmap,
 263         AS_HELP_STRING([--disable-mmap],[disable use of mmap]))
 264 if test "$enable_mmap" = "no"; then
 265         AC_DEFINE(NO_MMAP, 1, [Define if you don't want to use mmap.])
 266 fi
 267
 268 AC_ARG_ENABLE(afs-string-to-key,
 269         AS_HELP_STRING([--disable-afs-string-to-key],
 270         [disable use of weak AFS string-to-key functions]),
 271         [], [enable_afs_string_to_key=yes])
 272
 273 if test "$enable_afs_string_to_key" = "yes"; then
 274         AC_DEFINE(ENABLE_AFS_STRING_TO_KEY, 1, [Define if want to use the weak AFS string to key functions.])
 275 fi
 276
 277
 278 rk_CHECK_MAN
 279
 280 rk_TEST_PACKAGE(readline,
 281 [#include <stdio.h>
 282 #if defined(HAVE_READLINE_READLINE_H)
 283 #include <readline/readline.h>
 284 #elif defined(HAVE_READLINE_H)
 285 #include <readline.h>
 286 #endif
 287 ],-lreadline,,, READLINE,, [readline.h readline/readline.h])
 288
 289 rk_TEST_PACKAGE(libedit,
 290 [#include <stdio.h>
 291 #if defined(HAVE_READLINE_READLINE_H)
 292 #include <readline/readline.h>
 293 #elif defined(HAVE_READLINE_H)
 294 #include <readline.h>
 295 #endif
 296 ],-ledit,,, READLINE,, [readline.h readline/readline.h])
 297
 298 AC_CONFIG_SUBDIRS([lib/libedit])
 299
 300 rk_TEST_PACKAGE(hesiod,[#include <hesiod.h>],-lhesiod,,, HESIOD)
 301
 302 KRB_C_BIGENDIAN
 303 AC_C_INLINE
 304
 305 KRB_CHECK_X
 306
 307 AM_CONDITIONAL(HAVE_X, test "$no_x" != yes)
 308
 309 AC_CHECK_XAU
 310
 311 dnl AM_C_PROTOTYPES
 312
 313 dnl Checks for typedefs, structures, and compiler characteristics.
 314 AC_C_CONST
 315 AC_TYPE_OFF_T
 316 AC_CHECK_TYPE_EXTRA(mode_t, unsigned short, [])
 317 AC_CHECK_TYPE_EXTRA(sig_atomic_t, int, [#include <signal.h>])
 318 AC_HAVE_TYPE([long long])
 319 AC_HEADER_TIME
 320 AC_STRUCT_TM
 321
 322 dnl Checks for header files.
 323 AC_HEADER_STDC
 324
 325 AC_CHECK_HEADERS([\
 326         CommonCrypto/CommonDigest.h             \
 327         CommonCrypto/CommonCryptor.h            \
 328         arpa/ftp.h                              \
 329         arpa/telnet.h                           \
 330         bind/bitypes.h                          \
 331         bsdsetjmp.h                             \
 332         curses.h                                \
 333         dlfcn.h                                 \
 334         execinfo.h                              \
 335         fnmatch.h                               \
 336         inttypes.h                              \
 337         io.h                                    \
 338         libutil.h                               \
 339         limits.h                                \
 340         maillock.h                              \
 341         netgroup.h                              \
 342         netinet/in6_machtypes.h                 \
 343         pthread.h                               \
 344         pty.h                                   \
 345         sac.h                                   \
 346         sgtty.h                                 \
 347         siad.h                                  \
 348         signal.h                                \
 349         strings.h                               \
 350         stropts.h                               \
 351         sys/bitypes.h                           \
 352         sys/category.h                          \
 353         sys/file.h                              \
 354         sys/filio.h                             \
 355         sys/ioccom.h                            \
 356         sys/mman.h                              \
 357         sys/param.h                             \
 358         sys/pty.h                               \
 359         sys/ptyio.h                             \
 360         sys/select.h                            \
 361         sys/socket.h                            \
 362         sys/str_tty.h                           \
 363         sys/stream.h                            \
 364         sys/stropts.h                           \
 365         sys/syscall.h                           \
 366         sys/termio.h                            \
 367         sys/timeb.h                             \
 368         sys/times.h                             \
 369         sys/types.h                             \
 370         sys/un.h                                \
 371         locale.h                                \
 372         termcap.h                               \
 373         termio.h                                \
 374         termios.h                               \
 375         time.h                                  \
 376         tmpdir.h                                \
 377         udb.h                                   \
 378         util.h                                  \
 379         utmp.h                                  \
 380         utmpx.h                                 \
 381 ])
 382
 383 dnl On Solaris 8 there's a compilation warning for term.h because
 384 dnl it doesn't define `bool'.
 385 AC_CHECK_HEADERS(term.h, , , -)
 386
 387 dnl aix have asl.h (A/IX screen library) that we don't want
 388 AC_CHECK_HEADERS(asl.h, , , [
 389 #include <asl.h>
 390 #ifndef ASL_STRING_EMERG
 391 #error ASL_STRING_EMERG missing
 392 #endif])
 393
 394 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
 395 #if HAVE_SYS_SOCKET_H
 396 #include <sys/socket.h>
 397 #endif])
 398
 399 AC_CHECK_HEADERS(sys/ptyvar.h, , , [AC_INCLUDES_DEFAULT
 400 #if HAVE_SYS_TTY_H
 401 #include <sys/tty.h>
 402 #endif])
 403
 404 AC_CHECK_HEADERS(sys/strtty.h, , , [AC_INCLUDES_DEFAULT
 405 #if HAVE_TERMIOS_H
 406 #include <termios.h>
 407 #endif
 408 #if HAVE_SYS_STREAM_H
 409 #include <sys/stream.h>
 410 #endif])
 411
 412 AC_CHECK_HEADERS(sys/ucred.h, , , [AC_INCLUDES_DEFAULT
 413 #if HAVE_SYS_TYPES_H
 414 #include <sys/types.h>
 415 #endif
 416 #if HAVE_SYS_PARAM_H
 417 #include <sys/param.h>
 418 #endif])
 419
 420 AC_CHECK_HEADERS(security/pam_modules.h, , , [AC_INCLUDES_DEFAULT
 421 #include <security/pam_appl.h>
 422 ])
 423
 424 dnl export symbols
 425 rk_WIN32_EXPORT(BUILD_KRB5_LIB, KRB5_LIB)
 426 rk_WIN32_EXPORT(BUILD_ROKEN_LIB, ROKEN_LIB)
 427 rk_WIN32_EXPORT(BUILD_GSSAPI_LIB, GSSAPI_LIB)
 428
 429 dnl Checks for libraries.
 430
 431 AC_FIND_FUNC_NO_LIBS(logwtmp, util,[
 432 #ifdef HAVE_UTIL_H
 433 #include <util.h>
 434 #endif
 435 ],[0,0,0])
 436 AC_FIND_FUNC_NO_LIBS(logout, util,[
 437 #ifdef HAVE_UTIL_H
 438 #include <util.h>
 439 #endif
 440 ],[0])
 441 AC_FIND_FUNC_NO_LIBS(openpty, util,[
 442 #ifdef HAVE_UTIL_H
 443 #include <util.h>
 444 #endif
 445 ],[0,0,0,0,0])
 446
 447 AC_FIND_FUNC_NO_LIBS(tgetent, termcap ncurses curses,[
 448 #ifdef HAVE_TERMCAP_H
 449 #include <termcap.h>
 450 #endif
 451 #ifdef HAVE_CURSES_H
 452 #include <curses.h>
 453 #endif
 454 ],[0,0])
 455
 456 dnl Checks for library functions.
 457
 458 AC_CHECK_FUNCS([                                \
 459         _getpty                                 \
 460         _scrsize                                \
 461         arc4random                              \
 462         backtrace                               \
 463         fcntl                                   \
 464         getpeereid                              \
 465         getpeerucred                            \
 466         grantpt                                 \
 467         mktime                                  \
 468         ptsname                                 \
 469         rand                                    \
 470         revoke                                  \
 471         select                                  \
 472         setitimer                               \
 473         setpcred                                \
 474         setpgid                                 \
 475         setproctitle                            \
 476         setregid                                \
 477         setresgid                               \
 478         setresuid                               \
 479         setreuid                                \
 480         setsid                                  \
 481         setutent                                \
 482         sigaction                               \
 483         strstr                                  \
 484         ttyname                                 \
 485         ttyslot                                 \
 486         umask                                   \
 487         unlockpt                                \
 488         vhangup                                 \
 489         yp_get_default_domain                   \
 490 ])
 491
 492 AC_MSG_CHECKING([checking for __sync_add_and_fetch])
 493 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>]],
 494         [[unsigned int foo; __sync_add_and_fetch(&foo, 1);]])],
 495         [ac_rk_have___sync_add_and_fetch=yes], [ac_rk_have___sync_add_and_fetch=no])
 496 if test "$ac_rk_have___sync_add_and_fetch" = "yes" ; then
 497         AC_DEFINE_UNQUOTED(HAVE___SYNC_ADD_AND_FETCH, 1, [have __sync_add_and_fetch])
 498 fi
 499 AC_MSG_RESULT($ac_rk_have___sync_add_and_fetch)
 500
 501 AC_FUNC_MMAP
 502
 503 KRB_CAPABILITIES
 504
 505 AC_CHECK_GETPWNAM_R_POSIX
 506
 507 dnl detect doors on solaris
 508 if test "$enable_pthread_support" != no; then
 509    saved_LIBS="$LIBS"
 510    LIBS="$LIBS $PTHREADS_LIBS"
 511    AC_FIND_FUNC_NO_LIBS(door_create, door)
 512    LIBS="$saved_LIBS"
 513 fi
 514
 515 AC_ARG_ENABLE(kcm,
 516         AS_HELP_STRING([--enable-kcm],[enable Kerberos Credentials Manager]),
 517 ,[enable_kcm=yes])
 518
 519 if test "$enable_kcm" = yes ; then
 520    if test  "$ac_cv_header_sys_un_h" != yes -a "$ac_cv_funclib_door_create" != yes ; then
 521         enable_kcm=no
 522    fi
 523 fi
 524 if test "$enable_kcm" = yes; then
 525        AC_DEFINE(HAVE_KCM, 1,
 526                [Define if you want to use the Kerberos Credentials Manager.])
 527 fi
 528 AM_CONDITIONAL(KCM, test "$enable_kcm" = yes)
 529
 530
 531
 532 dnl Cray stuff
 533 AC_CHECK_FUNCS(getudbnam setlim)
 534
 535 dnl AC_KRB_FUNC_GETCWD_BROKEN
 536
 537 dnl
 538 dnl Check for fields in struct utmp
 539 dnl
 540
 541 AC_HAVE_STRUCT_FIELD(struct utmp, ut_addr, [#include <utmp.h>])
 542 AC_HAVE_STRUCT_FIELD(struct utmp, ut_host, [#include <utmp.h>])
 543 AC_HAVE_STRUCT_FIELD(struct utmp, ut_id, [#include <utmp.h>])
 544 AC_HAVE_STRUCT_FIELD(struct utmp, ut_pid, [#include <utmp.h>])
 545 AC_HAVE_STRUCT_FIELD(struct utmp, ut_type, [#include <utmp.h>])
 546 AC_HAVE_STRUCT_FIELD(struct utmp, ut_user, [#include <utmp.h>])
 547 AC_HAVE_STRUCT_FIELD(struct utmpx, ut_host, [#include <utmpx.h>])
 548 AC_HAVE_STRUCT_FIELD(struct utmpx, ut_id, [#include <utmpx.h>])
 549 AC_HAVE_STRUCT_FIELD(struct utmpx, ut_line, [#include <utmpx.h>])
 550 AC_HAVE_STRUCT_FIELD(struct utmpx, ut_pid, [#include <utmpx.h>])
 551 AC_HAVE_STRUCT_FIELD(struct utmpx, ut_tv, [#include <utmpx.h>])
 552 AC_HAVE_STRUCT_FIELD(struct utmpx, ut_type, [#include <utmpx.h>])
 553 AC_HAVE_STRUCT_FIELD(struct utmpx, ut_user, [#include <utmpx.h>])
 554 AC_HAVE_STRUCT_FIELD(struct utmpx, ut_exit, [#include <utmpx.h>])
 555 AC_HAVE_STRUCT_FIELD(struct utmpx, ut_syslen, [#include <utmpx.h>])
 556
 557 AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t,
 558         u_int8_t, u_int16_t, u_int32_t, u_int64_t,
 559         uint8_t, uint16_t, uint32_t, uint64_t],,,[
 560 #ifdef HAVE_INTTYPES_H
 561 #include <inttypes.h>
 562 #endif
 563 #ifdef HAVE_SYS_TYPES_H
 564 #include <sys/types.h>
 565 #endif
 566 #ifdef HAVE_SYS_BITYPES_H
 567 #include <sys/bitypes.h>
 568 #endif
 569 #ifdef HAVE_BIND_BITYPES_H
 570 #include <bind/bitypes.h>
 571 #endif
 572 #ifdef HAVE_NETINET_IN6_MACHTYPES_H
 573 #include <netinet/in6_machtypes.h>
 574 #endif
 575 ])
 576
 577 rk_FRAMEWORK_SECURITY
 578
 579 KRB_READLINE
 580
 581 rk_TELNET
 582
 583 dnl Some operating systems already have com_err and compile_et
 584 CHECK_COMPILE_ET
 585
 586 rk_AUTH_MODULES([sia afskauthlib])
 587
 588 rk_DESTDIRS
 589
 590 rk_WFLAGS([-Wall -Wmissing-prototypes -Wpointer-arith -Wbad-function-cast -Wmissing-declarations -Wnested-externs])
 591
 592
 593 AH_BOTTOM([#ifdef __APPLE__
 594 #include <AvailabilityMacros.h>
 595 #endif])
 596
 597 AH_BOTTOM([#ifdef ROKEN_RENAME
 598 #include "roken_rename.h"
 599 #endif])
 600
 601 AC_ARG_ENABLE(heimdal-documentation,
 602         AS_HELP_STRING([--disable-heimdal-documentation],
 603                 [if you want disable to heimdal documentation]))
 604 AM_CONDITIONAL(HEIMDAL_DOCUMENTATION, test "$enable_heimdal_documentation" != no)
 605
 606 AC_CONFIG_FILES(Makefile                \
 607         etc/Makefile                    \
 608         include/Makefile                \
 609         include/gssapi/Makefile         \
 610         include/hcrypto/Makefile        \
 611         include/kadm5/Makefile          \
 612         lib/Makefile                    \
 613         base/Makefile                   \
 614         lib/asn1/Makefile               \
 615         lib/com_err/Makefile            \
 616         lib/hcrypto/Makefile            \
 617         lib/hx509/Makefile              \
 618         lib/gssapi/Makefile             \
 619         lib/ntlm/Makefile               \
 620         lib/hdb/Makefile                \
 621         lib/ipc/Makefile                \
 622         lib/kadm5/Makefile              \
 623         lib/kafs/Makefile               \
 624         lib/kdfs/Makefile               \
 625         lib/krb5/Makefile               \
 626         lib/otp/Makefile                \
 627         lib/roken/Makefile              \
 628         lib/sl/Makefile                 \
 629         lib/sqlite/Makefile             \
 630         lib/vers/Makefile               \
 631         lib/wind/Makefile               \
 632         po/Makefile                     \
 633         kuser/Makefile                  \
 634         kpasswd/Makefile                \
 635         kadmin/Makefile                 \
 636         admin/Makefile                  \
 637         kcm/Makefile                    \
 638         kdc/Makefile                    \
 639         appl/Makefile                   \
 640         appl/afsutil/Makefile           \
 641         appl/ftp/Makefile               \
 642         appl/ftp/common/Makefile        \
 643         appl/ftp/ftp/Makefile           \
 644         appl/ftp/ftpd/Makefile          \
 645         appl/gssmask/Makefile           \
 646         appl/kx/Makefile                \
 647         appl/login/Makefile             \
 648         appl/otp/Makefile               \
 649         appl/popper/Makefile            \
 650         appl/push/Makefile              \
 651         appl/rsh/Makefile               \
 652         appl/rcp/Makefile               \
 653         appl/su/Makefile                \
 654         appl/xnlock/Makefile            \
 655         appl/telnet/Makefile            \
 656         appl/telnet/libtelnet/Makefile  \
 657         appl/telnet/telnet/Makefile     \
 658         appl/telnet/telnetd/Makefile    \
 659         appl/test/Makefile              \
 660         appl/kf/Makefile                \
 661         appl/dceutils/Makefile          \
 662         tests/Makefile                  \
 663         tests/bin/Makefile              \
 664         tests/can/Makefile              \
 665         tests/db/Makefile               \
 666         tests/kdc/Makefile              \
 667         tests/ldap/Makefile             \
 668         tests/gss/Makefile              \
 669         tests/java/Makefile             \
 670         tests/plugin/Makefile           \
 671         packages/Makefile               \
 672         packages/mac/Makefile           \
 673         doc/Makefile                    \
 674         tools/Makefile                  \
 675 )
 676
 677 AC_OUTPUT
 678
 679 dnl
 680 dnl This is the release version name-number[beta]
 681 dnl
 682
 683 cat > include/newversion.h.in <<EOF
 684 #ifndef VERSION_HIDDEN
 685 #define VERSION_HIDDEN
 686 #endif
 687 VERSION_HIDDEN const char *heimdal_long_version = "@([#])\$Version: $PACKAGE_STRING by @USER@ on @HOST@ ($host) @DATE@ \$";
 688 VERSION_HIDDEN const char *heimdal_version = "AC_PACKAGE_STRING";
 689 EOF
 690
 691 if test -f include/version.h && cmp -s include/newversion.h.in include/version.h.in; then
 692         echo "include/version.h is unchanged"
 693         rm -f include/newversion.h.in
 694 else
 695         echo "creating include/version.h"
 696         User=${USER-${LOGNAME}}
 697         Host=`(hostname || uname -n || echo unknown) 2>/dev/null | sed 1q`
 698         Date=`date`
 699         mv -f include/newversion.h.in include/version.h.in
 700         sed -e "s/@USER@/$User/" -e "s/@HOST@/$Host/" -e "s/@DATE@/$Date/" include/version.h.in > include/version.h
 701 fi