CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014,2015,2016, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 3.4.3)
  36
  37 # CMake modules/macros are in a subdirectory to keep this file cleaner
  38 # This needs to be set before project() in order to pick up toolchain files
  39 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  40
  41 project(Gromacs)
  42
  43 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  44 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  45 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  46
  47 # Set up common version variables, as well as general information about
  48 # the build tree (whether the build is from a source package or from a git
  49 # repository).  Also declares a few functions that will be used for generating
  50 # version info files later.
  51 include(gmxBuildTreeInfo)
  52 include(gmxVersionInfo)
  53
  54 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  55     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  56 endif()
  57 if("${CMAKE_INSTALL_PREFIX}" STREQUAL "${CMAKE_BINARY_DIR}")
  58     message(FATAL_ERROR "GROMACS cannot be installed into the build tree, choose a different location for CMAKE_INSTALL_PREFIX")
  59 endif()
  60
  61 include(gmxBuildTypeReference)
  62 include(gmxBuildTypeProfile)
  63 include(gmxBuildTypeTSAN)
  64 include(gmxBuildTypeASAN)
  65 include(gmxBuildTypeMSAN)
  66 include(gmxBuildTypeReleaseWithAssert)
  67
  68 if(NOT CMAKE_BUILD_TYPE)
  69     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference RelWithAssert Profile TSAN ASAN MSAN." FORCE)
  70     # Set the possible values of build type for cmake-gui
  71     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
  72         "MinSizeRel" "RelWithDebInfo" "Reference" "RelWithAssert" "Profile" "TSAN" "ASAN" "MSAN")
  73 endif()
  74 if(CMAKE_CONFIGURATION_TYPES)
  75     # Add appropriate GROMACS-specific build types for the Visual
  76     # Studio generator (Debug, Release, MinSizeRel and RelWithDebInfo
  77     # are already present by default).
  78     list(APPEND CMAKE_CONFIGURATION_TYPES "RelWithAssert" "Reference")
  79     list(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)
  80     set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
  81         "List of configuration types"
  82         FORCE)
  83 endif()
  84 set(build_types_with_explicit_flags RELEASE DEBUG RELWITHDEBINFO RELWITHASSERT MINSIZEREL PROFILE)
  85
  86 set_property(GLOBAL PROPERTY FIND_LIBRARY_USE_LIB64_PATHS ON)
  87
  88 include(gmxCTestUtilities)
  89 gmx_ctest_init()
  90
  91 include(gmxCPackUtilities)
  92 gmx_cpack_init()
  93
  94 # Variables that accumulate stuff influencing the installed headers
  95 set(INSTALLED_HEADER_INCLUDE_DIRS "")
  96 set(INSTALLED_HEADER_DEFINITIONS "")
  97
  98 ########################################################################
  99 # Check and warn if cache generated on a different host is being reused
 100 ########################################################################
 101 if(CMAKE_HOST_UNIX)
 102     execute_process(COMMAND hostname
 103                     OUTPUT_VARIABLE TMP_HOSTNAME
 104                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 105     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 106         message(WARNING "
 107             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 108             is being reused! This could lead to inconsistencies; therefore, it is
 109             recommended to regenerate the cache!")
 110     endif()
 111     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 112             "Hostname of the machine where the cache was generated.")
 113 endif()
 114
 115 ########################################################################
 116 # Detect architecture before setting options so we can alter defaults
 117 ########################################################################
 118 # Detect the architecture the compiler is targetting, detect
 119 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 120 # to use if none is specified, and populate the cache option for CPU
 121 # SIMD.
 122 include(gmxDetectTargetArchitecture)
 123 gmx_detect_target_architecture()
 124
 125 # Permit the user to specify a particular standard library, e.g. compiling
 126 # with "-stdlib=libc++" and linking with "-lc++abi -lc++" to get clang's libcxx.
 127 set(GMX_STDLIB_CXX_FLAGS "" CACHE STRING "Compiler flag for a C++ standard library flavour")
 128 set(GMX_STDLIB_LIBRARIES "" CACHE STRING "Linker libraries for a particular C++ standard library")
 129 mark_as_advanced(GMX_STDLIB_CXX_FLAGS)
 130 mark_as_advanced(GMX_STDLIB_LIBRARIES)
 131
 132 ########################################################################
 133 # Detect CXX11 support and flags
 134 ########################################################################
 135 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 136 # are used with permission from CMake v3.0.0 so that GROMACS can detect
 137 # invalid options with the Intel Compilers, and we have added a line
 138 # to detect warnings with the Fujitsu compilers on K computer and ICC.
 139 # CMake-3.0 also has a bug where the FAIL_REGEX pattern for AIX contains
 140 # a semicolon. Since this is also used as a separator in lists inside CMake,
 141 # that string ends up being split into two separate patterns, and the last
 142 # part is just a single word that also matches other messages. We solved this
 143 # by replacing the semicolon with a period that matches any character.
 144 #
 145 # These files should be removed from the source tree when a CMake version that
 146 # includes the features in question becomes required for building GROMACS.
 147 include(CheckCCompilerFlag)
 148 include(CheckCXXCompilerFlag)
 149
 150 # This must come early, since some of our configuration flag tests
 151 # depend on being able to compile C++11 source files.
 152 include(gmxTestCXX11)
 153 gmx_test_cxx11(GMX_CXX11_FLAGS GMX_STDLIB_CXX_FLAGS GMX_STDLIB_LIBRARIES)
 154
 155 # Make sure all C++ code will be compiled in C++11 mode, with the
 156 # expected standard library.
 157 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${GMX_CXX11_FLAGS} ${GMX_STDLIB_CXX_FLAGS}")
 158
 159 ########################################################################
 160 # User input options                                                   #
 161 ########################################################################
 162 include(gmxOptionUtilities)
 163
 164 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 165
 166 # Fujitsu only has SIMD in double precision, so this will be faster
 167 gmx_set_boolean(GMX_DOUBLE_DEFAULT GMX_TARGET_FUJITSU_SPARC64)
 168 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" ${GMX_DOUBLE_DEFAULT})
 169 option(GMX_RELAXED_DOUBLE_PRECISION "Accept single precision 1/sqrt(x) when using Fujitsu HPC-ACE SIMD" OFF)
 170 mark_as_advanced(GMX_RELAXED_DOUBLE_PRECISION)
 171
 172 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 173 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 174 gmx_dependent_option(
 175     GMX_MPI_IN_PLACE
 176     "Enable MPI_IN_PLACE for MPIs that have it defined"
 177     ON
 178     GMX_MPI)
 179 mark_as_advanced(GMX_MPI_IN_PLACE)
 180 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 181 mark_as_advanced(GMX_FAHCORE)
 182
 183 option(GMX_COOL_QUOTES "Enable GROMACS cool quotes" ON)
 184 mark_as_advanced(GMX_COOL_QUOTES)
 185 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 186
 187 option(GMX_USE_OPENCL "Enable OpenCL acceleration" OFF)
 188
 189 # Decide on GPU settings based on user-settings and GPU/CUDA
 190 # detection.  GCC 4.8 requires CUDA 6.0 (but we choose 6.5 for the
 191 # preliminary C++11 support), icc 15 requires CUDA 7.0, and VS2015
 192 # requires CUDA 8.0
 193 if(MSVC)
 194     set(REQUIRED_CUDA_VERSION 8.0)
 195 elseif(CMAKE_CXX_COMPILER_ID MATCHES "Intel")
 196     set(REQUIRED_CUDA_VERSION 7.0)
 197 else()
 198     set(REQUIRED_CUDA_VERSION 6.5)
 199 endif()
 200 set(REQUIRED_CUDA_COMPUTE_CAPABILITY 2.0)
 201
 202 # OpenCL required version: 1.1 or newer
 203 set(REQUIRED_OPENCL_MIN_VERSION 1.1)
 204
 205 if(NOT GMX_USE_OPENCL)
 206     # CUDA detection is done only if GMX_USE_OPENCL is OFF.
 207     include(gmxManageGPU)
 208     set(GMX_USE_CUDA ${GMX_GPU})
 209     if(GMX_GPU)
 210         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_CUDA")
 211     else()
 212         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_NONE")
 213     endif()
 214 else()
 215     #Now the OpenCL path (for both AMD and NVIDIA)
 216     if(GMX_GPU)
 217         include(gmxManageOpenCL)
 218         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_OPENCL")
 219     else()
 220         message(FATAL_ERROR "OpenCL requested but GPU option is not enabled (try -DGMX_GPU=on) ")
 221     endif()
 222 endif()
 223
 224 include(gmxDetectSimd)
 225 gmx_detect_simd(GMX_SUGGESTED_SIMD)
 226
 227 gmx_option_multichoice(
 228     GMX_SIMD
 229     "SIMD instruction set for CPU kernels and compiler optimization"
 230     "${GMX_SUGGESTED_SIMD}"
 231     None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 AVX_512 AVX_512_KNL MIC ARM_NEON ARM_NEON_ASIMD IBM_QPX IBM_VMX IBM_VSX Sparc64_HPC_ACE Reference)
 232
 233 if(GMX_TARGET_MIC)
 234     set(GMX_FFT_LIBRARY_DEFAULT "mkl")
 235 else()
 236     set(GMX_FFT_LIBRARY_DEFAULT "fftw3")
 237 endif()
 238
 239 gmx_option_multichoice(
 240     GMX_FFT_LIBRARY
 241     "FFT library"
 242     "${GMX_FFT_LIBRARY_DEFAULT}"
 243     fftw3 mkl "fftpack[built-in]")
 244 gmx_dependent_option(
 245     GMX_BUILD_OWN_FFTW
 246     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 247     OFF
 248     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 249 gmx_dependent_option(
 250     GMX_DISABLE_FFTW_MEASURE
 251     "Do not optimize FFTW setups (not needed with SSE)"
 252     OFF
 253     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 254 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 255 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 256
 257 gmx_option_multichoice(
 258     GMX_QMMM_PROGRAM
 259     "QM package for QM/MM"
 260     None
 261     none gaussian mopac gamess orca)
 262
 263 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH  "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 264 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
 265
 266 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
 267
 268 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 269 mark_as_advanced(GMX_BROKEN_CALLOC)
 270 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 271 mark_as_advanced(GMX_LOAD_PLUGINS)
 272
 273 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 274
 275 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 276
 277 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 278
 279 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 280 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 281
 282 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 283 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 284
 285 option(GMX_BUILD_FOR_COVERAGE
 286        "Tune build for better code coverage metrics (e.g., disable asserts)"
 287        OFF)
 288 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 289
 290 option(GMX_DEVELOPER_BUILD
 291     "Enable Developer convenience features: always build unit-tests"
 292     OFF)
 293 mark_as_advanced(GMX_DEVELOPER_BUILD)
 294
 295 gmx_set_boolean(GMX_COMPILER_WARNINGS_DEFAULT "NOT SOURCE_IS_SOURCE_DISTRIBUTION")
 296 option(GMX_COMPILER_WARNINGS
 297     "Enable a default set of compiler warnings"
 298     ${GMX_COMPILER_WARNINGS_DEFAULT})
 299 mark_as_advanced(GMX_COMPILER_WARNINGS)
 300 # Always turn on compiler warnings with a developer build.
 301 gmx_add_cache_dependency(GMX_COMPILER_WARNINGS BOOL "NOT GMX_DEVELOPER_BUILD" ON)
 302
 303 option(GMX_BUILD_SHARED_EXE
 304     "Build exectuables as shared binaries. If not set, this disables rpath and dynamic linker flags in an attempt to build a static binary, but this may require setting up the toolchain properly and making appropriate libraries available."
 305     ON)
 306 mark_as_advanced(GMX_BUILD_SHARED_EXE)
 307
 308 ######################################################################
 309 # Detect OpenMP support
 310 ######################################################################
 311 # The OpenMP detection _must_ come before tests for other CFLAGS.
 312 include(gmxManageOpenMP)
 313
 314
 315
 316 ######################################################################
 317 # Compiler tests
 318 # These need to be done early (before further tests).
 319 #####################################################################
 320
 321 include(gmxCFlags)
 322 gmx_c_flags()
 323
 324 # This variable should be used for additional compiler flags which are not
 325 # generated in gmxCFlags nor are SIMD or MPI related.
 326 set(EXTRA_C_FLAGS "")
 327 set(EXTRA_CXX_FLAGS "")
 328
 329 # Run through a number of tests for buggy compilers and other issues
 330 include(gmxTestCompilerProblems)
 331 gmx_test_compiler_problems()
 332
 333 # Implement double-precision option. This is complicated because we
 334 # need installed headers to use the precision mode of the build that
 335 # produced the library, but cannot use config.h in that case. We also
 336 # want such variables to always have a definition, because #if is more
 337 # robust than #ifdef. So, we put this value on the compiler command
 338 # line in all cases.
 339 #
 340 # GMX_RELAXED_DOUBLE_PRECISION does not need to be handled here,
 341 # because no installed header needs it
 342 if(GMX_DOUBLE)
 343     set(GMX_DOUBLE_VALUE 1)
 344 else()
 345     set(GMX_DOUBLE_VALUE 0)
 346 endif()
 347 add_definitions(-DGMX_DOUBLE=${GMX_DOUBLE_VALUE})
 348 list(APPEND INSTALLED_HEADER_DEFINITIONS "-DGMX_DOUBLE=${GMX_DOUBLE_VALUE}")
 349
 350 if(WIN32)
 351     list(APPEND GMX_EXTRA_LIBRARIES "wsock32")
 352     add_definitions(-DGMX_HAVE_WINSOCK)
 353 endif()
 354
 355
 356
 357 ########################################################################
 358 # Basic system tests (standard libraries, headers, functions, types)   #
 359 ########################################################################
 360 include(CheckIncludeFiles)
 361 include(CheckIncludeFileCXX)
 362 check_include_files(unistd.h     HAVE_UNISTD_H)
 363 check_include_files(pwd.h        HAVE_PWD_H)
 364 check_include_files(dirent.h     HAVE_DIRENT_H)
 365 check_include_files(time.h       HAVE_TIME_H)
 366 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 367 check_include_files(io.h         HAVE_IO_H)
 368 check_include_files(sched.h      HAVE_SCHED_H)
 369
 370 check_include_files(regex.h      HAVE_POSIX_REGEX)
 371 # TODO: It could be nice to inform the user if no regex support is found,
 372 # as selections won't be fully functional.
 373
 374 include(CheckCXXSymbolExists)
 375 check_cxx_symbol_exists(gettimeofday      sys/time.h   HAVE_GETTIMEOFDAY)
 376 check_cxx_symbol_exists(sysconf           unistd.h     HAVE_SYSCONF)
 377 check_cxx_symbol_exists(nice              unistd.h     HAVE_NICE)
 378 check_cxx_symbol_exists(fsync             unistd.h     HAVE_FSYNC)
 379 check_cxx_symbol_exists(_fileno           stdio.h      HAVE__FILENO)
 380 check_cxx_symbol_exists(fileno            stdio.h      HAVE_FILENO)
 381 check_cxx_symbol_exists(_commit           io.h         HAVE__COMMIT)
 382 check_cxx_symbol_exists(sigaction         signal.h     HAVE_SIGACTION)
 383
 384 # We cannot check for the __builtins as symbols, but check if code compiles
 385 check_cxx_source_compiles("int main(){ return __builtin_clz(1);}"   HAVE_BUILTIN_CLZ)
 386 check_cxx_source_compiles("int main(){ return __builtin_clzll(1);}" HAVE_BUILTIN_CLZLL)
 387 if(MSVC)
 388     check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned long i=1;_BitScanReverse(&r,i);return r;}" HAVE_BITSCANREVERSE)
 389     check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned __int64 i=1;_BitScanReverse(&r,i);return r;}" HAVE_BITSCANREVERSE64)
 390 elseif(CMAKE_CXX_COMPILER_ID MATCHES "XL")
 391     check_cxx_source_compiles("int main(){ return __cntlz4(1);}" HAVE_CNTLZ4)
 392     check_cxx_source_compiles("int main(){ return __cntlz8(1);}" HAVE_CNTLZ8)
 393 endif()
 394
 395 include(CheckLibraryExists)
 396 find_library(HAVE_LIBM m)
 397 mark_as_advanced(HAVE_LIBM)
 398 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 399 check_library_exists(m feenableexcept "" HAVE_FEENABLEEXCEPT)
 400
 401 include(TestSchedAffinity)
 402 test_sched_affinity(HAVE_SCHED_AFFINITY)
 403
 404 # Aligned memory allocation. We need to check for both mm_malloc(),
 405 # posix_memalign(), memalign(), and on windows also _aligned_malloc()
 406 include(gmxTestMMMalloc)
 407 gmx_test_mm_malloc(HAVE__MM_MALLOC)
 408 check_cxx_symbol_exists(posix_memalign    stdlib.h     HAVE_POSIX_MEMALIGN)
 409 check_cxx_symbol_exists(memalign          stdlib.h     HAVE_MEMALIGN)
 410 if(MSVC)
 411     # No need to waste time on this test on platforms where it will never be true
 412     check_cxx_symbol_exists(_aligned_malloc   stdlib.h     HAVE__ALIGNED_MALLOC)
 413 endif()
 414
 415 include(TestBigEndian)
 416 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 417
 418 gmx_set_boolean(GMX_USE_NICE "HAVE_UNISTD_H AND HAVE_NICE")
 419
 420 # Management of GROMACS options for specific toolchains should go
 421 # here. Because the initial settings for some of the main options have
 422 # already happened, but things like library detection and MPI compiler
 423 # feature detection have not, the docstrings for any over-rides of
 424 # GROMACS defaults or user settings will make sense. Also, any
 425 # toolchain-related reasons for choosing whether to detect various
 426 # things can be sorted out now, before the detection takes place.
 427 if(${CMAKE_SYSTEM_NAME} MATCHES BlueGene)
 428     include(gmxManageBlueGene)
 429 endif()
 430
 431 if(GMX_TARGET_FUJITSU_SPARC64)
 432     include(gmxManageFujitsuSparc64)
 433 endif()
 434
 435 ########################################################################
 436 #Process MPI settings
 437 ########################################################################
 438 include(gmxManageMPI)
 439
 440
 441 ########################################################################
 442 #Process shared/static library settings
 443 ########################################################################
 444 include(gmxManageSharedLibraries)
 445
 446
 447 ########################################################################
 448 # Find external packages                                               #
 449 ########################################################################
 450
 451 # Unconditionally find the package, as it is also required for unit
 452 # tests. This exports LIBXML2_FOUND, which we should not use because
 453 # it does not tell us that linking will succeed. Instead, we test that
 454 # next.
 455 #if(DEFINED LIBXML2_LIBRARIES)
 456 #  set(LibXml2_FIND_QUIETLY TRUE)
 457 #endif()
 458 #find_package(LibXml2)
 459 #include(gmxTestLibXml2)
 460 #gmx_test_libxml2(HAVE_LIBXML2)
 461 #option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 462 #set(PKG_XML "")
 463 #mark_as_advanced(GMX_XML)
 464 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 465 #if(GMX_XML AND NOT HAVE_LIBXML2)
 466 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 467 #endif()
 468 #if(GMX_XML)
 469 #    include_directories(${LIBXML2_INCLUDE_DIR})
 470 #    set(PKG_XML libxml-2.0)
 471 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 472 #endif()
 473
 474 if(DEFINED HWLOC_LIBRARIES)
 475   set(Hwloc_FIND_QUIETLY TRUE)
 476 endif()
 477 find_package(Hwloc 1.5)
 478 if(HWLOC_FOUND)
 479     set(GMX_HWLOC_DEFAULT ON)
 480 else()
 481     set(GMX_HWLOC_DEFAULT OFF)
 482 endif()
 483 option(GMX_HWLOC "Add support for hwloc Portable Hardware locality library" ${GMX_HWLOC_DEFAULT})
 484 if(GMX_HWLOC)
 485     if(HWLOC_FOUND)
 486         include_directories(SYSTEM ${HWLOC_INCLUDE_DIRS})
 487         list(APPEND GMX_EXTRA_LIBRARIES ${HWLOC_LIBRARIES})
 488     else()
 489         message(FATAL_ERROR "Hwloc package support requested, but not found.")
 490     endif()
 491 endif()
 492
 493 option(GMX_EXTERNAL_TINYXML2 "Use external TinyXML-2 instead of compiling the version bundled with GROMACS." OFF)
 494 mark_as_advanced(GMX_EXTERNAL_TINYXML2)
 495 if(GMX_EXTERNAL_TINYXML2)
 496     # Find an external TinyXML-2 library.
 497     find_package(TinyXML-2 3.0.0)
 498     set(HAVE_TINYXML2 ${TinyXML2_FOUND})
 499     if(NOT HAVE_TINYXML2)
 500         message(FATAL_ERROR "External TinyXML-2 could not be found, please adjust your search paths")
 501     endif()
 502 endif()
 503
 504 option(GMX_EXTRAE "Add support for tracing using EXTRAE" OFF)
 505 mark_as_advanced(GMX_EXTRAE)
 506
 507 if (GMX_EXTRAE)
 508   find_package(EXTRAE)
 509   if(EXTRAE_FOUND)
 510     include_directories(SYSTEM ${EXTRAE_INCLUDE_DIR})
 511     set(HAVE_EXTRAE 1)
 512   else()
 513     message(FATAL_ERROR "EXTRAE library was not found. Please add the correct path to CMAKE_PREFIX_PATH")
 514   endif()
 515 endif()
 516
 517 option(GMX_X11 "Use X window system" OFF)
 518 if (GMX_X11)
 519     find_package(X11)
 520     # X11 includes/libraries are only set in the ngmx subdirectory!
 521     if(NOT X11_FOUND)
 522         message(FATAL_ERROR
 523                 "X11 include files and/or libraries were not found. "
 524                 "Set GMX_X11=OFF to compile without X11 support. "
 525                 "gmx view will not be available.")
 526     endif()
 527     include_directories(SYSTEM ${X11_INCLUDE_DIR})
 528 endif()
 529
 530 include(ThreadMPI)
 531 # Enable core threading facilities
 532 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include")
 533 # Enable tMPI C++ support
 534 tmpi_enable_cxx()
 535 if(GMX_THREAD_MPI)
 536     # enable MPI functions
 537     tmpi_enable()
 538     set(MPI_IN_PLACE_EXISTS 1)
 539 endif()
 540 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
 541 if (TMPI_ATOMICS_DISABLED)
 542    add_definitions(-DTMPI_ATOMICS_DISABLED)
 543 endif()
 544
 545 include(gmxManageTNG)
 546
 547 include(gmxManageLmfit)
 548
 549 if(GMX_GPU)
 550     # now that we have detected the dependencies, do the second configure pass
 551     gmx_gpu_setup()
 552 endif()
 553
 554 if(CYGWIN)
 555     set(GMX_CYGWIN 1)
 556 endif()
 557
 558 if(WIN32)
 559     set(GMX_NATIVE_WINDOWS 1)
 560     # This makes windows.h not declare min/max as macros that would break
 561     # C++ code using std::min/std::max.
 562     add_definitions(-DNOMINMAX)
 563 endif()
 564
 565 if(CMAKE_SYSTEM_NAME STREQUAL "Darwin") #Work-around for cmake bug #10837
 566     if (CMAKE_COMPILER_IS_GNUCC OR CMAKE_C_COMPILER_ID MATCHES "Intel" OR CMAKE_C_COMPILER_ID MATCHES "Clang")
 567         set(CMAKE_INCLUDE_SYSTEM_FLAG_C "-isystem ")
 568     endif()
 569     if (CMAKE_COMPILER_IS_GNUCXX OR CMAKE_CXX_COMPILER_ID MATCHES "Intel" OR CMAKE_CXX_COMPILER_ID MATCHES "Clang")
 570         set(CMAKE_INCLUDE_SYSTEM_FLAG_CXX "-isystem ")
 571     endif()
 572 endif()
 573
 574 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING" ON)
 575 mark_as_advanced(GMX_BUILD_UNITTESTS)
 576 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 577
 578 ########################################################################
 579 # Our own GROMACS tests
 580 ########################################################################
 581
 582 add_definitions( -DHAVE_CONFIG_H )
 583 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src)
 584 # TODO required at high level because both libgromacs and progs/mdrun
 585 # require it, both for thread-MPI and its atomics and mutexes.
 586 include_directories(BEFORE SYSTEM ${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include)
 587 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 588 include_directories(BEFORE ${CMAKE_BINARY_DIR}/src)
 589
 590 include(gmxTestInlineASM)
 591 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 592
 593 include(gmxSetBuildInformation)
 594 gmx_set_build_information()
 595 # Turn on RDTSCP if:
 596 # - the build system's CPU supports it
 597 # - the acceleration is set to AVX as all AVX-capable CPUs support AVX (which
 598 #   at this point means that the user set it).
 599 # Note: it's better to not use the later set value of GMX_SIMD because
 600 # it reflects the system's capability of both compiling and running AVX code.
 601 # TODO: After merge with 5.0 one could implement a cache variable dependency
 602 # such that GMX_USE_RDTSCP can change if GMX_SIMD is changed to AVX
 603 # after the first cmake pass.
 604 if (BUILD_CPU_FEATURES MATCHES "rdtscp" OR GMX_SIMD MATCHES "AVX")
 605     set(GMX_USE_RDTSCP_DEFAULT_VALUE ON)
 606 else()
 607     set(GMX_USE_RDTSCP_DEFAULT_VALUE OFF)
 608 endif()
 609 option(GMX_USE_RDTSCP "Use RDTSCP for better CPU-based timers (available on recent x86 CPUs; might need to be off when compiling for heterogeneous environments)" ${GMX_USE_RDTSCP_DEFAULT_VALUE})
 610 mark_as_advanced(GMX_USE_RDTSCP)
 611 if(GMX_USE_RDTSCP)
 612     set(HAVE_RDTSCP 1)
 613 endif()
 614
 615 include(gmxTestLargeFiles)
 616 gmx_test_large_files(GMX_LARGEFILES)
 617
 618 include(gmxTestSignal)
 619 gmx_test_sigusr1(HAVE_SIGUSR1)
 620
 621 include(gmxTestPipes)
 622 gmx_test_pipes(HAVE_PIPES)
 623
 624 check_include_file_cxx(regex     HAVE_CXX11_REGEX)
 625
 626 include(gmxTestXDR)
 627 gmx_test_xdr(GMX_SYSTEM_XDR)
 628 if(NOT GMX_SYSTEM_XDR)
 629     set(GMX_INTERNAL_XDR 1)
 630 endif()
 631
 632
 633 ##################################################
 634 # Process SIMD instruction settings
 635 ##################################################
 636 # This checks what flags to add in order to
 637 # support the SIMD instructions we need, it sets
 638 # correct defines for the SIMD instructions supported,
 639 # and adds advanced options to control accuracy
 640 # for SIMD math operations.
 641 include(gmxManageSimd)
 642 gmx_manage_simd()
 643
 644 include(gmxManageCycleCounters)
 645 gmx_manage_cycle_counters()
 646
 647 # Process QM/MM Settings
 648 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 649     set(GMX_QMMM_GAUSSIAN 1)
 650 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 651     set(GMX_QMMM_MOPAC 1)
 652 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 653     set(GMX_QMMM_GAMESS 1)
 654 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 655     set(GMX_QMMM_ORCA 1)
 656 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 657     # nothing to do
 658 else()
 659     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 660 endif()
 661
 662
 663 ##################################################
 664 # Process FFT library settings
 665 ##################################################
 666 include(gmxManageFFTLibraries)
 667
 668
 669 include(gmxManageLinearAlgebraLibraries)
 670
 671 # Whether GROMACS will really try to compile support for VMD plugins
 672 set(GMX_USE_PLUGINS OFF)
 673
 674 if(GMX_LOAD_PLUGINS)
 675   if(NOT WIN32)
 676     # Native Windows does not have, nor need dlopen
 677     include(gmxTestdlopen)
 678     gmx_test_dlopen(HAVE_DLOPEN)
 679   endif()
 680
 681   # so, should we use plug-ins?
 682   if(WIN32 OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
 683     if(NOT VMD_QUIETLY)
 684       MESSAGE(STATUS "Using dynamic plugins (e.g VMD-supported file formats)")
 685     endif()
 686     if(NOT GMX_VMD_PLUGIN_PATH)
 687       find_package(VMD)
 688     endif()
 689     set(GMX_USE_PLUGINS ON)
 690     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
 691     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 692   else()
 693     set(PKG_DL_LIBS)
 694   endif()
 695 endif()
 696 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
 697
 698 # Link real-time library for POSIX timers. The check for clock_gettime
 699 # confirms the linkability of rt.
 700 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 701     list(APPEND GMX_EXTRA_LIBRARIES rt)
 702 endif()
 703
 704 # Math and thread libraries must often come after all others when linking...
 705 if(HAVE_LIBM)
 706     list(APPEND GMX_EXTRA_LIBRARIES m)
 707 endif()
 708
 709 option(GMX_NACL "Configure for Native Client builds" OFF)
 710 if (GMX_NACL)
 711   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 712   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 713   # TODO: Is this still necessary with the check for its presence?
 714   set(GMX_USE_NICE 0)
 715   set(GMX_NO_RENAME 1)
 716 endif()
 717 mark_as_advanced(GMX_NACL)
 718
 719 if(GMX_FAHCORE)
 720   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 721       "Path to swindirect.h")
 722   include_directories(${COREWRAP_INCLUDE_DIR})
 723 endif()
 724
 725 # Value of GMX_BUILD_HELP=AUTO tries to generate things, but will only
 726 # produce warnings if that fails.
 727 set(build_help_default AUTO)
 728 if (SOURCE_IS_SOURCE_DISTRIBUTION OR CMAKE_CROSSCOMPILING)
 729     set(build_help_default OFF)
 730 endif()
 731 gmx_option_trivalue(GMX_BUILD_HELP "Build completions automatically (requires that compiled binaries can be executed on the build host) and install man pages if built (requires building the 'man' target manually)" ${build_help_default})
 732 mark_as_advanced(GMX_BUILD_HELP)
 733 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND BUILD_IS_INSOURCE)
 734     message(FATAL_ERROR
 735         "Rebuilding shell completions or man pages is not supported for "
 736         "in-source builds from a source distribution. "
 737         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 738 endif()
 739
 740 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 741 # these are set after everything else
 742 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 743     set(CMAKE_C_FLAGS "${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
 744     set(CMAKE_CXX_FLAGS "${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
 745     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 746     set(CMAKE_SHARED_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 747 else()
 748     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 749     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
 750     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
 751     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
 752     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${GMXC_CXXFLAGS}")
 753     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
 754     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
 755     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 756     message("CMAKE_SHARED_LINKER_FLAGS: ${MPI_LINKER_FLAGS}")
 757 endif()
 758
 759 if(NOT GMX_OPENMP)
 760     #Unset all OpenMP flags in case OpenMP was disabled either by the user
 761     #or because it was only partially detected (e.g. only for C but not C++ compiler)
 762     unset(OpenMP_C_FLAGS CACHE)
 763     unset(OpenMP_CXX_FLAGS CACHE)
 764 else()
 765     set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} ${OpenMP_LINKER_FLAGS})
 766     set(GMX_SHARED_LINKER_FLAGS ${GMX_SHARED_LINKER_FLAGS} ${OpenMP_SHARED_LINKER_FLAGS})
 767 endif()
 768
 769 ########################################################################
 770 # Specify install locations
 771 ########################################################################
 772 # Use GNUInstallDirs to set paths on multiarch systems.
 773 include(GNUInstallDirs)
 774
 775 # Customization for the installation tree paths.
 776 set(GMX_LIB_INSTALL_DIR ${CMAKE_INSTALL_LIBDIR} CACHE STRING
 777     "Library installation directory (default: ${CMAKE_INSTALL_LIBDIR})")
 778 set(GMX_DATA_INSTALL_DIR gromacs CACHE STRING
 779     "Data installation directory under share/ (default: gromacs)")
 780 mark_as_advanced(GMX_LIB_INSTALL_DIR GMX_DATA_INSTALL_DIR)
 781
 782 # These variables are used internally to provide a central location for
 783 # customizing the install locations.
 784 set(LIB_INSTALL_DIR       ${GMX_LIB_INSTALL_DIR})
 785 set(BIN_INSTALL_DIR       bin)
 786 # This variable also gets written into config.h for use in finding the data
 787 # directories.
 788 set(DATA_INSTALL_DIR      share/${GMX_DATA_INSTALL_DIR})
 789 set(MAN_INSTALL_DIR       share/man)
 790 # If the nesting level wrt. the installation root is changed,
 791 # gromacs-config.cmake.cmakein needs to be adapted.
 792 set(CMAKE_INSTALL_DIR     share/cmake)
 793 # TODO: Make GMXRC adapt if this is changed
 794 set(PKGCONFIG_INSTALL_DIR ${LIB_INSTALL_DIR}/pkgconfig)
 795 set(OCL_INSTALL_DIR       ${DATA_INSTALL_DIR}/opencl)
 796 set(INCL_INSTALL_DIR      include)
 797
 798 list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${INCL_INSTALL_DIR})
 799
 800 # Binary and library suffix options
 801 include(gmxManageSuffixes)
 802
 803 ################################################################
 804 # Shared library load path settings
 805 ################################################################
 806 if(NOT GMX_BUILD_SHARED_EXE)
 807     # No rpath
 808     set(CMAKE_SKIP_RPATH TRUE)
 809     set(CMAKE_EXE_LINK_DYNAMIC_C_FLAGS) # remove -Wl,-Bdynamic
 810     set(CMAKE_EXE_LINK_DYNAMIC_CXX_FLAGS)
 811 else()
 812     # The build folder always has bin/ and lib/; if we are also going to
 813     # install to lib/, then the installation RPATH works also in the build
 814     # tree.  This makes installation slightly faster (no need to rewrite the
 815     # RPATHs), and makes the binaries in the build tree relocatable.
 816     if(GMX_LIB_INSTALL_DIR STREQUAL "lib")
 817         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 818     endif()
 819     # Set the RPATH as relative to the executable location to make the
 820     # binaries relocatable.
 821     if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin") #Assume OS X >=10.5
 822         set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${GMX_LIB_INSTALL_DIR}")
 823     else()
 824         set(CMAKE_INSTALL_RPATH "@executable_path/../${GMX_LIB_INSTALL_DIR}")
 825     endif()
 826     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 827     set(CMAKE_MACOSX_RPATH 1)
 828 endif()
 829
 830 #COPYING file: Only necessary for binary distributions.
 831 #Simpler to always install.
 832 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
 833
 834 if (GMX_BUILD_FOR_COVERAGE)
 835     # Code heavy with asserts makes conditional coverage close to useless metric,
 836     # as by design most of the false branches are impossible to trigger in
 837     # correctly functioning code.  And the benefit of testing those that could
 838     # be triggered by using an API against its specification isn't usually
 839     # worth the effort.
 840     add_definitions(-DNDEBUG -DGMX_DISABLE_ASSERTS)
 841 endif()
 842
 843 if (BUILD_TESTING)
 844     include(tests/CheckTarget.cmake)
 845 endif()
 846
 847 if (NOT GMX_BUILD_MDRUN_ONLY)
 848     add_subdirectory(docs)
 849     add_subdirectory(share)
 850     add_subdirectory(scripts)
 851 endif()
 852 add_subdirectory(src)
 853
 854 if (BUILD_TESTING)
 855     add_subdirectory(tests)
 856 endif()
 857
 858 gmx_cpack_write_config()
 859
 860 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
 861 # Don't bother the user after the first configure pass.
 862 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
 863     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
 864 endif()
 865 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
 866
 867 #######################
 868 ## uninstall target
 869 #######################
 870 CONFIGURE_FILE(   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 871                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 872                   IMMEDIATE @ONLY)
 873 ###########################
 874 ADD_CUSTOM_TARGET(uninstall
 875                   "${CMAKE_COMMAND}" -P
 876                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 877 ###########################
 878 set_directory_properties(PROPERTIES
 879             ADDITIONAL_MAKE_CLEAN_FILES "install_manifest.txt")