lisp/gnus-util.el

   1 ;;; gnus-util.el --- utility functions for Gnus
   2
   3 ;; Copyright (C) 1996-2011 Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; Nothing in this file depends on any other parts of Gnus -- all
  26 ;; functions and macros in this file are utility functions that are
  27 ;; used by Gnus and may be used by any other package without loading
  28 ;; Gnus first.
  29
  30 ;; [Unfortunately, it does depend on other parts of Gnus, e.g. the
  31 ;; autoloads and defvars below...]
  32
  33 ;;; Code:
  34
  35 ;; For Emacs <22.2 and XEmacs.
  36 (eval-and-compile
  37   (unless (fboundp 'declare-function) (defmacro declare-function (&rest r))))
  38 (eval-when-compile
  39   (require 'cl))
  40
  41 (require 'time-date)
  42
  43 (defcustom gnus-completing-read-function 'gnus-emacs-completing-read
  44   "Function use to do completing read."
  45   :version "24.1"
  46   :group 'gnus-meta
  47   :type `(radio (function-item
  48                  :doc "Use Emacs standard `completing-read' function."
  49                  gnus-emacs-completing-read)
  50                 ;; iswitchb.el is very old and ido.el is unavailable
  51                 ;; in XEmacs, so we exclude those function items.
  52                 ,@(unless (featurep 'xemacs)
  53                     '((function-item
  54                        :doc "Use `ido-completing-read' function."
  55                        gnus-ido-completing-read)
  56                       (function-item
  57                        :doc "Use iswitchb based completing-read function."
  58                        gnus-iswitchb-completing-read)))))
  59
  60 (defcustom gnus-completion-styles
  61   (if (and (boundp 'completion-styles-alist)
  62            (boundp 'completion-styles))
  63       (append (when (and (assq 'substring completion-styles-alist)
  64                          (not (memq 'substring completion-styles)))
  65                 (list 'substring))
  66               completion-styles)
  67     nil)
  68   "Value of `completion-styles' to use when completing."
  69   :version "24.1"
  70   :group 'gnus-meta
  71   :type 'list)
  72
  73 ;; Fixme: this should be a gnus variable, not nnmail-.
  74 (defvar nnmail-pathname-coding-system)
  75 (defvar nnmail-active-file-coding-system)
  76
  77 ;; Inappropriate references to other parts of Gnus.
  78 (defvar gnus-emphasize-whitespace-regexp)
  79 (defvar gnus-original-article-buffer)
  80 (defvar gnus-user-agent)
  81
  82 (autoload 'gnus-get-buffer-window "gnus-win")
  83 (autoload 'nnheader-narrow-to-headers "nnheader")
  84 (autoload 'nnheader-replace-chars-in-string "nnheader")
  85 (autoload 'mail-header-remove-comments "mail-parse")
  86
  87 (eval-and-compile
  88   (cond
  89    ;; Prefer `replace-regexp-in-string' (present in Emacs, XEmacs 21.5,
  90    ;; SXEmacs 22.1.4) over `replace-in-string'.  The latter leads to inf-loops
  91    ;; on empty matches:
  92    ;;   (replace-in-string "foo" "/*$" "/")
  93    ;;   (replace-in-string "xe" "\\(x\\)?" "")
  94    ((fboundp 'replace-regexp-in-string)
  95     (defun gnus-replace-in-string  (string regexp newtext &optional literal)
  96       "Replace all matches for REGEXP with NEWTEXT in STRING.
  97 If LITERAL is non-nil, insert NEWTEXT literally.  Return a new
  98 string containing the replacements.
  99
 100 This is a compatibility function for different Emacsen."
 101       (replace-regexp-in-string regexp newtext string nil literal)))
 102    ((fboundp 'replace-in-string)
 103     (defalias 'gnus-replace-in-string 'replace-in-string))))
 104
 105 (defun gnus-boundp (variable)
 106   "Return non-nil if VARIABLE is bound and non-nil."
 107   (and (boundp variable)
 108        (symbol-value variable)))
 109
 110 (defmacro gnus-eval-in-buffer-window (buffer &rest forms)
 111   "Pop to BUFFER, evaluate FORMS, and then return to the original window."
 112   (let ((tempvar (make-symbol "GnusStartBufferWindow"))
 113         (w (make-symbol "w"))
 114         (buf (make-symbol "buf")))
 115     `(let* ((,tempvar (selected-window))
 116             (,buf ,buffer)
 117             (,w (gnus-get-buffer-window ,buf 'visible)))
 118        (unwind-protect
 119            (progn
 120              (if ,w
 121                  (progn
 122                    (select-window ,w)
 123                    (set-buffer (window-buffer ,w)))
 124                (pop-to-buffer ,buf))
 125              ,@forms)
 126          (select-window ,tempvar)))))
 127
 128 (put 'gnus-eval-in-buffer-window 'lisp-indent-function 1)
 129 (put 'gnus-eval-in-buffer-window 'edebug-form-spec '(form body))
 130
 131 (defmacro gnus-intern-safe (string hashtable)
 132   "Get hash value.  Arguments are STRING and HASHTABLE."
 133   `(let ((symbol (intern ,string ,hashtable)))
 134      (or (boundp symbol)
 135          (set symbol nil))
 136      symbol))
 137
 138 (defsubst gnus-goto-char (point)
 139   (and point (goto-char point)))
 140
 141 (defmacro gnus-buffer-exists-p (buffer)
 142   `(let ((buffer ,buffer))
 143      (when buffer
 144        (funcall (if (stringp buffer) 'get-buffer 'buffer-name)
 145                 buffer))))
 146
 147 ;; The LOCAL arg to `add-hook' is interpreted differently in Emacs and
 148 ;; XEmacs.  In Emacs we don't need to call `make-local-hook' first.
 149 ;; It's harmless, though, so the main purpose of this alias is to shut
 150 ;; up the byte compiler.
 151 (defalias 'gnus-make-local-hook (if (featurep 'xemacs)
 152                                     'make-local-hook
 153                                   'ignore))
 154
 155 (defun gnus-delete-first (elt list)
 156   "Delete by side effect the first occurrence of ELT as a member of LIST."
 157   (if (equal (car list) elt)
 158       (cdr list)
 159     (let ((total list))
 160       (while (and (cdr list)
 161                   (not (equal (cadr list) elt)))
 162         (setq list (cdr list)))
 163       (when (cdr list)
 164         (setcdr list (cddr list)))
 165       total)))
 166
 167 ;; Delete the current line (and the next N lines).
 168 (defmacro gnus-delete-line (&optional n)
 169   `(delete-region (point-at-bol)
 170                   (progn (forward-line ,(or n 1)) (point))))
 171
 172 (defun gnus-byte-code (func)
 173   "Return a form that can be `eval'ed based on FUNC."
 174   (let ((fval (indirect-function func)))
 175     (if (byte-code-function-p fval)
 176         (let ((flist (append fval nil)))
 177           (setcar flist 'byte-code)
 178           flist)
 179       (cons 'progn (cddr fval)))))
 180
 181 (defun gnus-extract-address-components (from)
 182   "Extract address components from a From header.
 183 Given an RFC-822 address FROM, extract full name and canonical address.
 184 Returns a list of the form (FULL-NAME CANONICAL-ADDRESS).  Much more simple
 185 solution than `mail-extract-address-components', which works much better, but
 186 is slower."
 187   (let (name address)
 188     ;; First find the address - the thing with the @ in it.  This may
 189     ;; not be accurate in mail addresses, but does the trick most of
 190     ;; the time in news messages.
 191     (cond (;; Check ``<foo@bar>'' first in order to handle the quite common
 192            ;; form ``"abc@xyz" <foo@bar>'' (i.e. ``@'' as part of a comment)
 193            ;; correctly.
 194            (string-match "<\\([^@ \t<>]+[!@][^@ \t<>]+\\)>" from)
 195            (setq address (substring from (match-beginning 1) (match-end 1))))
 196           ((string-match "\\b[^@ \t<>]+[!@][^@ \t<>]+\\b" from)
 197            (setq address (substring from (match-beginning 0) (match-end 0)))))
 198     ;; Then we check whether the "name <address>" format is used.
 199     (and address
 200          ;; Linear white space is not required.
 201          (string-match (concat "[ \t]*<" (regexp-quote address) ">") from)
 202          (and (setq name (substring from 0 (match-beginning 0)))
 203               ;; Strip any quotes from the name.
 204               (string-match "^\".*\"$" name)
 205               (setq name (substring name 1 (1- (match-end 0))))))
 206     ;; If not, then "address (name)" is used.
 207     (or name
 208         (and (string-match "(.+)" from)
 209              (setq name (substring from (1+ (match-beginning 0))
 210                                    (1- (match-end 0)))))
 211         (and (string-match "()" from)
 212              (setq name address))
 213         ;; XOVER might not support folded From headers.
 214         (and (string-match "(.*" from)
 215              (setq name (substring from (1+ (match-beginning 0))
 216                                    (match-end 0)))))
 217     (list (if (string= name "") nil name) (or address from))))
 218
 219 (defun gnus-extract-address-component-name (from)
 220   "Extract name from a From header.
 221 Uses `gnus-extract-address-components'."
 222   (nth 0 (gnus-extract-address-components from)))
 223
 224 (defun gnus-extract-address-component-email (from)
 225   "Extract e-mail address from a From header.
 226 Uses `gnus-extract-address-components'."
 227   (nth 1 (gnus-extract-address-components from)))
 228
 229 (declare-function message-fetch-field "message" (header &optional not-all))
 230
 231 (defun gnus-fetch-field (field)
 232   "Return the value of the header FIELD of current article."
 233   (require 'message)
 234   (save-excursion
 235     (save-restriction
 236       (let ((inhibit-point-motion-hooks t))
 237         (nnheader-narrow-to-headers)
 238         (message-fetch-field field)))))
 239
 240 (defun gnus-fetch-original-field (field)
 241   "Fetch FIELD from the original version of the current article."
 242   (with-current-buffer gnus-original-article-buffer
 243     (gnus-fetch-field field)))
 244
 245
 246 (defun gnus-goto-colon ()
 247   (beginning-of-line)
 248   (let ((eol (point-at-eol)))
 249     (goto-char (or (text-property-any (point) eol 'gnus-position t)
 250                    (search-forward ":" eol t)
 251                    (point)))))
 252
 253 (declare-function gnus-find-method-for-group "gnus" (group &optional info))
 254 (declare-function gnus-group-name-decode "gnus-group" (string charset))
 255 (declare-function gnus-group-name-charset "gnus-group" (method group))
 256 ;; gnus-group requires gnus-int which requires message.
 257 (declare-function message-tokenize-header "message"
 258                   (header &optional separator))
 259
 260 (defun gnus-decode-newsgroups (newsgroups group &optional method)
 261   (require 'gnus-group)
 262   (let ((method (or method (gnus-find-method-for-group group))))
 263     (mapconcat (lambda (group)
 264                  (gnus-group-name-decode group (gnus-group-name-charset
 265                                                 method group)))
 266                (message-tokenize-header newsgroups)
 267                ",")))
 268
 269 (defun gnus-remove-text-with-property (prop)
 270   "Delete all text in the current buffer with text property PROP."
 271   (let ((start (point-min))
 272         end)
 273     (unless (get-text-property start prop)
 274       (setq start (next-single-property-change start prop)))
 275     (while start
 276       (setq end (text-property-any start (point-max) prop nil))
 277       (delete-region start (or end (point-max)))
 278       (setq start (when end
 279                     (next-single-property-change start prop))))))
 280
 281 (defun gnus-find-text-property-region (start end prop)
 282   "Return a list of text property regions that has property PROP."
 283   (let (regions value)
 284     (unless (get-text-property start prop)
 285       (setq start (next-single-property-change start prop)))
 286     (while start
 287       (setq value (get-text-property start prop)
 288             end (text-property-not-all start (point-max) prop value))
 289       (if (not end)
 290           (setq start nil)
 291         (when value
 292           (push (list (set-marker (make-marker) start)
 293                       (set-marker (make-marker) end)
 294                       value)
 295                 regions))
 296         (setq start (next-single-property-change start prop))))
 297     (nreverse regions)))
 298
 299 (defun gnus-newsgroup-directory-form (newsgroup)
 300   "Make hierarchical directory name from NEWSGROUP name."
 301   (let* ((newsgroup (gnus-newsgroup-savable-name newsgroup))
 302          (idx (string-match ":" newsgroup)))
 303     (concat
 304      (if idx (substring newsgroup 0 idx))
 305      (if idx "/")
 306      (nnheader-replace-chars-in-string
 307       (if idx (substring newsgroup (1+ idx)) newsgroup)
 308       ?. ?/))))
 309
 310 (defun gnus-newsgroup-savable-name (group)
 311   ;; Replace any slashes in a group name (eg. an ange-ftp nndoc group)
 312   ;; with dots.
 313   (nnheader-replace-chars-in-string group ?/ ?.))
 314
 315 (defun gnus-string> (s1 s2)
 316   (not (or (string< s1 s2)
 317            (string= s1 s2))))
 318
 319 (defun gnus-string< (s1 s2)
 320   "Return t if first arg string is less than second in lexicographic order.
 321 Case is significant if and only if `case-fold-search' is nil.
 322 Symbols are also allowed; their print names are used instead."
 323   (if case-fold-search
 324       (string-lessp (downcase (if (symbolp s1) (symbol-name s1) s1))
 325                     (downcase (if (symbolp s2) (symbol-name s2) s2)))
 326     (string-lessp s1 s2)))
 327
 328 ;;; Time functions.
 329
 330 (defun gnus-file-newer-than (file date)
 331   (let ((fdate (nth 5 (file-attributes file))))
 332     (or (> (car fdate) (car date))
 333         (and (= (car fdate) (car date))
 334              (> (nth 1 fdate) (nth 1 date))))))
 335
 336 ;; Every version of Emacs Gnus supports has built-in float-time.
 337 ;; The featurep test silences an irritating compiler warning.
 338 (eval-and-compile
 339   (if (or (featurep 'emacs)
 340           (fboundp 'float-time))
 341       (defalias 'gnus-float-time 'float-time)
 342     (defun gnus-float-time (&optional time)
 343       "Convert time value TIME to a floating point number.
 344 TIME defaults to the current time."
 345       (time-to-seconds (or time (current-time))))))
 346
 347 ;;; Keymap macros.
 348
 349 (defmacro gnus-local-set-keys (&rest plist)
 350   "Set the keys in PLIST in the current keymap."
 351   `(gnus-define-keys-1 (current-local-map) ',plist))
 352
 353 (defmacro gnus-define-keys (keymap &rest plist)
 354   "Define all keys in PLIST in KEYMAP."
 355   `(gnus-define-keys-1 (quote ,keymap) (quote ,plist)))
 356
 357 (defmacro gnus-define-keys-safe (keymap &rest plist)
 358   "Define all keys in PLIST in KEYMAP without overwriting previous definitions."
 359   `(gnus-define-keys-1 (quote ,keymap) (quote ,plist) t))
 360
 361 (put 'gnus-define-keys 'lisp-indent-function 1)
 362 (put 'gnus-define-keys-safe 'lisp-indent-function 1)
 363 (put 'gnus-local-set-keys 'lisp-indent-function 1)
 364
 365 (defmacro gnus-define-keymap (keymap &rest plist)
 366   "Define all keys in PLIST in KEYMAP."
 367   `(gnus-define-keys-1 ,keymap (quote ,plist)))
 368
 369 (put 'gnus-define-keymap 'lisp-indent-function 1)
 370
 371 (defun gnus-define-keys-1 (keymap plist &optional safe)
 372   (when (null keymap)
 373     (error "Can't set keys in a null keymap"))
 374   (cond ((symbolp keymap)
 375          (setq keymap (symbol-value keymap)))
 376         ((keymapp keymap))
 377         ((listp keymap)
 378          (set (car keymap) nil)
 379          (define-prefix-command (car keymap))
 380          (define-key (symbol-value (caddr keymap)) (cadr keymap) (car keymap))
 381          (setq keymap (symbol-value (car keymap)))))
 382   (let (key)
 383     (while plist
 384       (when (symbolp (setq key (pop plist)))
 385         (setq key (symbol-value key)))
 386       (if (or (not safe)
 387               (eq (lookup-key keymap key) 'undefined))
 388           (define-key keymap key (pop plist))
 389         (pop plist)))))
 390
 391 ;; Two silly functions to ensure that all `y-or-n-p' questions clear
 392 ;; the echo area.
 393 ;;
 394 ;; Do we really need these functions?  Workarounds for bugs in the corresponding
 395 ;; Emacs functions?  Maybe these bugs are no longer present in any supported
 396 ;; (X)Emacs version?  Alias them to the original functions and see if anyone
 397 ;; reports a problem.  If not, replace with original functions.  --rsteib,
 398 ;; 2007-12-14
 399 ;;
 400 ;; All supported Emacsen clear the echo area after `yes-or-no-p', so we can
 401 ;; remove `yes-or-no-p'.  RMS says that not clearing after `y-or-n-p' is
 402 ;; intentional (see below), so we could remove `gnus-y-or-n-p' too.
 403 ;; Objections?  --rsteib, 2008-02-16
 404 ;;
 405 ;; ,----[ http://thread.gmane.org/gmane.emacs.gnus.general/65099/focus=66070 ]
 406 ;; | From: Richard Stallman
 407 ;; | Subject: Re: Do we need gnus-yes-or-no-p and gnus-y-or-n-p?
 408 ;; | To: Katsumi Yamaoka [...]
 409 ;; | Cc: emacs-devel@[...], xemacs-beta@[...], ding@[...]
 410 ;; | Date: Mon, 07 Jan 2008 12:16:05 -0500
 411 ;; | Message-ID: <E1JBva1-000528-VY@fencepost.gnu.org>
 412 ;; |
 413 ;; |     The behavior of `y-or-n-p' that it doesn't clear the question
 414 ;; |     and the answer is not serious of course, but I feel it is not
 415 ;; |     cool.
 416 ;; |
 417 ;; | It is intentional.
 418 ;; |
 419 ;; |     Currently, it is commented out in the trunk by Reiner Steib.  He
 420 ;; |     also wrote the benefit of leaving the question and the answer in
 421 ;; |     the echo area as follows:
 422 ;; |
 423 ;; |     (http://article.gmane.org/gmane.emacs.gnus.general/66061)
 424 ;; |     > In contrast to yes-or-no-p it is much easier to type y, n,
 425 ;; |     > SPC, DEL, etc accidentally, so it might be useful for the user
 426 ;; |     > to see what he has typed.
 427 ;; |
 428 ;; | Yes, that is the reason.
 429 ;; `----
 430
 431 ;; (defun gnus-y-or-n-p (prompt)
 432 ;;   (prog1
 433 ;;       (y-or-n-p prompt)
 434 ;;     (message "")))
 435 ;; (defun gnus-yes-or-no-p (prompt)
 436 ;;   (prog1
 437 ;;       (yes-or-no-p prompt)
 438 ;;     (message "")))
 439
 440 (defalias 'gnus-y-or-n-p 'y-or-n-p)
 441 (defalias 'gnus-yes-or-no-p 'yes-or-no-p)
 442
 443 ;; By Frank Schmitt <ich@Frank-Schmitt.net>. Allows to have
 444 ;; age-depending date representations. (e.g. just the time if it's
 445 ;; from today, the day of the week if it's within the last 7 days and
 446 ;; the full date if it's older)
 447
 448 (defun gnus-seconds-today ()
 449   "Return the number of seconds passed today."
 450   (let ((now (decode-time (current-time))))
 451     (+ (car now) (* (car (cdr now)) 60) (* (car (nthcdr 2 now)) 3600))))
 452
 453 (defun gnus-seconds-month ()
 454   "Return the number of seconds passed this month."
 455   (let ((now (decode-time (current-time))))
 456     (+ (car now) (* (car (cdr now)) 60) (* (car (nthcdr 2 now)) 3600)
 457        (* (- (car (nthcdr 3 now)) 1) 3600 24))))
 458
 459 (defun gnus-seconds-year ()
 460   "Return the number of seconds passed this year."
 461   (let ((now (decode-time (current-time)))
 462         (days (format-time-string "%j" (current-time))))
 463     (+ (car now) (* (car (cdr now)) 60) (* (car (nthcdr 2 now)) 3600)
 464        (* (- (string-to-number days) 1) 3600 24))))
 465
 466 (defmacro gnus-date-get-time (date)
 467   "Convert DATE string to Emacs time.
 468 Cache the result as a text property stored in DATE."
 469   ;; Either return the cached value...
 470   `(let ((d ,date))
 471      (if (equal "" d)
 472          '(0 0)
 473        (or (get-text-property 0 'gnus-time d)
 474            ;; or compute the value...
 475            (let ((time (safe-date-to-time d)))
 476              ;; and store it back in the string.
 477              (put-text-property 0 1 'gnus-time time d)
 478              time)))))
 479
 480 (defun gnus-dd-mmm (messy-date)
 481   "Return a string like DD-MMM from a big messy string."
 482   (condition-case ()
 483       (format-time-string "%d-%b" (gnus-date-get-time messy-date))
 484     (error "  -   ")))
 485
 486 (defsubst gnus-time-iso8601 (time)
 487   "Return a string of TIME in YYYYMMDDTHHMMSS format."
 488   (format-time-string "%Y%m%dT%H%M%S" time))
 489
 490 (defun gnus-date-iso8601 (date)
 491   "Convert the DATE to YYYYMMDDTHHMMSS."
 492   (condition-case ()
 493       (gnus-time-iso8601 (gnus-date-get-time date))
 494     (error "")))
 495
 496 (defun gnus-mode-string-quote (string)
 497   "Quote all \"%\"'s in STRING."
 498   (gnus-replace-in-string string "%" "%%"))
 499
 500 ;; Make a hash table (default and minimum size is 256).
 501 ;; Optional argument HASHSIZE specifies the table size.
 502 (defun gnus-make-hashtable (&optional hashsize)
 503   (make-vector (if hashsize (max (gnus-create-hash-size hashsize) 256) 256) 0))
 504
 505 ;; Make a number that is suitable for hashing; bigger than MIN and
 506 ;; equal to some 2^x.  Many machines (such as sparcs) do not have a
 507 ;; hardware modulo operation, so they implement it in software.  On
 508 ;; many sparcs over 50% of the time to intern is spent in the modulo.
 509 ;; Yes, it's slower than actually computing the hash from the string!
 510 ;; So we use powers of 2 so people can optimize the modulo to a mask.
 511 (defun gnus-create-hash-size (min)
 512   (let ((i 1))
 513     (while (< i min)
 514       (setq i (* 2 i)))
 515     i))
 516
 517 (defcustom gnus-verbose 7
 518   "*Integer that says how verbose Gnus should be.
 519 The higher the number, the more messages Gnus will flash to say what
 520 it's doing.  At zero, Gnus will be totally mute; at five, Gnus will
 521 display most important messages; and at ten, Gnus will keep on
 522 jabbering all the time."
 523   :group 'gnus-start
 524   :type 'integer)
 525
 526 (defcustom gnus-add-timestamp-to-message nil
 527   "Non-nil means add timestamps to messages that Gnus issues.
 528 If it is `log', add timestamps to only the messages that go into the
 529 \"*Messages*\" buffer (in XEmacs, it is the \" *Message-Log*\" buffer).
 530 If it is neither nil nor `log', add timestamps not only to log messages
 531 but also to the ones displayed in the echo area."
 532   :version "23.1" ;; No Gnus
 533   :group  'gnus-various
 534   :type '(choice :format "%{%t%}:\n %[Value Menu%] %v"
 535                  (const :tag "Logged messages only" log)
 536                  (sexp :tag "All messages"
 537                        :match (lambda (widget value) value)
 538                        :value t)
 539                  (const :tag "No timestamp" nil)))
 540
 541 (eval-when-compile
 542   (defmacro gnus-message-with-timestamp-1 (format-string args)
 543     (let ((timestamp '(format-time-string "%Y%m%dT%H%M%S.%3N> " time)))
 544       (if (featurep 'xemacs)
 545           `(let (str time)
 546              (if (or (and (null ,format-string) (null ,args))
 547                      (progn
 548                        (setq str (apply 'format ,format-string ,args))
 549                        (zerop (length str))))
 550                  (prog1
 551                      (and ,format-string str)
 552                    (clear-message nil))
 553                (cond ((eq gnus-add-timestamp-to-message 'log)
 554                       (setq time (current-time))
 555                       (display-message 'no-log str)
 556                       (log-message 'message (concat ,timestamp str)))
 557                      (gnus-add-timestamp-to-message
 558                       (setq time (current-time))
 559                       (display-message 'message (concat ,timestamp str)))
 560                      (t
 561                       (display-message 'message str))))
 562              str)
 563         `(let (str time)
 564            (cond ((eq gnus-add-timestamp-to-message 'log)
 565                   (setq str (let (message-log-max)
 566                               (apply 'message ,format-string ,args)))
 567                   (when (and message-log-max
 568                              (> message-log-max 0)
 569                              (/= (length str) 0))
 570                     (setq time (current-time))
 571                     (with-current-buffer (get-buffer-create "*Messages*")
 572                       (goto-char (point-max))
 573                       (insert ,timestamp str "\n")
 574                       (forward-line (- message-log-max))
 575                       (delete-region (point-min) (point))
 576                       (goto-char (point-max))))
 577                   str)
 578                  (gnus-add-timestamp-to-message
 579                   (if (or (and (null ,format-string) (null ,args))
 580                           (progn
 581                             (setq str (apply 'format ,format-string ,args))
 582                             (zerop (length str))))
 583                       (prog1
 584                           (and ,format-string str)
 585                         (message nil))
 586                     (setq time (current-time))
 587                     (message "%s" (concat ,timestamp str))
 588                     str))
 589                  (t
 590                   (apply 'message ,format-string ,args))))))))
 591
 592 (defvar gnus-action-message-log nil)
 593
 594 (defun gnus-message-with-timestamp (format-string &rest args)
 595   "Display message with timestamp.  Arguments are the same as `message'.
 596 The `gnus-add-timestamp-to-message' variable controls how to add
 597 timestamp to message."
 598   (gnus-message-with-timestamp-1 format-string args))
 599
 600 (defun gnus-message (level &rest args)
 601   "If LEVEL is lower than `gnus-verbose' print ARGS using `message'.
 602
 603 Guideline for numbers:
 604 1 - error messages, 3 - non-serious error messages, 5 - messages for things
 605 that take a long time, 7 - not very important messages on stuff, 9 - messages
 606 inside loops."
 607   (if (<= level gnus-verbose)
 608       (let ((message
 609              (if gnus-add-timestamp-to-message
 610                  (apply 'gnus-message-with-timestamp args)
 611                (apply 'message args))))
 612         (when (and (consp gnus-action-message-log)
 613                    (<= level 3))
 614           (push message gnus-action-message-log))
 615         message)
 616     ;; We have to do this format thingy here even if the result isn't
 617     ;; shown - the return value has to be the same as the return value
 618     ;; from `message'.
 619     (apply 'format args)))
 620
 621 (defun gnus-final-warning ()
 622   (when (and (consp gnus-action-message-log)
 623              (setq gnus-action-message-log
 624                    (delete nil gnus-action-message-log)))
 625     (message "Warning: %s"
 626              (mapconcat #'identity gnus-action-message-log "; "))))
 627
 628 (defun gnus-error (level &rest args)
 629   "Beep an error if LEVEL is equal to or less than `gnus-verbose'.
 630 ARGS are passed to `message'."
 631   (when (<= (floor level) gnus-verbose)
 632     (apply 'message args)
 633     (ding)
 634     (let (duration)
 635       (when (and (floatp level)
 636                  (not (zerop (setq duration (* 10 (- level (floor level)))))))
 637         (sit-for duration))))
 638   nil)
 639
 640 (defun gnus-split-references (references)
 641   "Return a list of Message-IDs in REFERENCES."
 642   (let ((beg 0)
 643         (references (mail-header-remove-comments (or references "")))
 644         ids)
 645     (while (string-match "<[^<]+[^< \t]" references beg)
 646       (push (substring references (match-beginning 0) (setq beg (match-end 0)))
 647             ids))
 648     (nreverse ids)))
 649
 650 (defun gnus-extract-references (references)
 651   "Return a list of Message-IDs in REFERENCES (in In-Reply-To
 652   format), trimmed to only contain the Message-IDs."
 653   (let ((ids (gnus-split-references references))
 654         refs)
 655     (dolist (id ids)
 656       (when (string-match "<[^<>]+>" id)
 657         (push (match-string 0 id) refs)))
 658     refs))
 659
 660 (defsubst gnus-parent-id (references &optional n)
 661   "Return the last Message-ID in REFERENCES.
 662 If N, return the Nth ancestor instead."
 663   (when (and references
 664              (not (zerop (length references))))
 665     (if n
 666         (let ((ids (inline (gnus-split-references references))))
 667           (while (nthcdr n ids)
 668             (setq ids (cdr ids)))
 669           (car ids))
 670       (let ((references (mail-header-remove-comments references)))
 671         (when (string-match "\\(<[^<]+>\\)[ \t]*\\'" references)
 672           (match-string 1 references))))))
 673
 674 (defsubst gnus-buffer-live-p (buffer)
 675   "Say whether BUFFER is alive or not."
 676   (and buffer (buffer-live-p (get-buffer buffer))))
 677
 678 (defun gnus-horizontal-recenter ()
 679   "Recenter the current buffer horizontally."
 680   (if (< (current-column) (/ (window-width) 2))
 681       (set-window-hscroll (gnus-get-buffer-window (current-buffer) t) 0)
 682     (let* ((orig (point))
 683            (end (window-end (gnus-get-buffer-window (current-buffer) t)))
 684            (max 0))
 685       (when end
 686         ;; Find the longest line currently displayed in the window.
 687         (goto-char (window-start))
 688         (while (and (not (eobp))
 689                     (< (point) end))
 690           (end-of-line)
 691           (setq max (max max (current-column)))
 692           (forward-line 1))
 693         (goto-char orig)
 694         ;; Scroll horizontally to center (sort of) the point.
 695         (if (> max (window-width))
 696             (set-window-hscroll
 697              (gnus-get-buffer-window (current-buffer) t)
 698              (min (- (current-column) (/ (window-width) 3))
 699                   (+ 2 (- max (window-width)))))
 700           (set-window-hscroll (gnus-get-buffer-window (current-buffer) t) 0))
 701         max))))
 702
 703 (defun gnus-read-event-char (&optional prompt)
 704   "Get the next event."
 705   (let ((event (read-event prompt)))
 706     ;; should be gnus-characterp, but this can't be called in XEmacs anyway
 707     (cons (and (numberp event) event) event)))
 708
 709 (defun gnus-sortable-date (date)
 710   "Make string suitable for sorting from DATE."
 711   (gnus-time-iso8601 (date-to-time date)))
 712
 713 (defun gnus-copy-file (file &optional to)
 714   "Copy FILE to TO."
 715   (interactive
 716    (list (read-file-name "Copy file: " default-directory)
 717          (read-file-name "Copy file to: " default-directory)))
 718   (unless to
 719     (setq to (read-file-name "Copy file to: " default-directory)))
 720   (when (file-directory-p to)
 721     (setq to (concat (file-name-as-directory to)
 722                      (file-name-nondirectory file))))
 723   (copy-file file to))
 724
 725 (defvar gnus-work-buffer " *gnus work*")
 726
 727 (declare-function gnus-get-buffer-create "gnus" (name))
 728 ;; gnus.el requires mm-util.
 729 (declare-function mm-enable-multibyte "mm-util")
 730
 731 (defun gnus-set-work-buffer ()
 732   "Put point in the empty Gnus work buffer."
 733   (if (get-buffer gnus-work-buffer)
 734       (progn
 735         (set-buffer gnus-work-buffer)
 736         (erase-buffer))
 737     (set-buffer (gnus-get-buffer-create gnus-work-buffer))
 738     (kill-all-local-variables)
 739     (mm-enable-multibyte)))
 740
 741 (defmacro gnus-group-real-name (group)
 742   "Find the real name of a foreign newsgroup."
 743   `(let ((gname ,group))
 744      (if (string-match "^[^:]+:" gname)
 745          (substring gname (match-end 0))
 746        gname)))
 747
 748 (defmacro gnus-group-server (group)
 749   "Find the server name of a foreign newsgroup.
 750 For example, (gnus-group-server \"nnimap+yxa:INBOX.foo\") would
 751 yield \"nnimap:yxa\"."
 752   `(let ((gname ,group))
 753      (if (string-match "^\\([^:+]+\\)\\(?:\\+\\([^:]*\\)\\)?:" gname)
 754          (format "%s:%s" (match-string 1 gname) (or
 755                                                  (match-string 2 gname)
 756                                                  ""))
 757        (format "%s:%s" (car gnus-select-method) (cadr gnus-select-method)))))
 758
 759 (defun gnus-make-sort-function (funs)
 760   "Return a composite sort condition based on the functions in FUNS."
 761   (cond
 762    ;; Just a simple function.
 763    ((functionp funs) funs)
 764    ;; No functions at all.
 765    ((null funs) funs)
 766    ;; A list of functions.
 767    ((or (cdr funs)
 768         (listp (car funs)))
 769     (gnus-byte-compile
 770      `(lambda (t1 t2)
 771         ,(gnus-make-sort-function-1 (reverse funs)))))
 772    ;; A list containing just one function.
 773    (t
 774     (car funs))))
 775
 776 (defun gnus-make-sort-function-1 (funs)
 777   "Return a composite sort condition based on the functions in FUNS."
 778   (let ((function (car funs))
 779         (first 't1)
 780         (last 't2))
 781     (when (consp function)
 782       (cond
 783        ;; Reversed spec.
 784        ((eq (car function) 'not)
 785         (setq function (cadr function)
 786               first 't2
 787               last 't1))
 788        ((functionp function)
 789         ;; Do nothing.
 790         )
 791        (t
 792         (error "Invalid sort spec: %s" function))))
 793     (if (cdr funs)
 794         `(or (,function ,first ,last)
 795              (and (not (,function ,last ,first))
 796                   ,(gnus-make-sort-function-1 (cdr funs))))
 797       `(,function ,first ,last))))
 798
 799 (defun gnus-turn-off-edit-menu (type)
 800   "Turn off edit menu in `gnus-TYPE-mode-map'."
 801   (define-key (symbol-value (intern (format "gnus-%s-mode-map" type)))
 802     [menu-bar edit] 'undefined))
 803
 804 (defmacro gnus-bind-print-variables (&rest forms)
 805   "Bind print-* variables and evaluate FORMS.
 806 This macro is used with `prin1', `pp', etc. in order to ensure printed
 807 Lisp objects are loadable.  Bind `print-quoted' and `print-readably'
 808 to t, and `print-escape-multibyte', `print-escape-newlines',
 809 `print-escape-nonascii', `print-length', `print-level' and
 810 `print-string-length' to nil."
 811   `(let ((print-quoted t)
 812          (print-readably t)
 813          ;;print-circle
 814          ;;print-continuous-numbering
 815          print-escape-multibyte
 816          print-escape-newlines
 817          print-escape-nonascii
 818          ;;print-gensym
 819          print-length
 820          print-level
 821          print-string-length)
 822      ,@forms))
 823
 824 (defun gnus-prin1 (form)
 825   "Use `prin1' on FORM in the current buffer.
 826 Bind `print-quoted' and `print-readably' to t, and `print-length' and
 827 `print-level' to nil.  See also `gnus-bind-print-variables'."
 828   (gnus-bind-print-variables (prin1 form (current-buffer))))
 829
 830 (defun gnus-prin1-to-string (form)
 831   "The same as `prin1'.
 832 Bind `print-quoted' and `print-readably' to t, and `print-length' and
 833 `print-level' to nil.  See also `gnus-bind-print-variables'."
 834   (gnus-bind-print-variables (prin1-to-string form)))
 835
 836 (defun gnus-pp (form &optional stream)
 837   "Use `pp' on FORM in the current buffer.
 838 Bind `print-quoted' and `print-readably' to t, and `print-length' and
 839 `print-level' to nil.  See also `gnus-bind-print-variables'."
 840   (gnus-bind-print-variables (pp form (or stream (current-buffer)))))
 841
 842 (defun gnus-pp-to-string (form)
 843   "The same as `pp-to-string'.
 844 Bind `print-quoted' and `print-readably' to t, and `print-length' and
 845 `print-level' to nil.  See also `gnus-bind-print-variables'."
 846   (gnus-bind-print-variables (pp-to-string form)))
 847
 848 (defun gnus-make-directory (directory)
 849   "Make DIRECTORY (and all its parents) if it doesn't exist."
 850   (require 'nnmail)
 851   (let ((file-name-coding-system nnmail-pathname-coding-system))
 852     (when (and directory
 853                (not (file-exists-p directory)))
 854       (make-directory directory t)))
 855   t)
 856
 857 (defun gnus-write-buffer (file)
 858   "Write the current buffer's contents to FILE."
 859   (require 'nnmail)
 860   (let ((file-name-coding-system nnmail-pathname-coding-system))
 861     ;; Make sure the directory exists.
 862     (gnus-make-directory (file-name-directory file))
 863     ;; Write the buffer.
 864     (write-region (point-min) (point-max) file nil 'quietly)))
 865
 866 (defun gnus-delete-file (file)
 867   "Delete FILE if it exists."
 868   (when (file-exists-p file)
 869     (delete-file file)))
 870
 871 (defun gnus-delete-duplicates (list)
 872   "Remove duplicate entries from LIST."
 873   (let ((result nil))
 874     (while list
 875       (unless (member (car list) result)
 876         (push (car list) result))
 877       (pop list))
 878     (nreverse result)))
 879
 880 (defun gnus-delete-directory (directory)
 881   "Delete files in DIRECTORY.  Subdirectories remain.
 882 If there's no subdirectory, delete DIRECTORY as well."
 883   (when (file-directory-p directory)
 884     (let ((files (directory-files
 885                   directory t "^\\([^.]\\|\\.\\([^.]\\|\\..\\)\\).*"))
 886           file dir)
 887       (while files
 888         (setq file (pop files))
 889         (if (eq t (car (file-attributes file)))
 890             ;; `file' is a subdirectory.
 891             (setq dir t)
 892           ;; `file' is a file or a symlink.
 893           (delete-file file)))
 894       (unless dir
 895         (delete-directory directory)))))
 896
 897 ;; The following two functions are used in gnus-registry.
 898 ;; They were contributed by Andreas Fuchs <asf@void.at>.
 899 (defun gnus-alist-to-hashtable (alist)
 900   "Build a hashtable from the values in ALIST."
 901   (let ((ht (make-hash-table
 902              :size 4096
 903              :test 'equal)))
 904     (mapc
 905      (lambda (kv-pair)
 906        (puthash (car kv-pair) (cdr kv-pair) ht))
 907      alist)
 908      ht))
 909
 910 (defun gnus-hashtable-to-alist (hash)
 911   "Build an alist from the values in HASH."
 912   (let ((list nil))
 913     (maphash
 914      (lambda (key value)
 915        (setq list (cons (cons key value) list)))
 916      hash)
 917     list))
 918
 919 (defun gnus-strip-whitespace (string)
 920   "Return STRING stripped of all whitespace."
 921   (while (string-match "[\r\n\t ]+" string)
 922     (setq string (replace-match "" t t string)))
 923   string)
 924
 925 (declare-function gnus-put-text-property "gnus"
 926                   (start end property value &optional object))
 927
 928 (defsubst gnus-put-text-property-excluding-newlines (beg end prop val)
 929   "The same as `put-text-property', but don't put this prop on any newlines in the region."
 930   (save-match-data
 931     (save-excursion
 932       (save-restriction
 933         (goto-char beg)
 934         (while (re-search-forward gnus-emphasize-whitespace-regexp end 'move)
 935           (gnus-put-text-property beg (match-beginning 0) prop val)
 936           (setq beg (point)))
 937         (gnus-put-text-property beg (point) prop val)))))
 938
 939 (declare-function gnus-overlay-put  "gnus" (overlay prop value))
 940 (declare-function gnus-make-overlay "gnus"
 941                   (beg end &optional buffer front-advance rear-advance))
 942
 943 (defsubst gnus-put-overlay-excluding-newlines (beg end prop val)
 944   "The same as `put-text-property', but don't put this prop on any newlines in the region."
 945   (save-match-data
 946     (save-excursion
 947       (save-restriction
 948         (goto-char beg)
 949         (while (re-search-forward gnus-emphasize-whitespace-regexp end 'move)
 950           (gnus-overlay-put
 951            (gnus-make-overlay beg (match-beginning 0))
 952            prop val)
 953           (setq beg (point)))
 954         (gnus-overlay-put (gnus-make-overlay beg (point)) prop val)))))
 955
 956 (defun gnus-put-text-property-excluding-characters-with-faces (beg end
 957                                                                    prop val)
 958   "The same as `put-text-property', but don't put props on characters with the `gnus-face' property."
 959   (let ((b beg))
 960     (while (/= b end)
 961       (when (get-text-property b 'gnus-face)
 962         (setq b (next-single-property-change b 'gnus-face nil end)))
 963       (when (/= b end)
 964         (inline
 965           (gnus-put-text-property
 966            b (setq b (next-single-property-change b 'gnus-face nil end))
 967            prop val))))))
 968
 969 (defmacro gnus-faces-at (position)
 970   "Return a list of faces at POSITION."
 971   (if (featurep 'xemacs)
 972       `(let ((pos ,position))
 973          (mapcar-extents 'extent-face
 974                          nil (current-buffer) pos pos nil 'face))
 975     `(let ((pos ,position))
 976        (delq nil (cons (get-text-property pos 'face)
 977                        (mapcar
 978                         (lambda (overlay)
 979                           (overlay-get overlay 'face))
 980                         (overlays-at pos)))))))
 981
 982 (if (fboundp 'invisible-p)
 983     (defalias 'gnus-invisible-p 'invisible-p)
 984   ;; for Emacs < 22.2, and XEmacs.
 985   (defun gnus-invisible-p (pos)
 986     "Return non-nil if the character after POS is currently invisible."
 987     (let ((prop (get-char-property pos 'invisible)))
 988       (if (eq buffer-invisibility-spec t)
 989           prop
 990         (or (memq prop buffer-invisibility-spec)
 991             (assq prop buffer-invisibility-spec))))))
 992
 993 ;; Note: the optional 2nd argument has a different meaning between
 994 ;; Emacs and XEmacs.
 995 ;; (next-char-property-change POSITION &optional LIMIT)
 996 ;; (next-extent-change        POS      &optional OBJECT)
 997 (defalias 'gnus-next-char-property-change
 998   (if (fboundp 'next-extent-change)
 999       'next-extent-change 'next-char-property-change))
1000
1001 (defalias 'gnus-previous-char-property-change
1002   (if (fboundp 'previous-extent-change)
1003       'previous-extent-change 'previous-char-property-change))
1004
1005 ;;; Protected and atomic operations.  dmoore@ucsd.edu 21.11.1996
1006 ;; The primary idea here is to try to protect internal datastructures
1007 ;; from becoming corrupted when the user hits C-g, or if a hook or
1008 ;; similar blows up.  Often in Gnus multiple tables/lists need to be
1009 ;; updated at the same time, or information can be lost.
1010
1011 (defvar gnus-atomic-be-safe t
1012   "If t, certain operations will be protected from interruption by C-g.")
1013
1014 (defmacro gnus-atomic-progn (&rest forms)
1015   "Evaluate FORMS atomically, which means to protect the evaluation
1016 from being interrupted by the user.  An error from the forms themselves
1017 will return without finishing the operation.  Since interrupts from
1018 the user are disabled, it is recommended that only the most minimal
1019 operations are performed by FORMS.  If you wish to assign many
1020 complicated values atomically, compute the results into temporary
1021 variables and then do only the assignment atomically."
1022   `(let ((inhibit-quit gnus-atomic-be-safe))
1023      ,@forms))
1024
1025 (put 'gnus-atomic-progn 'lisp-indent-function 0)
1026
1027 (defmacro gnus-atomic-progn-assign (protect &rest forms)
1028   "Evaluate FORMS, but ensure that the variables listed in PROTECT
1029 are not changed if anything in FORMS signals an error or otherwise
1030 non-locally exits.  The variables listed in PROTECT are updated atomically.
1031 It is safe to use gnus-atomic-progn-assign with long computations.
1032
1033 Note that if any of the symbols in PROTECT were unbound, they will be
1034 set to nil on a successful assignment.  In case of an error or other
1035 non-local exit, it will still be unbound."
1036   (let* ((temp-sym-map (mapcar (lambda (x) (list (make-symbol
1037                                                   (concat (symbol-name x)
1038                                                           "-tmp"))
1039                                                  x))
1040                                protect))
1041          (sym-temp-map (mapcar (lambda (x) (list (cadr x) (car x)))
1042                                temp-sym-map))
1043          (temp-sym-let (mapcar (lambda (x) (list (car x)
1044                                                  `(and (boundp ',(cadr x))
1045                                                        ,(cadr x))))
1046                                temp-sym-map))
1047          (sym-temp-let sym-temp-map)
1048          (temp-sym-assign (apply 'append temp-sym-map))
1049          (sym-temp-assign (apply 'append sym-temp-map))
1050          (result (make-symbol "result-tmp")))
1051     `(let (,@temp-sym-let
1052            ,result)
1053        (let ,sym-temp-let
1054          (setq ,result (progn ,@forms))
1055          (setq ,@temp-sym-assign))
1056        (let ((inhibit-quit gnus-atomic-be-safe))
1057          (setq ,@sym-temp-assign))
1058        ,result)))
1059
1060 (put 'gnus-atomic-progn-assign 'lisp-indent-function 1)
1061 ;(put 'gnus-atomic-progn-assign 'edebug-form-spec '(sexp body))
1062
1063 (defmacro gnus-atomic-setq (&rest pairs)
1064   "Similar to setq, except that the real symbols are only assigned when
1065 there are no errors.  And when the real symbols are assigned, they are
1066 done so atomically.  If other variables might be changed via side-effect,
1067 see gnus-atomic-progn-assign.  It is safe to use gnus-atomic-setq
1068 with potentially long computations."
1069   (let ((tpairs pairs)
1070         syms)
1071     (while tpairs
1072       (push (car tpairs) syms)
1073       (setq tpairs (cddr tpairs)))
1074     `(gnus-atomic-progn-assign ,syms
1075        (setq ,@pairs))))
1076
1077 ;(put 'gnus-atomic-setq 'edebug-form-spec '(body))
1078
1079
1080 ;;; Functions for saving to babyl/mail files.
1081
1082 (eval-when-compile
1083   (if (featurep 'xemacs)
1084       ;; Don't load tm and apel XEmacs packages that provide some
1085       ;; Emacs emulating functions and variables.
1086       (let ((features features))
1087         (provide 'tm-view)
1088         (unless (fboundp 'set-alist) (defalias 'set-alist 'ignore))
1089         (require 'rmail)) ;; It requires tm-view that loads apel.
1090     (require 'rmail))
1091   (autoload 'rmail-update-summary "rmailsum"))
1092
1093 (defvar mm-text-coding-system)
1094
1095 (declare-function mm-append-to-file "mm-util"
1096                   (start end filename &optional codesys inhibit))
1097
1098 (defun gnus-output-to-rmail (filename &optional ask)
1099   "Append the current article to an Rmail file named FILENAME.
1100 In Emacs 22 this writes Babyl format; in Emacs 23 it writes mbox unless
1101 FILENAME exists and is Babyl format."
1102   (require 'rmail)
1103   (require 'mm-util)
1104   (require 'nnmail)
1105   ;; Some of this codes is borrowed from rmailout.el.
1106   (setq filename (expand-file-name filename))
1107   ;; FIXME should we really be messing with this defcustom?
1108   ;; It is not needed for the operation of this function.
1109   (if (boundp 'rmail-default-rmail-file)
1110       (setq rmail-default-rmail-file filename) ; 22
1111     (setq rmail-default-file filename))        ; 23
1112   (let ((artbuf (current-buffer))
1113         (tmpbuf (get-buffer-create " *Gnus-output*"))
1114         ;; Babyl rmail.el defines this, mbox does not.
1115         (babyl (fboundp 'rmail-insert-rmail-file-header)))
1116     (save-excursion
1117       ;; Note that we ignore the possibility of visiting a Babyl
1118       ;; format buffer in Emacs 23, since Rmail no longer supports that.
1119      (or (get-file-buffer filename)
1120          (progn
1121            ;; In case someone wants to write to a Babyl file from Emacs 23.
1122            (when (file-exists-p filename)
1123              (setq babyl (mail-file-babyl-p filename))
1124              t))
1125           (if (or (not ask)
1126                   (gnus-yes-or-no-p
1127                    (concat "\"" filename "\" does not exist, create it? ")))
1128               (let ((file-buffer (create-file-buffer filename)))
1129                 (with-current-buffer file-buffer
1130                   (if (fboundp 'rmail-insert-rmail-file-header)
1131                       (rmail-insert-rmail-file-header))
1132                   (let ((require-final-newline nil)
1133                         (coding-system-for-write mm-text-coding-system))
1134                     (gnus-write-buffer filename)))
1135                 (kill-buffer file-buffer))
1136             (error "Output file does not exist")))
1137       (set-buffer tmpbuf)
1138       (erase-buffer)
1139       (insert-buffer-substring artbuf)
1140       (if babyl
1141           (gnus-convert-article-to-rmail)
1142         ;; Non-Babyl case copied from gnus-output-to-mail.
1143         (goto-char (point-min))
1144         (if (looking-at "From ")
1145             (forward-line 1)
1146           (insert "From nobody " (current-time-string) "\n"))
1147         (let (case-fold-search)
1148           (while (re-search-forward "^From " nil t)
1149             (beginning-of-line)
1150             (insert ">"))))
1151       ;; Decide whether to append to a file or to an Emacs buffer.
1152       (let ((outbuf (get-file-buffer filename)))
1153         (if (not outbuf)
1154             (progn
1155               (unless babyl             ; from gnus-output-to-mail
1156                 (let ((buffer-read-only nil))
1157                   (goto-char (point-max))
1158                   (forward-char -2)
1159                   (unless (looking-at "\n\n")
1160                     (goto-char (point-max))
1161                     (unless (bolp)
1162                       (insert "\n"))
1163                     (insert "\n"))))
1164               (let ((file-name-coding-system nnmail-pathname-coding-system))
1165                 (mm-append-to-file (point-min) (point-max) filename)))
1166           ;; File has been visited, in buffer OUTBUF.
1167           (set-buffer outbuf)
1168           (let ((buffer-read-only nil)
1169                 (msg (and (boundp 'rmail-current-message)
1170                           (symbol-value 'rmail-current-message))))
1171             ;; If MSG is non-nil, buffer is in RMAIL mode.
1172             ;; Compare this with rmail-output-to-rmail-buffer in Emacs 23.
1173             (when msg
1174               (unless babyl
1175                 (rmail-swap-buffers-maybe)
1176                 (rmail-maybe-set-message-counters))
1177               (widen)
1178               (narrow-to-region (point-max) (point-max)))
1179             (insert-buffer-substring tmpbuf)
1180             (when msg
1181               (when babyl
1182                 (goto-char (point-min))
1183                 (widen)
1184                 (search-backward "\n\^_")
1185                 (narrow-to-region (point) (point-max)))
1186               (rmail-count-new-messages t)
1187               (when (rmail-summary-exists)
1188                 (rmail-select-summary
1189                  (rmail-update-summary)))
1190               (rmail-show-message msg))
1191             (save-buffer)))))
1192     (kill-buffer tmpbuf)))
1193
1194 (defun gnus-output-to-mail (filename &optional ask)
1195   "Append the current article to a mail file named FILENAME."
1196   (require 'nnmail)
1197   (setq filename (expand-file-name filename))
1198   (let ((artbuf (current-buffer))
1199         (tmpbuf (get-buffer-create " *Gnus-output*")))
1200     (save-excursion
1201       ;; Create the file, if it doesn't exist.
1202       (when (and (not (get-file-buffer filename))
1203                  (not (file-exists-p filename)))
1204         (if (or (not ask)
1205                 (gnus-y-or-n-p
1206                  (concat "\"" filename "\" does not exist, create it? ")))
1207             (let ((file-buffer (create-file-buffer filename)))
1208               (with-current-buffer file-buffer
1209                 (let ((require-final-newline nil)
1210                       (coding-system-for-write mm-text-coding-system))
1211                   (gnus-write-buffer filename)))
1212               (kill-buffer file-buffer))
1213           (error "Output file does not exist")))
1214       (set-buffer tmpbuf)
1215       (erase-buffer)
1216       (insert-buffer-substring artbuf)
1217       (goto-char (point-min))
1218       (if (looking-at "From ")
1219           (forward-line 1)
1220         (insert "From nobody " (current-time-string) "\n"))
1221       (let (case-fold-search)
1222         (while (re-search-forward "^From " nil t)
1223           (beginning-of-line)
1224           (insert ">")))
1225       ;; Decide whether to append to a file or to an Emacs buffer.
1226       (let ((outbuf (get-file-buffer filename)))
1227         (if (not outbuf)
1228             (let ((buffer-read-only nil))
1229               (save-excursion
1230                 (goto-char (point-max))
1231                 (forward-char -2)
1232                 (unless (looking-at "\n\n")
1233                   (goto-char (point-max))
1234                   (unless (bolp)
1235                     (insert "\n"))
1236                   (insert "\n"))
1237                 (goto-char (point-max))
1238                 (let ((file-name-coding-system nnmail-pathname-coding-system))
1239                   (mm-append-to-file (point-min) (point-max) filename))))
1240           ;; File has been visited, in buffer OUTBUF.
1241           (set-buffer outbuf)
1242           (let ((buffer-read-only nil))
1243             (goto-char (point-max))
1244             (unless (eobp)
1245               (insert "\n"))
1246             (insert "\n")
1247             (insert-buffer-substring tmpbuf)))))
1248     (kill-buffer tmpbuf)))
1249
1250 (defun gnus-convert-article-to-rmail ()
1251   "Convert article in current buffer to Rmail message format."
1252   (let ((buffer-read-only nil))
1253     ;; Convert article directly into Babyl format.
1254     (goto-char (point-min))
1255     (insert "\^L\n0, unseen,,\n*** EOOH ***\n")
1256     (while (search-forward "\n\^_" nil t) ;single char
1257       (replace-match "\n^_" t t))       ;2 chars: "^" and "_"
1258     (goto-char (point-max))
1259     (insert "\^_")))
1260
1261 (defun gnus-map-function (funs arg)
1262   "Apply the result of the first function in FUNS to the second, and so on.
1263 ARG is passed to the first function."
1264   (while funs
1265     (setq arg (funcall (pop funs) arg)))
1266   arg)
1267
1268 (defun gnus-run-hooks (&rest funcs)
1269   "Does the same as `run-hooks', but saves the current buffer."
1270   (save-current-buffer
1271     (apply 'run-hooks funcs)))
1272
1273 (defun gnus-run-hook-with-args (hook &rest args)
1274   "Does the same as `run-hook-with-args', but saves the current buffer."
1275   (save-current-buffer
1276     (apply 'run-hook-with-args hook args)))
1277
1278 (defun gnus-run-mode-hooks (&rest funcs)
1279   "Run `run-mode-hooks' if it is available, otherwise `run-hooks'.
1280 This function saves the current buffer."
1281   (if (fboundp 'run-mode-hooks)
1282       (save-current-buffer (apply 'run-mode-hooks funcs))
1283     (save-current-buffer (apply 'run-hooks funcs))))
1284
1285 ;;; Various
1286
1287 (defvar gnus-group-buffer)              ; Compiler directive
1288 (defun gnus-alive-p ()
1289   "Say whether Gnus is running or not."
1290   (and (boundp 'gnus-group-buffer)
1291        (get-buffer gnus-group-buffer)
1292        (with-current-buffer gnus-group-buffer
1293          (eq major-mode 'gnus-group-mode))))
1294
1295 (defun gnus-remove-if (predicate sequence &optional hash-table-p)
1296   "Return a copy of SEQUENCE with all items satisfying PREDICATE removed.
1297 SEQUENCE should be a list, a vector, or a string.  Returns always a list.
1298 If HASH-TABLE-P is non-nil, regards SEQUENCE as a hash table."
1299   (let (out)
1300     (if hash-table-p
1301         (mapatoms (lambda (symbol)
1302                     (unless (funcall predicate symbol)
1303                       (push symbol out)))
1304                   sequence)
1305       (unless (listp sequence)
1306         (setq sequence (append sequence nil)))
1307       (while sequence
1308         (unless (funcall predicate (car sequence))
1309           (push (car sequence) out))
1310         (setq sequence (cdr sequence))))
1311     (nreverse out)))
1312
1313 (defun gnus-remove-if-not (predicate sequence &optional hash-table-p)
1314   "Return a copy of SEQUENCE with all items not satisfying PREDICATE removed.
1315 SEQUENCE should be a list, a vector, or a string.  Returns always a list.
1316 If HASH-TABLE-P is non-nil, regards SEQUENCE as a hash table."
1317   (let (out)
1318     (if hash-table-p
1319         (mapatoms (lambda (symbol)
1320                     (when (funcall predicate symbol)
1321                       (push symbol out)))
1322                   sequence)
1323       (unless (listp sequence)
1324         (setq sequence (append sequence nil)))
1325       (while sequence
1326         (when (funcall predicate (car sequence))
1327           (push (car sequence) out))
1328         (setq sequence (cdr sequence))))
1329     (nreverse out)))
1330
1331 (if (fboundp 'assq-delete-all)
1332     (defalias 'gnus-delete-alist 'assq-delete-all)
1333   (defun gnus-delete-alist (key alist)
1334     "Delete from ALIST all elements whose car is KEY.
1335 Return the modified alist."
1336     (let (entry)
1337       (while (setq entry (assq key alist))
1338         (setq alist (delq entry alist)))
1339       alist)))
1340
1341 (defun gnus-grep-in-list (word list)
1342   "Find if a WORD matches any regular expression in the given LIST."
1343   (when (and word list)
1344     (catch 'found
1345       (dolist (r list)
1346         (when (string-match r word)
1347           (throw 'found r))))))
1348
1349 (defmacro gnus-alist-pull (key alist &optional assoc-p)
1350   "Modify ALIST to be without KEY."
1351   (unless (symbolp alist)
1352     (error "Not a symbol: %s" alist))
1353   (let ((fun (if assoc-p 'assoc 'assq)))
1354     `(setq ,alist (delq (,fun ,key ,alist) ,alist))))
1355
1356 (defun gnus-globalify-regexp (re)
1357   "Return a regexp that matches a whole line, if RE matches a part of it."
1358   (concat (unless (string-match "^\\^" re) "^.*")
1359           re
1360           (unless (string-match "\\$$" re) ".*$")))
1361
1362 (defun gnus-set-window-start (&optional point)
1363   "Set the window start to POINT, or (point) if nil."
1364   (let ((win (gnus-get-buffer-window (current-buffer) t)))
1365     (when win
1366       (set-window-start win (or point (point))))))
1367
1368 (defun gnus-annotation-in-region-p (b e)
1369   (if (= b e)
1370       (eq (cadr (memq 'gnus-undeletable (text-properties-at b))) t)
1371     (text-property-any b e 'gnus-undeletable t)))
1372
1373 (defun gnus-or (&rest elems)
1374   "Return non-nil if any of the elements are non-nil."
1375   (catch 'found
1376     (while elems
1377       (when (pop elems)
1378         (throw 'found t)))))
1379
1380 (defun gnus-and (&rest elems)
1381   "Return non-nil if all of the elements are non-nil."
1382   (catch 'found
1383     (while elems
1384       (unless (pop elems)
1385         (throw 'found nil)))
1386     t))
1387
1388 ;; gnus.el requires mm-util.
1389 (declare-function mm-disable-multibyte "mm-util")
1390
1391 (defun gnus-write-active-file (file hashtb &optional full-names)
1392   ;; `coding-system-for-write' should be `raw-text' or equivalent.
1393   (let ((coding-system-for-write nnmail-active-file-coding-system))
1394     (with-temp-file file
1395       ;; The buffer should be in the unibyte mode because group names
1396       ;; are ASCII text or encoded non-ASCII text (i.e., unibyte).
1397       (mm-disable-multibyte)
1398       (mapatoms
1399        (lambda (sym)
1400          (when (and sym
1401                     (boundp sym)
1402                     (symbol-value sym))
1403            (insert (format "%S %d %d y\n"
1404                            (if full-names
1405                                sym
1406                              (intern (gnus-group-real-name (symbol-name sym))))
1407                            (or (cdr (symbol-value sym))
1408                                (car (symbol-value sym)))
1409                            (car (symbol-value sym))))))
1410        hashtb)
1411       (goto-char (point-max))
1412       (while (search-backward "\\." nil t)
1413         (delete-char 1)))))
1414
1415 ;; Fixme: Why not use `with-output-to-temp-buffer'?
1416 (defmacro gnus-with-output-to-file (file &rest body)
1417   (let ((buffer (make-symbol "output-buffer"))
1418         (size (make-symbol "output-buffer-size"))
1419         (leng (make-symbol "output-buffer-length"))
1420         (append (make-symbol "output-buffer-append")))
1421     `(let* ((,size 131072)
1422             (,buffer (make-string ,size 0))
1423             (,leng 0)
1424             (,append nil)
1425             (standard-output
1426              (lambda (c)
1427                (aset ,buffer ,leng c)
1428
1429                (if (= ,size (setq ,leng (1+ ,leng)))
1430                    (progn (write-region ,buffer nil ,file ,append 'no-msg)
1431                           (setq ,leng 0
1432                                 ,append t))))))
1433        ,@body
1434        (when (> ,leng 0)
1435          (let ((coding-system-for-write 'no-conversion))
1436          (write-region (substring ,buffer 0 ,leng) nil ,file
1437                        ,append 'no-msg))))))
1438
1439 (put 'gnus-with-output-to-file 'lisp-indent-function 1)
1440 (put 'gnus-with-output-to-file 'edebug-form-spec '(form body))
1441
1442 (if (fboundp 'union)
1443     (defalias 'gnus-union 'union)
1444   (defun gnus-union (l1 l2)
1445     "Set union of lists L1 and L2."
1446     (cond ((null l1) l2)
1447           ((null l2) l1)
1448           ((equal l1 l2) l1)
1449           (t
1450            (or (>= (length l1) (length l2))
1451                (setq l1 (prog1 l2 (setq l2 l1))))
1452            (while l2
1453              (or (member (car l2) l1)
1454                  (push (car l2) l1))
1455              (pop l2))
1456            l1))))
1457
1458 (declare-function gnus-add-text-properties "gnus"
1459                   (start end properties &optional object))
1460
1461 (defun gnus-add-text-properties-when
1462   (property value start end properties &optional object)
1463   "Like `gnus-add-text-properties', only applied on where PROPERTY is VALUE."
1464   (let (point)
1465     (while (and start
1466                 (< start end) ;; XEmacs will loop for every when start=end.
1467                 (setq point (text-property-not-all start end property value)))
1468       (gnus-add-text-properties start point properties object)
1469       (setq start (text-property-any point end property value)))
1470     (if start
1471         (gnus-add-text-properties start end properties object))))
1472
1473 (defun gnus-remove-text-properties-when
1474   (property value start end properties &optional object)
1475   "Like `remove-text-properties', only applied on where PROPERTY is VALUE."
1476   (let (point)
1477     (while (and start
1478                 (< start end)
1479                 (setq point (text-property-not-all start end property value)))
1480       (remove-text-properties start point properties object)
1481       (setq start (text-property-any point end property value)))
1482     (if start
1483         (remove-text-properties start end properties object))
1484     t))
1485
1486 (defun gnus-string-remove-all-properties (string)
1487   (condition-case ()
1488       (let ((s string))
1489         (set-text-properties 0 (length string) nil string)
1490         s)
1491     (error string)))
1492
1493 ;; This might use `compare-strings' to reduce consing in the
1494 ;; case-insensitive case, but it has to cope with null args.
1495 ;; (`string-equal' uses symbol print names.)
1496 (defun gnus-string-equal (x y)
1497   "Like `string-equal', except it compares case-insensitively."
1498   (and (= (length x) (length y))
1499        (or (string-equal x y)
1500            (string-equal (downcase x) (downcase y)))))
1501
1502 (defcustom gnus-use-byte-compile t
1503   "If non-nil, byte-compile crucial run-time code.
1504 Setting it to nil has no effect after the first time `gnus-byte-compile'
1505 is run."
1506   :type 'boolean
1507   :version "22.1"
1508   :group 'gnus-various)
1509
1510 (defun gnus-byte-compile (form)
1511   "Byte-compile FORM if `gnus-use-byte-compile' is non-nil."
1512   (if gnus-use-byte-compile
1513       (progn
1514         (condition-case nil
1515             ;; Work around a bug in XEmacs 21.4
1516             (require 'byte-optimize)
1517           (error))
1518         (require 'bytecomp)
1519         (defalias 'gnus-byte-compile
1520           (lambda (form)
1521             (let ((byte-compile-warnings '(unresolved callargs redefine)))
1522               (byte-compile form))))
1523         (gnus-byte-compile form))
1524     form))
1525
1526 (defun gnus-remassoc (key alist)
1527   "Delete by side effect any elements of LIST whose car is `equal' to KEY.
1528 The modified LIST is returned.  If the first member
1529 of LIST has a car that is `equal' to KEY, there is no way to remove it
1530 by side effect; therefore, write `(setq foo (gnus-remassoc key foo))' to be
1531 sure of changing the value of `foo'."
1532   (when alist
1533     (if (equal key (caar alist))
1534         (cdr alist)
1535       (setcdr alist (gnus-remassoc key (cdr alist)))
1536       alist)))
1537
1538 (defun gnus-update-alist-soft (key value alist)
1539   (if value
1540       (cons (cons key value) (gnus-remassoc key alist))
1541     (gnus-remassoc key alist)))
1542
1543 (defun gnus-create-info-command (node)
1544   "Create a command that will go to info NODE."
1545   `(lambda ()
1546      (interactive)
1547      ,(concat "Enter the info system at node " node)
1548      (Info-goto-node ,node)
1549      (setq gnus-info-buffer (current-buffer))
1550      (gnus-configure-windows 'info)))
1551
1552 (defun gnus-not-ignore (&rest args)
1553   t)
1554
1555 (defvar gnus-directory-sep-char-regexp "/"
1556   "The regexp of directory separator character.
1557 If you find some problem with the directory separator character, try
1558 \"[/\\\\\]\" for some systems.")
1559
1560 (defun gnus-url-unhex (x)
1561   (if (> x ?9)
1562       (if (>= x ?a)
1563           (+ 10 (- x ?a))
1564         (+ 10 (- x ?A)))
1565     (- x ?0)))
1566
1567 ;; Fixme: Do it like QP.
1568 (defun gnus-url-unhex-string (str &optional allow-newlines)
1569   "Remove %XX, embedded spaces, etc in a url.
1570 If optional second argument ALLOW-NEWLINES is non-nil, then allow the
1571 decoding of carriage returns and line feeds in the string, which is normally
1572 forbidden in URL encoding."
1573   (let ((tmp "")
1574         (case-fold-search t))
1575     (while (string-match "%[0-9a-f][0-9a-f]" str)
1576       (let* ((start (match-beginning 0))
1577              (ch1 (gnus-url-unhex (elt str (+ start 1))))
1578              (code (+ (* 16 ch1)
1579                       (gnus-url-unhex (elt str (+ start 2))))))
1580         (setq tmp (concat
1581                    tmp (substring str 0 start)
1582                    (cond
1583                     (allow-newlines
1584                      (char-to-string code))
1585                     ((or (= code ?\n) (= code ?\r))
1586                      " ")
1587                     (t (char-to-string code))))
1588               str (substring str (match-end 0)))))
1589     (setq tmp (concat tmp str))
1590     tmp))
1591
1592 (defun gnus-make-predicate (spec)
1593   "Transform SPEC into a function that can be called.
1594 SPEC is a predicate specifier that contains stuff like `or', `and',
1595 `not', lists and functions.  The functions all take one parameter."
1596   `(lambda (elem) ,(gnus-make-predicate-1 spec)))
1597
1598 (defun gnus-make-predicate-1 (spec)
1599   (cond
1600    ((symbolp spec)
1601     `(,spec elem))
1602    ((listp spec)
1603     (if (memq (car spec) '(or and not))
1604         `(,(car spec) ,@(mapcar 'gnus-make-predicate-1 (cdr spec)))
1605       (error "Invalid predicate specifier: %s" spec)))))
1606
1607 (defun gnus-completing-read (prompt collection &optional require-match
1608                                     initial-input history def)
1609   "Call `gnus-completing-read-function'."
1610   (funcall gnus-completing-read-function
1611            (concat prompt (when def
1612                             (concat " (default " def ")"))
1613                    ": ")
1614            collection require-match initial-input history def))
1615
1616 (defun gnus-emacs-completing-read (prompt collection &optional require-match
1617                                           initial-input history def)
1618   "Call standard `completing-read-function'."
1619   (let ((completion-styles gnus-completion-styles))
1620     (completing-read prompt
1621                      ;; Old XEmacs (at least 21.4) expect an alist for
1622                      ;; collection.
1623                      (mapcar 'list collection)
1624                      nil require-match initial-input history def)))
1625
1626 (autoload 'ido-completing-read "ido")
1627 (defun gnus-ido-completing-read (prompt collection &optional require-match
1628                                         initial-input history def)
1629   "Call `ido-completing-read-function'."
1630   (ido-completing-read prompt collection nil require-match
1631                        initial-input history def))
1632
1633
1634 (declare-function iswitchb-read-buffer "iswitchb"
1635                   (prompt &optional default require-match start matches-set))
1636 (defvar iswitchb-temp-buflist)
1637
1638 (defun gnus-iswitchb-completing-read (prompt collection &optional require-match
1639                                             initial-input history def)
1640   "`iswitchb' based completing-read function."
1641   ;; Make sure iswitchb is loaded before we let-bind its variables.
1642   ;; If it is loaded inside the let, variables can become unbound afterwards.
1643   (require 'iswitchb)
1644   (let ((iswitchb-make-buflist-hook
1645          (lambda ()
1646            (setq iswitchb-temp-buflist
1647                  (let ((choices (append
1648                                  (when initial-input (list initial-input))
1649                                  (symbol-value history) collection))
1650                        filtered-choices)
1651                    (dolist (x choices)
1652                      (setq filtered-choices (adjoin x filtered-choices)))
1653                    (nreverse filtered-choices))))))
1654     (unwind-protect
1655         (progn
1656           (or iswitchb-mode
1657               (add-hook 'minibuffer-setup-hook 'iswitchb-minibuffer-setup))
1658           (iswitchb-read-buffer prompt def require-match))
1659       (or iswitchb-mode
1660           (remove-hook 'minibuffer-setup-hook 'iswitchb-minibuffer-setup)))))
1661
1662 (defun gnus-graphic-display-p ()
1663   (if (featurep 'xemacs)
1664       (device-on-window-system-p)
1665     (display-graphic-p)))
1666
1667 (put 'gnus-parse-without-error 'lisp-indent-function 0)
1668 (put 'gnus-parse-without-error 'edebug-form-spec '(body))
1669
1670 (defmacro gnus-parse-without-error (&rest body)
1671   "Allow continuing onto the next line even if an error occurs."
1672   `(while (not (eobp))
1673      (condition-case ()
1674          (progn
1675            ,@body
1676            (goto-char (point-max)))
1677        (error
1678         (gnus-error 4 "Invalid data on line %d"
1679                     (count-lines (point-min) (point)))
1680         (forward-line 1)))))
1681
1682 (defun gnus-cache-file-contents (file variable function)
1683   "Cache the contents of FILE in VARIABLE.  The contents come from FUNCTION."
1684   (let ((time (nth 5 (file-attributes file)))
1685         contents value)
1686     (if (or (null (setq value (symbol-value variable)))
1687             (not (equal (car value) file))
1688             (not (equal (nth 1 value) time)))
1689         (progn
1690           (setq contents (funcall function file))
1691           (set variable (list file time contents))
1692           contents)
1693       (nth 2 value))))
1694
1695 (defun gnus-multiple-choice (prompt choice &optional idx)
1696   "Ask user a multiple choice question.
1697 CHOICE is a list of the choice char and help message at IDX."
1698   (let (tchar buf)
1699     (save-window-excursion
1700       (save-excursion
1701         (while (not tchar)
1702           (message "%s (%s): "
1703                    prompt
1704                    (concat
1705                     (mapconcat (lambda (s) (char-to-string (car s)))
1706                                choice ", ") ", ?"))
1707           (setq tchar (read-char))
1708           (when (not (assq tchar choice))
1709             (setq tchar nil)
1710             (setq buf (get-buffer-create "*Gnus Help*"))
1711             (pop-to-buffer buf)
1712             (fundamental-mode)          ; for Emacs 20.4+
1713             (buffer-disable-undo)
1714             (erase-buffer)
1715             (insert prompt ":\n\n")
1716             (let ((max -1)
1717                   (list choice)
1718                   (alist choice)
1719                   (idx (or idx 1))
1720                   (i 0)
1721                   n width pad format)
1722               ;; find the longest string to display
1723               (while list
1724                 (setq n (length (nth idx (car list))))
1725                 (unless (> max n)
1726                   (setq max n))
1727                 (setq list (cdr list)))
1728               (setq max (+ max 4))      ; %c, `:', SPACE, a SPACE at end
1729               (setq n (/ (1- (window-width)) max)) ; items per line
1730               (setq width (/ (1- (window-width)) n)) ; width of each item
1731               ;; insert `n' items, each in a field of width `width'
1732               (while alist
1733                 (if (< i n)
1734                     ()
1735                   (setq i 0)
1736                   (delete-char -1)              ; the `\n' takes a char
1737                   (insert "\n"))
1738                 (setq pad (- width 3))
1739                 (setq format (concat "%c: %-" (int-to-string pad) "s"))
1740                 (insert (format format (caar alist) (nth idx (car alist))))
1741                 (setq alist (cdr alist))
1742                 (setq i (1+ i))))))))
1743     (if (buffer-live-p buf)
1744         (kill-buffer buf))
1745     tchar))
1746
1747 (if (featurep 'emacs)
1748     (defalias 'gnus-select-frame-set-input-focus 'select-frame-set-input-focus)
1749   (if (fboundp 'select-frame-set-input-focus)
1750       (defalias 'gnus-select-frame-set-input-focus 'select-frame-set-input-focus)
1751     ;; XEmacs 21.4, SXEmacs
1752     (defun gnus-select-frame-set-input-focus (frame)
1753       "Select FRAME, raise it, and set input focus, if possible."
1754       (raise-frame frame)
1755       (select-frame frame)
1756       (focus-frame frame))))
1757
1758 (defun gnus-frame-or-window-display-name (object)
1759   "Given a frame or window, return the associated display name.
1760 Return nil otherwise."
1761   (if (featurep 'xemacs)
1762       (device-connection (dfw-device object))
1763     (if (or (framep object)
1764             (and (windowp object)
1765                  (setq object (window-frame object))))
1766         (let ((display (frame-parameter object 'display)))
1767           (if (and (stringp display)
1768                    ;; Exclude invalid display names.
1769                    (string-match "\\`[^:]*:[0-9]+\\(\\.[0-9]+\\)?\\'"
1770                                  display))
1771               display)))))
1772
1773 (defvar tool-bar-mode)
1774
1775 (defun gnus-tool-bar-update (&rest ignore)
1776   "Update the tool bar."
1777   (when (and (boundp 'tool-bar-mode)
1778              tool-bar-mode)
1779     (let* ((args nil)
1780            (func (cond ((featurep 'xemacs)
1781                         'ignore)
1782                        ((fboundp 'tool-bar-update)
1783                         'tool-bar-update)
1784                        ((fboundp 'force-window-update)
1785                         'force-window-update)
1786                        ((fboundp 'redraw-frame)
1787                         (setq args (list (selected-frame)))
1788                         'redraw-frame)
1789                        (t 'ignore))))
1790       (apply func args))))
1791
1792 ;; Fixme: This has only one use (in gnus-agent), which isn't worthwhile.
1793 (defmacro gnus-mapcar (function seq1 &rest seqs2_n)
1794   "Apply FUNCTION to each element of the sequences, and make a list of the results.
1795 If there are several sequences, FUNCTION is called with that many arguments,
1796 and mapping stops as soon as the shortest sequence runs out.  With just one
1797 sequence, this is like `mapcar'.  With several, it is like the Common Lisp
1798 `mapcar' function extended to arbitrary sequence types."
1799
1800   (if seqs2_n
1801       (let* ((seqs (cons seq1 seqs2_n))
1802              (cnt 0)
1803              (heads (mapcar (lambda (seq)
1804                               (make-symbol (concat "head"
1805                                                    (int-to-string
1806                                                     (setq cnt (1+ cnt))))))
1807                             seqs))
1808              (result (make-symbol "result"))
1809              (result-tail (make-symbol "result-tail")))
1810         `(let* ,(let* ((bindings (cons nil nil))
1811                        (heads heads))
1812                   (nconc bindings (list (list result '(cons nil nil))))
1813                   (nconc bindings (list (list result-tail result)))
1814                   (while heads
1815                     (nconc bindings (list (list (pop heads) (pop seqs)))))
1816                   (cdr bindings))
1817            (while (and ,@heads)
1818              (setcdr ,result-tail (cons (funcall ,function
1819                                                  ,@(mapcar (lambda (h) (list 'car h))
1820                                                            heads))
1821                                         nil))
1822              (setq ,result-tail (cdr ,result-tail)
1823                    ,@(apply 'nconc (mapcar (lambda (h) (list h (list 'cdr h))) heads))))
1824            (cdr ,result)))
1825     `(mapcar ,function ,seq1)))
1826
1827 (if (fboundp 'merge)
1828     (defalias 'gnus-merge 'merge)
1829   ;; Adapted from cl-seq.el
1830   (defun gnus-merge (type list1 list2 pred)
1831     "Destructively merge lists LIST1 and LIST2 to produce a new list.
1832 Argument TYPE is for compatibility and ignored.
1833 Ordering of the elements is preserved according to PRED, a `less-than'
1834 predicate on the elements."
1835     (let ((res nil))
1836       (while (and list1 list2)
1837         (if (funcall pred (car list2) (car list1))
1838             (push (pop list2) res)
1839           (push (pop list1) res)))
1840       (nconc (nreverse res) list1 list2))))
1841
1842 (defvar xemacs-codename)
1843 (defvar sxemacs-codename)
1844 (defvar emacs-program-version)
1845
1846 (defun gnus-emacs-version ()
1847   "Stringified Emacs version."
1848   (let* ((lst (if (listp gnus-user-agent)
1849                   gnus-user-agent
1850                 '(gnus emacs type)))
1851          (system-v (cond ((memq 'config lst)
1852                           system-configuration)
1853                          ((memq 'type lst)
1854                           (symbol-name system-type))
1855                          (t nil)))
1856          codename emacsname)
1857     (cond ((featurep 'sxemacs)
1858            (setq emacsname "SXEmacs"
1859                  codename sxemacs-codename))
1860           ((featurep 'xemacs)
1861            (setq emacsname "XEmacs"
1862                  codename xemacs-codename))
1863           (t
1864            (setq emacsname "Emacs")))
1865     (cond
1866      ((not (memq 'emacs lst))
1867       nil)
1868      ((string-match "^\\(\\([.0-9]+\\)*\\)\\.[0-9]+$" emacs-version)
1869       ;; Emacs:
1870       (concat "Emacs/" (match-string 1 emacs-version)
1871               (if system-v
1872                   (concat " (" system-v ")")
1873                 "")))
1874      ((or (featurep 'sxemacs) (featurep 'xemacs))
1875       ;; XEmacs or SXEmacs:
1876       (concat emacsname "/" emacs-program-version
1877               (let (plst)
1878                 (when (memq 'codename lst)
1879                   (push codename plst))
1880                 (when system-v
1881                   (push system-v plst))
1882                 (unless (featurep 'mule)
1883                   (push "no MULE" plst))
1884                 (when (> (length plst) 0)
1885                   (concat
1886                    " (" (mapconcat 'identity (reverse plst) ", ") ")")))))
1887      (t emacs-version))))
1888
1889 (defun gnus-rename-file (old-path new-path &optional trim)
1890   "Rename OLD-PATH as NEW-PATH.  If TRIM, recursively delete
1891 empty directories from OLD-PATH."
1892   (when (file-exists-p old-path)
1893     (let* ((old-dir (file-name-directory old-path))
1894            (old-name (file-name-nondirectory old-path))
1895            (new-dir (file-name-directory new-path))
1896            (new-name (file-name-nondirectory new-path))
1897            temp)
1898       (gnus-make-directory new-dir)
1899       (rename-file old-path new-path t)
1900       (when trim
1901         (while (progn (setq temp (directory-files old-dir))
1902                       (while (member (car temp) '("." ".."))
1903                         (setq temp (cdr temp)))
1904                       (= (length temp) 0))
1905           (delete-directory old-dir)
1906           (setq old-dir (file-name-as-directory
1907                          (file-truename
1908                           (concat old-dir "..")))))))))
1909
1910 (defun gnus-set-file-modes (filename mode)
1911   "Wrapper for set-file-modes."
1912   (ignore-errors
1913     (set-file-modes filename mode)))
1914
1915 (if (fboundp 'set-process-query-on-exit-flag)
1916     (defalias 'gnus-set-process-query-on-exit-flag
1917       'set-process-query-on-exit-flag)
1918   (defalias 'gnus-set-process-query-on-exit-flag
1919     'process-kill-without-query))
1920
1921 (defalias 'gnus-read-shell-command
1922   (if (fboundp 'read-shell-command) 'read-shell-command 'read-string))
1923
1924 (defmacro gnus-put-display-table (range value display-table)
1925   "Set the value for char RANGE to VALUE in DISPLAY-TABLE.  "
1926   (if (featurep 'xemacs)
1927       (progn
1928         `(if (fboundp 'put-display-table)
1929           (put-display-table ,range ,value ,display-table)
1930           (if (sequencep ,display-table)
1931               (aset ,display-table ,range ,value)
1932             (put-char-table ,range ,value ,display-table))))
1933     `(aset ,display-table ,range ,value)))
1934
1935 (defmacro gnus-get-display-table (character display-table)
1936   "Find value for CHARACTER in DISPLAY-TABLE.  "
1937   (if (featurep 'xemacs)
1938       `(if (fboundp 'get-display-table)
1939           (get-display-table ,character ,display-table)
1940           (if (sequencep ,display-table)
1941               (aref ,display-table ,character)
1942             (get-char-table ,character ,display-table)))
1943     `(aref ,display-table ,character)))
1944
1945 (defun gnus-rescale-image (image size)
1946   "Rescale IMAGE to SIZE if possible.
1947 SIZE is in format (WIDTH . HEIGHT). Return a new image.
1948 Sizes are in pixels."
1949   (if (or (not (fboundp 'imagemagick-types))
1950           (not (get-buffer-window (current-buffer))))
1951       image
1952     (let ((new-width (car size))
1953           (new-height (cdr size)))
1954       (when (> (cdr (image-size image t)) new-height)
1955         (setq image (or (create-image (plist-get (cdr image) :data) 'imagemagick t
1956                                       :height new-height)
1957                         image)))
1958       (when (> (car (image-size image t)) new-width)
1959         (setq image (or
1960                    (create-image (plist-get (cdr image) :data) 'imagemagick t
1961                                  :width new-width)
1962                    image)))
1963       image)))
1964
1965 (defun gnus-list-memq-of-list (elements list)
1966   "Return non-nil if any of the members of ELEMENTS are in LIST."
1967   (let ((found nil))
1968     (dolist (elem elements)
1969       (setq found (or found
1970                       (memq elem list))))
1971     found))
1972
1973 (eval-and-compile
1974   (cond
1975    ((fboundp 'match-substitute-replacement)
1976     (defalias 'gnus-match-substitute-replacement 'match-substitute-replacement))
1977    (t
1978     (defun gnus-match-substitute-replacement (replacement &optional fixedcase literal string subexp)
1979       "Return REPLACEMENT as it will be inserted by `replace-match'.
1980 In other words, all back-references in the form `\\&' and `\\N'
1981 are substituted with actual strings matched by the last search.
1982 Optional FIXEDCASE, LITERAL, STRING and SUBEXP have the same
1983 meaning as for `replace-match'.
1984
1985 This is the definition of match-substitute-replacement in subr.el from GNU Emacs."
1986       (let ((match (match-string 0 string)))
1987         (save-match-data
1988           (set-match-data (mapcar (lambda (x)
1989                                     (if (numberp x)
1990                                         (- x (match-beginning 0))
1991                                       x))
1992                                   (match-data t)))
1993           (replace-match replacement fixedcase literal match subexp)))))))
1994
1995 (if (fboundp 'string-match-p)
1996     (defalias 'gnus-string-match-p 'string-match-p)
1997   (defsubst gnus-string-match-p (regexp string &optional start)
1998     "\
1999 Same as `string-match' except this function does not change the match data."
2000     (save-match-data
2001       (string-match regexp string start))))
2002
2003 (eval-and-compile
2004   (if (fboundp 'macroexpand-all)
2005       (defalias 'gnus-macroexpand-all 'macroexpand-all)
2006     (defun gnus-macroexpand-all (form &optional environment)
2007       "Return result of expanding macros at all levels in FORM.
2008 If no macros are expanded, FORM is returned unchanged.
2009 The second optional arg ENVIRONMENT specifies an environment of macro
2010 definitions to shadow the loaded ones for use in file byte-compilation."
2011       (if (consp form)
2012           (let ((idx 1)
2013                 (len (length (setq form (copy-sequence form))))
2014                 expanded)
2015             (while (< idx len)
2016               (setcar (nthcdr idx form) (gnus-macroexpand-all (nth idx form)
2017                                                               environment))
2018               (setq idx (1+ idx)))
2019             (if (eq (setq expanded (macroexpand form environment)) form)
2020                 form
2021               (gnus-macroexpand-all expanded environment)))
2022         form))))
2023
2024 (provide 'gnus-util)
2025
2026 ;;; gnus-util.el ends here