docs/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2014,2015,2016,2017, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 # This directory provides a unified place for building all kinds of
  36 # GROMACS documentation. This includes some "static" content (Doxygen
  37 # code documentation, reference manual, install guide, old online HTML
  38 # images), and content generated from the gmx program for the various
  39 # tools (man and HTML pages). It also provides the "webpage" target,
  40 # that combines all of the above (except man pages in man format) into
  41 # a form suitable for automated deployment to the GROMACS website. It
  42 # also provides the INSTALL file for the tarball.
  43 #
  44 # The webpage is mostly built by Sphinx.  Variable values for Sphinx
  45 # substitutions are configured by CMake (for things like version numbers),
  46 # using gmx_configure_version_file().  This happens during build time instead
  47 # of configure time, because 1) some of the version variables are only
  48 # available during build time, and 2) we don't want to do all the Sphinx setup
  49 # during configuration to save some time when not building the content.
  50 # All the generated values get put into conf-vars.py (generated from
  51 # conf-vars.py.cmakein), which in turn is included by the Sphinx configuration
  52 # file conf.py.
  53
  54 set(SOURCE_MD5SUM "unknown" CACHE STRING
  55     "MD5 sum of the source tarball, normally used only for the pre-release webpage build")
  56 # REGRESSIONTEST_MD5SUM is set in cmake/gmxVersionInfo.cmake because it is used also in tests/CMakeLists.txt
  57 mark_as_advanced(SOURCE_MD5SUM)
  58
  59 set(EXPECTED_DOXYGEN_VERSION 1.8.5)
  60
  61 set(EXPECTED_SPHINX_VERSION 1.4.1)
  62
  63 if (DEFINED PYTHON_EXECUTABLE)
  64     # Keep quiet on subsequent runs of cmake
  65     set(PythonInterp_FIND_QUIETLY ON)
  66 endif()
  67 find_package(PythonInterp 2.7)
  68 find_package(Sphinx ${EXPECTED_SPHINX_VERSION} QUIET COMPONENTS pygments)
  69
  70 # Even if we aren't going to make the full webpage, set up to put all
  71 # the documentation output in the same place, for convenience
  72 set(HTML_OUTPUT_DIR "${CMAKE_CURRENT_BINARY_DIR}/html")
  73 file(MAKE_DIRECTORY ${HTML_OUTPUT_DIR})
  74
  75 # The directory from which man pages will be installed; if it remains
  76 # empty, they will be silently skipped.
  77 set(MAN_PAGE_DIR)
  78 if (SOURCE_IS_SOURCE_DISTRIBUTION)
  79     # When building from the tarball, install the bundled man pages
  80     # (unless overridden).
  81     set(MAN_PAGE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  82 endif()
  83
  84 add_subdirectory(doxygen)
  85 add_subdirectory(manual)
  86
  87 if (SPHINX_FOUND)
  88     # We need to have all the Sphinx input files in a single directory, and
  89     # since some of them are generated, we copy everything into the build tree,
  90     # to this directory.
  91     set(SPHINX_INPUT_DIR ${CMAKE_CURRENT_BINARY_DIR}/sphinx-input)
  92     set(SPHINX_EXTENSION_PATH ${CMAKE_CURRENT_SOURCE_DIR})
  93     if (SOURCE_MD5SUM STREQUAL "unknown")
  94         # But for testing the webpage build (e.g. from the repo) we
  95         # need a default value.
  96         set(REGRESSIONTEST_MD5SUM_STRING "unknown")
  97     else()
  98         # The real build of the webpage happens from the tarball, and
  99         # this should be set to the matching MD5 sum.
 100         set(REGRESSIONTEST_MD5SUM_STRING "${REGRESSIONTEST_MD5SUM}")
 101     endif()
 102     set(SPHINX_SOURCE_FILES
 103         index.rst
 104         download.rst
 105         dev-manual/index.rst
 106         dev-manual/build-system.rst
 107         dev-manual/commitstyle.rst
 108         dev-manual/documentation-generation.rst
 109         dev-manual/doxygen.rst
 110         dev-manual/error-handling.rst
 111         dev-manual/formatting.rst
 112         dev-manual/gmxtree.rst
 113         dev-manual/includestyle.rst
 114         dev-manual/jenkins.rst
 115         dev-manual/language-features.rst
 116         dev-manual/naming.rst
 117         dev-manual/overview.rst
 118         dev-manual/redmine-states.png
 119         dev-manual/relocatable-binaries.rst
 120         dev-manual/reportstyle.rst
 121         dev-manual/style.rst
 122         dev-manual/testutils.rst
 123         dev-manual/tools.rst
 124         dev-manual/uncrustify.rst
 125         fragments/doxygen-links.rst
 126         install-guide/index.rst
 127         user-guide/index.rst
 128         user-guide/cutoff-schemes.rst
 129         user-guide/getting-started.rst
 130         user-guide/force-fields.rst
 131         user-guide/faq.rst
 132         user-guide/flow.rst
 133         user-guide/floating-point.rst
 134         user-guide/how-to.rst
 135         user-guide/system-preparation.rst
 136         user-guide/managing-simulations.rst
 137         user-guide/mdrun-features.rst
 138         user-guide/mdrun-performance.rst
 139         user-guide/mdp-options.rst
 140         user-guide/run-time-errors.rst
 141         user-guide/file-formats.rst
 142         user-guide/cmdline.rst
 143         user-guide/environment-variables.rst
 144         user-guide/terminology.rst
 145         user-guide/plotje.gif
 146         user-guide/xvgr.gif
 147         conf.py
 148         links.dat
 149         )
 150
 151     include(SphinxMacros.cmake)
 152     gmx_init_sphinx_setup(${SPHINX_INPUT_DIR})
 153
 154     set(SPHINX_CONFIG_VARS_FILE ${SPHINX_INPUT_DIR}/conf-vars.py)
 155     gmx_configure_version_file(conf-vars.py.cmakein ${SPHINX_CONFIG_VARS_FILE}
 156         EXTRA_VARS
 157             SPHINX_EXTENSION_PATH RELENG_PATH
 158             EXPECTED_DOXYGEN_VERSION
 159             EXPECTED_SPHINX_VERSION
 160             CMAKE_MINIMUM_REQUIRED_VERSION REQUIRED_CUDA_VERSION
 161             REQUIRED_OPENCL_MIN_VERSION
 162             REQUIRED_CUDA_COMPUTE_CAPABILITY REGRESSIONTEST_VERSION
 163             SOURCE_MD5SUM REGRESSIONTEST_MD5SUM_STRING
 164             GMX_TNG_MINIMUM_REQUIRED_VERSION
 165             GMX_LMFIT_MINIMUM_REQUIRED_VERSION
 166         COMMENT "Configuring Sphinx configuration file")
 167     gmx_add_sphinx_input_file(${SPHINX_CONFIG_VARS_FILE})
 168     gmx_add_sphinx_source_files(FILES ${SPHINX_SOURCE_FILES})
 169     if (EXISTS ${RELENG_PATH}/docs/FileList.cmake)
 170         include(${RELENG_PATH}/docs/FileList.cmake)
 171         gmx_add_sphinx_source_files(
 172             FROM ${RELENG_PATH}/docs TO dev-manual/releng PREFIX releng/docs/
 173             FILES ${RELENG_SPHINX_FILES})
 174     else()
 175         gmx_add_sphinx_source_files(FILES
 176             dev-manual/releng/index.rst
 177             dev-manual/releng/jenkins-howto.rst
 178             dev-manual/releng/jenkins-ui.rst
 179             )
 180     endif()
 181     gmx_add_sphinx_input_target(sphinx-input)
 182     # Remove other rst files from the build tree, since they confuse Sphinx.
 183     # Skip generated files in onlinehelp/, and fragments.
 184     # The latter do not cause issues with obsolete files, as they
 185     # are not considered as Sphinx input files, but will only be
 186     # included using an explicit .. include::.
 187     gmx_remove_obsolete_sphinx_input_files("^(onlinehelp|fragments)/.*\\\\.rst$")
 188
 189     # TODO: Make this remove obsolete .rst files.
 190     # TODO: This does not work in cross-compilation scenarios; disable up to
 191     # the necessary level.
 192     gmx_add_custom_output_target(sphinx-programs OUTPUT STAMP
 193         COMMAND ${CMAKE_COMMAND} -E make_directory onlinehelp
 194         COMMAND gmx -quiet help -export rst
 195         DEPENDS gmx
 196         WORKING_DIRECTORY ${SPHINX_INPUT_DIR}
 197         COMMENT "Generating reStructuredText help")
 198     # This dependency ensures that the directories exist before the
 199     # executable tries to write things there.
 200     add_dependencies(sphinx-programs sphinx-input)
 201
 202     # Make the INSTALL file for CPack for the tarball. This gets put
 203     # into the tarball via the CPack rules below, which requires that
 204     # the INSTALL file is in a separate directory by itself.
 205     set(TEXT_INSTALL_GUIDE_OUTPUT_DIR "install-guide/text")
 206     add_custom_target(install-guide
 207         COMMAND
 208             ${SPHINX_EXECUTABLE}
 209             -q -b text
 210             -w sphinx-install.log
 211             -d ${CMAKE_CURRENT_BINARY_DIR}/install-guide/_doctrees
 212             -c ${SPHINX_INPUT_DIR}
 213             "${SPHINX_INPUT_DIR}/install-guide"
 214             "${TEXT_INSTALL_GUIDE_OUTPUT_DIR}"
 215         COMMAND
 216             ${CMAKE_COMMAND} -E rename
 217             ${TEXT_INSTALL_GUIDE_OUTPUT_DIR}/index.txt
 218             ${TEXT_INSTALL_GUIDE_OUTPUT_DIR}/INSTALL
 219         WORKING_DIRECTORY
 220             ${CMAKE_CURRENT_BINARY_DIR}
 221         COMMENT "Building INSTALL with Sphinx"
 222         VERBATIM
 223         )
 224     add_dependencies(install-guide sphinx-input)
 225     gmx_cpack_add_generated_source_directory(install-guide/text DESTINATION /)
 226
 227     # Sphinx cache with pickled ReST documents
 228     set(SPHINX_CACHE_DIR "${CMAKE_CURRENT_BINARY_DIR}/_doctrees")
 229
 230     add_custom_target(webpage-sphinx
 231         COMMAND
 232             ${CMAKE_COMMAND} -E make_directory ${SPHINX_INPUT_DIR}/_static
 233         COMMAND
 234             ${SPHINX_EXECUTABLE}
 235             -q -b html
 236             -w sphinx-html.log
 237             -d "${SPHINX_CACHE_DIR}"
 238             "${SPHINX_INPUT_DIR}"
 239             "${HTML_OUTPUT_DIR}"
 240         WORKING_DIRECTORY
 241             ${CMAKE_CURRENT_BINARY_DIR}
 242         COMMENT "Building HTML documentation with Sphinx"
 243         VERBATIM
 244         )
 245     add_dependencies(webpage-sphinx sphinx-input sphinx-programs)
 246
 247     add_custom_target(man
 248         COMMAND
 249             ${SPHINX_EXECUTABLE}
 250             -q -b man
 251             -w sphinx-man.log
 252             -d ${SPHINX_CACHE_DIR}
 253             -t do_man
 254             ${SPHINX_INPUT_DIR}
 255             ${CMAKE_CURRENT_BINARY_DIR}/man
 256         COMMENT "Building man pages with Sphinx"
 257         VERBATIM)
 258     add_dependencies(man sphinx-input sphinx-programs)
 259     if (GMX_BUILD_HELP)
 260         # If requested, install the man pages built by the 'man' target
 261         # created above.  Nothing will be installed if the user did not
 262         # manually build the target.
 263         set(MAN_PAGE_DIR ${CMAKE_CURRENT_BINARY_DIR})
 264     endif()
 265 else()
 266     add_custom_target(webpage-sphinx
 267         COMMAND ${CMAKE_COMMAND} -E echo
 268             "HTML pages cannot be built because Sphinx version ${EXPECTED_SPHINX_VERSION} is not available"
 269         VERBATIM)
 270     add_custom_target(install-guide
 271         COMMAND ${CMAKE_COMMAND} -E echo
 272             "INSTALL cannot be built because Sphinx version ${EXPECTED_SPHINX_VERSION} is not available"
 273         VERBATIM)
 274     add_custom_target(man
 275         COMMAND ${CMAKE_COMMAND} -E echo
 276             "man pages cannot be built because Sphinx version ${EXPECTED_SPHINX_VERSION} is not available"
 277         VERBATIM)
 278 endif()
 279
 280 if (MAN_PAGE_DIR)
 281     set(MAN_PAGE_DIR ${MAN_PAGE_DIR}/man)
 282     # Trailing slash on directory is significant for
 283     # install(DIRECTORY). See CMake docs.
 284     install(DIRECTORY ${MAN_PAGE_DIR}/
 285         DESTINATION ${MAN_INSTALL_DIR}/man1
 286         COMPONENT man OPTIONAL
 287         FILES_MATCHING PATTERN "*.1")
 288 endif()
 289 gmx_cpack_add_generated_source_directory(man)
 290
 291 # Determine whether we can build all the HTML pages and content linked from
 292 # there.  If not, construct an informative message if the user tries to
 293 # build the target; most people never need to know, unless they've asked for
 294 # the webpage build.
 295 set(HTML_BUILD_IS_POSSIBLE ON)
 296 set(HTML_BUILD_NOT_POSSIBLE_REASON)
 297 set(HTML_BUILD_WARNINGS)
 298
 299 # Next, turn it off if any of the preconditions are unsatisified
 300 if (NOT PYTHON_EXECUTABLE)
 301     set(HTML_BUILD_IS_POSSIBLE OFF)
 302     set(HTML_BUILD_NOT_POSSIBLE_REASON "Python is required")
 303 elseif (NOT SPHINX_FOUND)
 304     # Hardly anything gets built if Sphinx is not available, so don't bother.
 305     set(HTML_BUILD_IS_POSSIBLE OFF)
 306     set(HTML_BUILD_NOT_POSSIBLE_REASON "Sphinx version ${EXPECTED_SPHINX_VERSION} is required")
 307 endif()
 308 if (NOT MANUAL_BUILD_IS_POSSIBLE)
 309     list(APPEND HTML_BUILD_WARNINGS
 310          "Reference PDF manual was not built, so links to it do not work")
 311 endif()
 312 if (NOT DOXYGEN_EXECUTABLE)
 313     list(APPEND HTML_BUILD_WARNINGS
 314         "Doxygen was not available, so links to Doxygen do not work")
 315 endif()
 316 if (NOT DOXYGEN_DOT_EXECUTABLE)
 317     list(APPEND HTML_BUILD_WARNINGS
 318         "dot/graphviz was not found, so some graphs are missing")
 319 endif()
 320
 321 if (HTML_BUILD_IS_POSSIBLE)
 322     set(_webpage_target_properties)
 323     if (HTML_BUILD_WARNINGS)
 324         list(APPEND _webpage_target_properties
 325              COMMAND ${CMAKE_COMMAND} -E echo
 326                  "webpage was built, but with the following limitations:")
 327         foreach(_warning ${HTML_BUILD_WARNINGS})
 328         list(APPEND _webpage_target_properties
 329              COMMAND ${CMAKE_COMMAND} -E echo " - ${_warning}")
 330         endforeach()
 331     endif()
 332
 333     if (MANUAL_BUILD_IS_POSSIBLE)
 334         # Make the PDF reference guide
 335         # TODO Try to make the PDF arrive directly in ${HTML_OUTPUT_DIR}
 336         # TODO Make this depend on the output of the manual build, so that the
 337         # file actually gets copied multiple times.
 338         set(_manual_target_location ${HTML_OUTPUT_DIR}/manual-${GMX_VERSION_STRING}.pdf)
 339         add_custom_command(
 340             OUTPUT ${_manual_target_location}
 341             COMMAND ${CMAKE_COMMAND}
 342                 -E remove -f ${_manual_target_location}
 343             COMMAND ${CMAKE_COMMAND}
 344                 -E copy ${CMAKE_CURRENT_BINARY_DIR}/manual/gromacs.pdf ${_manual_target_location}
 345             DEPENDS manual
 346             VERBATIM)
 347         list(APPEND _webpage_target_properties
 348              DEPENDS ${_manual_target_location})
 349     endif()
 350
 351     # The Doxygen configuration in doxygen/Doxyfile-common.cmakein
 352     # makes all the Doxygen output directly in
 353     # ${HTML_OUTPUT_DIR}/doxygen (and makes the directory if it needs
 354     # to).
 355
 356     # Add a top-level target that builds everything related to the webpage,
 357     # for Jenkins (and possibly others) to use
 358     add_custom_target(webpage ${_webpage_target_properties}
 359         COMMENT "Building webpage"
 360         VERBATIM)
 361     add_dependencies(webpage webpage-sphinx doxygen-all)
 362 else()
 363     add_custom_target(webpage
 364         COMMAND ${CMAKE_COMMAND} -E echo
 365             "Cannot build webpage because ${HTML_BUILD_NOT_POSSIBLE_REASON}"
 366         COMMENT "Webpage build not possible"
 367         VERBATIM)
 368 endif()