m4/acosf.m4

   1 # acosf.m4
   2 # serial 4
   3 dnl Copyright (C) 2011-2024 Free Software Foundation, Inc.
   4 dnl This file is free software; the Free Software Foundation
   5 dnl gives unlimited permission to copy and/or distribute it,
   6 dnl with or without modifications, as long as this notice is preserved.
   7
   8 AC_DEFUN([gl_FUNC_ACOSF],
   9 [
  10   AC_REQUIRE([gl_MATH_H_DEFAULTS])
  11   AC_REQUIRE([gl_FUNC_ACOS])
  12
  13   dnl Persuade glibc <math.h> to declare acosf().
  14   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  15
  16   dnl Test whether acosf() exists. Assume that acosf(), if it exists, is
  17   dnl defined in the same library as acos().
  18   saved_LIBS="$LIBS"
  19   LIBS="$LIBS $ACOS_LIBM"
  20   AC_CHECK_FUNCS([acosf])
  21   LIBS="$saved_LIBS"
  22   if test $ac_cv_func_acosf = yes; then
  23     ACOSF_LIBM="$ACOS_LIBM"
  24   else
  25     HAVE_ACOSF=0
  26     dnl If the function is declared but does not appear to exist, it may be
  27     dnl defined as an inline function. In order to avoid a conflict, we have
  28     dnl to define rpl_acosf, not acosf.
  29     AC_CHECK_DECLS([acosf], [REPLACE_ACOSF=1], , [[#include <math.h>]])
  30     ACOSF_LIBM="$ACOS_LIBM"
  31   fi
  32   AC_SUBST([ACOSF_LIBM])
  33 ])