configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION($Revision$)
   3 AC_PREREQ(2.62)
   4 test -z "$CFLAGS" && CFLAGS="-g"
   5 AC_INIT([Heimdal],[1.2.1rc1],[heimdal-bugs@h5l.org])
   6 AC_CONFIG_SRCDIR([kuser/kinit.c])
   7 AC_CONFIG_HEADERS(include/config.h)
   8 AC_CONFIG_MACRO_DIR([cf])
   9
  10 AM_INIT_AUTOMAKE([foreign 1.10])
  11 AM_MAINTAINER_MODE
  12
  13 dnl Checks for programs.
  14 AC_PROG_CC
  15 AM_PROG_CC_C_O
  16 AC_PROG_CPP
  17
  18 AC_PREFIX_DEFAULT(/usr/heimdal)
  19
  20 test "$sysconfdir" = '${prefix}/etc' && sysconfdir='/etc'
  21 test "$localstatedir" = '${prefix}/var' && localstatedir='/var/heimdal'
  22
  23 AC_CANONICAL_HOST
  24 CANONICAL_HOST=$host
  25 AC_SUBST(CANONICAL_HOST)
  26
  27 dnl Hints for autobuild
  28 AB_INIT
  29
  30 rk_SYS_LARGEFILE
  31
  32 dnl
  33 dnl this is needed to run the configure tests against glibc
  34 dnl
  35 AC_DEFINE([_GNU_SOURCE], 1,
  36         [Define to enable extensions on glibc-based systems such as Linux.])
  37
  38 AC_OBJEXT
  39 AC_EXEEXT
  40
  41 dnl AC_KRB_PROG_YACC
  42 AC_PROG_YACC
  43 AM_PROG_LEX
  44 dnl AC_PROG_RANLIB
  45 AC_PROG_AWK
  46 AC_KRB_PROG_LN_S
  47
  48 AC_MIPS_ABI
  49 CC="$CC $abi"
  50 libdir="$libdir$abilibdirext"
  51
  52 AC_C___ATTRIBUTE__
  53
  54 LT_PREREQ([2.2])
  55 LT_INIT([shared static win32-dll])
  56
  57 AM_CONDITIONAL(ENABLE_SHARED, test "$enable_shared" = "yes")
  58 rk_VERSIONSCRIPT
  59
  60 rk_TEST_PACKAGE(openldap,
  61 [#include <lber.h>
  62 #include <ldap.h>],
  63 [-lldap -llber],,,OPENLDAP)
  64
  65 AC_ARG_ENABLE(hdb-openldap-module,
  66         AS_HELP_STRING([--enable-hdb-openldap-module],
  67                 [if you want support to build openldap hdb as shared object]))
  68 if test "$enable_hdb_openldap_module" = yes -a "$with_openldap" = yes; then
  69     AC_DEFINE(OPENLDAP_MODULE, 1, [Define if you want support for hdb ldap module])
  70 fi
  71 AM_CONDITIONAL(OPENLDAP_MODULE, test "$enable_hdb_openldap_module" = yes -a "$with_openldap" = yes)
  72
  73 AC_ARG_ENABLE(pk-init,
  74         AS_HELP_STRING([--disable-pk-init],
  75                 [if you want disable to PK-INIT support]))
  76 if test "$enable_pk_init" != no ;then
  77         AC_DEFINE([PKINIT], 1, [Define to enable PKINIT.])
  78 fi
  79 AM_CONDITIONAL(PKINIT, test "$enable_pk_init" != no)
  80
  81
  82 dnl path where the hdb directory is stored
  83 AC_ARG_WITH([hdbdir],
  84         [AS_HELP_STRING([--with-hdbdir],[Default location for KDC database @<:@default=/var/heimdal@:>@])],
  85         [],
  86         [with_hdbdir=/var/heimdal])
  87 DIR_hdbdir="$with_hdbdir"
  88 AC_SUBST([DIR_hdbdir])
  89
  90
  91 dnl no kerberos4 any more
  92 with_krb4=no
  93 AC_SUBST(INCLUDE_krb4)
  94 AC_SUBST(LIB_krb4)
  95 AM_CONDITIONAL(KRB4, false)
  96
  97 AM_CONDITIONAL(KRB5, true)
  98 AM_CONDITIONAL(do_roken_rename, true)
  99
 100 AC_DEFINE(KRB5, 1, [Enable Kerberos 5 support in applications.])dnl
 101 AC_SUBST(LIB_kdb)dnl
 102
 103 KRB_CRYPTO
 104
 105 KRB_PTHREADS
 106
 107 AC_ARG_ENABLE(dce,
 108         AS_HELP_STRING([--enable-dce],[if you want support for DCE/DFS PAG's]))
 109 if test "$enable_dce" = yes; then
 110     AC_DEFINE(DCE, 1, [Define if you want support for DCE/DFS PAG's.])
 111 fi
 112 AM_CONDITIONAL(DCE, test "$enable_dce" = yes)
 113
 114 ## XXX quite horrible:
 115 if test -f /etc/ibmcxx.cfg; then
 116         dpagaix_ldadd=`sed -n '/^xlc_r4/,/^$/p' /etc/ibmcxx.cfg | sed -n -e '/libraries/{;s/^[[^=]]*=\(.*\)/\1/;s/,/ /gp;}'`
 117         dpagaix_cflags=`sed -n '/^xlc_r4/,/^$/p' /etc/ibmcxx.cfg | sed -n -e '/options/{;s/^[[^=]]*=\(.*\)/\1/;s/-q[^,]*//;s/,/ /gp;}'`
 118         dpagaix_ldflags=
 119 else
 120         dpagaix_cflags="-D_THREAD_SAFE -D_AIX_PTHREADS_D7 -D_AIX32_THREADS=1 -D_AES_SOURCE -D_AIX41 -I/usr/include/dce"
 121         dpagaix_ldadd="-L/usr/lib/threads -ldcelibc_r -ldcepthreads -lpthreads_compat lpthreads -lc_r"
 122         dpagaix_ldflags="-Wl,-bI:dfspag.exp"
 123 fi
 124 AC_SUBST(dpagaix_cflags)
 125 AC_SUBST(dpagaix_ldadd)
 126 AC_SUBST(dpagaix_ldflags)
 127
 128 AC_ARG_ENABLE([afs-support],
 129         AS_HELP_STRING([--disable-afs-support],[if you don't want support for AFS]))
 130 if test "$enable_afs_support" = no; then
 131         AC_DEFINE(NO_AFS, 1, [Define if you don't wan't support for AFS.])
 132 fi
 133
 134 rk_DB
 135
 136 dnl AC_ROKEN(10,[/usr/heimdal /usr/athena],[lib/roken],[$(top_builddir)/lib/roken/libroken.la],[-I$(top_builddir)/lib/roken -I$(top_srcdir)/lib/roken])
 137
 138 rk_ROKEN(lib/roken)
 139 LIBADD_roken="$LIB_roken"
 140 AC_SUBST(LIBADD_roken)dnl
 141 LIB_roken="\$(top_builddir)/lib/vers/libvers.la $LIB_roken"
 142
 143 rk_OTP
 144
 145 AC_CHECK_OSFC2
 146
 147 AC_ARG_ENABLE(mmap,
 148         AS_HELP_STRING([--disable-mmap],[disable use of mmap]))
 149 if test "$enable_mmap" = "no"; then
 150         AC_DEFINE(NO_MMAP, 1, [Define if you don't want to use mmap.])
 151 fi
 152
 153 AC_ARG_ENABLE(afs-string-to-key,
 154         AS_HELP_STRING([--disable-afs-string-to-key],
 155         [disable use of weak AFS string-to-key functions]),
 156         [], [enable_afs_string_to_key=yes])
 157
 158 if test "$enable_afs_string_to_key" = "yes"; then
 159         AC_DEFINE(ENABLE_AFS_STRING_TO_KEY, 1, [Define if want to use the weak AFS string to key functions.])
 160 fi
 161
 162
 163 rk_CHECK_MAN
 164
 165 rk_TEST_PACKAGE(readline,
 166 [#include <stdio.h>
 167  #include <readline.h>],-lreadline,,, READLINE)
 168
 169 rk_TEST_PACKAGE(hesiod,[#include <hesiod.h>],-lhesiod,,, HESIOD)
 170
 171 KRB_C_BIGENDIAN
 172 AC_C_INLINE
 173
 174 rk_AIX
 175 rk_IRIX
 176 rk_SUNOS
 177
 178 KRB_CHECK_X
 179
 180 AM_CONDITIONAL(HAVE_X, test "$no_x" != yes)
 181
 182 AC_CHECK_XAU
 183
 184 dnl AM_C_PROTOTYPES
 185
 186 dnl Checks for typedefs, structures, and compiler characteristics.
 187 AC_C_CONST
 188 AC_TYPE_OFF_T
 189 AC_CHECK_TYPE_EXTRA(mode_t, unsigned short, [])
 190 AC_CHECK_TYPE_EXTRA(sig_atomic_t, int, [#include <signal.h>])
 191 AC_HAVE_TYPE([long long])
 192 AC_HEADER_TIME
 193 AC_STRUCT_TM
 194
 195 dnl Checks for header files.
 196 AC_HEADER_STDC
 197
 198 AC_CHECK_HEADERS([\
 199         arpa/ftp.h                              \
 200         arpa/telnet.h                           \
 201         asl.h                                   \
 202         bind/bitypes.h                          \
 203         bsdsetjmp.h                             \
 204         curses.h                                \
 205         dlfcn.h                                 \
 206         fnmatch.h                               \
 207         inttypes.h                              \
 208         io.h                                    \
 209         libutil.h                               \
 210         limits.h                                \
 211         maillock.h                              \
 212         netgroup.h                              \
 213         netinet/in6_machtypes.h                 \
 214         netinfo/ni.h                            \
 215         pthread.h                               \
 216         pty.h                                   \
 217         sac.h                                   \
 218         sgtty.h                                 \
 219         siad.h                                  \
 220         signal.h                                \
 221         strings.h                               \
 222         stropts.h                               \
 223         sys/bitypes.h                           \
 224         sys/category.h                          \
 225         sys/file.h                              \
 226         sys/filio.h                             \
 227         sys/ioccom.h                            \
 228         sys/mman.h                              \
 229         sys/param.h                             \
 230         sys/pty.h                               \
 231         sys/ptyio.h                             \
 232         sys/select.h                            \
 233         sys/socket.h                            \
 234         sys/str_tty.h                           \
 235         sys/stream.h                            \
 236         sys/stropts.h                           \
 237         sys/syscall.h                           \
 238         sys/termio.h                            \
 239         sys/timeb.h                             \
 240         sys/times.h                             \
 241         sys/types.h                             \
 242         sys/un.h                                \
 243         termcap.h                               \
 244         termio.h                                \
 245         termios.h                               \
 246         time.h                                  \
 247         tmpdir.h                                \
 248         udb.h                                   \
 249         util.h                                  \
 250         utmp.h                                  \
 251         utmpx.h                                 \
 252 ])
 253
 254 dnl On Solaris 8 there's a compilation warning for term.h because
 255 dnl it doesn't define `bool'.
 256 AC_CHECK_HEADERS(term.h, , , -)
 257
 258 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
 259 #if HAVE_SYS_SOCKET_H
 260 #include <sys/socket.h>
 261 #endif])
 262
 263 AC_CHECK_HEADERS(sys/ptyvar.h, , , [AC_INCLUDES_DEFAULT
 264 #if HAVE_SYS_TTY_H
 265 #include <sys/tty.h>
 266 #endif])
 267
 268 AC_CHECK_HEADERS(sys/strtty.h, , , [AC_INCLUDES_DEFAULT
 269 #if HAVE_TERMIOS_H
 270 #include <termios.h>
 271 #endif
 272 #if HAVE_SYS_STREAM_H
 273 #include <sys/stream.h>
 274 #endif])
 275
 276 AC_CHECK_HEADERS(sys/ucred.h, , , [AC_INCLUDES_DEFAULT
 277 #if HAVE_SYS_TYPES_H
 278 #include <sys/types.h>
 279 #endif
 280 #if HAVE_SYS_PARAM_H
 281 #include <sys/param.h>
 282 #endif])
 283
 284 AC_CHECK_HEADERS(security/pam_modules.h, , , [AC_INCLUDES_DEFAULT
 285 #include <security/pam_appl.h>
 286 ])
 287
 288 AC_ARG_ENABLE(netinfo,
 289         AS_HELP_STRING([--enable-netinfo],[enable netinfo for configuration lookup]))
 290
 291 if test "$ac_cv_header_netinfo_ni_h" = yes -a "$enable_netinfo" = yes; then
 292        AC_DEFINE(HAVE_NETINFO, 1,
 293                [Define if you want to use Netinfo instead of krb5.conf.])
 294 fi
 295
 296 dnl export symbols
 297 rk_WIN32_EXPORT(BUILD_KRB5_LIB, KRB5_LIB)
 298 rk_WIN32_EXPORT(BUILD_ROKEN_LIB, ROKEN_LIB)
 299 rk_WIN32_EXPORT(BUILD_GSSAPI_LIB, GSSAPI_LIB)
 300
 301 dnl Checks for libraries.
 302
 303 AC_FIND_FUNC_NO_LIBS(logwtmp, util,[
 304 #ifdef HAVE_UTIL_H
 305 #include <util.h>
 306 #endif
 307 ],[0,0,0])
 308 AC_FIND_FUNC_NO_LIBS(logout, util,[
 309 #ifdef HAVE_UTIL_H
 310 #include <util.h>
 311 #endif
 312 ],[0])
 313 AC_FIND_FUNC_NO_LIBS(openpty, util,[
 314 #ifdef HAVE_UTIL_H
 315 #include <util.h>
 316 #endif
 317 ],[0,0,0,0,0])
 318
 319 AC_FIND_FUNC_NO_LIBS(tgetent, termcap ncurses curses,[
 320 #ifdef HAVE_TERMCAP_H
 321 #include <termcap.h>
 322 #endif
 323 #ifdef HAVE_CURSES_H
 324 #include <curses.h>
 325 #endif
 326 ],[0,0])
 327
 328 dnl Checks for library functions.
 329
 330 AC_CHECK_FUNCS([                                \
 331         _getpty                                 \
 332         _scrsize                                \
 333         arc4random                              \
 334         fcntl                                   \
 335         getpeereid                              \
 336         getpeerucred                            \
 337         grantpt                                 \
 338         mktime                                  \
 339         ptsname                                 \
 340         rand                                    \
 341         revoke                                  \
 342         select                                  \
 343         setitimer                               \
 344         setpcred                                \
 345         setpgid                                 \
 346         setproctitle                            \
 347         setregid                                \
 348         setresgid                               \
 349         setresuid                               \
 350         setreuid                                \
 351         setsid                                  \
 352         setutent                                \
 353         sigaction                               \
 354         strstr                                  \
 355         ttyname                                 \
 356         ttyslot                                 \
 357         umask                                   \
 358         unlockpt                                \
 359         vhangup                                 \
 360         yp_get_default_domain                   \
 361 ])
 362
 363 AC_FUNC_MMAP
 364
 365 KRB_CAPABILITIES
 366
 367 AC_CHECK_GETPWNAM_R_POSIX
 368
 369 dnl detect doors on solaris
 370 if test "$enable_pthread_support" != no; then
 371    saved_LIBS="$LIBS"
 372    LIBS="$LIBS $PTHREADS_LIBS"
 373    AC_FIND_FUNC_NO_LIBS(door_create, door)
 374    LIBS="$saved_LIBS"
 375 fi
 376
 377 AC_ARG_ENABLE(kcm,
 378         AS_HELP_STRING([--enable-kcm],[enable Kerberos Credentials Manager]),
 379 ,[enable_kcm=yes])
 380
 381 if test "$enable_kcm" = yes ; then
 382    if test  "$ac_cv_header_sys_un_h" != yes -a "$ac_cv_funclib_door_create" != yes ; then
 383         enable_kcm=no
 384    fi
 385 fi
 386 if test "$enable_kcm" = yes; then
 387        AC_DEFINE(HAVE_KCM, 1,
 388                [Define if you want to use the Kerberos Credentials Manager.])
 389 fi
 390 AM_CONDITIONAL(KCM, test "$enable_kcm" = yes)
 391
 392
 393
 394 dnl Cray stuff
 395 AC_CHECK_FUNCS(getudbnam setlim)
 396
 397 dnl AC_KRB_FUNC_GETCWD_BROKEN
 398
 399 dnl
 400 dnl Check for fields in struct utmp
 401 dnl
 402
 403 AC_HAVE_STRUCT_FIELD(struct utmp, ut_addr, [#include <utmp.h>])
 404 AC_HAVE_STRUCT_FIELD(struct utmp, ut_host, [#include <utmp.h>])
 405 AC_HAVE_STRUCT_FIELD(struct utmp, ut_id, [#include <utmp.h>])
 406 AC_HAVE_STRUCT_FIELD(struct utmp, ut_pid, [#include <utmp.h>])
 407 AC_HAVE_STRUCT_FIELD(struct utmp, ut_type, [#include <utmp.h>])
 408 AC_HAVE_STRUCT_FIELD(struct utmp, ut_user, [#include <utmp.h>])
 409 AC_HAVE_STRUCT_FIELD(struct utmpx, ut_exit, [#include <utmpx.h>])
 410 AC_HAVE_STRUCT_FIELD(struct utmpx, ut_syslen, [#include <utmpx.h>])
 411
 412 AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t,
 413         u_int8_t, u_int16_t, u_int32_t, u_int64_t,
 414         uint8_t, uint16_t, uint32_t, uint64_t],,,[
 415 #ifdef HAVE_INTTYPES_H
 416 #include <inttypes.h>
 417 #endif
 418 #ifdef HAVE_SYS_TYPES_H
 419 #include <sys/types.h>
 420 #endif
 421 #ifdef HAVE_SYS_BITYPES_H
 422 #include <sys/bitypes.h>
 423 #endif
 424 #ifdef HAVE_BIND_BITYPES_H
 425 #include <bind/bitypes.h>
 426 #endif
 427 #ifdef HAVE_NETINET_IN6_MACHTYPES_H
 428 #include <netinet/in6_machtypes.h>
 429 #endif
 430 ])
 431
 432 rk_FRAMEWORK_SECURITY
 433
 434 KRB_READLINE
 435
 436 rk_TELNET
 437
 438 dnl Some operating systems already have com_err and compile_et
 439 CHECK_COMPILE_ET
 440
 441 rk_AUTH_MODULES([sia afskauthlib])
 442
 443 rk_DESTDIRS
 444
 445 rk_WFLAGS([-Wall -Wmissing-prototypes -Wpointer-arith -Wbad-function-cast -Wmissing-declarations -Wnested-externs])
 446
 447
 448 AH_BOTTOM([#ifdef ROKEN_RENAME
 449 #include "roken_rename.h"
 450 #endif])
 451
 452 AC_CONFIG_FILES(Makefile                \
 453         etc/Makefile                    \
 454         include/Makefile                \
 455         include/gssapi/Makefile         \
 456         include/hcrypto/Makefile        \
 457         include/kadm5/Makefile          \
 458         lib/Makefile                    \
 459         lib/45/Makefile                 \
 460         lib/auth/Makefile               \
 461         lib/auth/afskauthlib/Makefile   \
 462         lib/auth/pam/Makefile           \
 463         lib/auth/sia/Makefile           \
 464         lib/asn1/Makefile               \
 465         lib/com_err/Makefile            \
 466         lib/hcrypto/Makefile            \
 467         lib/editline/Makefile           \
 468         lib/hx509/Makefile              \
 469         lib/gssapi/Makefile             \
 470         lib/ntlm/Makefile               \
 471         lib/hdb/Makefile                \
 472         lib/kadm5/Makefile              \
 473         lib/kafs/Makefile               \
 474         lib/kdfs/Makefile               \
 475         lib/krb5/Makefile               \
 476         lib/otp/Makefile                \
 477         lib/roken/Makefile              \
 478         lib/sl/Makefile                 \
 479         lib/sqlite/Makefile             \
 480         lib/vers/Makefile               \
 481         lib/wind/Makefile               \
 482         kuser/Makefile                  \
 483         kpasswd/Makefile                \
 484         kadmin/Makefile                 \
 485         admin/Makefile                  \
 486         kcm/Makefile                    \
 487         kdc/Makefile                    \
 488         appl/Makefile                   \
 489         appl/afsutil/Makefile           \
 490         appl/ftp/Makefile               \
 491         appl/ftp/common/Makefile        \
 492         appl/ftp/ftp/Makefile           \
 493         appl/ftp/ftpd/Makefile          \
 494         appl/gssmask/Makefile           \
 495         appl/kx/Makefile                \
 496         appl/login/Makefile             \
 497         appl/otp/Makefile               \
 498         appl/popper/Makefile            \
 499         appl/push/Makefile              \
 500         appl/rsh/Makefile               \
 501         appl/rcp/Makefile               \
 502         appl/su/Makefile                \
 503         appl/xnlock/Makefile            \
 504         appl/telnet/Makefile            \
 505         appl/telnet/libtelnet/Makefile  \
 506         appl/telnet/telnet/Makefile     \
 507         appl/telnet/telnetd/Makefile    \
 508         appl/test/Makefile              \
 509         appl/kf/Makefile                \
 510         appl/dceutils/Makefile          \
 511         tests/Makefile                  \
 512         tests/can/Makefile              \
 513         tests/db/Makefile               \
 514         tests/kdc/Makefile              \
 515         tests/ldap/Makefile             \
 516         tests/gss/Makefile              \
 517         tests/java/Makefile             \
 518         tests/plugin/Makefile           \
 519         packages/Makefile               \
 520         packages/mac/Makefile           \
 521         packages/debian/Makefile        \
 522         doc/Makefile                    \
 523         tools/Makefile                  \
 524 )
 525
 526 AC_OUTPUT
 527
 528 dnl
 529 dnl This is the release version name-number[beta]
 530 dnl
 531
 532 cat > include/newversion.h.in <<EOF
 533 const char *heimdal_long_version = "@([#])\$Version: $PACKAGE_STRING by @USER@ on @HOST@ ($host) @DATE@ \$";
 534 const char *heimdal_version = "AC_PACKAGE_STRING";
 535 EOF
 536
 537 if test -f include/version.h && cmp -s include/newversion.h.in include/version.h.in; then
 538         echo "include/version.h is unchanged"
 539         rm -f include/newversion.h.in
 540 else
 541         echo "creating include/version.h"
 542         User=${USER-${LOGNAME}}
 543         Host=`(hostname || uname -n || echo unknown) 2>/dev/null | sed 1q`
 544         Date=`date`
 545         mv -f include/newversion.h.in include/version.h.in
 546         sed -e "s/@USER@/$User/" -e "s/@HOST@/$Host/" -e "s/@DATE@/$Date/" include/version.h.in > include/version.h
 547 fi