configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 # Copyright (C) 2000-2012 Free Software Foundation, Inc.
   3 #
   4 # Author: Nikos Mavrogiannopoulos, Simon Josefsson
   5 #
   6 # This file is part of GnuTLS.
   7 #
   8 # This program is free software; you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 # General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program; if not, write to the Free Software
  20 # Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301
  21 # USA
  22
  23 AC_PREREQ(2.61)
  24 AC_INIT([GnuTLS], [3.0.23], [bug-gnutls@gnu.org])
  25 AC_CONFIG_AUX_DIR([build-aux])
  26 AC_CONFIG_MACRO_DIR([m4])
  27
  28 AM_INIT_AUTOMAKE([1.11 no-dist-gzip dist-xz dist-lzip -Wall -Werror -Wno-override])
  29 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  30 AM_CONFIG_HEADER(config.h)
  31
  32 AC_MSG_RESULT([***
  33 *** Checking for compilation programs...
  34 ])
  35
  36 dnl Checks for programs.
  37 AC_PROG_CC
  38 AM_PROG_AS
  39 AC_PROG_CXX
  40 gl_EARLY
  41
  42 # For includes/gnutls/gnutls.h.in.
  43 AC_SUBST(MAJOR_VERSION, `echo $PACKAGE_VERSION | sed 's/\(.*\)\..*\..*/\1/g'`)
  44 AC_SUBST(MINOR_VERSION, `echo $PACKAGE_VERSION | sed 's/.*\.\(.*\)\..*/\1/g'`)
  45 AC_SUBST(PATCH_VERSION, `echo $PACKAGE_VERSION | sed 's/.*\..*\.\(.*\)/\1/g'`)
  46 AC_SUBST(NUMBER_VERSION, `printf "0x%02x%02x%02x" $MAJOR_VERSION $MINOR_VERSION $PATCH_VERSION`)
  47
  48 touch suppressions.valgrind
  49 dnl C and C++ capabilities
  50 AC_C_INLINE
  51 AC_HEADER_STDC
  52
  53 # For the C++ code
  54 AC_ARG_ENABLE(cxx,
  55   AS_HELP_STRING([--disable-cxx], [unconditionally disable the C++ library]),
  56     use_cxx=$enableval, use_cxx=yes)
  57 if test "$use_cxx" != "no"; then
  58   AC_LANG_PUSH(C++)
  59   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])], use_cxx=yes, use_cxx=no)
  60   AC_LANG_POP(C++)
  61 fi
  62 AM_CONDITIONAL(ENABLE_CXX, test "$use_cxx" != "no")
  63 AM_CONDITIONAL(WANT_TEST_SUITE, [test -f tests/suite/mini-eagain2.c])
  64
  65 dnl Detect windows build
  66 case "$host" in
  67   *mingw32* | *mingw64*)
  68     have_win=yes
  69   ;;
  70   *darwin*)
  71     have_macosx=yes
  72   ;;
  73   *)
  74     have_elf=yes
  75   ;;
  76 esac
  77
  78 AM_CONDITIONAL(WINDOWS, test "$have_win" = yes)
  79 AM_CONDITIONAL(MACOSX, test "$have_macosx" = yes)
  80 AM_CONDITIONAL(ELF, test "$have_elf" = yes)
  81
  82 dnl Hardware Acceleration
  83 AC_ARG_ENABLE(hardware-acceleration,
  84   AS_HELP_STRING([--disable-hardware-acceleration], [unconditionally disable hardware acceleration]),
  85     use_accel=$enableval, use_accel=yes)
  86 hw_accel=none
  87
  88
  89 if test "$use_accel" != "no"; then
  90 case $host_cpu in
  91   i?86 | x86_64 | amd64)
  92 dnl    GCC_FLAG_ADD([-maes -mpclmul],[X86])
  93 dnl    if test "x$X86" = "xyes";then
  94       AC_CHECK_HEADERS(cpuid.h)
  95       if test "$host_cpu" = "x86_64" || test "$host_cpu" = "amd64"; then
  96         hw_accel="x86-64"
  97       else
  98         hw_accel="x86"
  99       fi
 100 dnl    fi
 101   ;;
 102   *)
 103   ;;
 104 esac
 105
 106 fi
 107
 108 AM_CONDITIONAL(ASM_X86_64, test x"$hw_accel" = x"x86-64")
 109 AM_CONDITIONAL(ASM_X86_32, test x"$hw_accel" = x"x86")
 110 AM_CONDITIONAL(ASM_X86, test x"$hw_accel" = x"x86" || test x"$hw_accel" = x"x86-64")
 111 AM_CONDITIONAL(HAVE_GCC_GNU89_INLINE_OPTION, test "$gnu89_inline" = "yes"])
 112 AM_CONDITIONAL(HAVE_GCC, test "$GCC" = "yes")
 113
 114 dnl Try the hooks.m4
 115 LIBGNUTLS_HOOKS
 116 LIBGNUTLS_EXTRA_HOOKS
 117
 118 GTK_DOC_CHECK(1.1)
 119 AM_GNU_GETTEXT([external])
 120 AM_GNU_GETTEXT_VERSION([0.18])
 121
 122 AC_C_BIGENDIAN
 123
 124
 125
 126 dnl No fork on MinGW, disable some self-tests until we fix them.
 127 AC_CHECK_FUNCS([fork getrusage getpwuid_r daemon],,)
 128 AM_CONDITIONAL(HAVE_FORK, test "$ac_cv_func_fork" != "no")
 129 AC_LIB_HAVE_LINKFLAGS(pthread,, [#include <pthread.h>], [pthread_mutex_lock (0);])
 130
 131 dnl Check for p11-kit
 132 AC_ARG_WITH(p11-kit,
 133         AS_HELP_STRING([--without-p11-kit],
 134                 [Build without p11-kit and PKCS#11 support]))
 135 if test "$with_p11_kit" != "no"; then
 136         PKG_CHECK_MODULES(P11_KIT, [p11-kit-1 >= 0.11], [with_p11_kit=yes], [with_p11_kit=no])
 137         if test "$with_p11_kit" != "no";then
 138                 AC_DEFINE([ENABLE_PKCS11], 1, [Build PKCS#11 support])
 139                 if test "x$GNUTLS_REQUIRES_PRIVATE" = "x"; then
 140                         GNUTLS_REQUIRES_PRIVATE="Requires.private: p11-kit-1"
 141                 else
 142                         GNUTLS_REQUIRES_PRIVATE="${GNUTLS_REQUIRES_PRIVATE}, p11-kit-1"
 143                 fi
 144         else
 145                 with_p11_kit=no
 146                 AC_MSG_WARN([[
 147 ***
 148 *** p11-kit was not found. PKCS #11 support will be disabled.
 149 *** You may get it from http://p11-glue.freedesktop.org/p11-kit.html
 150 *** ]])
 151         fi
 152 fi
 153
 154 AM_CONDITIONAL(ENABLE_PKCS11, test "$with_p11_kit" != "no")
 155
 156 enable_local_libopts=yes
 157 dnl PKG_CHECK_MODULES([autoopts], autoopts >= 36.2.11,, [enable_local_libopts=yes])
 158
 159 NEED_LIBOPTS_DIR=true
 160 LIBOPTS_CHECK([src/libopts])
 161
 162 AC_CHECK_TYPE(ssize_t,
 163   [
 164     DEFINE_SSIZE_T="#include <sys/types.h>"
 165     AC_SUBST(DEFINE_SSIZE_T)
 166   ], [
 167     AC_DEFINE([NO_SSIZE_T], 1, [no ssize_t type was found])
 168     DEFINE_SSIZE_T="typedef int ssize_t;"
 169     AC_SUBST(DEFINE_SSIZE_T)
 170   ], [
 171     #include <sys/types.h>
 172   ])
 173
 174 # For minitasn1.
 175 AC_CHECK_SIZEOF(unsigned long int, 4)
 176 AC_CHECK_SIZEOF(unsigned int, 4)
 177
 178 AC_ARG_WITH(zlib, AS_HELP_STRING([--without-zlib],
 179                                  [disable zlib compression support]),
 180             ac_zlib=$withval, ac_zlib=yes)
 181 AC_MSG_CHECKING([whether to include zlib compression support])
 182 if test x$ac_zlib != xno; then
 183  AC_MSG_RESULT(yes)
 184  AC_LIB_HAVE_LINKFLAGS(z,, [#include <zlib.h>], [compress (0, 0, 0, 0);])
 185  if test x$ac_cv_libz != xyes; then
 186    AC_MSG_WARN(
 187 ***
 188 *** ZLIB was not found. You will not be able to use ZLIB compression.)
 189  fi
 190 else
 191  AC_MSG_RESULT(no)
 192 fi
 193
 194 PKG_CHECK_EXISTS(zlib, ZLIB_HAS_PKGCONFIG=y, ZLIB_HAS_PKGCONFIG=n)
 195
 196 if test x$ac_zlib != xno; then
 197   if test "$ZLIB_HAS_PKGCONFIG" = "y" ; then
 198     if test "x$GNUTLS_REQUIRES_PRIVATE" = x; then
 199       GNUTLS_REQUIRES_PRIVATE="Requires.private: zlib"
 200     else
 201       GNUTLS_REQUIRES_PRIVATE="$GNUTLS_REQUIRES_PRIVATE, zlib"
 202     fi
 203   else
 204     GNUTLS_ZLIB_LIBS_PRIVATE="$LTLIBZ"
 205   fi
 206 fi
 207 AC_SUBST(GNUTLS_REQUIRES_PRIVATE)
 208 AC_SUBST(GNUTLS_ZLIB_LIBS_PRIVATE)
 209
 210
 211 gl_INIT
 212
 213 dnl GCC warnings to enable
 214
 215 AC_ARG_ENABLE([gcc-warnings],
 216   [AS_HELP_STRING([--enable-gcc-warnings],
 217                   [turn on lots of GCC warnings (for developers)])],
 218   [case $enableval in
 219      yes|no) ;;
 220      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 221    esac
 222    gl_gcc_warnings=$enableval],
 223   [gl_gcc_warnings=no]
 224 )
 225
 226 if test "$gl_gcc_warnings" = yes; then
 227   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 228   gl_WARN_ADD([-Wframe-larger-than=5120], [WSTACK_CFLAGS])
 229
 230   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 231   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
 232   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
 233   nw="$nw -Wtraditional"            # Warns on #elif which we use often
 234   nw="$nw -Wlogical-op"             # Too many false positives
 235   nw="$nw -Wold-style-definition"   #
 236   nw="$nw -Wpadded"                 # Our structs are not padded
 237   nw="$nw -Wunreachable-code"       # Too many false positives
 238   nw="$nw -Wtraditional-conversion" # Too many warnings for now
 239   nw="$nw -Wcast-qual"              # Too many warnings for now
 240   nw="$nw -Waggregate-return"       # Too many warnings for now
 241   nw="$nw -Wshadow"                 # Too many warnings for now
 242   nw="$nw -Wswitch-default"         # Too many warnings for now
 243   nw="$nw -Wswitch-enum"            # Too many warnings for now
 244   nw="$nw -Wconversion"             # Too many warnings for now
 245   nw="$nw -Wsign-conversion"        # Too many warnings for now
 246   nw="$nw -Wformat-y2k"             # Too many warnings for now
 247   nw="$nw -Wvla"                    # There is no point to avoid C99 variable length arrays
 248   nw="$nw -Wformat-nonliteral"      # Incompatible with gettext _()
 249   nw="$nw -Wunsafe-loop-optimizations"
 250   nw="$nw -Wstrict-overflow"
 251   nw="$nw -Wmissing-noreturn"
 252
 253   gl_MANYWARN_ALL_GCC([ws])
 254   gl_MANYWARN_COMPLEMENT(ws, [$ws], [$nw])
 255   for w in $ws; do
 256     gl_WARN_ADD([$w])
 257   done
 258
 259   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 260   gl_WARN_ADD([-Wno-format-y2k])     # Too many warnings for now
 261   gl_WARN_ADD([-Wno-suggest-attribute=pure])     # Too many warnings for now
 262   gl_WARN_ADD([-Wno-suggest-attribute=const])     # Too many warnings for now
 263   gl_WARN_ADD([-Wno-suggest-attribute=noreturn])     # Too many warnings for now
 264   gl_WARN_ADD([-Wno-unused-value]) # warnings for things we don't want to get
 265   gl_WARN_ADD([-Wno-unused-result]) # warnings for things we don't want to get
 266   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 267   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 268   gl_WARN_ADD([-Wno-stack-protector])  # Some functions cannot be protected
 269   gl_WARN_ADD([-Wno-int-to-pointer-cast])  # Some files cannot be compiled with that (gl_fd_to_handle)
 270   gl_WARN_ADD([-Wno-redundant-decls])  # Some files cannot be compiled with that (gl_fd_to_handle)
 271   gl_WARN_ADD([-fdiagnostics-show-option])
 272 fi
 273
 274 AC_SUBST([WERROR_CFLAGS])
 275 AC_SUBST([WSTACK_CFLAGS])
 276 AC_SUBST([WARN_CFLAGS])
 277
 278 dnl Programs for compilation or development
 279 AC_PROG_LN_S
 280 AC_LIBTOOL_WIN32_DLL
 281 AC_PROG_LIBTOOL
 282
 283 AC_ARG_WITH([default-trust-store-pkcs11],
 284   [AS_HELP_STRING([--with-default-trust-store-pkcs11=URI],
 285     [use the given pkcs11 uri as default trust store])])
 286
 287 if test "x$with_default_trust_store_pkcs11" != x; then
 288   if test "x$with_p11_kit" = xno; then
 289     AC_MSG_ERROR([cannot use pkcs11 store without p11-kit])
 290   fi
 291   AC_DEFINE_UNQUOTED([DEFAULT_TRUST_STORE_PKCS11],
 292     ["$with_default_trust_store_pkcs11"], [use the given pkcs11 uri as default trust store])
 293 fi
 294
 295 AC_ARG_WITH([default-trust-store-file],
 296   [AS_HELP_STRING([--with-default-trust-store-file=FILE],
 297     [use the given file default trust store])])
 298
 299 AC_ARG_WITH([default-crl-file],
 300   [AS_HELP_STRING([--with-default-crl-file=FILE],
 301     [use the given CRL file as default])])
 302
 303 if test "x$with_default_trust_store_pkcs11" = x -a "x$with_default_trust_store_file" = x; then
 304   # auto detect http://lists.gnu.org/archive/html/help-gnutls/2012-05/msg00004.html
 305   for i in \
 306     /etc/ssl/certs/ca-certificates.crt \
 307     /etc/pki/tls/cert.pem \
 308     /usr/local/share/certs/ca-root-nss.crt \
 309     /etc/ssl/cert.pem
 310     do
 311     if test -e $i; then
 312       with_default_trust_store_file="$i"
 313       break
 314     fi
 315   done
 316 fi
 317
 318 if test "x$with_default_trust_store_file" != x; then
 319   AC_DEFINE_UNQUOTED([DEFAULT_TRUST_STORE_FILE],
 320     ["$with_default_trust_store_file"], [use the given file default trust store])
 321 fi
 322
 323 if test "x$with_default_crl_file" != x; then
 324   AC_DEFINE_UNQUOTED([DEFAULT_CRL_FILE],
 325     ["$with_default_crl_file"], [use the given CRL file])
 326 fi
 327
 328 dnl Guile bindings.
 329 opt_guile_bindings=yes
 330 AC_MSG_CHECKING([whether building Guile bindings])
 331 AC_ARG_ENABLE(guile,
 332         AS_HELP_STRING([--enable-guile], [build GNU Guile bindings]),
 333 opt_guile_bindings=$enableval)
 334 AC_MSG_RESULT($opt_guile_bindings)
 335
 336 AC_ARG_WITH([--with-guile-site-dir],
 337   [AS_HELP_STRING([--with-guile-site-dir],
 338      [use the given directory as the Guile site (use with care)])])
 339
 340 if test "$opt_guile_bindings" = "yes"; then
 341    AC_MSG_RESULT([***
 342 *** Detecting GNU Guile...
 343 ])
 344
 345    AC_PATH_PROG([guile_snarf], [guile-snarf])
 346    if test "x$guile_snarf" = "x"; then
 347       AC_MSG_WARN([`guile-snarf' from Guile 1.8 not found.  Guile bindings not built.])
 348       opt_guile_bindings=no
 349    else
 350       GUILE_PROGS
 351       GUILE_FLAGS
 352
 353       save_CFLAGS="$CFLAGS"
 354       save_LIBS="$LIBS"
 355       CFLAGS="$CFLAGS $GUILE_CFLAGS"
 356       LIBS="$LIBS $GUILE_LDFLAGS"
 357       AC_MSG_CHECKING([whether GNU Guile is recent enough])
 358       AC_LINK_IFELSE(AC_LANG_CALL([], [scm_from_locale_string]),
 359         [], [opt_guile_bindings=no])
 360       CFLAGS="$save_CFLAGS"
 361       LIBS="$save_LIBS"
 362
 363       if test "$opt_guile_bindings" = "yes"; then
 364         AC_MSG_RESULT([yes])
 365         case "x$with_guile_site_dir" in
 366              xno)
 367                 # Use the default $(GUILE_SITE).
 368                 GUILE_SITE_DIR
 369                 ;;
 370              x|xyes)
 371                 # Automatically derive $(GUILE_SITE) from $(pkgdatadir).  This
 372                 # hack is used to allow `distcheck' to work (see
 373                 # `DISTCHECK_CONFIGURE_FLAGS' in the top-level `Makefile.am').
 374                 GUILE_SITE="\$(datadir)/guile/site"
 375                 AC_SUBST(GUILE_SITE)
 376                 ;;
 377              *)
 378                 # Use the user-specified directory as $(GUILE_SITE).
 379                 GUILE_SITE="$with_guile_site_dir"
 380                 AC_SUBST(GUILE_SITE)
 381                 ;;
 382         esac
 383         AC_MSG_CHECKING([whether gcc supports -fgnu89-inline])
 384         _gcc_cflags_save="$CFLAGS"
 385         CFLAGS="${CFLAGS} -fgnu89-inline"
 386         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
 387                           gnu89_inline=yes, gnu89_inline=no)
 388         AC_MSG_RESULT($gnu89_inline)
 389         CFLAGS="$_gcc_cflags_save"
 390
 391         # Optional Guile functions.
 392         save_CFLAGS="$CFLAGS"
 393         save_LIBS="$LIBS"
 394         CFLAGS="$CFLAGS $GUILE_CFLAGS"
 395         LIBS="$LIBS $GUILE_LDFLAGS"
 396         AC_CHECK_FUNCS([scm_gc_malloc_pointerless])
 397         CFLAGS="$save_CFLAGS"
 398         LIBS="$save_LIBS"
 399
 400         # The place where guile-gnutls.la will go.
 401         AC_MSG_CHECKING([the Guile effective version])
 402         guile_effective_version="`$GUILE -c '(display (effective-version))'`"
 403         AC_MSG_RESULT([$guile_effective_version])
 404         guileextensiondir="$libdir/guile/$guile_effective_version"
 405         AC_SUBST([guileextensiondir])
 406       else
 407         AC_MSG_RESULT([no])
 408         AC_MSG_WARN([A sufficiently recent GNU Guile not found.  Guile bindings not built.])
 409         opt_guile_bindings=no
 410       fi
 411    fi
 412 fi
 413 AM_CONDITIONAL(HAVE_GUILE, test "$opt_guile_bindings" = "yes")
 414
 415 LIBGNUTLS_LIBS="-L${libdir} -lgnutls $LIBS"
 416 LIBGNUTLS_CFLAGS="-I${includedir}"
 417 AC_SUBST(LIBGNUTLS_LIBS)
 418 AC_SUBST(LIBGNUTLS_CFLAGS)
 419
 420
 421 AC_DEFINE([GNUTLS_COMPAT_H], 1, [Make sure we don't use old features in code.])
 422 AC_DEFINE([GNUTLS_INTERNAL_BUILD], 1, [We allow temporarily usage of deprecated functions - until they are removed.])
 423
 424 AC_DEFINE([fread_file], [_gnutls_fread_file], [static lib rename])
 425 AC_DEFINE([read_file], [_gnutls_read_file], [static lib rename])
 426 AC_DEFINE([read_binary_file], [_gnutls_read_binary_file], [static lib rename])
 427
 428 dnl Crywrap dependencies
 429    AC_MSG_RESULT([***
 430 *** Checking dependencies for crywrap...
 431 ])
 432
 433 crywrap=no
 434
 435 if test "$have_win" != "yes"; then
 436
 437 AC_CHECK_HEADERS([arpa/inet.h netinet/in.h sys/select.h sys/types.h sys/wait.h])
 438
 439 dnl **********************
 440 dnl * Typedefs & co
 441 dnl **********************
 442 AC_CACHE_CHECK([return type of signal handlers],[ac_cv_type_signal],[AC_COMPILE_IFELSE(
 443 [AC_LANG_PROGRAM([#include <sys/types.h>
 444 #include <signal.h>
 445 ],
 446                  [return *(signal (0, 0)) (0) == 1;])],
 447                    [ac_cv_type_signal=int],
 448                    [ac_cv_type_signal=void])])
 449 AC_DEFINE_UNQUOTED([RETSIGTYPE],[$ac_cv_type_signal],[Define as the return type of signal handlers
 450                     (`int' or `void').])
 451
 452 AC_FUNC_SELECT_ARGTYPES
 453 AC_CHECK_FUNCS([alarm atexit dup2 epoll_create kqueue memchr memset munmap \
 454                 putenv regcomp scandir select socket strcasecmp strchr \
 455                 strdup strerror strncasecmp strrchr strstr strtoul uname])
 456
 457 AC_ARG_ENABLE(crywrap,
 458         AS_HELP_STRING([--disable-crywrap], [unconditionally disable the crywrap TLS proxy service]))
 459
 460  libidn=no
 461
 462  if test "x$enable_crywrap" != "xno" ; then
 463         PKG_CHECK_MODULES(LIBIDN, libidn >= 0.0.0, [libidn=yes], [libidn=no])
 464  fi
 465
 466  if test "x$libidn" != "xno" && test "$ac_cv_func_daemon" != "no";then
 467   crywrap=yes
 468  fi
 469
 470 fi
 471
 472 AM_CONDITIONAL(ENABLE_CRYWRAP, test "x$crywrap" != "xno")
 473 rm -f suppressions.valgrind
 474 dnl end of crywrap requirements
 475
 476 AC_CONFIG_FILES([guile/pre-inst-guile], [chmod +x guile/pre-inst-guile])
 477 AC_CONFIG_FILES([
 478   Makefile
 479   doc/Makefile
 480   doc/credentials/Makefile
 481   doc/credentials/openpgp/Makefile
 482   doc/credentials/srp/Makefile
 483   doc/credentials/x509/Makefile
 484   doc/cyclo/Makefile
 485   doc/doxygen/Doxyfile
 486   doc/examples/Makefile
 487   doc/latex/Makefile
 488   doc/manpages/Makefile
 489   doc/reference/Makefile
 490   doc/reference/version.xml
 491   doc/scripts/Makefile
 492   extra/Makefile
 493   extra/includes/Makefile
 494   gl/Makefile
 495   gl/tests/Makefile
 496   guile/Makefile
 497   guile/modules/Makefile
 498   guile/src/Makefile
 499   guile/tests/Makefile
 500   lib/Makefile
 501   lib/accelerated/Makefile
 502   lib/accelerated/x86/Makefile
 503   lib/algorithms/Makefile
 504   lib/auth/Makefile
 505   lib/ext/Makefile
 506   lib/extras/Makefile
 507   lib/gnutls.pc
 508   lib/includes/Makefile
 509   lib/includes/gnutls/gnutls.h
 510   lib/minitasn1/Makefile
 511   lib/nettle/Makefile
 512   lib/opencdk/Makefile
 513   lib/openpgp/Makefile
 514   lib/x509/Makefile
 515   po/Makefile.in
 516   src/Makefile
 517   src/crywrap/Makefile
 518   tests/Makefile
 519   tests/cert-tests/Makefile
 520   tests/dsa/Makefile
 521   tests/dtls/Makefile
 522   tests/srp/Makefile
 523   tests/ecdsa/Makefile
 524   tests/key-id/Makefile
 525   tests/openpgp-certs/Makefile
 526   tests/pkcs1-padding/Makefile
 527   tests/pkcs12-decode/Makefile
 528   tests/pkcs8-decode/Makefile
 529   tests/rsa-md5-collision/Makefile
 530   tests/safe-renegotiation/Makefile
 531   tests/scripts/Makefile
 532   tests/sha2/Makefile
 533   tests/slow/Makefile
 534   tests/suite/Makefile
 535   tests/userid/Makefile
 536 ])
 537
 538 AC_OUTPUT
 539
 540 AC_MSG_NOTICE([summary of build options:
 541
 542   version:          ${VERSION} shared $LT_CURRENT:$LT_REVISION:$LT_AGE
 543   Host type:        ${host}
 544   Install prefix:   ${prefix}
 545   Compiler:         ${CC}
 546   CFlags:           ${CFLAGS}
 547   Warning flags:    errors: ${WERROR_CFLAGS} warnings: ${WARN_CFLAGS}
 548   Library types:    Shared=${enable_shared}, Static=${enable_static}
 549   Valgrind:         $opt_valgrind_tests ${VALGRIND}
 550 ])
 551
 552 AC_MSG_NOTICE([Optional features:
 553 (note that included applications might not compile properly
 554 if features are disabled)
 555
 556   OCSP support:     $ac_enable_ocsp
 557   OpenPGP support:  $ac_enable_openpgp
 558   SRP support:      $ac_enable_srp
 559   PSK support:      $ac_enable_psk
 560   Anon auth support:$ac_enable_anon
 561
 562   Trust store pkcs: $with_default_trust_store_pkcs11
 563   Trust store file: $with_default_trust_store_file
 564   CRL file: $with_default_crl_file
 565 ])
 566
 567 AC_MSG_NOTICE([Optional applications:
 568
 569   crywrap app:      $libidn
 570   local libopts:    $enable_local_libopts
 571 ])
 572
 573 AC_MSG_NOTICE([Optional libraries:
 574
 575   Guile wrappers:   $opt_guile_bindings
 576   C++ library:      $use_cxx
 577   OpenSSL compat:   $enable_openssl
 578 ])
 579
 580 AC_MSG_NOTICE([Hardware acceleration/support:
 581
 582   /dev/crypto:      $enable_cryptodev
 583   Hardware accel:   $hw_accel
 584   PKCS#11 support:  $with_p11_kit
 585 ])