python_packaging/src/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2019,2020, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 # This CMakeLists.txt allows source distributions of the gmxapi Python package
  36 # to rely on scikit-build for support of various Python packaging systems. The
  37 # simplest use case is to allow the `setup.py` file to invoke skbuild to
  38 # configure and run CMake. CMake could be invoked directly by the user or a
  39 # parent package, but the Python distribution would not be packaged automatically.
  40 # Reference https://gitlab.com/gromacs/gromacs/-/issues/2896 for additional discussion.
  41 cmake_minimum_required(VERSION 3.13.0)
  42
  43 # This needs to be set before project() in order to pick up toolchain files
  44 #list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/../../cmake)
  45
  46 # OS X deployment target should be >=10.14 for modern C++ compatibility.
  47 # Reference https://scikit-build.readthedocs.io/en/latest/generators.html#macosx
  48 # and https://github.com/MacPython/wiki/wiki/Spinning-wheels
  49 set(CMAKE_OSX_DEPLOYMENT_TARGET 10.14 CACHE STRING
  50     "OS X deployment target below 10.14 does not use modern standard library")
  51 set(CMAKE_OSX_ARCHITECTURES x86_64 CACHE STRING
  52     "OS X should build Python package for 64-bit architecture"
  53     FORCE)
  54
  55 # Note that this is the gmxapi._gmxapi Python bindings package version,
  56 # not the C++ API version. It is not essential that it match the pure Python
  57 # package version, but is likely to do so.
  58 project(gmxapi VERSION 0.3.0)
  59
  60 # Check if Python package is being built directly or via add_subdirectory
  61 set(GMXAPI_MASTER_PROJECT OFF)
  62 if (CMAKE_CURRENT_SOURCE_DIR STREQUAL CMAKE_SOURCE_DIR)
  63     set(GMXAPI_MASTER_PROJECT ON)
  64 endif()
  65
  66 set(CMAKE_CXX_STANDARD 17)
  67 set(CMAKE_CXX_STANDARD_REQUIRED ON)
  68
  69 # Only interpret if() arguments as variables or keywords when unquoted.
  70 cmake_policy(SET CMP0054 NEW)
  71 # honor the language standard settings for try_compile()
  72 cmake_policy(SET CMP0067 NEW)
  73 if(POLICY CMP0074) #3.12
  74     # Allow gmxapi_ROOT hint.
  75     cmake_policy(SET CMP0074 NEW)
  76 endif()
  77
  78 if(GMXAPI_MASTER_PROJECT)
  79     # TODO: Retain compatibility with libgmxapi 0.1 and back down the requirement.
  80     find_package(gmxapi 0.2.0 REQUIRED
  81                  HINTS "$ENV{GROMACS_DIR}"
  82                  )
  83 endif()
  84 if(gmxapi_FOUND)
  85     set(_suffix "")
  86     # GROMACS master branch and development branches may have divergent
  87     # pre-release APIs. This check allows us to distinguish them and behave
  88     # differently if needed. github.com/kassonlab/gromacs-gmxapi devel branch
  89     # sets gmxapi_EXPERIMENTAL=TRUE. Upstream GROMACS master branch does not.
  90     # Ref: https://github.com/kassonlab/gmxapi/issues/166
  91     if(gmxapi_EXPERIMENTAL)
  92         set(_suffix " (unofficial)")
  93     endif()
  94     message(STATUS "Found gmxapi version ${gmxapi_VERSION}${_suffix}")
  95 endif()
  96
  97 # The Gromacs::gmxapi target could be imported from an existing installation or
  98 # provided as an alias target within the GROMACS build tree.
  99 if (NOT TARGET Gromacs::gmxapi)
 100     message(FATAL_ERROR "Cannot build Python package without GROMACS gmxapi support.")
 101 endif ()
 102
 103 # TODO: Provide user hints for mpi4py installation.
 104 # Note that neither the Python package nor the Gromacs::gmxapi CMake target are
 105 # built with MPI in any case, but they _should_ be built with a C++ compiler
 106 # that is compatible with the available MPI compiler wrappers, and technically
 107 # _that_ is what we want to help the user identify when installing mpi4py, even
 108 # if libgromacs is not built with MPI support either.
 109 # For convenience, it is fine if libgmxapi and _gmxapi are built with the mpi
 110 # compiler wrapper.
 111
 112 option(GMXAPI_USE_BUNDLED_PYBIND
 113        "Use pybind11 headers bundled with this repository. If OFF, CMake does `find_package(pybind11)`."
 114        ON)
 115 if(GMXAPI_USE_BUNDLED_PYBIND)
 116     add_subdirectory(external/pybind)
 117 else()
 118     # Reference https://gitlab.com/gromacs/gromacs/-/issues/2896
 119     find_package(pybind11 2.2 REQUIRED)
 120 endif()
 121
 122 set(GMXAPI_PYTHON_EXTENSION_SOURCES
 123     gmxapi/module.cpp
 124     gmxapi/export_context.cpp
 125     gmxapi/export_exceptions.cpp
 126     gmxapi/export_system.cpp
 127     gmxapi/export_tprfile.cpp
 128     gmxapi/pycontext.cpp
 129     gmxapi/pysystem.cpp
 130     )
 131
 132 pybind11_add_module(_gmxapi
 133                     ${GMXAPI_PYTHON_EXTENSION_SOURCES}
 134                     )
 135
 136 target_include_directories(_gmxapi PRIVATE
 137                            ${CMAKE_CURRENT_SOURCE_DIR}/gmxapi
 138                            ${CMAKE_CURRENT_BINARY_DIR}/gmxapi
 139                            )
 140
 141 # RPATH management: make sure build artifacts can find GROMACS library.
 142 set_target_properties(_gmxapi PROPERTIES SKIP_BUILD_RPATH FALSE)
 143
 144 # Python sources (*.py) will be packaged by scikit-build and setuptools.
 145 # Note that library targets are built in CMAKE_LIBRARY_OUTPUT_DIRECTORY if not otherwise specified.
 146 # This may be an unexpected location, whether inherited from the GROMACS build tree
 147 # or the SKBUILD framework. Note, also, that when scikit-build is invoked with setup.py,
 148 # the CMake build takes place in a subdirectory of ./_skbuild/.
 149 set(GMXAPI_PYTHON_STAGING_DIR ${CMAKE_CURRENT_BINARY_DIR}/gmxapi_staging)
 150 set_target_properties(_gmxapi PROPERTIES
 151                       LIBRARY_OUTPUT_DIRECTORY ${GMXAPI_PYTHON_STAGING_DIR}/gmxapi)
 152
 153 if(GMXAPI_MASTER_PROJECT)
 154     # TODO: This requirement is probably overly restrictive.
 155     find_package(GROMACS 2021 REQUIRED
 156                  NAMES gromacs gromacs_mpi
 157                  HINTS "$ENV{GROMACS_DIR}"
 158                  )
 159 endif()
 160
 161 # Get details of GROMACS installation needed by the Python package at run time.
 162
 163 # Get the MPI capability.
 164 get_target_property(_gmx_mpi Gromacs::gmxapi MPI)
 165 if (${_gmx_mpi} STREQUAL "library")
 166     set(_gmx_mpi_type "\"library\"")
 167 elseif(${_gmx_mpi} STREQUAL "tmpi")
 168     set(_gmx_mpi_type "\"tmpi\"")
 169 elseif(${_gmx_mpi} STREQUAL "none")
 170     set(_gmx_mpi_type "null")
 171 else()
 172     message(FATAL_ERROR "Unrecognized gmxapi MPI value: ${_gmx_mpi}")
 173 endif ()
 174 unset(_gmx_mpi)
 175 # Get the path of the command line entry point and binary install directory.
 176 if (NOT TARGET Gromacs::gmx)
 177     message(FATAL_ERROR "GROMACS command line tool not found.")
 178 endif ()
 179 get_target_property(_gmx_executable_imported Gromacs::gmx IMPORTED)
 180 if (_gmx_executable_imported)
 181     get_target_property(_gmx_executable Gromacs::gmx LOCATION)
 182     get_filename_component(_gmx_bindir ${_gmx_executable} DIRECTORY)
 183     message(STATUS "Imported ${_gmx_bindir} executable.")
 184     unset(_gmx_executable_imported)
 185 else()
 186     get_target_property(_gmx_bindir Gromacs::gmx RUNTIME_OUTPUT_DIRECTORY)
 187     get_target_property(_gmx_executable Gromacs::gmx OUTPUT_NAME)
 188     set(_gmx_executable "${_gmx_bindir}/${_gmx_executable}")
 189     message(STATUS "Using ${_gmx_executable} from build tree.")
 190 endif ()
 191 if (NOT _gmx_bindir OR NOT _gmx_executable)
 192     message(FATAL_ERROR "Could not get path for gmx wrapper binary.")
 193 endif ()
 194 configure_file(gmxapi/gmxconfig.json.in ${GMXAPI_PYTHON_STAGING_DIR}/gmxapi/gmxconfig.json)
 195 unset(_gmx_executable)
 196 unset(_gmx_bindir)
 197 unset(_gmx_mpi_type)
 198
 199 # scikit-build sets SKBUILD when running Python packaging tools through setup.py
 200 # (e.g. with pip)
 201 if(SKBUILD)
 202     # The Python module is being built for a GROMACS installation.
 203     set_target_properties(_gmxapi PROPERTIES BUILD_WITH_INSTALL_RPATH TRUE)
 204     set_target_properties(_gmxapi PROPERTIES INSTALL_RPATH_USE_LINK_PATH TRUE)
 205     target_link_libraries(_gmxapi PRIVATE Gromacs::gmxapi)
 206     # By default, scikit-build expects the library to be installed into a directory
 207     # named for the Python package as in setup.py.
 208     install(TARGETS _gmxapi LIBRARY DESTINATION gmxapi)
 209     install(FILES ${GMXAPI_PYTHON_STAGING_DIR}/gmxapi/gmxconfig.json DESTINATION gmxapi)
 210 else()
 211     # The Python module is being built against GROMACS in its build tree.
 212     # Note: we do not have plans to install the staged package when SKBUILD != TRUE
 213     set_target_properties(_gmxapi PROPERTIES BUILD_WITH_INSTALL_RPATH FALSE)
 214     target_link_libraries(_gmxapi PRIVATE Gromacs::gmxapi)
 215
 216     # TODO: Determine packaging and installation cases and implementation.
 217     # Reference https://gitlab.com/gromacs/gromacs/-/issues/2896 for additional discussion.
 218     # Currently, CMake should be run by scikit-build through setup.py for proper Python packaging.
 219     # We don't want to install by default in the outer scope of the GROMACS
 220     # CMake procedure because we could end up trying to install to a system directory
 221     # the user did not intend, or a user might install a Python-installation-specific
 222     # package into an overly generic GROMACS path.
 223
 224     # Instead, we should probably build a source package and alert the user of its location.
 225     # We can use CMake to call the Python packaging tools to create an 'sdist'
 226     # source distribution archive to be installed in the GROMACS installation
 227     # destination. We can use the build directory as the working directory for
 228     # easier clean-up, as well.
 229     # TODO: (ref Issue #2896) Build and install 'sdist' with GROMACS.
 230
 231     # However, we can still produce an importable package for documentation builds and
 232     # basic testing in ${CMAKE_CURRENT_BINARY_DIR}/gmxapi_staging
 233     file(GLOB_RECURSE _py_sources
 234          CONFIGURE_DEPENDS
 235          ${CMAKE_CURRENT_SOURCE_DIR}/gmxapi/*.py)
 236     foreach(_package_file IN LISTS _py_sources)
 237         get_filename_component(_absolute_dir ${_package_file} DIRECTORY)
 238         file(RELATIVE_PATH _relative_dir ${CMAKE_CURRENT_SOURCE_DIR} ${_absolute_dir})
 239         file(COPY ${_package_file} DESTINATION ${GMXAPI_PYTHON_STAGING_DIR}/${_relative_dir})
 240     endforeach()
 241     file(COPY setup.py CMakeLists.txt DESTINATION ${GMXAPI_PYTHON_STAGING_DIR})
 242     # Set CMake variable pybind11_DIR to ${CMAKE_CURRENT_SOURCE_DIR}/external/pybind/tools
 243     # if re-invoking CMake (including via Python setuptools) for the files in gmxapi_staging.
 244
 245     # Unit test and build docs using PYTHONPATH=$CMAKE_CURRENT_BINARY_DIR/gmxapi_staging
 246     set_target_properties(_gmxapi PROPERTIES staging_dir ${GMXAPI_PYTHON_STAGING_DIR})
 247     # Note: Integration testing for multiple Python versions and/or CMake-driven
 248     # sdist preparation could be performed with CMake custom_commands and custom_targets.
 249 endif()
 250
 251 # When building as part of GROMACS umbrella project, add a testing target
 252 # to the `check` target. Normal usage is to first install the Python package,
 253 # then run `pytest` on the `tests` directory. Refer to gmxapi package documentation.
 254 if(NOT GMXAPI_MASTER_PROJECT)
 255     add_subdirectory(test)
 256 endif()