src/programs/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2010,2011,2012,2013,2014 by the GROMACS development team.
   5 # Copyright (c) 2015,2016,2018,2019,2020, by the GROMACS development team, led by
   6 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   7 # and including many others, as listed in the AUTHORS file in the
   8 # top-level source directory and at http://www.gromacs.org.
   9 #
  10 # GROMACS is free software; you can redistribute it and/or
  11 # modify it under the terms of the GNU Lesser General Public License
  12 # as published by the Free Software Foundation; either version 2.1
  13 # of the License, or (at your option) any later version.
  14 #
  15 # GROMACS is distributed in the hope that it will be useful,
  16 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  18 # Lesser General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU Lesser General Public
  21 # License along with GROMACS; if not, see
  22 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  23 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  24 #
  25 # If you want to redistribute modifications to GROMACS, please
  26 # consider that scientific software is very special. Version
  27 # control is crucial - bugs must be traceable. We will be happy to
  28 # consider code for inclusion in the official distribution, but
  29 # derived work must not be called official GROMACS. Details are found
  30 # in the README & COPYING files - if they are missing, get the
  31 # official version at http://www.gromacs.org.
  32 #
  33 # To help us fund GROMACS development, we humbly ask that you cite
  34 # the research papers on the package. Check out http://www.gromacs.org.
  35
  36 file(GLOB MDRUN_SOURCES mdrun/*.cpp)
  37 # make an "object library" that we can re-use for multiple targets
  38 add_library(mdrun_objlib OBJECT ${MDRUN_SOURCES})
  39 gmx_target_compile_options(mdrun_objlib)
  40 target_compile_definitions(mdrun_objlib PRIVATE HAVE_CONFIG_H)
  41 target_include_directories(mdrun_objlib SYSTEM BEFORE PRIVATE ${PROJECT_SOURCE_DIR}/src/external/thread_mpi/include)
  42 # Should be possible to remove this when resolving #3290
  43 target_include_directories(mdrun_objlib SYSTEM PRIVATE ${PROJECT_SOURCE_DIR}/src/external)
  44 target_link_libraries(mdrun_objlib PRIVATE common)
  45 target_link_libraries(mdrun_objlib PRIVATE legacy_api)
  46 # TODO: Explicitly link specific modules.
  47 target_link_libraries(mdrun_objlib PRIVATE legacy_modules)
  48
  49 if(GMX_FAHCORE)
  50     # The lack of a real source file here alongside the object library
  51     # may break some generators, according to CMake documentation. If
  52     # so, we can consider adding some dummy file to make it work.
  53     add_library(fahcore $<TARGET_OBJECTS:mdrun_objlib>)
  54     target_link_libraries(fahcore PRIVATE ${GMX_COMMON_LIBRARIES} legacy_api)
  55 elseif(GMX_BUILD_MDRUN_ONLY)
  56     add_executable(mdrun $<TARGET_OBJECTS:mdrun_objlib> mdrun_main.cpp)
  57     gmx_target_compile_options(mdrun)
  58     target_include_directories(mdrun SYSTEM BEFORE PRIVATE ${PROJECT_SOURCE_DIR}/src/external/thread_mpi/include)
  59     target_compile_definitions(mdrun PRIVATE HAVE_CONFIG_H)
  60     target_link_libraries(mdrun libgromacs
  61         ${GMX_COMMON_LIBRARIES}
  62         ${GMX_EXE_LINKER_FLAGS})
  63     set(BINARY_NAME "mdrun${GMX_BINARY_SUFFIX}")
  64     set_target_properties(mdrun PROPERTIES
  65         OUTPUT_NAME "${BINARY_NAME}")
  66     install(TARGETS mdrun DESTINATION ${CMAKE_INSTALL_BINDIR} COMPONENT mdrun)
  67     file(WRITE ${CMAKE_CURRENT_BINARY_DIR}/gmx-completion-${BINARY_NAME}.bash
  68          "complete -o nospace -F _gmx_mdrun_compl ${BINARY_NAME}")
  69     install(FILES ${CMAKE_CURRENT_BINARY_DIR}/gmx-completion-${BINARY_NAME}.bash
  70             DESTINATION ${CMAKE_INSTALL_BINDIR} COMPONENT runtime)
  71 else()
  72     file(GLOB GMX_MAIN_SOURCES gmx.cpp legacymodules.cpp)
  73     if(GMX_X11)
  74         file(GLOB VIEW_SOURCES view/*.cpp)
  75     else()
  76         file(GLOB VIEW_SOURCES view/view.cpp)
  77     endif()
  78     add_library(view_objlib OBJECT ${VIEW_SOURCES})
  79     gmx_target_compile_options(view_objlib)
  80     target_compile_definitions(view_objlib PRIVATE HAVE_CONFIG_H)
  81     target_include_directories(view_objlib SYSTEM PRIVATE ${PROJECT_SOURCE_DIR}/src/external)
  82     target_link_libraries(view_objlib PRIVATE common legacy_api)
  83     # TODO: Explicitly link specific modules.
  84     target_link_libraries(view_objlib PRIVATE legacy_modules)
  85     add_library(gmx_objlib OBJECT ${GMX_MAIN_SOURCES})
  86     target_link_libraries(gmx_objlib PRIVATE common legacy_api)
  87     # TODO: Explicitly link specific modules.
  88     target_link_libraries(gmx_objlib PRIVATE legacy_modules)
  89     target_include_directories(gmx_objlib SYSTEM PRIVATE ${PROJECT_SOURCE_DIR}/src/external)
  90     target_include_directories(gmx_objlib SYSTEM BEFORE PRIVATE ${PROJECT_SOURCE_DIR}/src/external/thread_mpi/include)
  91     add_executable(gmx
  92         $<TARGET_OBJECTS:gmx_objlib>
  93         $<TARGET_OBJECTS:mdrun_objlib>
  94         $<TARGET_OBJECTS:view_objlib>)
  95     add_executable(Gromacs::gmx ALIAS gmx)
  96     gmx_target_compile_options(gmx)
  97     target_compile_definitions(gmx PRIVATE HAVE_CONFIG_H)
  98     target_link_libraries(gmx PRIVATE
  99                           common
 100                           libgromacs
 101                           ${GMX_COMMON_LIBRARIES}
 102                           ${GMX_EXE_LINKER_FLAGS})
 103     if(GMX_X11)
 104         target_link_libraries(gmx ${X11_LIBRARIES})
 105     endif()
 106     set(BINARY_NAME "gmx${GMX_BINARY_SUFFIX}")
 107     set_target_properties(gmx PROPERTIES
 108         OUTPUT_NAME "${BINARY_NAME}")
 109     # Add the executable to the INSTALL target and to the libgromacs EXPORT configuration.
 110     # The GROMACS installation then provides an importable (e.g. find_package(GROMACS))
 111     # Gromacs::gmx target, which may be used as the executable COMMAND argument for functions like
 112     # add_custom_command() or add_test(). The full path to the installed binary may retrieved
 113     # from the LOCATION property or with a $<TARGET_FILE:Gromacs:gmx> generator expression
 114     # (where generator expressions are allowed).
 115     install(TARGETS gmx
 116             EXPORT libgromacs
 117             RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 118
 119     ########################
 120     # Completion generation
 121
 122     include(gmxCustomCommandUtilities)
 123
 124     set(COMPLETION_DIR ${CMAKE_CURRENT_SOURCE_DIR}/completion)
 125     # Using GMX_BUILD_HELP here is somewhat confusing, but the conditions when
 126     # this can be done are exactly the same (ability to run the compiled
 127     # binaries).
 128     if (GMX_BUILD_HELP)
 129         gmx_add_custom_output_target(completion OUTPUT STAMP
 130             COMMAND ${CMAKE_COMMAND}
 131                 -D GMX_EXECUTABLE=$<TARGET_FILE:gmx>
 132                 -D ERRORS_ARE_FATAL=${GMX_BUILD_HELP_FORCE}
 133                 -P ${CMAKE_CURRENT_SOURCE_DIR}/BuildCompletions.cmake
 134             WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}
 135             DEPENDS gmx ${CMAKE_CURRENT_SOURCE_DIR}/BuildCompletions.cmake
 136             COMMENT "Generating command-line completions for programs")
 137         set_target_properties(completion PROPERTIES EXCLUDE_FROM_ALL OFF)
 138         set_directory_properties(PROPERTIES
 139             ADDITIONAL_MAKE_CLEAN_FILES "completion")
 140         set(COMPLETION_DIR ${CMAKE_CURRENT_BINARY_DIR}/completion)
 141     endif()
 142     if (SOURCE_IS_SOURCE_DISTRIBUTION OR GMX_BUILD_HELP)
 143         install(DIRECTORY ${COMPLETION_DIR}/
 144                 DESTINATION ${CMAKE_INSTALL_BINDIR} COMPONENT runtime OPTIONAL)
 145         file(WRITE ${CMAKE_CURRENT_BINARY_DIR}/gmx-completion-${BINARY_NAME}.bash
 146              "complete -o nospace -F _gmx_compl ${BINARY_NAME}")
 147         install(FILES ${CMAKE_CURRENT_BINARY_DIR}/gmx-completion-${BINARY_NAME}.bash
 148                 DESTINATION ${CMAKE_INSTALL_BINDIR} COMPONENT runtime)
 149     endif()
 150     gmx_cpack_add_generated_source_directory(completion)
 151
 152     if(BUILD_TESTING)
 153         add_subdirectory(mdrun/tests)
 154     endif()
 155 endif()