CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014,2015,2016,2017,2018, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 3.4.3)
  36
  37 # CMake modules/macros are in a subdirectory to keep this file cleaner
  38 # This needs to be set before project() in order to pick up toolchain files
  39 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  40
  41 project(Gromacs)
  42
  43 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  44 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  45 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  46
  47 # Set up common version variables, as well as general information about
  48 # the build tree (whether the build is from a source package or from a git
  49 # repository).  Also declares a few functions that will be used for generating
  50 # version info files later.
  51 include(gmxBuildTreeInfo)
  52 include(gmxVersionInfo)
  53
  54 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  55     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  56 endif()
  57 if("${CMAKE_INSTALL_PREFIX}" STREQUAL "${CMAKE_BINARY_DIR}")
  58     message(FATAL_ERROR "GROMACS cannot be installed into the build tree, choose a different location for CMAKE_INSTALL_PREFIX")
  59 endif()
  60
  61 include(gmxBuildTypeReference)
  62 include(gmxBuildTypeProfile)
  63 include(gmxBuildTypeTSAN)
  64 include(gmxBuildTypeASAN)
  65 include(gmxBuildTypeMSAN)
  66 include(gmxBuildTypeReleaseWithAssert)
  67
  68 if(NOT CMAKE_BUILD_TYPE)
  69     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference RelWithAssert Profile TSAN ASAN MSAN." FORCE)
  70     # Set the possible values of build type for cmake-gui
  71     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
  72         "MinSizeRel" "RelWithDebInfo" "Reference" "RelWithAssert" "Profile" "TSAN" "ASAN" "MSAN")
  73 endif()
  74 if(CMAKE_CONFIGURATION_TYPES)
  75     # Add appropriate GROMACS-specific build types for the Visual
  76     # Studio generator (Debug, Release, MinSizeRel and RelWithDebInfo
  77     # are already present by default).
  78     list(APPEND CMAKE_CONFIGURATION_TYPES "RelWithAssert" "Reference")
  79     list(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)
  80     set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
  81         "List of configuration types"
  82         FORCE)
  83 endif()
  84 set(build_types_with_explicit_flags RELEASE DEBUG RELWITHDEBINFO RELWITHASSERT MINSIZEREL PROFILE)
  85
  86 set_property(GLOBAL PROPERTY FIND_LIBRARY_USE_LIB64_PATHS ON)
  87
  88 include(gmxCTestUtilities)
  89 gmx_ctest_init()
  90
  91 include(gmxCPackUtilities)
  92 gmx_cpack_init()
  93
  94 # Variables that accumulate stuff influencing the installed headers
  95 set(INSTALLED_HEADER_INCLUDE_DIRS "")
  96 set(INSTALLED_HEADER_DEFINITIONS "")
  97
  98 ########################################################################
  99 # Global non-cache variables for implementing the build system
 100 ########################################################################
 101
 102 # These variables collect libraries that GROMACS requires for
 103 # linking. They should be appended to with list(APPEND ${name}
 104 # new-library) calls. They are:
 105 #  - Libraries that are required for libgromacs (only)
 106 set(GMX_EXTRA_LIBRARIES "")
 107 #  - Libraries that are required for all code in the repository
 108 set(GMX_COMMON_LIBRARIES "")
 109 #  - Libraries that all code linked against libgromacs needs
 110 #    (i.e., something that is exposed in installed headers).
 111 set(GMX_PUBLIC_LIBRARIES "")
 112
 113 ########################################################################
 114 # Check and warn if cache generated on a different host is being reused
 115 ########################################################################
 116 if(CMAKE_HOST_UNIX)
 117     execute_process(COMMAND hostname
 118                     OUTPUT_VARIABLE TMP_HOSTNAME
 119                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 120     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 121         message(WARNING "
 122             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 123             is being reused! This could lead to inconsistencies; therefore, it is
 124             recommended to regenerate the cache!")
 125     endif()
 126     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 127             "Hostname of the machine where the cache was generated.")
 128 endif()
 129
 130 ########################################################################
 131 # Detect architecture before setting options so we can alter defaults
 132 ########################################################################
 133 # Detect the architecture the compiler is targetting, detect
 134 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 135 # to use if none is specified, and populate the cache option for CPU
 136 # SIMD.
 137 include(gmxDetectTargetArchitecture)
 138 gmx_detect_target_architecture()
 139
 140 # Permit the user to specify a particular standard library, e.g. compiling
 141 # with "-stdlib=libc++" and linking with "-lc++abi -lc++" to get clang's libcxx.
 142 set(GMX_STDLIB_CXX_FLAGS "" CACHE STRING "Compiler flag for a C++ standard library flavour")
 143 set(GMX_STDLIB_LIBRARIES "" CACHE STRING "Linker libraries for a particular C++ standard library")
 144 mark_as_advanced(GMX_STDLIB_CXX_FLAGS)
 145 mark_as_advanced(GMX_STDLIB_LIBRARIES)
 146
 147 ########################################################################
 148 # Detect CXX11 support and flags
 149 ########################################################################
 150 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 151 # are used with permission from CMake v3.0.0 so that GROMACS can detect
 152 # invalid options with the Intel Compilers, and we have added a line
 153 # to detect warnings with the Fujitsu compilers on K computer and ICC.
 154 # CMake-3.0 also has a bug where the FAIL_REGEX pattern for AIX contains
 155 # a semicolon. Since this is also used as a separator in lists inside CMake,
 156 # that string ends up being split into two separate patterns, and the last
 157 # part is just a single word that also matches other messages. We solved this
 158 # by replacing the semicolon with a period that matches any character.
 159 #
 160 # These files should be removed from the source tree when a CMake version that
 161 # includes the features in question becomes required for building GROMACS.
 162 include(CheckCCompilerFlag)
 163 include(CheckCXXCompilerFlag)
 164
 165 # This must come early, since some of our configuration flag tests
 166 # depend on being able to compile C++11 source files.
 167 include(gmxTestCXX11)
 168 gmx_test_cxx11(GMX_CXX11_FLAGS GMX_STDLIB_CXX_FLAGS GMX_STDLIB_LIBRARIES)
 169
 170 # Make sure all C++ code will be compiled in C++11 mode, with the
 171 # expected standard library.
 172 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${GMX_CXX11_FLAGS} ${GMX_STDLIB_CXX_FLAGS}")
 173
 174 ########################################################################
 175 # User input options                                                   #
 176 ########################################################################
 177 include(gmxOptionUtilities)
 178
 179 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 180
 181 # Fujitsu only has SIMD in double precision, so this will be faster
 182 gmx_set_boolean(GMX_DOUBLE_DEFAULT GMX_TARGET_FUJITSU_SPARC64)
 183 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" ${GMX_DOUBLE_DEFAULT})
 184 option(GMX_RELAXED_DOUBLE_PRECISION "Accept single precision 1/sqrt(x) when using Fujitsu HPC-ACE SIMD" OFF)
 185 mark_as_advanced(GMX_RELAXED_DOUBLE_PRECISION)
 186
 187 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 188 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 189 gmx_dependent_option(
 190     GMX_MPI_IN_PLACE
 191     "Enable MPI_IN_PLACE for MPIs that have it defined"
 192     ON
 193     GMX_MPI)
 194 mark_as_advanced(GMX_MPI_IN_PLACE)
 195 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 196 mark_as_advanced(GMX_FAHCORE)
 197
 198 option(GMX_COOL_QUOTES "Enable GROMACS cool quotes" ON)
 199 mark_as_advanced(GMX_COOL_QUOTES)
 200 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 201
 202 option(GMX_USE_OPENCL "Enable OpenCL acceleration" OFF)
 203
 204 # Decide on GPU settings based on user-settings and GPU/CUDA
 205 # detection.  GCC 4.8 requires CUDA 6.0 (but we choose 6.5 for the
 206 # preliminary C++11 support), icc 15 requires CUDA 7.0, and VS2015
 207 # requires CUDA 8.0
 208 if(MSVC)
 209     set(REQUIRED_CUDA_VERSION 8.0)
 210 elseif(CMAKE_CXX_COMPILER_ID MATCHES "Intel")
 211     set(REQUIRED_CUDA_VERSION 7.0)
 212 else()
 213     set(REQUIRED_CUDA_VERSION 6.5)
 214 endif()
 215 set(REQUIRED_CUDA_COMPUTE_CAPABILITY 2.0)
 216
 217 # OpenCL required version: 1.1 or newer
 218 set(REQUIRED_OPENCL_MIN_VERSION 1.1)
 219
 220 if(NOT GMX_USE_OPENCL)
 221     # CUDA detection is done only if GMX_USE_OPENCL is OFF.
 222     include(gmxManageGPU)
 223     set(GMX_USE_CUDA ${GMX_GPU})
 224     if(GMX_GPU)
 225         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_CUDA")
 226     else()
 227         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_NONE")
 228     endif()
 229 else()
 230     #Now the OpenCL path (for both AMD and NVIDIA)
 231     if(GMX_GPU)
 232         include(gmxManageOpenCL)
 233         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_OPENCL")
 234     else()
 235         message(FATAL_ERROR "OpenCL requested but GPU option is not enabled (try -DGMX_GPU=on) ")
 236     endif()
 237 endif()
 238
 239 gmx_option_multichoice(
 240     GMX_SIMD
 241     "SIMD instruction set for CPU kernels and compiler optimization"
 242     "AUTO"
 243     AUTO None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 AVX2_128 AVX_512 AVX_512_KNL MIC ARM_NEON ARM_NEON_ASIMD IBM_VMX IBM_VSX Sparc64_HPC_ACE Reference)
 244
 245 if(GMX_TARGET_MIC)
 246     set(GMX_FFT_LIBRARY_DEFAULT "mkl")
 247 else()
 248     set(GMX_FFT_LIBRARY_DEFAULT "fftw3")
 249 endif()
 250
 251 gmx_option_multichoice(
 252     GMX_FFT_LIBRARY
 253     "FFT library"
 254     "${GMX_FFT_LIBRARY_DEFAULT}"
 255     fftw3 mkl "fftpack[built-in]")
 256 gmx_dependent_option(
 257     GMX_BUILD_OWN_FFTW
 258     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 259     OFF
 260     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 261 gmx_dependent_option(
 262     GMX_DISABLE_FFTW_MEASURE
 263     "Do not optimize FFTW setups (not needed with SSE)"
 264     OFF
 265     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 266 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 267 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 268
 269 gmx_option_multichoice(
 270     GMX_QMMM_PROGRAM
 271     "QM package for QM/MM"
 272     None
 273     none gaussian mopac gamess orca)
 274
 275 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH  "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 276 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
 277
 278 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
 279
 280 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 281 mark_as_advanced(GMX_BROKEN_CALLOC)
 282
 283 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 284
 285 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 286
 287 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 288
 289 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 290 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 291
 292 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 293 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 294
 295 option(GMX_BUILD_FOR_COVERAGE
 296        "Tune build for better code coverage metrics (e.g., disable asserts)"
 297        OFF)
 298 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 299
 300 option(GMX_DEVELOPER_BUILD
 301     "Enable Developer convenience features: always build unit-tests"
 302     OFF)
 303 mark_as_advanced(GMX_DEVELOPER_BUILD)
 304
 305 gmx_set_boolean(GMX_COMPILER_WARNINGS_DEFAULT "NOT SOURCE_IS_SOURCE_DISTRIBUTION")
 306 option(GMX_COMPILER_WARNINGS
 307     "Enable a default set of compiler warnings"
 308     ${GMX_COMPILER_WARNINGS_DEFAULT})
 309 mark_as_advanced(GMX_COMPILER_WARNINGS)
 310 # Always turn on compiler warnings with a developer build.
 311 gmx_add_cache_dependency(GMX_COMPILER_WARNINGS BOOL "NOT GMX_DEVELOPER_BUILD" ON)
 312
 313 option(GMX_BUILD_SHARED_EXE
 314     "Build exectuables as shared binaries. If not set, this disables rpath and dynamic linker flags in an attempt to build a static binary, but this may require setting up the toolchain properly and making appropriate libraries available."
 315     ON)
 316 mark_as_advanced(GMX_BUILD_SHARED_EXE)
 317
 318 option(GMX_PHYSICAL_VALIDATION
 319        "Include physical validation tests in ctest environment. These can then be called using 'make check-phys' or
 320        'make check-all'. Warning: Running the physical validation tests takes significantly more time than other tests!"
 321        OFF)
 322 mark_as_advanced(GMX_PHYSICAL_VALIDATION)
 323
 324 ######################################################################
 325 # Detect OpenMP support
 326 ######################################################################
 327 # The OpenMP detection _must_ come before tests for other CFLAGS.
 328 include(gmxManageOpenMP)
 329
 330
 331
 332 ######################################################################
 333 # Compiler tests
 334 # These need to be done early (before further tests).
 335 #####################################################################
 336
 337 include(gmxCFlags)
 338 gmx_c_flags()
 339
 340 # This variable should be used for additional compiler flags which are not
 341 # generated in gmxCFlags nor are SIMD or MPI related.
 342 #
 343 # TODO These variables should be consolidated into
 344 # EXTRA_COMPILER_FLAGS so that we we don't perpetrate bugs where
 345 # things that work in C compilation (e.g. merging from old branches)
 346 # also work for C++ compilation.
 347 set(EXTRA_C_FLAGS "")
 348 set(EXTRA_CXX_FLAGS "")
 349
 350 # Run through a number of tests for buggy compilers and other issues
 351 include(gmxTestCompilerProblems)
 352 gmx_test_compiler_problems()
 353
 354 # Implement double-precision option. This is complicated because we
 355 # need installed headers to use the precision mode of the build that
 356 # produced the library, but cannot use config.h in that case. We also
 357 # want such variables to always have a definition, because #if is more
 358 # robust than #ifdef. So, we put this value on the compiler command
 359 # line in all cases.
 360 #
 361 # GMX_RELAXED_DOUBLE_PRECISION does not need to be handled here,
 362 # because no installed header needs it
 363 if(GMX_DOUBLE)
 364     set(GMX_DOUBLE_VALUE 1)
 365 else()
 366     set(GMX_DOUBLE_VALUE 0)
 367 endif()
 368 add_definitions(-DGMX_DOUBLE=${GMX_DOUBLE_VALUE})
 369 list(APPEND INSTALLED_HEADER_DEFINITIONS "-DGMX_DOUBLE=${GMX_DOUBLE_VALUE}")
 370
 371 if(WIN32)
 372     list(APPEND GMX_EXTRA_LIBRARIES "wsock32")
 373     add_definitions(-DGMX_HAVE_WINSOCK)
 374 endif()
 375
 376
 377
 378 ########################################################################
 379 # Basic system tests (standard libraries, headers, functions, types)   #
 380 ########################################################################
 381 include(CheckIncludeFiles)
 382 include(CheckIncludeFileCXX)
 383 check_include_files(unistd.h     HAVE_UNISTD_H)
 384 check_include_files(pwd.h        HAVE_PWD_H)
 385 check_include_files(dirent.h     HAVE_DIRENT_H)
 386 check_include_files(time.h       HAVE_TIME_H)
 387 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 388 check_include_files(io.h         HAVE_IO_H)
 389 check_include_files(sched.h      HAVE_SCHED_H)
 390
 391 check_include_files(regex.h      HAVE_POSIX_REGEX)
 392 # TODO: It could be nice to inform the user if no regex support is found,
 393 # as selections won't be fully functional.
 394
 395 include(CheckCXXSymbolExists)
 396 check_cxx_symbol_exists(gettimeofday      sys/time.h   HAVE_GETTIMEOFDAY)
 397 check_cxx_symbol_exists(sysconf           unistd.h     HAVE_SYSCONF)
 398 check_cxx_symbol_exists(nice              unistd.h     HAVE_NICE)
 399 check_cxx_symbol_exists(fsync             unistd.h     HAVE_FSYNC)
 400 check_cxx_symbol_exists(_fileno           stdio.h      HAVE__FILENO)
 401 check_cxx_symbol_exists(fileno            stdio.h      HAVE_FILENO)
 402 check_cxx_symbol_exists(_commit           io.h         HAVE__COMMIT)
 403 check_cxx_symbol_exists(sigaction         signal.h     HAVE_SIGACTION)
 404
 405 # We cannot check for the __builtins as symbols, but check if code compiles
 406 check_cxx_source_compiles("int main(){ return __builtin_clz(1);}"   HAVE_BUILTIN_CLZ)
 407 check_cxx_source_compiles("int main(){ return __builtin_clzll(1);}" HAVE_BUILTIN_CLZLL)
 408 if(MSVC)
 409     check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned long i=1;_BitScanReverse(&r,i);return r;}" HAVE_BITSCANREVERSE)
 410     check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned __int64 i=1;_BitScanReverse(&r,i);return r;}" HAVE_BITSCANREVERSE64)
 411 elseif(CMAKE_CXX_COMPILER_ID MATCHES "XL")
 412     check_cxx_source_compiles("int main(){ return __cntlz4(1);}" HAVE_CNTLZ4)
 413     check_cxx_source_compiles("int main(){ return __cntlz8(1);}" HAVE_CNTLZ8)
 414 endif()
 415
 416 include(CheckLibraryExists)
 417 find_library(HAVE_LIBM m)
 418 mark_as_advanced(HAVE_LIBM)
 419 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 420 check_library_exists(m feenableexcept "" HAVE_FEENABLEEXCEPT)
 421
 422 include(TestSchedAffinity)
 423 test_sched_affinity(HAVE_SCHED_AFFINITY)
 424
 425 # Aligned memory allocation. We need to check for both mm_malloc(),
 426 # posix_memalign(), memalign(), and on windows also _aligned_malloc()
 427 include(gmxTestMMMalloc)
 428 gmx_test_mm_malloc(HAVE__MM_MALLOC)
 429 check_cxx_symbol_exists(posix_memalign    stdlib.h     HAVE_POSIX_MEMALIGN)
 430 check_cxx_symbol_exists(memalign          stdlib.h     HAVE_MEMALIGN)
 431 if(MSVC)
 432     # No need to waste time on this test on platforms where it will never be true
 433     check_cxx_symbol_exists(_aligned_malloc   stdlib.h     HAVE__ALIGNED_MALLOC)
 434 endif()
 435
 436 include(TestBigEndian)
 437 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 438
 439 gmx_set_boolean(GMX_USE_NICE "HAVE_UNISTD_H AND HAVE_NICE")
 440
 441 # Management of GROMACS options for specific toolchains should go
 442 # here. Because the initial settings for some of the main options have
 443 # already happened, but things like library detection and MPI compiler
 444 # feature detection have not, the docstrings for any over-rides of
 445 # GROMACS defaults or user settings will make sense. Also, any
 446 # toolchain-related reasons for choosing whether to detect various
 447 # things can be sorted out now, before the detection takes place.
 448 if(GMX_TARGET_FUJITSU_SPARC64)
 449     include(gmxManageFujitsuSparc64)
 450 endif()
 451
 452 ########################################################################
 453 #Process MPI settings
 454 ########################################################################
 455 include(gmxManageMPI)
 456
 457
 458 ########################################################################
 459 #Process shared/static library settings
 460 ########################################################################
 461 include(gmxManageSharedLibraries)
 462
 463
 464 ########################################################################
 465 # Find external packages                                               #
 466 ########################################################################
 467
 468 # Unconditionally find the package, as it is also required for unit
 469 # tests. This exports LIBXML2_FOUND, which we should not use because
 470 # it does not tell us that linking will succeed. Instead, we test that
 471 # next.
 472 #if(DEFINED LIBXML2_LIBRARIES)
 473 #  set(LibXml2_FIND_QUIETLY TRUE)
 474 #endif()
 475 #find_package(LibXml2)
 476 #include(gmxTestLibXml2)
 477 #gmx_test_libxml2(HAVE_LIBXML2)
 478 #option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 479 #set(PKG_XML "")
 480 #mark_as_advanced(GMX_XML)
 481 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 482 #if(GMX_XML AND NOT HAVE_LIBXML2)
 483 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 484 #endif()
 485 #if(GMX_XML)
 486 #    include_directories(${LIBXML2_INCLUDE_DIR})
 487 #    set(PKG_XML libxml-2.0)
 488 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 489 #endif()
 490
 491 if(DEFINED HWLOC_LIBRARIES)
 492   set(Hwloc_FIND_QUIETLY TRUE)
 493 endif()
 494 find_package(Hwloc 1.5)
 495 if (HWLOC_FOUND)
 496     if (HWLOC_LIBRARIES MATCHES ".a$")
 497         set(_STATIC_HWLOC TRUE)
 498     endif()
 499
 500     gmx_check_if_changed(HWLOC_FOUND_CHANGED HWLOC_FOUND)
 501     if (_STATIC_HWLOC AND HWLOC_FOUND_CHANGED)
 502         message(STATUS "Static hwloc library found, will not attempt using it as it could lead to link-time errors. To use the detected library, manually set GMX_HWLOC=ON and you will likely have to pass appropriate linker flags too to satisfy the link-time dependencies of your hwloc library. Try \"pkg-config --libs --static hwloc\" for suggestions on what you will need.")
 503         set(GMX_HWLOC_DEFAULT OFF)
 504     else()
 505         set(GMX_HWLOC_DEFAULT ON)
 506     endif()
 507 else()
 508     set(GMX_HWLOC_DEFAULT OFF)
 509 endif()
 510 option(GMX_HWLOC "Add support for hwloc Portable Hardware locality library" ${GMX_HWLOC_DEFAULT})
 511 if(GMX_HWLOC)
 512     if(HWLOC_FOUND)
 513         include_directories(SYSTEM ${HWLOC_INCLUDE_DIRS})
 514         list(APPEND GMX_EXTRA_LIBRARIES ${HWLOC_LIBRARIES})
 515     else()
 516         message(FATAL_ERROR "Hwloc package support requested, but not found.")
 517     endif()
 518 endif()
 519
 520 option(GMX_EXTERNAL_TINYXML2 "Use external TinyXML-2 instead of compiling the version bundled with GROMACS." OFF)
 521 mark_as_advanced(GMX_EXTERNAL_TINYXML2)
 522 if(GMX_EXTERNAL_TINYXML2)
 523     # Find an external TinyXML-2 library.
 524     find_package(TinyXML-2 3.0.0)
 525     set(HAVE_TINYXML2 ${TinyXML2_FOUND})
 526     if(NOT HAVE_TINYXML2)
 527         message(FATAL_ERROR "External TinyXML-2 could not be found, please adjust your search paths")
 528     endif()
 529 endif()
 530
 531 option(GMX_EXTRAE "Add support for tracing using EXTRAE" OFF)
 532 mark_as_advanced(GMX_EXTRAE)
 533
 534 if (GMX_EXTRAE)
 535   find_package(EXTRAE)
 536   if(EXTRAE_FOUND)
 537     include_directories(SYSTEM ${EXTRAE_INCLUDE_DIR})
 538     set(HAVE_EXTRAE 1)
 539   else()
 540     message(FATAL_ERROR "EXTRAE library was not found. Please add the correct path to CMAKE_PREFIX_PATH")
 541   endif()
 542 endif()
 543
 544 option(GMX_X11 "Use X window system" OFF)
 545 if (GMX_X11)
 546     find_package(X11)
 547     # X11 includes/libraries are only set in the ngmx subdirectory!
 548     if(NOT X11_FOUND)
 549         message(FATAL_ERROR
 550                 "X11 include files and/or libraries were not found. "
 551                 "Set GMX_X11=OFF to compile without X11 support. "
 552                 "gmx view will not be available.")
 553     endif()
 554     include_directories(SYSTEM ${X11_INCLUDE_DIR})
 555 endif()
 556
 557 include(ThreadMPI)
 558 # Enable core threading facilities
 559 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include")
 560 if(GMX_THREAD_MPI)
 561     # enable MPI functions
 562     tmpi_enable()
 563     set(MPI_IN_PLACE_EXISTS 1)
 564 endif()
 565 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
 566 if (TMPI_ATOMICS_DISABLED)
 567    add_definitions(-DTMPI_ATOMICS_DISABLED)
 568 endif()
 569
 570 include(gmxManageTNG)
 571
 572 include(gmxManageLmfit)
 573
 574 if(GMX_GPU)
 575     # now that we have detected the dependencies, do the second configure pass
 576     gmx_gpu_setup()
 577     if (GMX_CLANG_CUDA)
 578         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_CUDA_CLANG_LINK_LIBS})
 579         link_directories("${GMX_CUDA_CLANG_LINK_DIRS}")
 580     endif()
 581 endif()
 582
 583 if(CYGWIN)
 584     set(GMX_CYGWIN 1)
 585 endif()
 586
 587 if(WIN32)
 588     set(GMX_NATIVE_WINDOWS 1)
 589     # This makes windows.h not declare min/max as macros that would break
 590     # C++ code using std::min/std::max.
 591     add_definitions(-DNOMINMAX)
 592 endif()
 593
 594 if(CMAKE_SYSTEM_NAME STREQUAL "Darwin") #Work-around for cmake bug #10837
 595     if (CMAKE_COMPILER_IS_GNUCC OR CMAKE_C_COMPILER_ID MATCHES "Intel" OR CMAKE_C_COMPILER_ID MATCHES "Clang")
 596         set(CMAKE_INCLUDE_SYSTEM_FLAG_C "-isystem ")
 597     endif()
 598     if (CMAKE_COMPILER_IS_GNUCXX OR CMAKE_CXX_COMPILER_ID MATCHES "Intel" OR CMAKE_CXX_COMPILER_ID MATCHES "Clang")
 599         set(CMAKE_INCLUDE_SYSTEM_FLAG_CXX "-isystem ")
 600     endif()
 601 endif()
 602
 603 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING" ON)
 604 mark_as_advanced(GMX_BUILD_UNITTESTS)
 605 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 606
 607 ########################################################################
 608 # Our own GROMACS tests
 609 ########################################################################
 610
 611 add_definitions( -DHAVE_CONFIG_H )
 612 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src)
 613 # TODO required at high level because both libgromacs and progs/mdrun
 614 # require it, both for thread-MPI and its atomics and mutexes.
 615 include_directories(BEFORE SYSTEM ${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include)
 616 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 617 include_directories(BEFORE ${CMAKE_BINARY_DIR}/src)
 618
 619 include(gmxTestInlineASM)
 620 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 621
 622 include(gmxSetBuildInformation)
 623 gmx_set_build_information()
 624
 625 gmx_option_multichoice(
 626     GMX_USE_RDTSCP
 627     "Use low-latency RDTSCP instruction for CPU-based timers for mdrun execution; might need to be off when compiling for heterogeneous environments)"
 628     "AUTO"
 629     OFF ON AUTO DETECT)
 630 mark_as_advanced(GMX_USE_RDTSCP)
 631
 632 macro(gmx_check_rdtscp)
 633     if (CPU_DETECTION_FEATURES MATCHES "rdtscp")
 634         set(HAVE_RDTSCP 1)
 635         set(RDTSCP_DETECTION_MESSAGE " - detected on the build host")
 636     else()
 637         set(RDTSCP_DETECTION_MESSAGE " - not detected on the build host")
 638     endif()
 639 endmacro()
 640
 641 set(HAVE_RDTSCP 0)
 642 if (GMX_USE_RDTSCP STREQUAL "ON")
 643     set(HAVE_RDTSCP 1)
 644 elseif(GMX_USE_RDTSCP STREQUAL "DETECT")
 645     gmx_check_rdtscp()
 646 elseif(GMX_USE_RDTSCP STREQUAL "AUTO")
 647     # If the user specified automated SIMD selection, that the choice
 648     # is made based on detection on the build host. If so, then RDTSCP
 649     # should be chosen the same way.
 650     #
 651     # If the user specified an AVX SIMD level (e.g. when
 652     # cross-compiling GROMACS) then they will get our best guess, ie
 653     # that in practice AVX mostly correlates with rdtscp (and anyway
 654     # is only relevant in rather old x86 hardware).
 655     if (GMX_SIMD STREQUAL "AUTO")
 656         gmx_check_rdtscp()
 657     elseif (GMX_SIMD MATCHES "AVX")
 658         set(HAVE_RDTSCP 1)
 659     endif()
 660 endif()
 661 gmx_check_if_changed(HAVE_RDTSCP_CHANGED HAVE_RDTSCP)
 662 if (HAVE_RDTSCP_CHANGED)
 663     if (HAVE_RDTSCP)
 664         message(STATUS "Enabling RDTSCP support${RDTSCP_DETECTION_MESSAGE}")
 665     else()
 666         message(STATUS "Disabling RDTSCP support${RDTSCP_DETECTION_MESSAGE}")
 667     endif()
 668 endif()
 669
 670 include(gmxTestLargeFiles)
 671 gmx_test_large_files(GMX_LARGEFILES)
 672
 673 include(gmxTestSignal)
 674 gmx_test_sigusr1(HAVE_SIGUSR1)
 675
 676 include(gmxTestPipes)
 677 gmx_test_pipes(HAVE_PIPES)
 678
 679 check_include_file_cxx(regex     HAVE_CXX11_REGEX)
 680
 681 include(gmxTestXDR)
 682 gmx_test_xdr(GMX_SYSTEM_XDR)
 683 if(NOT GMX_SYSTEM_XDR)
 684     set(GMX_INTERNAL_XDR 1)
 685 endif()
 686
 687
 688 ##################################################
 689 # Process SIMD instruction settings
 690 ##################################################
 691 # This checks what flags to add in order to
 692 # support the SIMD instructions we need, it sets
 693 # correct defines for the SIMD instructions supported,
 694 # and adds advanced options to control accuracy
 695 # for SIMD math operations.
 696 include(gmxManageSimd)
 697 gmx_manage_simd()
 698
 699 include(gmxManageCycleCounters)
 700 gmx_manage_cycle_counters()
 701
 702 # Process QM/MM Settings
 703 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 704     set(GMX_QMMM_GAUSSIAN 1)
 705 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 706     set(GMX_QMMM_MOPAC 1)
 707 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 708     set(GMX_QMMM_GAMESS 1)
 709 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 710     set(GMX_QMMM_ORCA 1)
 711 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 712     # nothing to do
 713 else()
 714     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 715 endif()
 716
 717
 718 ##################################################
 719 # Process FFT library settings
 720 ##################################################
 721 include(gmxManageFFTLibraries)
 722
 723
 724 include(gmxManageLinearAlgebraLibraries)
 725
 726 include(gmxManagePluginSupport)
 727
 728 if (GMX_USE_PLUGINS)
 729     if(NOT GMX_VMD_PLUGIN_PATH)
 730         find_package(VMD)
 731     endif()
 732 endif()
 733
 734 # Link real-time library for POSIX timers. The check for clock_gettime
 735 # confirms the linkability of rt.
 736 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 737     list(APPEND GMX_EXTRA_LIBRARIES rt)
 738 endif()
 739
 740 # Math and thread libraries must often come after all others when linking...
 741 if (HAVE_LIBM)
 742     list(APPEND GMX_PUBLIC_LIBRARIES m)
 743 endif()
 744
 745 option(GMX_NACL "Configure for Native Client builds" OFF)
 746 if (GMX_NACL)
 747   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 748   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 749   # TODO: Is this still necessary with the check for its presence?
 750   set(GMX_USE_NICE 0)
 751   set(GMX_NO_RENAME 1)
 752 endif()
 753 mark_as_advanced(GMX_NACL)
 754
 755 if(GMX_FAHCORE)
 756   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 757       "Path to swindirect.h")
 758   include_directories(${COREWRAP_INCLUDE_DIR})
 759 endif()
 760
 761 # Value of GMX_BUILD_HELP=AUTO tries to generate things, but will only
 762 # produce warnings if that fails.
 763 set(build_help_default AUTO)
 764 if (SOURCE_IS_SOURCE_DISTRIBUTION OR CMAKE_CROSSCOMPILING)
 765     set(build_help_default OFF)
 766 endif()
 767 gmx_option_trivalue(GMX_BUILD_HELP "Build completions automatically (requires that compiled binaries can be executed on the build host) and install man pages if built (requires building the 'man' target manually)" ${build_help_default})
 768 mark_as_advanced(GMX_BUILD_HELP)
 769 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND BUILD_IS_INSOURCE)
 770     message(FATAL_ERROR
 771         "Rebuilding shell completions or man pages is not supported for "
 772         "in-source builds from a source distribution. "
 773         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 774 endif()
 775
 776 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 777 # these are set after everything else
 778 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 779     set(CMAKE_C_FLAGS "${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
 780     set(CMAKE_CXX_FLAGS "${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
 781     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 782     set(CMAKE_SHARED_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 783 else()
 784     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 785     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
 786     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
 787     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
 788     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${GMXC_CXXFLAGS}")
 789     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
 790     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
 791     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 792     message("CMAKE_SHARED_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 793 endif()
 794
 795 if(NOT GMX_OPENMP)
 796     #Unset all OpenMP flags in case OpenMP was disabled either by the user
 797     #or because it was only partially detected (e.g. only for C but not C++ compiler)
 798     unset(OpenMP_C_FLAGS CACHE)
 799     unset(OpenMP_CXX_FLAGS CACHE)
 800 else()
 801     set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} ${OpenMP_LINKER_FLAGS})
 802     set(GMX_SHARED_LINKER_FLAGS ${GMX_SHARED_LINKER_FLAGS} ${OpenMP_SHARED_LINKER_FLAGS})
 803 endif()
 804
 805 ########################################################################
 806 # Specify install locations
 807 ########################################################################
 808 # Use GNUInstallDirs to set paths on multiarch systems.
 809 include(GNUInstallDirs)
 810
 811 # Customization for the installation tree paths.
 812 set(GMX_LIB_INSTALL_DIR ${CMAKE_INSTALL_LIBDIR} CACHE STRING
 813     "Library installation directory (default: ${CMAKE_INSTALL_LIBDIR})")
 814 set(GMX_DATA_INSTALL_DIR gromacs CACHE STRING
 815     "Data installation directory under share/ (default: gromacs)")
 816 mark_as_advanced(GMX_LIB_INSTALL_DIR GMX_DATA_INSTALL_DIR)
 817
 818 # These variables are used internally to provide a central location for
 819 # customizing the install locations.
 820 set(LIB_INSTALL_DIR       ${GMX_LIB_INSTALL_DIR})
 821 set(BIN_INSTALL_DIR       bin)
 822 # This variable also gets written into config.h for use in finding the data
 823 # directories.
 824 set(DATA_INSTALL_DIR      share/${GMX_DATA_INSTALL_DIR})
 825 set(MAN_INSTALL_DIR       share/man)
 826 # If the nesting level wrt. the installation root is changed,
 827 # gromacs-config.cmake.cmakein needs to be adapted.
 828 set(CMAKE_INSTALL_DIR     share/cmake)
 829 # TODO: Make GMXRC adapt if this is changed
 830 set(PKGCONFIG_INSTALL_DIR ${LIB_INSTALL_DIR}/pkgconfig)
 831 set(OCL_INSTALL_DIR       ${DATA_INSTALL_DIR}/opencl)
 832 set(INCL_INSTALL_DIR      include)
 833
 834 list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${INCL_INSTALL_DIR})
 835
 836 # Binary and library suffix options
 837 include(gmxManageSuffixes)
 838
 839 ################################################################
 840 # Shared library load path settings
 841 ################################################################
 842 if(NOT GMX_BUILD_SHARED_EXE)
 843     # No rpath
 844     set(CMAKE_SKIP_RPATH TRUE)
 845     set(CMAKE_EXE_LINK_DYNAMIC_C_FLAGS) # remove -Wl,-Bdynamic
 846     set(CMAKE_EXE_LINK_DYNAMIC_CXX_FLAGS)
 847 else()
 848     # The build folder always has bin/ and lib/; if we are also going to
 849     # install to lib/, then the installation RPATH works also in the build
 850     # tree.  This makes installation slightly faster (no need to rewrite the
 851     # RPATHs), and makes the binaries in the build tree relocatable.
 852     if(GMX_LIB_INSTALL_DIR STREQUAL "lib")
 853         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 854         if(POLICY CMP0068)
 855             cmake_policy(SET CMP0068 NEW) # From CMake-3.9
 856             set(CMAKE_BUILD_WITH_INSTALL_NAME_DIR TRUE)
 857         endif()
 858     endif()
 859     # Set the RPATH as relative to the executable location to make the
 860     # binaries relocatable.
 861     if(CMAKE_SYSTEM_NAME STREQUAL "Darwin") #Assume OS X >=10.5
 862         set(CMAKE_INSTALL_RPATH "@executable_path/../${GMX_LIB_INSTALL_DIR}")
 863         set(CMAKE_INSTALL_NAME_DIR ${CMAKE_INSTALL_RPATH})
 864     else()
 865         set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${GMX_LIB_INSTALL_DIR}")
 866     endif()
 867     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 868     set(CMAKE_MACOSX_RPATH 1)
 869 endif()
 870
 871 #COPYING file: Only necessary for binary distributions.
 872 #Simpler to always install.
 873 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
 874
 875 if (GMX_BUILD_FOR_COVERAGE)
 876     # Code heavy with asserts makes conditional coverage close to useless metric,
 877     # as by design most of the false branches are impossible to trigger in
 878     # correctly functioning code.  And the benefit of testing those that could
 879     # be triggered by using an API against its specification isn't usually
 880     # worth the effort.
 881     add_definitions(-DNDEBUG -DGMX_DISABLE_ASSERTS)
 882 endif()
 883
 884 if (BUILD_TESTING)
 885     include(tests/CheckTarget.cmake)
 886 endif()
 887
 888 if (NOT GMX_BUILD_MDRUN_ONLY)
 889     add_subdirectory(docs)
 890     add_subdirectory(share)
 891     add_subdirectory(scripts)
 892 endif()
 893 add_subdirectory(src)
 894
 895 if (BUILD_TESTING)
 896     add_subdirectory(tests)
 897 endif()
 898
 899 gmx_cpack_write_config()
 900
 901 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
 902 # Don't bother the user after the first configure pass.
 903 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
 904     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
 905 endif()
 906 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
 907
 908 #######################
 909 ## uninstall target
 910 #######################
 911 CONFIGURE_FILE(   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 912                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 913                   IMMEDIATE @ONLY)
 914 ###########################
 915 ADD_CUSTOM_TARGET(uninstall
 916                   "${CMAKE_COMMAND}" -P
 917                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 918 ###########################
 919 set_directory_properties(PROPERTIES
 920             ADDITIONAL_MAKE_CLEAN_FILES "install_manifest.txt")