CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014,2015,2016,2017, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 2.8.8)
  36 # When we require cmake >= 2.8.12, it will provide
  37 # CMAKE_MINIMUM_REQUIRED_VERSION automatically, but in the meantime we
  38 # need to set a variable, and it must have a different name.
  39 set(GMX_CMAKE_MINIMUM_REQUIRED_VERSION "2.8.8")
  40
  41 # CMake modules/macros are in a subdirectory to keep this file cleaner
  42 # This needs to be set before project() in order to pick up toolchain files
  43 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  44
  45 project(Gromacs)
  46
  47 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  48 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  49 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  50
  51 # Set up common version variables, as well as general information about
  52 # the build tree (whether the build is from a source package or from a git
  53 # repository).  Also declares a few functions that will be used for generating
  54 # version info files later.
  55 include(gmxBuildTreeInfo)
  56 include(gmxVersionInfo)
  57
  58 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  59     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  60 endif()
  61 if("${CMAKE_INSTALL_PREFIX}" STREQUAL "${CMAKE_BINARY_DIR}")
  62     message(FATAL_ERROR "GROMACS cannot be installed into the build tree, choose a different location for CMAKE_INSTALL_PREFIX")
  63 endif()
  64
  65 include(gmxBuildTypeReference)
  66 include(gmxBuildTypeProfile)
  67 include(gmxBuildTypeTSAN)
  68 include(gmxBuildTypeASAN)
  69 include(gmxBuildTypeMSAN)
  70 include(gmxBuildTypeReleaseWithAssert)
  71
  72 if(NOT CMAKE_BUILD_TYPE)
  73     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference RelWithAssert Profile." FORCE)
  74     # There's no need to offer a user the choice of ThreadSanitizer
  75     # Set the possible values of build type for cmake-gui
  76     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
  77         "MinSizeRel" "RelWithDebInfo" "Reference" "RelWithAssert" "Profile")
  78 endif()
  79 if(CMAKE_CONFIGURATION_TYPES)
  80     # Add appropriate GROMACS-specific build types for the Visual
  81     # Studio generator (Debug, Release, MinSizeRel and RelWithDebInfo
  82     # are already present by default).
  83     list(APPEND CMAKE_CONFIGURATION_TYPES "RelWithAssert" "Reference")
  84     list(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)
  85     set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
  86         "List of configuration types"
  87         FORCE)
  88 endif()
  89 set(build_types_with_explicit_flags RELEASE DEBUG RELWITHDEBINFO RELWITHASSERT MINSIZEREL PROFILE)
  90
  91 set_property(GLOBAL PROPERTY FIND_LIBRARY_USE_LIB64_PATHS ON)
  92
  93 # Set a default valgrind suppression file.
  94 # This unfortunately needs to duplicate information from CTest to work as
  95 # expected...
  96 set(MEMORYCHECK_SUPPRESSIONS_FILE
  97     "${CMAKE_SOURCE_DIR}/cmake/legacy_and_external.supp"
  98     CACHE FILEPATH
  99     "File that contains suppressions for the memory checker")
 100 include(CTest)
 101
 102 include(gmxCPackUtilities)
 103 gmx_cpack_init()
 104
 105 # Variables that accumulate stuff influencing the installed headers
 106 set(INSTALLED_HEADER_INCLUDE_DIRS "")
 107 set(INSTALLED_HEADER_DEFINITIONS "")
 108
 109 ########################################################################
 110 # Check and warn if cache generated on a different host is being reused
 111 ########################################################################
 112 if(CMAKE_HOST_UNIX)
 113     execute_process(COMMAND hostname
 114                     OUTPUT_VARIABLE TMP_HOSTNAME
 115                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 116     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 117         message(WARNING "
 118             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 119             is being reused! This could lead to inconsistencies; therefore, it is
 120             recommended to regenerate the cache!")
 121     endif()
 122     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 123             "Hostname of the machine where the cache was generated.")
 124 endif()
 125
 126 ########################################################################
 127 # Detect architecture before setting options so we can alter defaults
 128 ########################################################################
 129 # Detect the architecture the compiler is targetting, detect
 130 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 131 # to use if none is specified, and populate the cache option for CPU
 132 # SIMD.
 133 include(gmxDetectTargetArchitecture)
 134 gmx_detect_target_architecture()
 135
 136 # Permit the user to specify a particular standard library, e.g. compiling
 137 # with "-stdlib=libc++" and linking with "-lc++abi -lc++" to get clang's libcxx.
 138 set(GMX_STDLIB_CXX_FLAGS "" CACHE STRING "Compiler flag for a C++ standard library flavour")
 139 set(GMX_STDLIB_LIBRARIES "" CACHE STRING "Linker libraries for a particular C++ standard library")
 140 mark_as_advanced(GMX_STDLIB_CXX_FLAGS)
 141 mark_as_advanced(GMX_STDLIB_LIBRARIES)
 142
 143 ########################################################################
 144 # Detect CXX11 support and flags
 145 ########################################################################
 146 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 147 # are used with permission from CMake v3.0.0 so that GROMACS can detect
 148 # invalid options with the Intel Compilers, and we have added a line
 149 # to detect warnings with the Fujitsu compilers on K computer and ICC.
 150 # CMake-3.0 also has a bug where the FAIL_REGEX pattern for AIX contains
 151 # a semicolon. Since this is also used as a separator in lists inside CMake,
 152 # that string ends up being split into two separate patterns, and the last
 153 # part is just a single word that also matches other messages. We solved this
 154 # by replacing the semicolon with a period that matches any character.
 155 #
 156 # These files should be removed from the source tree when a CMake version that
 157 # includes the features in question becomes required for building GROMACS.
 158 include(CheckCCompilerFlag)
 159 include(CheckCXXCompilerFlag)
 160
 161 # This must come early, since some of our configuration flag tests
 162 # depend on being able to compile C++11 source files.
 163 include(gmxTestCXX11)
 164 gmx_test_cxx11(GMX_CXX11_FLAGS GMX_STDLIB_CXX_FLAGS GMX_STDLIB_LIBRARIES)
 165
 166 # Make sure all C++ code will be compiled in C++11 mode, with the
 167 # expected standard library.
 168 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${GMX_CXX11_FLAGS} ${GMX_STDLIB_CXX_FLAGS}")
 169
 170 ########################################################################
 171 # User input options                                                   #
 172 ########################################################################
 173 include(gmxOptionUtilities)
 174
 175 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 176
 177 # Fujitsu only has SIMD in double precision, so this will be faster
 178 gmx_set_boolean(GMX_DOUBLE_DEFAULT GMX_TARGET_FUJITSU_SPARC64)
 179 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" ${GMX_DOUBLE_DEFAULT})
 180 option(GMX_RELAXED_DOUBLE_PRECISION "Accept single precision 1/sqrt(x) when using Fujitsu HPC-ACE SIMD" OFF)
 181 mark_as_advanced(GMX_RELAXED_DOUBLE_PRECISION)
 182
 183 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 184 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 185 gmx_dependent_option(
 186     GMX_MPI_IN_PLACE
 187     "Enable MPI_IN_PLACE for MPIs that have it defined"
 188     ON
 189     GMX_MPI)
 190 mark_as_advanced(GMX_MPI_IN_PLACE)
 191 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 192 mark_as_advanced(GMX_FAHCORE)
 193
 194 option(GMX_COOL_QUOTES "Enable GROMACS cool quotes" ON)
 195 mark_as_advanced(GMX_COOL_QUOTES)
 196 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 197
 198 option(GMX_USE_OPENCL "Enable OpenCL acceleration" OFF)
 199
 200 # Decide on GPU settings based on user-settings and GPU/CUDA detection.
 201 # GCC 4.6 requires CUDA 5.0 and VS2015 requires CUDA 8.0
 202 if(MSVC)
 203     set(REQUIRED_CUDA_VERSION 8.0)
 204 else()
 205     set(REQUIRED_CUDA_VERSION 5.0)
 206 endif()
 207 set(REQUIRED_CUDA_COMPUTE_CAPABILITY 2.0)
 208
 209 # OpenCL required version: 1.1 or newer
 210 set(REQUIRED_OPENCL_MIN_VERSION 1.1)
 211
 212 if(NOT GMX_USE_OPENCL)
 213     # CUDA detection is done only if GMX_USE_OPENCL is OFF.
 214     include(gmxManageGPU)
 215     set(GMX_USE_CUDA ${GMX_GPU})
 216     if(GMX_GPU)
 217         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_CUDA")
 218     else()
 219         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_NONE")
 220     endif()
 221 else()
 222     #Now the OpenCL path (for both AMD and NVIDIA)
 223     if(GMX_GPU)
 224         include(gmxManageOpenCL)
 225         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_OPENCL")
 226     else()
 227         message(FATAL_ERROR "OpenCL requested but GPU option is not enabled (try -DGMX_GPU=on) ")
 228     endif()
 229 endif()
 230
 231 include(gmxDetectSimd)
 232 gmx_detect_simd(GMX_SUGGESTED_SIMD)
 233
 234 gmx_option_multichoice(
 235     GMX_SIMD
 236     "SIMD instruction set for CPU kernels and compiler optimization"
 237     "${GMX_SUGGESTED_SIMD}"
 238     None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 AVX_512 AVX_512_KNL MIC ARM_NEON ARM_NEON_ASIMD IBM_QPX IBM_VMX IBM_VSX Sparc64_HPC_ACE Reference)
 239
 240 if(GMX_TARGET_MIC)
 241     set(GMX_FFT_LIBRARY_DEFAULT "mkl")
 242 else()
 243     set(GMX_FFT_LIBRARY_DEFAULT "fftw3")
 244 endif()
 245
 246 gmx_option_multichoice(
 247     GMX_FFT_LIBRARY
 248     "FFT library"
 249     "${GMX_FFT_LIBRARY_DEFAULT}"
 250     fftw3 mkl "fftpack[built-in]")
 251 gmx_dependent_option(
 252     GMX_BUILD_OWN_FFTW
 253     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 254     OFF
 255     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 256 gmx_dependent_option(
 257     GMX_DISABLE_FFTW_MEASURE
 258     "Do not optimize FFTW setups (not needed with SSE)"
 259     OFF
 260     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 261 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 262 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 263
 264 gmx_option_multichoice(
 265     GMX_QMMM_PROGRAM
 266     "QM package for QM/MM"
 267     None
 268     none gaussian mopac gamess orca)
 269
 270 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH  "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 271 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
 272
 273 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
 274
 275 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 276 mark_as_advanced(GMX_BROKEN_CALLOC)
 277
 278 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 279
 280 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 281
 282 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 283
 284 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 285 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 286
 287 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 288 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 289
 290 option(GMX_BUILD_FOR_COVERAGE
 291        "Tune build for better code coverage metrics (e.g., disable asserts)"
 292        OFF)
 293 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 294
 295 option(GMX_DEVELOPER_BUILD
 296     "Enable Developer convenience features: always build unit-tests"
 297     OFF)
 298 mark_as_advanced(GMX_DEVELOPER_BUILD)
 299
 300 gmx_set_boolean(GMX_COMPILER_WARNINGS_DEFAULT "NOT SOURCE_IS_SOURCE_DISTRIBUTION")
 301 option(GMX_COMPILER_WARNINGS
 302     "Enable a default set of compiler warnings"
 303     ${GMX_COMPILER_WARNINGS_DEFAULT})
 304 mark_as_advanced(GMX_COMPILER_WARNINGS)
 305 # Always turn on compiler warnings with a developer build.
 306 gmx_add_cache_dependency(GMX_COMPILER_WARNINGS BOOL "NOT GMX_DEVELOPER_BUILD" ON)
 307
 308 option(GMX_BUILD_SHARED_EXE
 309     "Build exectuables as shared binaries. If not set, this disables rpath and dynamic linker flags in an attempt to build a static binary, but this may require setting up the toolchain properly and making appropriate libraries available."
 310     ON)
 311 mark_as_advanced(GMX_BUILD_SHARED_EXE)
 312
 313 ######################################################################
 314 # Detect OpenMP support
 315 ######################################################################
 316 # The OpenMP detection _must_ come before tests for other CFLAGS.
 317 include(gmxManageOpenMP)
 318
 319
 320
 321 ######################################################################
 322 # Compiler tests
 323 # These need to be done early (before further tests).
 324 #####################################################################
 325
 326 include(gmxCFlags)
 327 gmx_c_flags()
 328
 329 # This variable should be used for additional compiler flags which are not
 330 # generated in gmxCFlags nor are SIMD or MPI related.
 331 #
 332 # TODO These variables should be consolidated into
 333 # EXTRA_COMPILER_FLAGS so that we we don't perpetrate bugs where
 334 # things that work in C compilation (e.g. merging from old branches)
 335 # also work for C++ compilation.
 336 set(EXTRA_C_FLAGS "")
 337 set(EXTRA_CXX_FLAGS "")
 338
 339 # Run through a number of tests for buggy compilers and other issues
 340 include(gmxTestCompilerProblems)
 341 gmx_test_compiler_problems()
 342 # GMX_SIMD will not be set automatically until the second
 343 # pass (which is not strictly guaranteed to occur), so putting this
 344 # check here among logically-related tests is inefficient, but the
 345 # potential loss is likely zero.
 346 if(GMX_SIMD STREQUAL "AVX_256"
 347         AND CMAKE_COMPILER_IS_GNUCC
 348         AND (C_COMPILER_VERSION VERSION_EQUAL "4.6.1"
 349             OR CXX_COMPILER_VERSION VERSION_EQUAL "4.6.1"))
 350     message(FATAL_ERROR "gcc 4.6.1 has buggy support for AVX, and GROMACS mdrun will not work. If you want simulation performance, use a more recent compiler. Otherwise, use GMX_SIMD=SSE4.1")
 351     # See http://gcc.gnu.org/bugzilla/show_bug.cgi?id=49002
 352 endif()
 353
 354 # Implement double-precision option. This is complicated because we
 355 # need installed headers to use the precision mode of the build that
 356 # produced the library, but cannot use config.h in that case. We also
 357 # want such variables to always have a definition, because #if is more
 358 # robust than #ifdef. So, we put this value on the compiler command
 359 # line in all cases.
 360 #
 361 # GMX_RELAXED_DOUBLE_PRECISION does not need to be handled here,
 362 # because no installed header needs it
 363 if(GMX_DOUBLE)
 364     set(GMX_DOUBLE_VALUE 1)
 365 else()
 366     set(GMX_DOUBLE_VALUE 0)
 367 endif()
 368 add_definitions(-DGMX_DOUBLE=${GMX_DOUBLE_VALUE})
 369 list(APPEND INSTALLED_HEADER_DEFINITIONS "-DGMX_DOUBLE=${GMX_DOUBLE_VALUE}")
 370
 371 if(WIN32)
 372     list(APPEND GMX_EXTRA_LIBRARIES "wsock32")
 373     add_definitions(-DGMX_HAVE_WINSOCK)
 374 endif()
 375
 376
 377
 378 ########################################################################
 379 # Basic system tests (standard libraries, headers, functions, types)   #
 380 ########################################################################
 381 include(CheckIncludeFiles)
 382 include(CheckIncludeFileCXX)
 383 check_include_files(unistd.h     HAVE_UNISTD_H)
 384 check_include_files(pwd.h        HAVE_PWD_H)
 385 check_include_files(dirent.h     HAVE_DIRENT_H)
 386 check_include_files(time.h       HAVE_TIME_H)
 387 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 388 check_include_files(io.h         HAVE_IO_H)
 389 check_include_files(sched.h      HAVE_SCHED_H)
 390
 391 check_include_files(regex.h      HAVE_POSIX_REGEX)
 392 # TODO: It could be nice to inform the user if no regex support is found,
 393 # as selections won't be fully functional.
 394
 395 include(CheckCXXSymbolExists)
 396 check_cxx_symbol_exists(gettimeofday      sys/time.h   HAVE_GETTIMEOFDAY)
 397 check_cxx_symbol_exists(sysconf           unistd.h     HAVE_SYSCONF)
 398 check_cxx_symbol_exists(nice              unistd.h     HAVE_NICE)
 399 check_cxx_symbol_exists(fsync             unistd.h     HAVE_FSYNC)
 400 check_cxx_symbol_exists(_fileno           stdio.h      HAVE__FILENO)
 401 check_cxx_symbol_exists(fileno            stdio.h      HAVE_FILENO)
 402 check_cxx_symbol_exists(_commit           io.h         HAVE__COMMIT)
 403 check_cxx_symbol_exists(sigaction         signal.h     HAVE_SIGACTION)
 404
 405 # We cannot check for the __builtins as symbols, but check if code compiles
 406 check_cxx_source_compiles("int main(){ return __builtin_clz(1);}"   HAVE_BUILTIN_CLZ)
 407 check_cxx_source_compiles("int main(){ return __builtin_clzll(1);}" HAVE_BUILTIN_CLZLL)
 408 if(MSVC)
 409     check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned long i=1;_BitScanReverse(&r,i);return r;}" HAVE_BITSCANREVERSE)
 410     check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned __int64 i=1;_BitScanReverse(&r,i);return r;}" HAVE_BITSCANREVERSE64)
 411 elseif(CMAKE_CXX_COMPILER_ID MATCHES "XL")
 412     check_cxx_source_compiles("int main(){ return __cntlz4(1);}" HAVE_CNTLZ4)
 413     check_cxx_source_compiles("int main(){ return __cntlz8(1);}" HAVE_CNTLZ8)
 414 endif()
 415
 416 include(CheckLibraryExists)
 417 find_library(HAVE_LIBM m)
 418 mark_as_advanced(HAVE_LIBM)
 419 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 420 check_library_exists(m feenableexcept "" HAVE_FEENABLEEXCEPT)
 421
 422 include(TestSchedAffinity)
 423 test_sched_affinity(HAVE_SCHED_AFFINITY)
 424
 425 # Aligned memory allocation. We need to check for both mm_malloc(),
 426 # posix_memalign(), memalign(), and on windows also _aligned_malloc()
 427 include(gmxTestMMMalloc)
 428 gmx_test_mm_malloc(HAVE__MM_MALLOC)
 429 check_cxx_symbol_exists(posix_memalign    stdlib.h     HAVE_POSIX_MEMALIGN)
 430 check_cxx_symbol_exists(memalign          stdlib.h     HAVE_MEMALIGN)
 431 if(MSVC)
 432     # No need to waste time on this test on platforms where it will never be true
 433     check_cxx_symbol_exists(_aligned_malloc   stdlib.h     HAVE__ALIGNED_MALLOC)
 434 endif()
 435
 436 include(TestBigEndian)
 437 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 438
 439 gmx_set_boolean(GMX_USE_NICE "HAVE_UNISTD_H AND HAVE_NICE")
 440
 441 # Management of GROMACS options for specific toolchains should go
 442 # here. Because the initial settings for some of the main options have
 443 # already happened, but things like library detection and MPI compiler
 444 # feature detection have not, the docstrings for any over-rides of
 445 # GROMACS defaults or user settings will make sense. Also, any
 446 # toolchain-related reasons for choosing whether to detect various
 447 # things can be sorted out now, before the detection takes place.
 448 if(${CMAKE_SYSTEM_NAME} MATCHES BlueGene)
 449     include(gmxManageBlueGene)
 450 endif()
 451
 452 if(GMX_TARGET_FUJITSU_SPARC64)
 453     include(gmxManageFujitsuSparc64)
 454 endif()
 455
 456 ########################################################################
 457 #Process MPI settings
 458 ########################################################################
 459 include(gmxManageMPI)
 460
 461
 462 ########################################################################
 463 #Process shared/static library settings
 464 ########################################################################
 465 include(gmxManageSharedLibraries)
 466
 467
 468 ########################################################################
 469 # Find external packages                                               #
 470 ########################################################################
 471
 472 # TNG wants zlib if it is available. And static libxml2 might have a dependency
 473 find_package(ZLIB QUIET)
 474 include(gmxTestZLib)
 475 gmx_test_zlib(HAVE_ZLIB)
 476
 477 # Unconditionally find the package, as it is also required for unit
 478 # tests. This exports LIBXML2_FOUND, which we should not use because
 479 # it does not tell us that linking will succeed. Instead, we test that
 480 # next.
 481 #if(DEFINED LIBXML2_LIBRARIES)
 482 #  set(LibXml2_FIND_QUIETLY TRUE)
 483 #endif()
 484 #find_package(LibXml2)
 485 #include(gmxTestLibXml2)
 486 #gmx_test_libxml2(HAVE_LIBXML2)
 487 #option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 488 #set(PKG_XML "")
 489 #mark_as_advanced(GMX_XML)
 490 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 491 #if(GMX_XML AND NOT HAVE_LIBXML2)
 492 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 493 #endif()
 494 #if(GMX_XML)
 495 #    include_directories(${LIBXML2_INCLUDE_DIR})
 496 #    set(PKG_XML libxml-2.0)
 497 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 498 #endif()
 499
 500 if(DEFINED HWLOC_LIBRARIES)
 501   set(Hwloc_FIND_QUIETLY TRUE)
 502 endif()
 503 find_package(Hwloc 1.5)
 504 if (HWLOC_FOUND)
 505     if (HWLOC_LIBRARIES MATCHES ".a$")
 506         set(_STATIC_HWLOC TRUE)
 507     endif()
 508
 509     gmx_check_if_changed(HWLOC_FOUND_CHANGED HWLOC_FOUND)
 510     if (_STATIC_HWLOC AND HWLOC_FOUND_CHANGED)
 511         message(STATUS "Static hwloc library found, will not attempt using it as it could lead to link-time errors. To use the detected library, manually set GMX_HWLOC=ON and you will likely have to pass appropriate linker flags too to satisfy the link-time dependencies of your hwloc library. Try \"pkg-config --libs --static hwloc\" for suggestions on what you will need.")
 512         set(GMX_HWLOC_DEFAULT OFF)
 513     else()
 514         set(GMX_HWLOC_DEFAULT ON)
 515     endif()
 516 else()
 517     set(GMX_HWLOC_DEFAULT OFF)
 518 endif()
 519 option(GMX_HWLOC "Add support for hwloc Portable Hardware locality library" ${GMX_HWLOC_DEFAULT})
 520 if(GMX_HWLOC)
 521     if(HWLOC_FOUND)
 522         include_directories(${HWLOC_INCLUDE_DIRS})
 523         list(APPEND GMX_EXTRA_LIBRARIES ${HWLOC_LIBRARIES})
 524     else()
 525         message(FATAL_ERROR "Hwloc package support requested, but not found.")
 526     endif()
 527 endif()
 528
 529 option(GMX_EXTERNAL_TINYXML2 "Use external TinyXML-2 instead of compiling the version bundled with GROMACS." OFF)
 530 mark_as_advanced(GMX_EXTERNAL_TINYXML2)
 531 if(GMX_EXTERNAL_TINYXML2)
 532     # Find an external TinyXML-2 library.
 533     find_package(TinyXML-2 3.0.0)
 534     set(HAVE_TINYXML2 ${TinyXML2_FOUND})
 535     if(NOT HAVE_TINYXML2)
 536         message(FATAL_ERROR "External TinyXML-2 could not be found, please adjust your search paths")
 537     endif()
 538 endif()
 539
 540 option(GMX_EXTRAE "Add support for tracing using EXTRAE" OFF)
 541 mark_as_advanced(GMX_EXTRAE)
 542
 543 if (GMX_EXTRAE)
 544   find_package(EXTRAE)
 545   if(EXTRAE_FOUND)
 546     include_directories(SYSTEM ${EXTRAE_INCLUDE_DIR})
 547     set(HAVE_EXTRAE 1)
 548   else()
 549     message(FATAL_ERROR "EXTRAE library was not found. Please add the correct path to CMAKE_PREFIX_PATH")
 550   endif()
 551 endif()
 552
 553 option(GMX_X11 "Use X window system" OFF)
 554 if (GMX_X11)
 555     find_package(X11)
 556     # X11 includes/libraries are only set in the ngmx subdirectory!
 557     if(NOT X11_FOUND)
 558         message(FATAL_ERROR
 559                 "X11 include files and/or libraries were not found. "
 560                 "Set GMX_X11=OFF to compile without X11 support. "
 561                 "gmx view will not be available.")
 562     endif()
 563     include_directories(SYSTEM ${X11_INCLUDE_DIR})
 564 endif()
 565
 566 include(ThreadMPI)
 567 # Enable core threading facilities
 568 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include")
 569 # Enable tMPI C++ support
 570 tmpi_enable_cxx()
 571 if(GMX_THREAD_MPI)
 572     # enable MPI functions
 573     tmpi_enable()
 574     set(MPI_IN_PLACE_EXISTS 1)
 575 endif()
 576 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
 577 if (TMPI_ATOMICS_DISABLED)
 578    add_definitions(-DTMPI_ATOMICS_DISABLED)
 579 endif()
 580
 581 # Note this relies on zlib detection having already run
 582 include(gmxManageTNG)
 583
 584 include(gmxManageLmfit)
 585
 586 if(GMX_GPU)
 587     # now that we have detected the dependencies, do the second configure pass
 588     gmx_gpu_setup()
 589 else()
 590     mark_as_advanced(CUDA_HOST_COMPILER)
 591 endif()
 592
 593 if(CYGWIN)
 594     set(GMX_CYGWIN 1)
 595 endif()
 596
 597 if(WIN32)
 598     set(GMX_NATIVE_WINDOWS 1)
 599     # This makes windows.h not declare min/max as macros that would break
 600     # C++ code using std::min/std::max.
 601     add_definitions(-DNOMINMAX)
 602 endif()
 603
 604 if(CMAKE_SYSTEM_NAME STREQUAL "Darwin") #Work-around for cmake bug #10837
 605     if (CMAKE_COMPILER_IS_GNUCC OR CMAKE_C_COMPILER_ID MATCHES "Intel" OR CMAKE_C_COMPILER_ID MATCHES "Clang")
 606         set(CMAKE_INCLUDE_SYSTEM_FLAG_C "-isystem ")
 607     endif()
 608     if (CMAKE_COMPILER_IS_GNUCXX OR CMAKE_CXX_COMPILER_ID MATCHES "Intel" OR CMAKE_CXX_COMPILER_ID MATCHES "Clang")
 609         set(CMAKE_INCLUDE_SYSTEM_FLAG_CXX "-isystem ")
 610     endif()
 611 endif()
 612
 613 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING" ON)
 614 mark_as_advanced(GMX_BUILD_UNITTESTS)
 615 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 616
 617 ########################################################################
 618 # Our own GROMACS tests
 619 ########################################################################
 620
 621 add_definitions( -DHAVE_CONFIG_H )
 622 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src)
 623 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include)
 624 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 625 include_directories(BEFORE ${CMAKE_BINARY_DIR}/src)
 626
 627 include(gmxTestInlineASM)
 628 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 629
 630 include(gmxSetBuildInformation)
 631 gmx_set_build_information()
 632 # Turn on RDTSCP if:
 633 # - the build system's CPU supports it
 634 # - the acceleration is set to AVX as all AVX-capable CPUs support AVX (which
 635 #   at this point means that the user set it).
 636 # Note: it's better to not use the later set value of GMX_SIMD because
 637 # it reflects the system's capability of both compiling and running AVX code.
 638 # TODO: After merge with 5.0 one could implement a cache variable dependency
 639 # such that GMX_USE_RDTSCP can change if GMX_SIMD is changed to AVX
 640 # after the first cmake pass.
 641 if (BUILD_CPU_FEATURES MATCHES "rdtscp" OR GMX_SIMD MATCHES "AVX")
 642     set(GMX_USE_RDTSCP_DEFAULT_VALUE ON)
 643 else()
 644     set(GMX_USE_RDTSCP_DEFAULT_VALUE OFF)
 645 endif()
 646 option(GMX_USE_RDTSCP "Use RDTSCP for better CPU-based timers (available on recent x86 CPUs; might need to be off when compiling for heterogeneous environments)" ${GMX_USE_RDTSCP_DEFAULT_VALUE})
 647 mark_as_advanced(GMX_USE_RDTSCP)
 648 if(GMX_USE_RDTSCP)
 649     set(HAVE_RDTSCP 1)
 650 endif()
 651
 652 include(gmxTestLargeFiles)
 653 gmx_test_large_files(GMX_LARGEFILES)
 654
 655 include(gmxTestSignal)
 656 gmx_test_sigusr1(HAVE_SIGUSR1)
 657
 658 include(gmxTestPipes)
 659 gmx_test_pipes(HAVE_PIPES)
 660
 661 check_include_file_cxx(regex     HAVE_CXX11_REGEX)
 662
 663 include(gmxTestXDR)
 664 gmx_test_xdr(GMX_SYSTEM_XDR)
 665 if(NOT GMX_SYSTEM_XDR)
 666     set(GMX_INTERNAL_XDR 1)
 667 endif()
 668
 669
 670 ##################################################
 671 # Process SIMD instruction settings
 672 ##################################################
 673 # This checks what flags to add in order to
 674 # support the SIMD instructions we need, it sets
 675 # correct defines for the SIMD instructions supported,
 676 # and adds advanced options to control accuracy
 677 # for SIMD math operations.
 678 include(gmxManageSimd)
 679 gmx_manage_simd()
 680
 681 include(gmxManageCycleCounters)
 682 gmx_manage_cycle_counters()
 683
 684 # Process QM/MM Settings
 685 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 686     set(GMX_QMMM_GAUSSIAN 1)
 687 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 688     set(GMX_QMMM_MOPAC 1)
 689 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 690     set(GMX_QMMM_GAMESS 1)
 691 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 692     set(GMX_QMMM_ORCA 1)
 693 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 694     # nothing to do
 695 else()
 696     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 697 endif()
 698
 699
 700 ##################################################
 701 # Process FFT library settings
 702 ##################################################
 703 include(gmxManageFFTLibraries)
 704
 705
 706 include(gmxManageLinearAlgebraLibraries)
 707
 708 include(gmxManagePluginSupport)
 709
 710 if (GMX_USE_PLUGINS)
 711     if(NOT GMX_VMD_PLUGIN_PATH)
 712         find_package(VMD)
 713     endif()
 714 endif()
 715
 716 # Link real-time library for POSIX timers. The check for clock_gettime
 717 # confirms the linkability of rt.
 718 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 719     list(APPEND GMX_EXTRA_LIBRARIES rt)
 720 endif()
 721
 722 # Math and thread libraries must often come after all others when linking...
 723 if(HAVE_LIBM)
 724     list(APPEND GMX_EXTRA_LIBRARIES m)
 725 endif()
 726
 727 option(GMX_NACL "Configure for Native Client builds" OFF)
 728 if (GMX_NACL)
 729   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 730   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 731   # TODO: Is this still necessary with the check for its presence?
 732   set(GMX_USE_NICE 0)
 733   set(GMX_NO_RENAME 1)
 734 endif()
 735 mark_as_advanced(GMX_NACL)
 736
 737 if(GMX_FAHCORE)
 738   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 739       "Path to swindirect.h")
 740   include_directories(${COREWRAP_INCLUDE_DIR})
 741 endif()
 742
 743 # Value of GMX_BUILD_HELP=AUTO tries to generate things, but will only
 744 # produce warnings if that fails.
 745 set(build_help_default AUTO)
 746 if (SOURCE_IS_SOURCE_DISTRIBUTION OR CMAKE_CROSSCOMPILING)
 747     set(build_help_default OFF)
 748 endif()
 749 gmx_option_trivalue(GMX_BUILD_HELP "Build completions automatically (requires that compiled binaries can be executed on the build host) and install man pages if built (requires building the 'man' target manually)" ${build_help_default})
 750 mark_as_advanced(GMX_BUILD_HELP)
 751 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND BUILD_IS_INSOURCE)
 752     message(FATAL_ERROR
 753         "Rebuilding shell completions or man pages is not supported for "
 754         "in-source builds from a source distribution. "
 755         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 756 endif()
 757
 758 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 759 # these are set after everything else
 760 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 761     set(CMAKE_C_FLAGS "${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
 762     set(CMAKE_CXX_FLAGS "${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
 763     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 764     set(CMAKE_SHARED_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 765 else()
 766     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 767     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
 768     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
 769     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
 770     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${GMXC_CXXFLAGS}")
 771     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
 772     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
 773     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 774     message("CMAKE_SHARED_LINKER_FLAGS: ${MPI_LINKER_FLAGS}")
 775 endif()
 776
 777 if(NOT GMX_OPENMP)
 778     #Unset all OpenMP flags in case OpenMP was disabled either by the user
 779     #or because it was only partially detected (e.g. only for C but not C++ compiler)
 780     unset(OpenMP_C_FLAGS CACHE)
 781     unset(OpenMP_CXX_FLAGS CACHE)
 782 else()
 783     set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} ${OpenMP_LINKER_FLAGS})
 784     set(GMX_SHARED_LINKER_FLAGS ${GMX_SHARED_LINKER_FLAGS} ${OpenMP_SHARED_LINKER_FLAGS})
 785 endif()
 786
 787 ########################################################################
 788 # Specify install locations
 789 ########################################################################
 790 # Use GNUInstallDirs to set paths on multiarch systems.
 791 include(GNUInstallDirs)
 792
 793 # Customization for the installation tree paths.
 794 set(GMX_LIB_INSTALL_DIR ${CMAKE_INSTALL_LIBDIR} CACHE STRING
 795     "Library installation directory (default: ${CMAKE_INSTALL_LIBDIR})")
 796 set(GMX_DATA_INSTALL_DIR gromacs CACHE STRING
 797     "Data installation directory under share/ (default: gromacs)")
 798 mark_as_advanced(GMX_LIB_INSTALL_DIR GMX_DATA_INSTALL_DIR)
 799
 800 # These variables are used internally to provide a central location for
 801 # customizing the install locations.
 802 set(LIB_INSTALL_DIR       ${GMX_LIB_INSTALL_DIR})
 803 set(BIN_INSTALL_DIR       bin)
 804 # This variable also gets written into config.h for use in finding the data
 805 # directories.
 806 set(DATA_INSTALL_DIR      share/${GMX_DATA_INSTALL_DIR})
 807 set(MAN_INSTALL_DIR       share/man)
 808 # If the nesting level wrt. the installation root is changed,
 809 # gromacs-config.cmake.cmakein needs to be adapted.
 810 set(CMAKE_INSTALL_DIR     share/cmake)
 811 # TODO: Make GMXRC adapt if this is changed
 812 set(PKGCONFIG_INSTALL_DIR ${LIB_INSTALL_DIR}/pkgconfig)
 813 set(OCL_INSTALL_DIR       ${DATA_INSTALL_DIR}/opencl)
 814 set(INCL_INSTALL_DIR      include)
 815
 816 list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${INCL_INSTALL_DIR})
 817
 818 # Binary and library suffix options
 819 include(gmxManageSuffixes)
 820
 821 ################################################################
 822 # Shared library load path settings
 823 ################################################################
 824 # CMake supports RPATH on OS X only from 2.8.12 upwards.
 825 # CMAKE_SYSTEM_VERSION > 8.0 matches OS X 10.5 and above, where RPATH support
 826 # was added.
 827
 828 if(NOT GMX_BUILD_SHARED_EXE)
 829     # No rpath
 830     set(CMAKE_SKIP_RPATH TRUE)
 831     set(CMAKE_EXE_LINK_DYNAMIC_C_FLAGS) # remove -Wl,-Bdynamic
 832     set(CMAKE_EXE_LINK_DYNAMIC_CXX_FLAGS)
 833 elseif((NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin") OR
 834    ((CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0) AND (NOT CMAKE_VERSION VERSION_LESS 2.8.12)))
 835     # The build folder always has bin/ and lib/; if we are also going to
 836     # install to lib/, then the installation RPATH works also in the build
 837     # tree.  This makes installation slightly faster (no need to rewrite the
 838     # RPATHs), and makes the binaries in the build tree relocatable.
 839     if(GMX_LIB_INSTALL_DIR STREQUAL "lib")
 840         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 841     endif()
 842     # Set the RPATH as relative to the executable location to make the
 843     # binaries relocatable.
 844     if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 845         set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${GMX_LIB_INSTALL_DIR}")
 846     else()
 847         set(CMAKE_INSTALL_RPATH "@executable_path/../${GMX_LIB_INSTALL_DIR}")
 848     endif()
 849     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 850     set(CMAKE_MACOSX_RPATH 1)
 851 else()
 852     # We are on Darwin/OSX, and CMake cannot handle RPATHs automatically.
 853     if(CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0)
 854         # Set the RPATH options manually.
 855         set(CMAKE_INSTALL_NAME_DIR "@rpath")
 856         set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} "-Wl,-rpath,@executable_path/../${GMX_LIB_INSTALL_DIR}")
 857     else()
 858         # Use the old INSTALL_NAME_DIR mechanism if RPATH is not supported.
 859         set(CMAKE_INSTALL_NAME_DIR "${CMAKE_INSTALL_PREFIX}/${LIB_INSTALL_DIR}")
 860     endif()
 861 endif()
 862
 863 #COPYING file: Only necessary for binary distributions.
 864 #Simpler to always install.
 865 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
 866
 867 if (GMX_BUILD_FOR_COVERAGE)
 868     # Code heavy with asserts makes conditional coverage close to useless metric,
 869     # as by design most of the false branches are impossible to trigger in
 870     # correctly functioning code.  And the benefit of testing those that could
 871     # be triggered by using an API against its specification isn't usually
 872     # worth the effort.
 873     add_definitions(-DNDEBUG -DGMX_DISABLE_ASSERTS)
 874 endif()
 875
 876 if (BUILD_TESTING)
 877     # "tests" target builds all the separate test binaries.
 878     add_custom_target(tests)
 879     # "run-ctest" is an internal target that actually runs the tests.
 880     # This is necessary to be able to add separate targets that execute as part
 881     # of 'make check', but are ensured to be executed after the actual tests.
 882     add_custom_target(run-ctest
 883                       COMMAND ${CMAKE_CTEST_COMMAND} --output-on-failure
 884                       COMMENT "Running all tests"
 885                       VERBATIM)
 886     add_dependencies(run-ctest tests)
 887     # "check" target builds and runs all tests.
 888     add_custom_target(check DEPENDS run-ctest)
 889 endif()
 890
 891 if (NOT GMX_BUILD_MDRUN_ONLY)
 892     add_subdirectory(docs)
 893     add_subdirectory(share)
 894     add_subdirectory(scripts)
 895 endif()
 896 add_subdirectory(src)
 897
 898 if (BUILD_TESTING)
 899     add_subdirectory(tests)
 900 endif()
 901
 902 gmx_cpack_write_config()
 903
 904 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
 905 # Don't bother the user after the first configure pass.
 906 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
 907     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
 908 endif()
 909 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
 910
 911 #######################
 912 ## uninstall target
 913 #######################
 914 CONFIGURE_FILE(   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 915                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 916                   IMMEDIATE @ONLY)
 917 ###########################
 918 ADD_CUSTOM_TARGET(uninstall
 919                   "${CMAKE_COMMAND}" -P
 920                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 921 ###########################
 922 set_directory_properties(PROPERTIES
 923             ADDITIONAL_MAKE_CLEAN_FILES "install_manifest.txt")