src/gromacs/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2010,2011,2012,2013,2014 by the GROMACS development team.
   5 # Copyright (c) 2015,2016,2017,2018,2019,2020, by the GROMACS development team, led by
   6 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   7 # and including many others, as listed in the AUTHORS file in the
   8 # top-level source directory and at http://www.gromacs.org.
   9 #
  10 # GROMACS is free software; you can redistribute it and/or
  11 # modify it under the terms of the GNU Lesser General Public License
  12 # as published by the Free Software Foundation; either version 2.1
  13 # of the License, or (at your option) any later version.
  14 #
  15 # GROMACS is distributed in the hope that it will be useful,
  16 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  18 # Lesser General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU Lesser General Public
  21 # License along with GROMACS; if not, see
  22 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  23 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  24 #
  25 # If you want to redistribute modifications to GROMACS, please
  26 # consider that scientific software is very special. Version
  27 # control is crucial - bugs must be traceable. We will be happy to
  28 # consider code for inclusion in the official distribution, but
  29 # derived work must not be called official GROMACS. Details are found
  30 # in the README & COPYING files - if they are missing, get the
  31 # official version at http://www.gromacs.org.
  32 #
  33 # To help us fund GROMACS development, we humbly ask that you cite
  34 # the research papers on the package. Check out http://www.gromacs.org.
  35
  36 set(LIBGROMACS_SOURCES)
  37
  38 if (GMX_CLANG_CUDA)
  39     include(gmxClangCudaUtils)
  40 endif()
  41
  42 set_property(GLOBAL PROPERTY GMX_LIBGROMACS_SOURCES)
  43 set_property(GLOBAL PROPERTY CUDA_SOURCES)
  44 set_property(GLOBAL PROPERTY GMX_INSTALLED_HEADERS)
  45 set_property(GLOBAL PROPERTY GMX_AVX_512_SOURCE)
  46
  47 set(libgromacs_object_library_dependencies "")
  48 function (_gmx_add_files_to_property PROPERTY)
  49     foreach (_file ${ARGN})
  50         if (IS_ABSOLUTE "${_file}")
  51             set_property(GLOBAL APPEND PROPERTY ${PROPERTY} ${_file})
  52         else()
  53             set_property(GLOBAL APPEND PROPERTY ${PROPERTY}
  54                          ${CMAKE_CURRENT_LIST_DIR}/${_file})
  55         endif()
  56     endforeach()
  57 endfunction ()
  58
  59 function (gmx_add_libgromacs_sources)
  60     _gmx_add_files_to_property(GMX_LIBGROMACS_SOURCES ${ARGN})
  61 endfunction ()
  62
  63 # Permit the configuration to disable compiling the many nbnxm kernels
  64 # and others involved in force calculations. Currently only
  65 # short-ranged and bonded kernels are disabled this way, but in future
  66 # others may be appropriate. Thus the cmake option is not specific to
  67 # nbnxm module.
  68 option(GMX_USE_SIMD_KERNELS "Whether to compile NBNXM and other SIMD kernels" ON)
  69 mark_as_advanced(GMX_USE_SIMD_KERNELS)
  70
  71 # Add these contents first because linking their tests can take a lot
  72 # of time, so we want lots of parallel work still available after
  73 # linking starts.
  74 add_subdirectory(utility)
  75 # Add normal contents
  76 add_subdirectory(gmxlib)
  77 add_subdirectory(mdlib)
  78 add_subdirectory(applied_forces)
  79 add_subdirectory(listed_forces)
  80 add_subdirectory(nbnxm)
  81 add_subdirectory(commandline)
  82 add_subdirectory(domdec)
  83 add_subdirectory(ewald)
  84 add_subdirectory(fft)
  85 add_subdirectory(gpu_utils)
  86 add_subdirectory(hardware)
  87 add_subdirectory(linearalgebra)
  88 add_subdirectory(math)
  89 add_subdirectory(mdrun)
  90 add_subdirectory(mdrunutility)
  91 add_subdirectory(mdspan)
  92 add_subdirectory(mdtypes)
  93 add_subdirectory(onlinehelp)
  94 add_subdirectory(options)
  95 add_subdirectory(pbcutil)
  96 add_subdirectory(random)
  97 add_subdirectory(restraint)
  98 add_subdirectory(tables)
  99 add_subdirectory(taskassignment)
 100 add_subdirectory(timing)
 101 add_subdirectory(topology)
 102 add_subdirectory(trajectory)
 103 add_subdirectory(swap)
 104 add_subdirectory(essentialdynamics)
 105 add_subdirectory(pulling)
 106 add_subdirectory(simd)
 107 add_subdirectory(imd)
 108 add_subdirectory(compat)
 109 add_subdirectory(mimic)
 110 add_subdirectory(modularsimulator)
 111 # Note that this subset should match the subset of module
 112 # BUILD_INTERFACEs added to libgromacs below.
 113 if (NOT GMX_BUILD_MDRUN_ONLY)
 114     add_subdirectory(gmxana)
 115     add_subdirectory(gmxpreprocess)
 116     add_subdirectory(correlationfunctions)
 117     add_subdirectory(statistics)
 118     add_subdirectory(analysisdata)
 119     add_subdirectory(coordinateio)
 120     add_subdirectory(trajectoryanalysis)
 121     add_subdirectory(energyanalysis)
 122     add_subdirectory(tools)
 123 endif()
 124
 125 get_property(PROPERTY_SOURCES GLOBAL PROPERTY GMX_LIBGROMACS_SOURCES)
 126 list(APPEND LIBGROMACS_SOURCES ${GMXLIB_SOURCES} ${MDLIB_SOURCES} ${PROPERTY_SOURCES})
 127
 128 # This would be the standard way to include thread_mpi, but
 129 # we want libgromacs to link the functions directly
 130 #if(GMX_THREAD_MPI)
 131 #    add_subdirectory(thread_mpi)
 132 #endif()
 133 #target_link_libraries(gmx ${GMX_EXTRA_LIBRARIES} ${THREAD_MPI_LIB})
 134 tmpi_get_source_list(THREAD_MPI_SOURCES ${PROJECT_SOURCE_DIR}/src/external/thread_mpi/src)
 135 add_library(thread_mpi OBJECT ${THREAD_MPI_SOURCES})
 136 target_compile_definitions(thread_mpi PRIVATE HAVE_CONFIG_H)
 137 if(CYGWIN)
 138     # Needs POSIX-isms for strdup, not just std-isms
 139     target_compile_definitions(thread_mpi PRIVATE _POSIX_C_SOURCE=200809L)
 140 endif()
 141 gmx_target_compile_options(thread_mpi)
 142 if (WIN32)
 143     gmx_target_warning_suppression(thread_mpi /wd4996 HAS_NO_MSVC_UNSAFE_FUNCTION)
 144 endif()
 145 list(APPEND libgromacs_object_library_dependencies thread_mpi)
 146
 147 if(GMX_INSTALL_LEGACY_API)
 148   install(FILES
 149           analysisdata.h
 150           options.h
 151           selection.h
 152           trajectoryanalysis.h
 153           DESTINATION include/gromacs)
 154 endif()
 155
 156 # This code is here instead of utility/CMakeLists.txt, because CMake
 157 # custom commands and source file properties can only be set in the directory
 158 # that contains the target that uses them.
 159 # TODO: Generate a header instead that can be included from baseversion.cpp.
 160 # That probably simplifies things somewhat.
 161 set(GENERATED_VERSION_FILE utility/baseversion-gen.cpp)
 162 gmx_configure_version_file(
 163     utility/baseversion-gen.cpp.cmakein ${GENERATED_VERSION_FILE}
 164     REMOTE_HASH
 165     EXTRA_VARS
 166         GMX_SOURCE_DOI
 167         GMX_RELEASE_HASH
 168         GMX_SOURCE_HASH
 169         )
 170 list(APPEND LIBGROMACS_SOURCES ${GENERATED_VERSION_FILE})
 171
 172 # Mark some shared GPU implementation files to compile with CUDA if needed
 173 if (GMX_GPU_CUDA)
 174     get_property(CUDA_SOURCES GLOBAL PROPERTY CUDA_SOURCES)
 175     set_source_files_properties(${CUDA_SOURCES} PROPERTIES CUDA_SOURCE_PROPERTY_FORMAT OBJ)
 176 endif()
 177
 178 if (GMX_GPU_CUDA)
 179     # Work around FindCUDA that prevents using target_link_libraries()
 180     # with keywords otherwise...
 181     set(CUDA_LIBRARIES PRIVATE ${CUDA_LIBRARIES})
 182     if (NOT GMX_CLANG_CUDA)
 183         gmx_cuda_add_library(libgromacs ${LIBGROMACS_SOURCES})
 184     else()
 185         add_library(libgromacs ${LIBGROMACS_SOURCES})
 186     endif()
 187     target_link_libraries(libgromacs PRIVATE ${CUDA_CUFFT_LIBRARIES})
 188 else()
 189     add_library(libgromacs ${LIBGROMACS_SOURCES})
 190 endif()
 191 target_link_libraries(libgromacs PRIVATE $<BUILD_INTERFACE:common>)
 192 # As long as the libgromacs target has source files that reference headers from
 193 # modules that don't provide CMake targets, libgromacs needs to use `src/`
 194 # amongst its include directories (to support `#include "gromacs/module/header.h"`).
 195 add_library(legacy_modules INTERFACE)
 196 target_include_directories(legacy_modules INTERFACE $<BUILD_INTERFACE:${CMAKE_SOURCE_DIR}/src>)
 197 target_link_libraries(libgromacs PRIVATE $<BUILD_INTERFACE:legacy_modules>)
 198
 199 # Add these contents first because linking their tests can take a lot
 200 # of time, so we want lots of parallel work still available after
 201 # linking starts.
 202 add_subdirectory(fileio)
 203 add_subdirectory(selection)
 204
 205 # Suppress a warning about our abuse of t_inputrec
 206 gmx_source_file_warning_suppression(mdtypes/inputrec.cpp -Wno-class-memaccess HAS_NO_CLASS_MEMACCESS)
 207
 208 # Handle the object libraries that contain the source file
 209 # dependencies that need special handling because they are generated
 210 # or external code.
 211 foreach(object_library ${libgromacs_object_library_dependencies})
 212     if (BUILD_SHARED_LIBS)
 213         set_target_properties(${object_library} PROPERTIES POSITION_INDEPENDENT_CODE true)
 214     endif()
 215     target_include_directories(${object_library} SYSTEM BEFORE PRIVATE ${PROJECT_SOURCE_DIR}/src/external/thread_mpi/include)
 216     target_link_libraries(${object_library} PRIVATE common)
 217
 218     # Add the sources from the object libraries to the main library.
 219     target_sources(libgromacs PRIVATE $<TARGET_OBJECTS:${object_library}>)
 220 endforeach()
 221 gmx_target_compile_options(libgromacs)
 222 target_compile_definitions(libgromacs PRIVATE HAVE_CONFIG_H)
 223 target_include_directories(libgromacs SYSTEM BEFORE PRIVATE ${PROJECT_SOURCE_DIR}/src/external/thread_mpi/include)
 224
 225 if (GMX_GPU_OPENCL)
 226     option(GMX_EXTERNAL_CLFFT "True if an external clFFT is required to be used" FALSE)
 227     mark_as_advanced(GMX_EXTERNAL_CLFFT)
 228
 229     # Default to using clFFT found on the system
 230     # switch to quiet at the second run.
 231     if (DEFINED clFFT_LIBRARY)
 232         set (clFFT_FIND_QUIETLY TRUE)
 233     endif()
 234     find_package(clFFT)
 235     if (NOT clFFT_FOUND)
 236         if (GMX_EXTERNAL_CLFFT)
 237             message(FATAL_ERROR "Did not find required external clFFT library, consider setting clFFT_ROOT_DIR")
 238         endif()
 239
 240         if(MSVC)
 241             message(FATAL_ERROR
 242 "An OpenCL build was requested with Visual Studio compiler, but GROMACS
 243 requires clFFT, which was not found on your system. GROMACS does bundle
 244 clFFT to help with building for OpenCL, but that clFFT has not yet been
 245 ported to the more recent versions of that compiler that GROMACS itself
 246 requires. Thus for now, OpenCL is not available with MSVC and the internal
 247 build of clFFT in GROMACS 2019. Either change compiler, try installing
 248 a clFFT package, or use the latest GROMACS 2018 point release.")
 249         endif()
 250
 251         # Fall back on the internal version
 252         set (_clFFT_dir ../external/clFFT/src)
 253         add_subdirectory(${_clFFT_dir} clFFT-build)
 254         target_sources(libgromacs PRIVATE
 255             $<TARGET_OBJECTS:clFFT>
 256         )
 257         target_include_directories(libgromacs SYSTEM PRIVATE ${_clFFT_dir}/include)
 258         # Use the magic variable for how to link any library needed for
 259         # dlopen, etc.  which is -ldl where needed, and empty otherwise
 260         # (e.g. Windows, BSD, Mac).
 261         target_link_libraries(libgromacs PRIVATE "${CMAKE_DL_LIBS}")
 262     else()
 263         target_link_libraries(libgromacs PRIVATE clFFT)
 264     endif()
 265 endif()
 266
 267 # Permit GROMACS code to include externally developed headers, such as
 268 # the functionality from the nonstd project that we use for
 269 # gmx::compat::optional. These are included as system headers so that
 270 # no warnings are issued from them.
 271 #
 272 # TODO Perhaps generalize this for all headers from src/external
 273 target_include_directories(libgromacs SYSTEM PRIVATE ${PROJECT_SOURCE_DIR}/src/external)
 274
 275 if(SIMD_AVX_512_CXX_SUPPORTED AND NOT ("${GMX_SIMD_ACTIVE}" STREQUAL "AVX_512_KNL"))
 276     # Since we might be overriding -march=core-avx2, add a flag so we don't warn for this specific file.
 277     # On KNL this can cause illegal instruction because the compiler might use non KNL AVX instructions
 278     # with the SIMD_AVX_512_CXX_FLAGS flags.
 279     set_source_files_properties(hardware/identifyavx512fmaunits.cpp PROPERTIES COMPILE_FLAGS "${SIMD_AVX_512_CXX_FLAGS} ${CXX_NO_UNUSED_OPTION_WARNING_FLAGS}")
 280 endif()
 281
 282 # Do any special handling needed for .cpp files that use
 283 # CUDA runtime headers
 284 if (GMX_GPU_CUDA AND CMAKE_CXX_COMPILER_ID MATCHES "Clang")
 285     # CUDA header cuda_runtime_api.h in at least CUDA 10.1 uses 0
 286     # where nullptr would be preferable. GROMACS can't fix these, so
 287     # must suppress them.
 288     GMX_TEST_CXXFLAG(CXXFLAGS_NO_ZERO_AS_NULL_POINTER_CONSTANT "-Wno-zero-as-null-pointer-constant" NVCC_CLANG_SUPPRESSIONS_CXXFLAGS)
 289
 290     foreach(_compile_flag ${NVCC_CLANG_SUPPRESSIONS_CXXFLAGS})
 291         set(GMX_CUDA_CLANG_FLAGS "${GMX_CUDA_CLANG_FLAGS} ${_compile_flag}")
 292     endforeach()
 293     if (GMX_CLANG_CUDA)
 294         foreach (_file ${LIBGROMACS_SOURCES})
 295             get_filename_component(_ext ${_file} EXT)
 296             get_source_file_property(_cuda_source_format ${_file} CUDA_SOURCE_PROPERTY_FORMAT)
 297             if ("${_ext}" STREQUAL ".cu" OR _cuda_source_format)
 298                 gmx_compile_cuda_file_with_clang(${_file})
 299             endif()
 300         endforeach()
 301     else()
 302         get_property(CUDA_SOURCES GLOBAL PROPERTY CUDA_SOURCES)
 303         set_source_files_properties(${CUDA_SOURCES} PROPERTIES COMPILE_FLAGS ${GMX_CUDA_CLANG_FLAGS})
 304     endif()
 305 endif()
 306
 307 # Only add the -fsycl flag to sources that really need it
 308 if (GMX_GPU_SYCL)
 309     get_property(SYCL_SOURCES GLOBAL PROPERTY SYCL_SOURCES)
 310     set_source_files_properties(${SYCL_SOURCES} PROPERTIES COMPILE_FLAGS "${SYCL_CXX_FLAGS}")
 311 endif()
 312
 313 gmx_setup_tng_for_libgromacs()
 314
 315 # We apply the SYCL flag explicitly just for libgromacs, since bugs in the beta versions of
 316 # icpx/dpcpp leads to crashes if we try to link an library without any SYCL code with the
 317 # -fsycl flag enabled. Once that bug is fixed, we should change it to simply add
 318 # SYCL_CXX_FLAGS to GMX_SHARED_LINKER_FLAGS.
 319 target_link_libraries(libgromacs
 320                       PRIVATE
 321                       ${EXTRAE_LIBRARIES}
 322                       ${GMX_EXTRA_LIBRARIES}
 323                       ${GMX_COMMON_LIBRARIES}
 324                       ${FFT_LIBRARIES} ${LINEAR_ALGEBRA_LIBRARIES}
 325                       ${THREAD_LIB} ${GMX_SHARED_LINKER_FLAGS}
 326                       ${SYCL_CXX_FLAGS}
 327                       ${OpenCL_LIBRARIES}
 328                       $<$<PLATFORM_ID:SunOS>:socket>
 329                       PUBLIC
 330                       ${GMX_PUBLIC_LIBRARIES}
 331                       )
 332 target_link_libraries(libgromacs PUBLIC legacy_api)
 333 # Dependencies from libgromacs to the modules are set up here, but
 334 # once the add_subdirectory() commands are re-ordered then
 335 # responsibility for setting this up will move to the respective
 336 # modules.
 337 target_link_libraries(libgromacs PRIVATE
 338                       $<BUILD_INTERFACE:applied_forces>
 339                       $<BUILD_INTERFACE:commandline>
 340                       $<BUILD_INTERFACE:compat>
 341                       $<BUILD_INTERFACE:domdec>
 342 #                      $<BUILD_INTERFACE:energyanalysis>
 343                       $<BUILD_INTERFACE:essentialdynamics>
 344                       $<BUILD_INTERFACE:ewald>
 345                       $<BUILD_INTERFACE:fft>
 346                       $<BUILD_INTERFACE:fileio>
 347                       $<BUILD_INTERFACE:gmxlib>
 348                       $<BUILD_INTERFACE:gpu_utils>
 349                       $<BUILD_INTERFACE:hardware>
 350                       $<BUILD_INTERFACE:imd>
 351                       $<BUILD_INTERFACE:linearalgebra>
 352                       $<BUILD_INTERFACE:listed_forces>
 353                       $<BUILD_INTERFACE:math>
 354                       $<BUILD_INTERFACE:mdlib>
 355                       $<BUILD_INTERFACE:mdrun>
 356                       $<BUILD_INTERFACE:mdrunutility>
 357                       $<BUILD_INTERFACE:mdspan>
 358                       $<BUILD_INTERFACE:mdtypes>
 359                       $<BUILD_INTERFACE:mimic>
 360                       $<BUILD_INTERFACE:modularsimulator>
 361                       $<BUILD_INTERFACE:nbnxm>
 362                       $<BUILD_INTERFACE:onlinehelp>
 363                       $<BUILD_INTERFACE:options>
 364                       $<BUILD_INTERFACE:pbcutil>
 365                       $<BUILD_INTERFACE:pulling>
 366                       $<BUILD_INTERFACE:random>
 367                       $<BUILD_INTERFACE:restraint>
 368                       $<BUILD_INTERFACE:selection>
 369                       $<BUILD_INTERFACE:simd>
 370                       $<BUILD_INTERFACE:swap>
 371                       $<BUILD_INTERFACE:tables>
 372                       $<BUILD_INTERFACE:taskassignment>
 373                       $<BUILD_INTERFACE:timing>
 374                       $<BUILD_INTERFACE:topology>
 375                       $<BUILD_INTERFACE:trajectory>
 376                       $<BUILD_INTERFACE:utility>
 377                       )
 378 # Note that this subset should match the subset of module
 379 # subdirectories added above.
 380 if (NOT GMX_BUILD_MDRUN_ONLY)
 381     target_link_libraries(libgromacs PRIVATE
 382                           $<BUILD_INTERFACE:analysisdata>
 383                           $<BUILD_INTERFACE:coordinateio>
 384                           $<BUILD_INTERFACE:correlationfunctions>
 385                           $<BUILD_INTERFACE:gmxana>
 386                           $<BUILD_INTERFACE:gmxpreprocess>
 387                           $<BUILD_INTERFACE:statistics>
 388                           $<BUILD_INTERFACE:tools>
 389                           $<BUILD_INTERFACE:trajectoryanalysis>
 390                           )
 391 endif()
 392 if (GMX_OPENMP)
 393     target_link_libraries(libgromacs PUBLIC OpenMP::OpenMP_CXX)
 394 endif()
 395 set_target_properties(libgromacs PROPERTIES
 396                       OUTPUT_NAME "gromacs${GMX_LIBS_SUFFIX}"
 397                       SOVERSION ${LIBRARY_SOVERSION_MAJOR}
 398                       VERSION ${LIBRARY_VERSION}
 399                       )
 400
 401 gmx_manage_lmfit()
 402 target_link_libraries(libgromacs PRIVATE lmfit)
 403
 404 # Make sure we fix "everything" found by more recent versions of clang.
 405 if (CMAKE_CXX_COMPILER_ID MATCHES "Clang" AND CMAKE_CXX_COMPILER_VERSION VERSION_GREATER "7")
 406    target_compile_options(libgromacs PRIVATE $<$<COMPILE_LANGUAGE:CXX>:-Weverything ${IGNORED_CLANG_ALL_WARNINGS}>)
 407 endif()
 408 if (CMAKE_CXX_COMPILER_ID STREQUAL "MSVC")
 409    target_compile_options(libgromacs PRIVATE $<$<COMPILE_LANGUAGE:CXX>:/analyze /analyze:stacksize 70000
 410      #Control flow warnings are disabled because the commond line output is insufficient. There is no tool
 411      #to convert the xml report to e.g. HTML and even in Visual Studio the viewer doesn't work with cmake support.
 412      /wd6001  #unitialized memory
 413      /wd6011  #derefencing NULL
 414      /wd6053  #prior call not zero-terminate
 415      /wd6054  #might not be zero-terminated
 416      /wd6385  #reading invalid data
 417      /wd6386  #buffer overrun
 418      /wd6387  #could be '0'
 419      /wd28199 #uninitialized memory
 420      # For compile time constant (e.g. templates) the following warnings have flase postives
 421      /wd6239  #(<non-zero> && <expr>)
 422      /wd6240  #(<expr> && <non-zero>)
 423      /wd6294  #Ill-defined for-loop
 424      /wd6326  #comparison of constant with other constant
 425      /wd28020 #expression involving paramter is not true
 426      # Misc
 427      /wd6330  #incorrect type to function (warns for char (instead of unsigned) for isspace/isalpha/isdigit/..))
 428      /wd6993  #OpenMP ignored
 429      #TODO
 430      /wd6031  #return value ignored (important - mostly warnigns about sscanf)
 431      /wd6244  #hides declaration (known issue - we ingore similar warnings for other compilers)
 432      /wd6246  #hides declaration
 433      >
 434    )
 435 endif()
 436
 437 if (GMX_CLANG_TIDY)
 438    set_target_properties(libgromacs PROPERTIES CXX_CLANG_TIDY
 439        "${CLANG_TIDY_EXE};-warnings-as-errors=*")
 440 endif()
 441
 442 # clang-3.6 warns about a number of issues that are not reported by more modern compilers
 443 # and we know they are not real issues. So we only check that it can compile without error
 444 # but ignore all warnings.
 445 if (CMAKE_CXX_COMPILER_ID MATCHES "Clang" AND CMAKE_CXX_COMPILER_VERSION MATCHES "^3\.6")
 446     target_compile_options(libgromacs PRIVATE $<$<COMPILE_LANGUAGE:CXX>:-w>)
 447 endif()
 448
 449 # Only install the library in mdrun-only mode if it is actually necessary
 450 # for the binary
 451 # TODO: Stop installing libgromacs. Possibly allow installation during deprecation period with GMX_INSTALL_LEGACY_API.
 452 if (NOT GMX_BUILD_MDRUN_ONLY OR BUILD_SHARED_LIBS)
 453     install(TARGETS libgromacs
 454             EXPORT libgromacs
 455             LIBRARY
 456                 DESTINATION ${CMAKE_INSTALL_LIBDIR}
 457                 COMPONENT libraries
 458             RUNTIME
 459                 DESTINATION ${CMAKE_INSTALL_BINDIR}
 460                 COMPONENT libraries
 461             ARCHIVE
 462                 DESTINATION ${CMAKE_INSTALL_LIBDIR}
 463                 COMPONENT libraries
 464             INCLUDES DESTINATION include)
 465     target_compile_definitions(libgromacs PUBLIC $<INSTALL_INTERFACE:GMX_DOUBLE=${GMX_DOUBLE_VALUE}>)
 466     # legacy headers use c++17 features, so consumer codes need to use that standard, too
 467     if(GMX_INSTALL_LEGACY_API)
 468         target_compile_features(libgromacs INTERFACE cxx_std_${CMAKE_CXX_STANDARD})
 469     endif()
 470 endif()
 471 add_library(Gromacs::libgromacs ALIAS libgromacs)
 472
 473 if (NOT GMX_BUILD_MDRUN_ONLY)
 474     include(InstallLibInfo.cmake)
 475 endif()
 476
 477 # Technically, the user could want to do this for an OpenCL build
 478 # using the CUDA runtime, but currently there's no reason to want to
 479 # do that.
 480 if (INSTALL_CUDART_LIB) #can be set manual by user
 481     if (GMX_GPU_CUDA)
 482         foreach(CUDA_LIB ${CUDA_LIBRARIES})
 483             string(REGEX MATCH "cudart" IS_CUDART ${CUDA_LIB})
 484             if(IS_CUDART) #libcuda should not be installed
 485                 #install also name-links (linker uses those)
 486                 file(GLOB CUDA_LIBS ${CUDA_LIB}*)
 487                 install(FILES ${CUDA_LIBS} DESTINATION
 488                     ${CMAKE_INSTALL_LIBDIR} COMPONENT libraries)
 489             endif()
 490         endforeach()
 491     else()
 492         message(WARNING "INSTALL_CUDART_LIB only makes sense when configuring for CUDA support")
 493     endif()
 494 endif()
 495
 496 if(GMX_GPU_OPENCL)
 497     # Install the utility headers
 498     file(GLOB OPENCL_INSTALLED_FILES
 499         gpu_utils/vectype_ops.clh
 500         gpu_utils/device_utils.clh
 501         )
 502     install(FILES ${OPENCL_INSTALLED_FILES}
 503         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/gpu_utils
 504         COMPONENT libraries)
 505     file(GLOB OPENCL_INSTALLED_FILES
 506         pbcutil/ishift.h
 507         )
 508     install(FILES ${OPENCL_INSTALLED_FILES}
 509         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/pbcutil
 510         COMPONENT libraries)
 511
 512     # Install the NBNXM source and headers
 513     file(GLOB OPENCL_INSTALLED_FILES
 514         nbnxm/constants.h
 515         )
 516     install(FILES ${OPENCL_INSTALLED_FILES}
 517         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/nbnxm
 518         COMPONENT libraries)
 519     file(GLOB OPENCL_INSTALLED_FILES
 520         nbnxm/opencl/nbnxm_ocl_kernels.cl
 521         nbnxm/opencl/nbnxm_ocl_kernel.clh
 522         nbnxm/opencl/nbnxm_ocl_kernel_pruneonly.clh
 523         nbnxm/opencl/nbnxm_ocl_kernels.clh
 524         nbnxm/opencl/nbnxm_ocl_kernels_fastgen.clh
 525         nbnxm/opencl/nbnxm_ocl_kernels_fastgen_add_twincut.clh
 526         nbnxm/opencl/nbnxm_ocl_kernel_utils.clh
 527         nbnxm/opencl/nbnxm_ocl_consts.h
 528         )
 529     install(FILES ${OPENCL_INSTALLED_FILES}
 530         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/nbnxm/opencl
 531         COMPONENT libraries)
 532
 533     # Install the PME source and headers
 534     file(GLOB OPENCL_INSTALLED_FILES
 535         ewald/pme_spread.clh
 536         ewald/pme_solve.clh
 537         ewald/pme_gather.clh
 538         ewald/pme_gpu_calculate_splines.clh
 539         ewald/pme_program.cl
 540         ewald/pme_gpu_types.h
 541         )
 542     install(FILES ${OPENCL_INSTALLED_FILES}
 543         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/ewald
 544         COMPONENT libraries)
 545 endif()